subdirmk/generate

   1 #!/usr/bin/perl -w
   2 #
   3 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
   4 #
   5 # generates in each subdirectory        from in each subdirectory
   6 #     Subdir.mk.tmp                         Subdir.sd.mk
   7 #     Makefile
   8 # and in toplevel                       and in toplevel
   9 #     main.mk.tmp                           Perdir.sd.mk
  10
  11 use strict;
  12 use POSIX;
  13
  14 print "$0 @ARGV\n" or die $!;
  15
  16 our $srcdir='.';
  17
  18 while (@ARGV && $ARGV[0] =~ m/^-/) {
  19     $_ = shift @ARGV;
  20     last if $_ eq '--';
  21     if (s/^--srcdir=//) {
  22         $srcdir=$';
  23     } else {
  24         die "$0: unknown option \`$_'\n";
  25     }
  26 }
  27 our @subdirs = @ARGV;
  28
  29 s{/+$}{} foreach @subdirs;
  30
  31 our $root = [ '.', [ ] ];
  32 # each node is [ 'relative subdir name', \@children ]
  33
  34 sub build_tree () {
  35     foreach my $subdir (@subdirs) {
  36         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
  37         my $node = $root;
  38         foreach my $d (@path) {
  39             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
  40             if (!$c) {
  41                 $c = [ $d, [ ] ];
  42                 push @{ $node->[1] }, $c;
  43             }
  44             $node = $c;
  45         }
  46     }
  47 }
  48
  49 sub target_varname ($$) {
  50     my ($var_prefix, $target) = @_;
  51     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
  52 }
  53
  54 our $writing_output;
  55 our $buffering_output;
  56 our %output_files;
  57 our %input_files;
  58
  59 sub close_any_output_file() {
  60     return unless defined $writing_output;
  61     O->error and die "error writing $writing_output.tmp: $! (?)\n";
  62     close O or die "error closing $writing_output.tmp: $!\n";
  63     $writing_output = undef;
  64 }
  65
  66 sub o {
  67     if (defined $buffering_output) {
  68         $buffering_output .= $_ foreach @_;
  69         return;
  70     }
  71     die unless defined $writing_output;
  72     print O @_ or die "error writing $writing_output.tmp: $!\n";
  73 }
  74
  75 sub start_output_file ($) {
  76     close_any_output_file();
  77     ($writing_output) = @_;
  78     die "$writing_output ?" if $output_files{$writing_output}++;
  79     my $tmp = "$writing_output.tmp";
  80     open O, ">", $tmp or die "create $tmp: $!\n";
  81     o "# autogenerated - do not edit\n";
  82 }
  83
  84 sub install_output_files () {
  85     close_any_output_file();
  86     foreach my $f (sort keys %output_files) {
  87         rename "$f.tmp", $f or die "install new $f: $!\n";
  88     }
  89 }
  90
  91 sub write_makefile ($$) {
  92     my ($dir_prefix,$depth) = @_;
  93     #print STDERR "write_makefile @_\n";
  94     start_output_file("${dir_prefix}Makefile");
  95     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
  96     o <<END;
  97 default: all
  98 %:      FORCE-ALWAYS-RUN
  99         \@:
 100 Makefile FORCE-ALWAYS-RUN:
 101         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(MAKECMDGOALS))
 102 .SUFFIXES:
 103 END
 104 }
 105
 106 sub process_input_mk ($$$$$$$$);
 107 sub process_input_mk ($$$$$$$$) {
 108     my ($dir_prefix, $dir_suffix, $dir_name,
 109         $var_prefix, $targets,
 110         $f, $esclitr, $enoent_ok) = @_;
 111
 112     my $caps_re = qr{[A-Z]};
 113     my $lc_re = qr{[a-z]};
 114
 115     my $esc;
 116     my $set_esc = sub {
 117         $esc = $$esclitr;
 118         $esc =~ s/\W/\\$&/g;
 119     };
 120     $set_esc->();
 121
 122     my $input = new IO::File $f, '<';
 123     if (!$input) {
 124         die "open $f: $!\n" unless $!==ENOENT && $enoent_ok;
 125         return;
 126     }
 127     $input_files{$f}++;
 128
 129     while (<$input>) {
 130         if (s#^\s*$esc\:##) {
 131             $buffering_output='';
 132         }
 133         for (;;) {
 134             unless (s{^(.*?)(\\)?(?=$esc)}{}) { o $_; last; }
 135             o $1;
 136             if ($2) { o $$esclitr; next; }
 137             s{^$esc}{} or die "$_ ?";
 138             if (s{^$esc}{}) { o "$$esclitr$$esclitr" }
 139             elsif (s{^TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
 140                 my $t = $1 // 'all';
 141                 o target_varname($var_prefix, $t);
 142                 $targets->{$t} //= [ ];
 143             }
 144             elsif (m{^(?=$caps_re)}) { o $var_prefix }
 145             elsif (m{^(?=$lc_re)}) { o $dir_prefix }
 146             elsif (s{^_}{}) { o $var_prefix }
 147             elsif (s{^/}{}) { o $dir_prefix }
 148             elsif (s{^=_}{}) { o $var_prefix }
 149             elsif (s{^=/}{}) { o $dir_name }
 150             elsif (s{^\^}{}) { o "\$(top_srcdir)${dir_suffix}" }
 151             elsif (s{^\}}{}) { o "\$(abs_top_srcdir)${dir_suffix}" }
 152             elsif (s{^(?:[ \t]+([~^]))?(?=[ \t])}{}) {
 153                 my $prefix =
 154                     !$1       ? $dir_prefix                     :
 155                     $1 eq '~' ? '$(abs_top_srcdir)'.$dir_suffix :
 156                     $1 eq '~' ? '$(abs_top_srcdir)'.$dir_suffix :
 157                     die;
 158                 my $after='';
 159                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
 160                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
 161                 o $_;
 162                 $_ = $after;
 163             } elsif (s{^![ \t]+}{}) {
 164                 o $_;
 165                 $_ = '';
 166             } elsif (s{^!(\S+)(?:[ \t]+|$)}{}) {
 167                 $$esclitr = $1;
 168                 $set_esc->();
 169             } else {
 170                 die "bad escape $$esclitr$_ ";
 171             }
 172         }
 173         if (defined $buffering_output) {
 174             $_=$buffering_output;
 175             $buffering_output=undef;
 176             if (m#^(-?)include\s+(\S+)\s+$#) {
 177                 my $subf = "$srcdir/$2";
 178                 process_input_mk($dir_prefix, $dir_suffix, $dir_name,
 179                                  $var_prefix, $targets,
 180                                  $subf, $esclitr, $1);
 181                 o "\n";
 182             } else {
 183                 die "unknown directive $_ ";
 184             }
 185         }
 186     }
 187     $input->error and die "read $f: $!\n";
 188     close $input or die "close $f: $!\n";
 189 }
 190
 191 sub filter_subdir_mk ($$$$$) {
 192     my ($dir_prefix, $dir_suffix, $dir_name,
 193         $var_prefix, $targets) = @_;
 194
 195     #use Data::Dumper;
 196     #print STDERR "filter @_\n";
 197
 198     my $esclit = '&';
 199
 200     my $pi = sub {
 201         my ($f, $enoentok) = @_;
 202         process_input_mk($dir_prefix, $dir_suffix, $dir_name,
 203                          $var_prefix, $targets,
 204                          "${srcdir}/$f", \$esclit, $enoentok);
 205     };
 206     $pi->("${dir_prefix}Subdir.sd.mk", 0);
 207     $pi->("Perdir.sd.mk",              1);
 208 }
 209
 210 sub process_subtree ($$);
 211 sub process_subtree ($$) {
 212     # => list of descendants (in form SUBDIR/)
 213     # recursive, children first
 214     my ($node, $path) = @_;
 215
 216     #use Data::Dumper;
 217     #print STDERR Dumper(\@_);
 218
 219     my $dir_prefix = join '', map { "$_/" } @$path;
 220     my $dir_suffix = join '', map { "/$_" } @$path;
 221     my $dir_name = join '/', @$path ? @$path : '.';
 222     my $var_prefix = join '', map { "${_}_" } @$path ? @$path : qw(TOP);
 223
 224     write_makefile($dir_prefix, scalar @$path);
 225
 226     my %targets = (all => []);
 227     foreach my $child (@{ $node->[1] }) {
 228         my @childpath = (@$path, $child->[0]);
 229         my $child_subdir = join '/', @childpath;
 230         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!";
 231         push @{ $targets{$_} }, $child_subdir foreach
 232             process_subtree($child, \@childpath);
 233     }
 234     start_output_file("${dir_prefix}Subdir.mk.tmp");
 235
 236     filter_subdir_mk($dir_prefix, $dir_suffix, $dir_name,
 237                      $var_prefix, \%targets);
 238
 239     o "\n";
 240
 241     my @targets = sort keys %targets;
 242     foreach my $target (@targets) {
 243         my $target_varname = target_varname($var_prefix, $target);
 244         print O "${dir_prefix}${target}:: \$($target_varname)";
 245         foreach my $child_subdir (@{ $targets{$target} }) {
 246             print O " $child_subdir/$target";
 247         }
 248         print O "\n";
 249     }
 250
 251     return @targets;
 252 }
 253
 254 sub process_tree() {
 255     process_subtree($root, [ ]);
 256     start_output_file("main.mk.tmp");
 257     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
 258         o "$v=\@$v@\n";
 259     }
 260     o "MAKEFILES += Subdir.mk\n";
 261     foreach my $subdir (@subdirs) {
 262         o "MAKEFILES += $subdir/Subdir.mk\n";
 263     }
 264     foreach my $input (sort keys %input_files) {
 265         o "MAKEFILE_TEMPLATES += $input\n";
 266     }
 267     o "include \$(MAKEFILES)";
 268 }
 269
 270 build_tree();
 271 process_tree();
 272 install_output_files();