digispark-with-cable.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 //tongue_w = 11.92 + 0.4;
   6
   7 usb_w = 12.01 + 0.19;
   8 usb_wall_w = 0.51;
   9 usb_tongue_d = 8.97 - 0.2;
  10 usb_tongue_w_slop = +0.5;
  11 usb_wall_h = 4.54 - 2.04;
  12 usb_ceil_th = 0.425;
  13
  14 side_wall_th = 1.5; // XXXX rename wall_th
  15
  16 board_l = 17.56 + 0.2;
  17 board_w = 19.14 + 0.2;
  18 board_th = 1.92 + 0.1;
  19
  20 sw_to_edge = board_w/2 + 0.1;
  21
  22 front_wall_th = 0.75;
  23 // egress_w = 8.0;
  24
  25 wall_y_min = -board_l - side_wall_th; // XXXX remove
  26 ceil_y_min = wall_y_min - 5;;
  27
  28 small_walls = [
  29                [ [0, 0], [-sw_to_edge, -1.0] ],
  30                [ [sw_to_edge-4.5, -4.5], [sw_to_edge, -5.7] ],
  31 //             [ [3.0, -11.72],              [sw_to_edge, -13.38] ],
  32                [ [-sw_to_edge+3.85, -14.90], [sw_to_edge, -13.38] ],
  33                ];
  34 chip_cutout = [[ -sw_to_edge + 4.20,    -3.75 ],
  35                [ -sw_to_edge + 11.95,  -11.90 ]];
  36
  37 strain_w = 2.0 + 0.5;
  38 strain_t = 1.0 + 0.5;
  39 strain_pitch_across = 5;
  40 strain_pitch_along = 10;
  41 strain_groove_d = 2;
  42 strain_groove_w = 3;
  43
  44 cover_strap_c_d_y = 5.5; // from front of board
  45 cover_registration_sz_y = 2;
  46 cover_registration_sz_z = 3;
  47
  48 cable_space_z = 6;
  49 cable_dia = 5;
  50 bottom_floor_th = 1.5;
  51
  52 fit_gap_z = 0.5;
  53 fit_gap_y = 0.25;
  54 side_x_gap = 0.5;
  55
  56 cover_ceil_th = 0.9;
  57
  58 cover_strap_sz_x = side_wall_th * 3.5;
  59
  60 // calculated
  61
  62 strap_w = strain_w;
  63 cover_strap_cutout_z = side_wall_th;
  64
  65 top_top_z = usb_wall_h;
  66 top_base_z = -board_th;
  67 bottom_base_z = top_base_z - cable_space_z - bottom_floor_th;;
  68
  69 front_y_max = front_wall_th;
  70 main_y_min = -board_l - side_wall_th;
  71
  72 strain_0_y_c = main_y_min - strain_w/2;
  73 strain_1_y_c = strain_0_y_c - strain_pitch_along;
  74 total_y_min = strain_1_y_c - strain_w/2 - side_wall_th;
  75
  76 bottom_wall_top_z = (top_top_z + top_base_z) * 0.5 - fit_gap_z/2;
  77 cover_wall_bot_z  = (top_top_z + top_base_z) * 0.5 + fit_gap_z/2;
  78 cover_top_z  = top_top_z + cover_ceil_th;
  79
  80 top_side_wall_x = +board_w/2 + side_wall_th;
  81 total_side_wall_x = top_side_wall_x + side_wall_th + side_x_gap;
  82
  83 cover_registration_c_dy = -cover_strap_c_d_y - strap_w/2
  84   - side_wall_th - cover_registration_sz_y/2;
  85
  86 module BothSides(){
  87   for (m=[0,1]) {
  88     mirror([m,0,0]) {
  89       children();
  90     }
  91   }
  92 }
  93
  94 module NormalStrapCutouts(y_c, z, rot){
  95   BothSides(){
  96     translate([ -total_side_wall_x, y_c, z ])
  97       rotate([0, rot, 0])
  98       cube([ side_wall_th,
  99              strap_w,
 100              10 ],
 101            center=true);
 102   }
 103 }
 104 module BottomStrapCutouts(y_c){
 105   NormalStrapCutouts(y_c, bottom_base_z, -45);
 106 }
 107 // XXXX need rear strap
 108 // XXXX need bottom-to-top registration
 109 module CoverStrapCutouts(){
 110   BothSides(){
 111     translate([ -total_side_wall_x, -cover_strap_c_d_y, cover_top_z ])
 112       cube([ cover_strap_sz_x*2,
 113              strap_w,
 114              cover_strap_cutout_z*2 ],
 115            center=true);
 116   }
 117 }
 118
 119 module FrontWallsPlan(slop) {
 120   BothSides(){
 121     rectfromto([ -board_w/2 - side_wall_th,    0             ],
 122                [ -usb_w/2 - slop,              front_wall_th ]);
 123   }
 124 }
 125 module TopSmallWallsPlan() {
 126   for (m=[0,1]) {
 127     mirror([m,0]) {
 128       rectfromto([ -usb_w/2,              -0.01        ],
 129                  [ -usb_w/2 + usb_wall_w, usb_tongue_d ]);
 130     }
 131   }
 132   FrontWallsPlan(0);
 133   for (w=small_walls) {
 134     rectfromto(w[0], w[1]);
 135   }
 136 }
 137 module TopCeilPlan() {
 138   difference(){
 139     BothSides(){
 140       rectfromto([ -usb_w/2,              -0.01        ],
 141                  [ 0.1,                   usb_tongue_d ]);
 142       rectfromto([ -board_w/2 - side_wall_th, 0            ],
 143                  [ 0.1,                       ceil_y_min   ]);
 144     }
 145     rectfromto(chip_cutout[0], chip_cutout[1]);
 146   }
 147 }
 148 module TopMainWallsPlan() {
 149   BothSides(){
 150     rectfromto([ -board_w/2 - side_wall_th, 0          ],
 151                [ -board_w/2,                wall_y_min ]);
 152   }
 153   FrontWallsPlan(usb_tongue_w_slop);
 154   rectfromto([ -board_w/2 - side_wall_th + 0, -      board_l   ],
 155              [ +board_w/2 + side_wall_th,            total_y_min ]);
 156 }
 157
 158 module CoverRegistrations(){
 159   linextr_y_xz(cover_registration_c_dy - strap_w/2,
 160                cover_registration_c_dy + strap_w/2) {
 161     difference(){
 162       rectfromto([ -total_side_wall_x,
 163                           cover_wall_bot_z - cover_registration_sz_z  ],
 164                  [ +total_side_wall_x, cover_top_z ]);
 165       hull(){
 166         TopElevationForCutout();
 167         translate([0, -20]) TopElevationForCutout();
 168       }
 169     }
 170   }
 171 }
 172
 173 module Top(){ ////toplevel
 174   difference(){
 175     union(){
 176       linextr(0, usb_wall_h)
 177         TopSmallWallsPlan();
 178       linextr(usb_wall_h - usb_ceil_th, usb_wall_h)
 179         TopCeilPlan();
 180       linextr(-board_th, usb_wall_h)
 181         TopMainWallsPlan();
 182       BothSides()
 183         linextr(cover_wall_bot_z, top_top_z)
 184         rectfromto([ -(board_w/2 + 0.1),  total_y_min             ],
 185                    [ -total_side_wall_x,  main_y_min - fit_gap_y  ]);
 186     }
 187
 188     for (y_c = [strain_0_y_c, strain_1_y_c]) {
 189       for (x_c = [-1,+1] * strain_pitch_across/2) {
 190         translate([x_c, y_c, 0])
 191           linextr(-20, 20)
 192           square([ strain_t, strain_w ], center=true);
 193       }
 194     }
 195     linextr_y_xz(total_y_min-1, main_y_min)
 196       translate([0, top_base_z])
 197       scale([1, strain_groove_d/strain_groove_w])
 198       circle(strain_groove_w/2, $fn = 8);
 199   }
 200 }
 201
 202 module TopElevationForCutout(){
 203     rectfromto([ -(top_side_wall_x + side_x_gap), top_base_z ],
 204                [ +(top_side_wall_x + side_x_gap), top_top_z  ]);
 205 }
 206 module BottomMainElevation(){
 207   difference(){
 208     rectfromto([ -total_side_wall_x, bottom_base_z        ],
 209                [ +total_side_wall_x, bottom_wall_top_z    ]);
 210
 211     TopElevationForCutout();
 212   }
 213 }
 214 module Bottom(){ ////toplevel
 215   difference(){
 216     union(){
 217       linextr_y_xz(total_y_min, front_y_max)
 218         BottomMainElevation();
 219     }
 220
 221     linextr_y_xz(total_y_min + side_wall_th,
 222                  front_y_max - side_wall_th)
 223       rectfromto([ -board_w/2, bottom_base_z + bottom_floor_th ],
 224                  [ +board_w/2, 20         ]);
 225
 226     linextr_y_xz(total_y_min - 1,
 227                  total_y_min + side_wall_th + 1){
 228       translate([ 0, top_base_z ]){
 229         hull(){
 230           translate([ 0, -cable_dia/2 ])
 231             circle(r = cable_dia/2, $fa = 10, $fs = 1);
 232           square([ cable_dia, 0.1 ], center=true);
 233         }
 234       }
 235     }
 236     minkowski(){
 237       CoverRegistrations();
 238       cube([ 1, fit_gap_y*2, fit_gap_z*2 ], center=true);
 239     }
 240     BottomStrapCutouts(-cover_strap_c_d_y);
 241   }
 242 }
 243
 244 module CoverMainElevation(){
 245   difference(){
 246     rectfromto([ -total_side_wall_x, cover_wall_bot_z        ],
 247                [ +total_side_wall_x, cover_top_z    ]);
 248
 249     TopElevationForCutout();
 250   }
 251 }
 252 module Cover(){ ////toplevel
 253   difference(){
 254     union(){
 255       linextr_y_xz(main_y_min, front_y_max)
 256         CoverMainElevation();
 257       CoverRegistrations();
 258     }
 259     CoverStrapCutouts();
 260   }
 261 }
 262
 263 module BottomDemo(){ ////toplevel
 264   translate([0, 0, -0.25]) Bottom();
 265   %Top();
 266   translate([0, 0, +0.25]) Cover();
 267 }