configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[15],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  31
  32 AM_SILENT_RULES([yes])
  33
  34 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  35
  36 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  37         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  38         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  39 ])
  40
  41 AC_PROG_MKDIR_P
  42 AC_PROG_LN_S
  43 AC_PROG_SED
  44
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47 AM_PROG_CC_C_O
  48 AC_PROG_GCC_TRADITIONAL
  49 AC_USE_SYSTEM_EXTENSIONS
  50
  51 AC_CHECK_TOOL(OBJCOPY, objcopy)
  52 AC_CHECK_TOOL(STRINGS, strings)
  53
  54 CC_CHECK_CFLAGS_APPEND([ \
  55         -pipe \
  56         -Wall \
  57         -W \
  58         -Wextra \
  59         -Wno-inline \
  60         -Wvla \
  61         -Wundef \
  62         -Wformat=2 \
  63         -Wlogical-op \
  64         -Wsign-compare \
  65         -Wformat-security \
  66         -Wmissing-include-dirs \
  67         -Wformat-nonliteral \
  68         -Wold-style-definition \
  69         -Wpointer-arith \
  70         -Winit-self \
  71         -Wdeclaration-after-statement \
  72         -Wfloat-equal \
  73         -Wmissing-prototypes \
  74         -Wstrict-prototypes \
  75         -Wredundant-decls \
  76         -Wmissing-declarations \
  77         -Wmissing-noreturn \
  78         -Wshadow \
  79         -Wendif-labels \
  80         -Wcast-align \
  81         -Wstrict-aliasing=2 \
  82         -Wwrite-strings \
  83         -Wno-long-long \
  84         -Wno-overlength-strings \
  85         -Wno-unused-parameter \
  86         -Wno-missing-field-initializers \
  87         -Wno-unused-result \
  88         -Wp,-D_FORTIFY_SOURCE=2 \
  89         -ffast-math \
  90         -fno-common \
  91         -fdiagnostics-show-option \
  92         -fno-strict-aliasing \
  93         -fvisibility=hidden \
  94         -ffunction-sections \
  95         -fdata-sections \
  96         -Wl,--as-needed \
  97         -Wl,--gc-sections])
  98
  99 LT_PREREQ(2.2)
 100 LT_INIT
 101
 102 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 103 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 104 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 105 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 106
 107 # This makes sure pkg.m4 is available.
 108 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 109
 110 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
 111 AC_SUBST(UDEV_CFLAGS)
 112 AC_SUBST(UDEV_LIBS)
 113
 114 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 115 AC_SUBST(DBUS_CFLAGS)
 116 AC_SUBST(DBUS_LIBS)
 117
 118 have_selinux=no
 119 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 120 if test "x$enable_selinux" != "xno"; then
 121         # not using PKG_CHECK_MODULES as for some reason libselinux didn't
 122         # install any pkg-config modules here
 123         AC_SEARCH_LIBS([getcon], [selinux],
 124                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELINUX is available]) have_selinux=yes],
 125                 have_selinux=no)
 126         AC_SUBST(SELINUX_CFLAGS)
 127         AC_SUBST(SELINUX_LIBS)
 128         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 129                 AC_MSG_ERROR([*** selinux support requested but libraries not found])
 130         fi
 131 fi
 132 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 133
 134 AC_ARG_ENABLE([tcpwrap],
 135         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 136                 [case "${enableval}" in
 137                         yes) have_tcpwrap=yes ;;
 138                         no) have_tcpwrap=no ;;
 139                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 140                 esac],
 141                 [have_tcpwrap=auto])
 142
 143 if test "x${have_tcpwrap}" != xno ; then
 144         ACX_LIBWRAP
 145         if test "x${LIBWRAP_LIBS}" = x ; then
 146                 if test "x$have_tcpwrap" = xyes ; then
 147                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 148                 fi
 149                 have_tcpwrap=no
 150         else
 151                 have_tcpwrap=yes
 152         fi
 153 else
 154         LIBWRAP_LIBS=
 155 fi
 156 AC_SUBST(LIBWRAP_LIBS)
 157
 158 AC_ARG_ENABLE([pam],
 159         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 160                 [case "${enableval}" in
 161                         yes) have_pam=yes ;;
 162                         no) have_pam=no ;;
 163                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 164                 esac],
 165                 [have_pam=auto])
 166
 167 if test "x${have_pam}" != xno ; then
 168         AC_CHECK_HEADERS(
 169                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 170                 [have_pam=yes],
 171                 [if test "x$have_pam" = xyes ; then
 172                         AC_MSG_ERROR([*** PAM headers not found.])
 173                 fi])
 174
 175         AC_CHECK_LIB(
 176                 [pam],
 177                 [pam_syslog],
 178                 [have_pam=yes],
 179                 [if test "x$have_pam" = xyes ; then
 180                         AC_MSG_ERROR([*** libpam not found.])
 181                 fi])
 182
 183         if test "x$have_pam" = xyes ; then
 184                 PAM_LIBS="-lpam -lpam_misc"
 185                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 186         else
 187                 have_pam=no
 188         fi
 189 else
 190         PAM_LIBS=
 191 fi
 192 AC_SUBST(PAM_LIBS)
 193 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 194
 195 AC_ARG_ENABLE([audit],
 196         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 197                 [case "${enableval}" in
 198                         yes) have_audit=yes ;;
 199                         no) have_audit=no ;;
 200                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 201                 esac],
 202                 [have_audit=auto])
 203
 204 if test "x${have_audit}" != xno ; then
 205         AC_CHECK_HEADERS(
 206                 [libaudit.h],
 207                 [have_audit=yes],
 208                 [if test "x$have_audit" = xyes ; then
 209                         AC_MSG_ERROR([*** AUDIT headers not found.])
 210                 fi])
 211
 212         AC_CHECK_LIB(
 213                 [audit],
 214                 [audit_open],
 215                 [have_audit=yes],
 216                 [if test "x$have_audit" = xyes ; then
 217                         AC_MSG_ERROR([*** libaudit not found.])
 218                 fi])
 219
 220         if test "x$have_audit" = xyes ; then
 221                 AUDIT_LIBS="-laudit"
 222                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 223         else
 224                 have_audit=no
 225         fi
 226 else
 227         AUDIT_LIBS=
 228 fi
 229 AC_SUBST(AUDIT_LIBS)
 230
 231 have_libcryptsetup=no
 232 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 233 if test "x$enable_libcryptsetup" != "xno"; then
 234         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 235                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 236         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
 237         AC_SUBST(LIBCRYPTSETUP_LIBS)
 238         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 239              AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 240         fi
 241 fi
 242 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 243
 244 have_gtk=no
 245 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 246 if test "x$enable_gtk" != "xno"; then
 247         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 gio-unix-2.0 ],
 248                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 249         AC_SUBST(GTK_CFLAGS)
 250         AC_SUBST(GTK_LIBS)
 251         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 252              AC_MSG_ERROR([*** gtk support requested but libraries not found])
 253         fi
 254 fi
 255 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 256
 257 if test "$have_gtk" = "yes"; then
 258         PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
 259         AC_SUBST(DBUSGLIB_CFLAGS)
 260         AC_SUBST(DBUSGLIB_LIBS)
 261
 262         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
 263         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
 264
 265         AC_SUBST(LIBNOTIFY_CFLAGS)
 266         AC_SUBST(LIBNOTIFY_LIBS)
 267 fi
 268 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
 269
 270 AM_PROG_VALAC([0.10])
 271 AC_SUBST(VAPIDIR)
 272 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 273
 274 AC_PATH_PROG([XSLTPROC], [xsltproc])
 275 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 276
 277 AC_PATH_PROG([M4], [m4])
 278
 279 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware or other]))
 280 if test "z$with_distro" = "z"; then
 281         if test "$cross_compiling" = yes; then
 282                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 283         else
 284                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 285                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 286                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 287                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
 288                         with_distro="ubuntu"
 289                 fi
 290                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 291                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 292                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 293                 AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
 294         fi
 295         if test "z$with_distro" = "z"; then
 296                 with_distro=`uname -s`
 297         fi
 298 fi
 299 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 300 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 301
 302 # Default generic names
 303 SPECIAL_SYSLOG_SERVICE=syslog.service
 304
 305 # Location of the init scripts as mandated by LSB
 306 SYSTEM_SYSVINIT_PATH=/etc/init.d
 307
 308 M4_DISTRO_FLAG=
 309
 310 case $with_distro in
 311         fedora)
 312                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 313                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 314
 315                 # A little background why we define this special unit
 316                 # names here in configure.ac: SysV services currently
 317                 # cannot have aliases. As long as syslog is started
 318                 # via a SysV init script we hence define this name to
 319                 # the actual SysV name here. Later on when SysV init
 320                 # scripts are not used anymore it is advisable to use
 321                 # the generic name instead and use symlinks in the
 322                 # unit directories to point to the right native unit
 323                 # file.
 324
 325                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 326                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 327                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 328                 ;;
 329         suse)
 330                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 331                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 332                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 333                 ;;
 334         debian)
 335                 SYSTEM_SYSVRCND_PATH=/etc
 336                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 337                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 338                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 339                 ;;
 340         ubuntu)
 341                 SYSTEM_SYSVRCND_PATH=/etc
 342                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 343                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 344                 M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
 345                 ;;
 346         arch)
 347                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 348                 SYSTEM_SYSVRCND_PATH=/etc
 349                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 350                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 351                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 352                 ;;
 353         gentoo)
 354                 SYSTEM_SYSVINIT_PATH=
 355                 SYSTEM_SYSVRCND_PATH=
 356                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 357                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 358                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 359                 ;;
 360         slackware)
 361                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 362                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 363                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 364                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 365                 ;;
 366         frugalware)
 367                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 368                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 369                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 370                 M4_DISTRO_FLAG=-DTARGET_FRUGALWARE=1
 371                 ;;
 372         other)
 373                 AS_IF([test "x$with_syslog_service" = "x"],
 374                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 375                 ;;
 376         *)
 377                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 378                 ;;
 379 esac
 380
 381 AC_ARG_WITH([sysvinit-path],
 382         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 383                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 384         [SYSTEM_SYSVINIT_PATH="$withval"],
 385         [])
 386
 387 AC_ARG_WITH([sysvrcd-path],
 388         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 389                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 390         [SYSTEM_SYSVRCND_PATH="$withval"],
 391         [])
 392
 393 AC_ARG_WITH([syslog-service],
 394         [AS_HELP_STRING([--with-syslog-service=UNIT],
 395                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 396         [SPECIAL_SYSLOG_SERVICE="$withval"],
 397         [])
 398
 399 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 400 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 401 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 402 AC_SUBST(M4_DISTRO_FLAG)
 403
 404 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 405         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 406         SYSTEM_SYSV_COMPAT="yes"
 407 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 408         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 409 else
 410         SYSTEM_SYSV_COMPAT="no"
 411 fi
 412
 413 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 414 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 415 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 416 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 417 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 418 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 419 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 420 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 421 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 422
 423 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 424
 425 AC_ARG_WITH([dbuspolicydir],
 426         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 427         [],
 428         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 429
 430 AC_ARG_WITH([dbussessionservicedir],
 431         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 432         [],
 433         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 434
 435 AC_ARG_WITH([dbussystemservicedir],
 436         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 437         [],
 438         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 439
 440 AC_ARG_WITH([dbusinterfacedir],
 441         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 442         [],
 443         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 444
 445 AC_ARG_WITH([udevrulesdir],
 446         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 447         [],
 448         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 449
 450 AC_ARG_WITH([pamlibdir],
 451         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 452         [],
 453         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 454
 455 AC_ARG_WITH([rootdir],
 456         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 457         [],
 458         [with_rootdir=${ac_default_prefix}])
 459
 460 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 461 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 462 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 463 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 464 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 465 AC_SUBST([pamlibdir], [$with_pamlibdir])
 466 AC_SUBST([rootdir], [$with_rootdir])
 467
 468 AC_CONFIG_FILES([Makefile])
 469 AC_OUTPUT
 470
 471 echo "
 472         $PACKAGE_NAME $VERSION
 473
 474         Distribution:            ${with_distro}
 475         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 476         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 477         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 478         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 479         Gtk:                     ${have_gtk}
 480         libcryptsetup:           ${have_libcryptsetup}
 481         tcpwrap:                 ${have_tcpwrap}
 482         PAM:                     ${have_pam}
 483         AUDIT:                   ${have_audit}
 484         SELinux:                 ${have_selinux}
 485         prefix:                  ${prefix}
 486         root dir:                ${with_rootdir}
 487         udev rules dir:          ${with_udevrulesdir}
 488         pam modules dir:         ${with_pamlibdir}
 489         dbus policy dir:         ${with_dbuspolicydir}
 490         dbus session dir:        ${with_dbussessionservicedir}
 491         dbus system dir:         ${with_dbussystemservicedir}
 492         dbus interfaces dir:     ${with_dbusinterfacedir}
 493 "