generate

   1 #!/usr/bin/perl -w
   2 #
   3 # subdirmk - &-filter (makefile generation program)
   4 #  Copyright 2019 Ian Jackson
   5 # SPDX-License-Identifier: LGPL-2.0-or-later
   6 #
   7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
   8 #
   9 # generates in each subdirectory
  10 #     Dir.mk.tmp
  11 #     Makefile
  12 # and in toplevel
  13 #     main.mk.tmp
  14
  15 use strict;
  16 use POSIX;
  17
  18 print "$0 @ARGV\n" or die $!;
  19
  20 our $srcdir='.';
  21
  22 # error handling methods:
  23 #
  24 # Error in input file, while $err_file and $. set, eg in most of
  25 # process_input_mk:
  26 #         err "message";
  27 #
  28 # Other input or usage errors:
  29 #         die "subdirmk: $file:$lno: problem\n";
  30 #         die "subdirmk: some problem not locatable in that way\n";
  31 #
  32 # Usage error:
  33 #         die "subdirmk $0: explanation of problem\n";
  34 #
  35 # System call error (not ENOENT) accessing input/output files:
  36 #         die "description of problem eg maybe erbing noun: $!\n";
  37 #
  38 # Bug detedcted in `generate':
  39 #         die "internal error (some information)?"; # or similar
  40
  41 while (@ARGV && $ARGV[0] =~ m/^-/) {
  42     $_ = shift @ARGV;
  43     last if $_ eq '--';
  44     if (s/^--srcdir=//) {
  45         $srcdir=$';
  46     } else {
  47         die "subdirmk $0: unknown option \`$_'\n";
  48     }
  49 }
  50 our @subdirs = @ARGV;
  51
  52 s{/+$}{} foreach @subdirs;
  53
  54 our $root = [ '.', [ ], 1 ];
  55 # each node is [ 'relative subdir name', \@children, $mentioned ]
  56
  57 sub build_tree () {
  58     foreach my $subdir (@subdirs) {
  59         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
  60         my $node = $root;
  61         foreach my $d (@path) {
  62             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
  63             if (!$c) {
  64                 $c = [ $d, [ ] ];
  65                 push @{ $node->[1] }, $c;
  66             }
  67             $node = $c;
  68         }
  69         $node->[2] = 1;
  70     }
  71 }
  72
  73 sub target_varname ($$) {
  74     my ($var_prefix, $target) = @_;
  75     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
  76 }
  77
  78 our $writing_output;
  79 our $buffering_output;
  80 our %output_files;
  81 our %input_files;
  82 our @output_makefiles;
  83
  84 sub close_any_output_file() {
  85     return unless defined $writing_output;
  86     O->error and die "error writing $writing_output.tmp: $! (?)\n";
  87     close O or die "error closing $writing_output.tmp: $!\n";
  88     $writing_output = undef;
  89 }
  90
  91 sub oraw {
  92     die 'internal error' unless defined $writing_output;
  93     print O @_ or die "error writing $writing_output.tmp: $!\n";
  94 }
  95
  96 sub oud { # undoubled
  97     if (defined $buffering_output) {
  98         $buffering_output .= $_ foreach @_;
  99         return;
 100     }
 101     oraw @_;
 102 }
 103
 104 our $ddbl;
 105
 106 sub od { # maybe $-doubled
 107     if (!$ddbl) {
 108         oud @_;
 109         return;
 110     }
 111     foreach (@_) {
 112         my $e = $_;
 113         $e =~ s{\$}{\$\$}g;
 114         oud $e;
 115     }
 116 }
 117
 118 sub start_output_file ($) {
 119     close_any_output_file();
 120     ($writing_output) = @_;
 121     die "internal error ($writing_output?)"
 122         if $output_files{$writing_output}++;
 123     my $tmp = "$writing_output.tmp";
 124     open O, ">", $tmp or die "create $tmp: $!\n";
 125     oraw "# autogenerated - do not edit\n";
 126 }
 127
 128 sub install_output_files () {
 129     close_any_output_file();
 130     foreach my $f (sort keys %output_files) {
 131         rename "$f.tmp", $f or die "install new $f: $!\n";
 132     }
 133 }
 134
 135 sub write_makefile ($$) {
 136     my ($dir_prefix,$depth) = @_;
 137     #print STDERR "write_makefile @_\n";
 138     start_output_file("${dir_prefix}Makefile");
 139     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
 140     my $suppress_templates=
 141         '$(if $(filter-out clean real-clean, $(subdirmk_targets)),,'.
 142         ' MAKEFILE_TEMPLATES=)';
 143     oraw <<END;
 144 default: all
 145 \$(filter-out all,\$(MAKECMDGOALS)) all: run-main.mk
 146         \@:
 147 subdirmk_targets:=\$(or \$(MAKECMDGOALS),all)
 148 Makefile run-main.mk:
 149         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(subdirmk_targets))$suppress_templates
 150 .SUFFIXES:
 151 .PHONY: run-main.mk
 152 END
 153 }
 154
 155 our ($dir_prefix, $dir_suffix, $dir_name,
 156      $var_prefix, $var_prefix_name);
 157
 158 sub dir_prefix ($) {
 159     my ($path) = @_;
 160     join '', map { "$_/" } @$path;
 161 }
 162
 163 sub set_dir_vars ($) {
 164     my ($path) = @_;
 165     $dir_prefix = dir_prefix($path);
 166     $dir_suffix = join '', map { "/$_" } @$path;
 167     $dir_name = join '/', @$path ? @$path : '.';
 168     $var_prefix_name = join '_', @$path ? @$path : qw(TOP);
 169     $var_prefix = "${var_prefix_name}_";
 170 }
 171
 172 our $err_file;
 173
 174 sub err ($) {
 175     my ($m) = @_;
 176     die "subdirmk: ${err_file}:$.: $m\n";
 177 }
 178
 179 sub ddbl_only ($) {
 180     my ($e) = @_;
 181     return if $ddbl;
 182     err "escape &$e is valid only during \$-doubling";
 183 }
 184
 185 sub process_input_mk ($$$$);
 186 sub process_input_mk ($$$$) {
 187     my ($targets, $f, $esclitr, $enoent_ok) = @_;
 188
 189     my $caps_re = qr{[A-Z]};
 190     my $lc_re = qr{[a-z]};
 191
 192     my $esc;
 193     my $set_esc = sub {
 194         $esc = $$esclitr;
 195         $esc =~ s/\W/\\$&/g;
 196     };
 197     $set_esc->();
 198
 199     my $input = new IO::File $f, '<';
 200     if (!$input) {
 201         err "open $f: $!" unless $!==ENOENT && $enoent_ok;
 202         return;
 203     }
 204     $input_files{$f}++;
 205
 206     local $err_file=$f;
 207
 208     my %srcdirmap = (
 209                   '^' => "\$(top_srcdir)${dir_suffix}",
 210                   '~' => "\$(top_srcdir)",
 211                     );
 212     my %pfxmap = (
 213                   ''  => $dir_prefix,
 214                  );
 215     $pfxmap{$_} = $srcdirmap{$_}.'/' foreach keys %srcdirmap;
 216
 217     local $ddbl;
 218     my @nest = (['']);
 219
 220     my $push_nest = sub {
 221         my ($nk, $nndbl, $what) = @_;
 222         unshift @nest, [ $nk, $ddbl, $what, $. ];
 223         $ddbl = $nndbl;
 224     };
 225     my $pop_nest = sub {
 226         my ($nk) = @_;
 227         err "unexpectedly closed $nk in middle of $nest[0][0] ($nest[0][2])"
 228             unless $nest[0][0] eq $nk;
 229         $ddbl = (shift @nest)[1];
 230     };
 231
 232     while (<$input>) {
 233         if (s#^\s*$esc\:changequote\s+(\S+)\s+$##) {
 234             $$esclitr = $1;
 235             $set_esc->();
 236             next;
 237         } elsif (s#^\s*$esc\:endm\s+$##) {
 238             $pop_nest->('macro');
 239             od "endef\n";
 240             next;
 241         } elsif (s#^\s*$esc\:(?=(-?)include|macro)##) {
 242             $buffering_output='';
 243         } elsif (m#^\s*$esc\:([a-z][-0-9a-z_]*)#) {
 244             err "unknown directive &:$1 or bad argumnt syntax";
 245         } elsif (s{^\s*${esc}TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
 246             my $t = $1 // 'all';
 247             od target_varname($var_prefix, $t);
 248             $targets->{$t} //= [ ];
 249         }
 250         for (;;) {
 251             err 'cannot $-double &-processed RHS of directive'
 252                 if $ddbl && defined $buffering_output;
 253             unless ($nest[0][0] eq 'eval'
 254                     ? s{^(.*?)($esc|[{}])}{}
 255                     : s{^(.*?)($esc)}{}) { od $_; last; }
 256             od $1;
 257             if ($2 eq '{') {
 258                 $ddbl++;
 259                 next;
 260             } elsif ($2 eq '}') {
 261                 next if --$ddbl;
 262                 $pop_nest->('eval');
 263                 od '}}';
 264                 next;
 265             }
 266             if (s{^\\$esc}{}) { od "$$esclitr" }
 267             elsif (s{^\\\$}{}) { oud '$' }
 268             elsif (s{^\\\s+$}{}) { }
 269             elsif (s{^$esc}{}) { od "$$esclitr$$esclitr" }
 270             elsif (m{^(?=$caps_re)}) { od $var_prefix }
 271             elsif (s{^\$([A-Za-z]\w+)}{}) { od "\$(${var_prefix}$1)" }
 272             elsif (s{^([~^]?)(?=$lc_re)}{}) { od $pfxmap{$1} }
 273             elsif (s{^_}{}) { od $var_prefix }
 274             elsif (s{^=}{}) { od $var_prefix_name }
 275             elsif (s{^([~^]?)/}{}) { od $pfxmap{$1} }
 276             elsif (s{^\.}{}) { od $dir_name }
 277             elsif (s{^([~^])\.}{}) { od $srcdirmap{$1} }
 278             elsif (s{^\$\-}{}) { $ddbl=undef; }
 279             elsif (s{^\$\+}{}) { $ddbl=1; }
 280             elsif (s{^\$\(}{}) { ddbl_only($&); oud "\$("; }
 281             elsif (s{^\$(\d+)}{}) { ddbl_only($&); oud "\$($1)"; }
 282             elsif (s{^\$\{}{}) {
 283                 err 'macro invocation cannot be re-$-doubled' if $ddbl;
 284                 od '${eval ${call ';
 285                 $push_nest->('eval',1, '&${...}');
 286             } elsif (s{^([~^]?)(?=[ \t])}{}) {
 287                 my $prefix = $pfxmap{$1} // die "internal error ($1?)";
 288                 my $after='';
 289                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
 290                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
 291                 od $_;
 292                 $_ = $after;
 293             } elsif (s{^\#}{}) {
 294                 $_ = '';
 295             } elsif (s{^![ \t]+}{}) {
 296                 od $_;
 297                 $_ = '';
 298             } else {
 299                 m{^.{0,5}};
 300                 err "bad &-escape \`$$esclitr$&'";
 301             }
 302         }
 303         if (defined $buffering_output) {
 304             $_=$buffering_output;
 305             $buffering_output=undef;
 306             if (m#^(-?)include\s+(\S+)\s+$#) {
 307                 my $subf = "$srcdir/$2";
 308                 process_input_mk($targets, $subf, $esclitr, $1);
 309                 od "\n";
 310             } elsif (m#^macro\s+(\S+)\s+$#) {
 311                 od "define $1\n";
 312                 $push_nest->('macro', 1, '&:macro');
 313             } else {
 314                 err "bad directive argument syntax";
 315             }
 316         }
 317     }
 318     die "subdirmk: $f:$nest[0][3]: unclosed $nest[0][0] ($nest[0][2])\n"
 319         if $nest[0][0];
 320     $input->error and die "read $f: $!\n";
 321     close $input or die "close $f: $!\n";
 322 }
 323
 324 sub filter_subdir_mk ($) {
 325     my ($targets) = @_;
 326
 327     #use Data::Dumper;
 328     #print STDERR "filter @_\n";
 329
 330     my $esclit = '&';
 331
 332     my $pi = sub {
 333         my ($f, $enoentok) = @_;
 334         process_input_mk($targets, "${srcdir}/$f", \$esclit, $enoentok);
 335     };
 336     $pi->("Prefix.sd.mk",           1);
 337     $pi->("${dir_prefix}Dir.sd.mk", 0);
 338     $pi->("Suffix.sd.mk",           1);
 339 }
 340
 341 sub process_subtree ($$);
 342 sub process_subtree ($$) {
 343     # => list of targets (in form SUBDIR/)
 344     # recursive, children first
 345     my ($node, $path) = @_;
 346
 347     #use Data::Dumper;
 348     #print STDERR Dumper(\@_);
 349
 350     my $dir_prefix = dir_prefix($path);
 351     # ^ this is the only var which we need before we come back from
 352     #   the recursion.
 353
 354     push @output_makefiles, "${dir_prefix}Dir.mk";
 355     write_makefile($dir_prefix, scalar @$path);
 356
 357     my %targets = (all => []);
 358     foreach my $child (@{ $node->[1] }) {
 359         my @childpath = (@$path, $child->[0]);
 360         my $child_subdir = join '/', @childpath;
 361         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!\n";
 362         push @{ $targets{$_} }, $child_subdir foreach
 363             process_subtree($child, \@childpath);
 364     }
 365
 366     set_dir_vars($path);
 367     start_output_file("${dir_prefix}Dir.mk.tmp");
 368
 369     if ($node->[2]) {
 370         filter_subdir_mk(\%targets);
 371     } else {
 372         my $sdmk = "${dir_prefix}Dir.sd.mk";
 373         if (stat $sdmk) {
 374             die
 375  "subdirmk: $sdmk unexpectedly exists (${dir_prefix} not mentioned on subdirmk/generate command line, maybe directory is missing from SUBDIRMK_SUBDIRS)";
 376         } elsif ($!==ENOENT) {
 377         } else {
 378             die "stat $sdmk: $!\n";
 379         }
 380     }
 381
 382     oraw "\n";
 383
 384     my @targets = sort keys %targets;
 385     foreach my $target (@targets) {
 386         my $target_varname = target_varname($var_prefix, $target);
 387         print O "${dir_prefix}${target}:: \$($target_varname)";
 388         foreach my $child_subdir (@{ $targets{$target} }) {
 389             print O " $child_subdir/$target";
 390         }
 391         print O "\n";
 392     }
 393     if (@targets) {
 394         print O ".PHONY:";
 395         print O " ${dir_prefix}${_}" foreach @targets;
 396         print O "\n";
 397     }
 398
 399     return @targets;
 400 }
 401
 402 sub process_final ($) {
 403     my ($otargets) = @_;
 404     set_dir_vars([]);
 405     push @output_makefiles, "Final.mk";
 406     start_output_file("Final.mk.tmp");
 407     my %ntargets;
 408     my $esclit='&';
 409     process_input_mk(\%ntargets, "${srcdir}/Final.sd.mk", \$esclit, 1);
 410     delete $ntargets{$_} foreach @$otargets;
 411     my @ntargets = sort keys %ntargets;
 412     die "subdirmk: Final.sd.mk may not introduce new top-level targets".
 413         " (@ntargets)\n" if @ntargets;
 414 }
 415
 416 sub process_tree() {
 417     my @targets = process_subtree($root, [ ]);
 418     process_final(\@targets);
 419     start_output_file("main.mk.tmp");
 420     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
 421         oraw "$v=\@$v@\n";
 422     }
 423     oraw "SUBDIRMK_MAKEFILES :=\n";
 424     oraw "MAKEFILE_TEMPLATES :=\n";
 425     foreach my $mf (@output_makefiles) {
 426         oraw "SUBDIRMK_MAKEFILES += $mf\n";
 427     }
 428     foreach my $input (sort keys %input_files) {
 429         oraw "MAKEFILE_TEMPLATES += $input\n";
 430     }
 431     oraw "include \$(SUBDIRMK_MAKEFILES)\n";
 432 }
 433
 434 build_tree();
 435 process_tree();
 436 install_output_files();