generate

   1 #!/usr/bin/perl -w
   2 #
   3 # subdirmk - &-filter (makefile generation program)
   4 #  Copyright 2019 Ian Jackson
   5 # SPDX-License-Identifier: LGPL-2.0-or-later
   6 #
   7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
   8 #
   9 # generates in each subdirectory
  10 #     Dir.mk.tmp
  11 #     Makefile
  12 # and in toplevel
  13 #     main.mk.tmp
  14
  15 use strict;
  16 use POSIX;
  17
  18 print "$0 @ARGV\n" or die $!;
  19
  20 our $srcdir='.';
  21
  22 # error handling methods:
  23 #
  24 # Error in input file, while $err_file and $. set, eg in most of
  25 # process_input_mk:
  26 #         err "message";
  27 #
  28 # Other input or usage errors:
  29 #         die "subdirmk: $file:$lno: problem\n";
  30 #         die "subdirmk: some problem not locatable in that way\n";
  31 #
  32 # Usage error:
  33 #         die "subdirmk $0: explanation of problem\n";
  34 #
  35 # System call error (not ENOENT) accessing input/output files:
  36 #         die "description of problem eg maybe erbing noun: $!\n";
  37 #
  38 # Bug detedcted in `generate':
  39 #         die "internal error (some information)?"; # or similar
  40
  41 while (@ARGV && $ARGV[0] =~ m/^-/) {
  42     $_ = shift @ARGV;
  43     last if $_ eq '--';
  44     if (s/^--srcdir=//) {
  45         $srcdir=$';
  46     } else {
  47         die "subdirmk $0: unknown option \`$_'\n";
  48     }
  49 }
  50 our @subdirs = @ARGV;
  51
  52 s{/+$}{} foreach @subdirs;
  53
  54 our $root = [ '.', [ ], 1 ];
  55 # each node is [ 'relative subdir name', \@children, $mentioned ]
  56
  57 sub build_tree () {
  58     foreach my $subdir (@subdirs) {
  59         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
  60         my $node = $root;
  61         foreach my $d (@path) {
  62             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
  63             if (!$c) {
  64                 $c = [ $d, [ ] ];
  65                 push @{ $node->[1] }, $c;
  66             }
  67             $node = $c;
  68         }
  69         $node->[2] = 1;
  70     }
  71 }
  72
  73 sub target_varname ($$) {
  74     my ($var_prefix, $target) = @_;
  75     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
  76 }
  77
  78 our $writing_output;
  79 our $buffering_output;
  80 our %output_files;
  81 our %input_files;
  82 our @output_makefiles;
  83
  84 sub close_any_output_file() {
  85     return unless defined $writing_output;
  86     O->error and die "error writing $writing_output.tmp: $! (?)\n";
  87     close O or die "error closing $writing_output.tmp: $!\n";
  88     $writing_output = undef;
  89 }
  90
  91 sub oraw {
  92     die 'internal error' unless defined $writing_output;
  93     print O @_ or die "error writing $writing_output.tmp: $!\n";
  94 }
  95
  96 sub oud { # undoubled
  97     if (defined $buffering_output) {
  98         $buffering_output .= $_ foreach @_;
  99         return;
 100     }
 101     oraw @_;
 102 }
 103
 104 our $ddbl;
 105
 106 sub od { # maybe $-doubled
 107     if (!$ddbl) {
 108         oud @_;
 109         return;
 110     }
 111     foreach (@_) {
 112         my $e = $_;
 113         $e =~ s{\$}{\$\$}g;
 114         oud $e;
 115     }
 116 }
 117
 118 sub start_output_file ($) {
 119     close_any_output_file();
 120     ($writing_output) = @_;
 121     die "internal error ($writing_output?)"
 122         if $output_files{$writing_output}++;
 123     my $tmp = "$writing_output.tmp";
 124     open O, ">", $tmp or die "create $tmp: $!\n";
 125     oraw "# autogenerated - do not edit\n";
 126 }
 127
 128 sub install_output_files () {
 129     close_any_output_file();
 130     foreach my $f (sort keys %output_files) {
 131         rename "$f.tmp", $f or die "install new $f: $!\n";
 132     }
 133 }
 134
 135 sub write_makefile ($$) {
 136     my ($dir_prefix,$depth) = @_;
 137     #print STDERR "write_makefile @_\n";
 138     start_output_file("${dir_prefix}Makefile");
 139     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
 140     my $suppress_templates=
 141         '$(if $(filter-out clean real-clean, $(subdirmk_targets)),,'.
 142         ' MAKEFILE_TEMPLATES=)';
 143     oraw <<END;
 144 default: all
 145 \$(filter-out all,\$(MAKECMDGOALS)) all: run-main.mk
 146         \@:
 147 subdirmk_targets:=\$(or \$(MAKECMDGOALS),all)
 148 Makefile run-main.mk:
 149         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(subdirmk_targets))$suppress_templates
 150 .SUFFIXES:
 151 .PHONY: run-main.mk
 152 END
 153 }
 154
 155 our %varref;
 156
 157 our ($dir_prefix, $dir_suffix, $dir_name,
 158      $var_prefix, $var_prefix_name);
 159
 160 sub dir_prefix ($) {
 161     my ($path) = @_;
 162     join '', map { "$_/" } @$path;
 163 }
 164
 165 sub set_dir_vars ($) {
 166     my ($path) = @_;
 167     $dir_prefix = dir_prefix($path);
 168     $dir_suffix = join '', map { "/$_" } @$path;
 169     $dir_name = join '/', @$path ? @$path : '.';
 170     $var_prefix_name = join '_', @$path ? @$path : qw(TOP);
 171     $var_prefix = "${var_prefix_name}_";
 172 }
 173
 174 our $err_file;
 175
 176 our @warn_ena_dfl = map { $_ => 1 } qw(
 177     local+global
 178     single-char-var
 179     unknown-warning
 180 );
 181 our %warn_ena = @warn_ena_dfl;
 182
 183 our $warned;
 184 our %warn_unk;
 185
 186 sub err ($) {
 187     my ($m) = @_;
 188     die "subdirmk: ${err_file}:$.: $m\n";
 189 }
 190
 191 sub wrncore ($$) {
 192     my ($wk,$m) = @_;
 193     return 0 unless $warn_ena{$wk} // warn "internal error $wk ?";
 194     $warned++;
 195     print STDERR "subdirmk: warning ($wk): $m\n";
 196     return 1;
 197 }
 198
 199 sub wrn ($$) {
 200     my ($wk,$m) = @_;
 201     wrncore($wk, "${err_file}:$.: $m");
 202 }
 203
 204 sub ddbl_only ($) {
 205     my ($e) = @_;
 206     return if $ddbl;
 207     err "escape &$e is valid only during \$-doubling";
 208 }
 209
 210 sub process_input_mk ($$$$);
 211 sub process_input_mk ($$$$) {
 212     my ($targets, $f, $esclitr, $enoent_ok) = @_;
 213
 214     my $caps_re = qr{[A-Z]};
 215     my $lc_re = qr{[a-z]};
 216
 217     my $esc;
 218     my $set_esc = sub {
 219         $esc = $$esclitr;
 220         $esc =~ s/\W/\\$&/g;
 221     };
 222     $set_esc->();
 223
 224     my $input = new IO::File $f, '<';
 225     if (!$input) {
 226         err "open $f: $!" unless $!==ENOENT && $enoent_ok;
 227         return;
 228     }
 229     $input_files{$f}++;
 230
 231     local $err_file=$f;
 232
 233     my %srcdirmap = (
 234                   '^' => "\$(top_srcdir)${dir_suffix}",
 235                   '~' => "\$(top_srcdir)",
 236                     );
 237     my %pfxmap = (
 238                   ''  => $dir_prefix,
 239                  );
 240     $pfxmap{$_} = $srcdirmap{$_}.'/' foreach keys %srcdirmap;
 241
 242     local $ddbl;
 243     my @nest = (['']);
 244     my $evalcall_brackets;
 245
 246     my $push_nest = sub {
 247         my ($nk, $nndbl, $what) = @_;
 248         unshift @nest, [ $nk, $ddbl, $what, $. ];
 249         $ddbl = $nndbl;
 250     };
 251     my $pop_nest = sub {
 252         my ($nk) = @_;
 253         err "unexpectedly closed $nk in middle of $nest[0][0] ($nest[0][2])"
 254             unless $nest[0][0] eq $nk;
 255         $ddbl = (shift @nest)[1];
 256     };
 257
 258     # Our detection of variable settings does not have to be completely
 259     # accurate, since it is only going to be used for advice to the user.
 260     my $note_varref = sub {
 261         my ($vn,$amp) = @_;
 262         $varref{$vn}{$amp}{"$f:$."} = 1;
 263     };
 264
 265     while (<$input>) {
 266         if (m#^\s*($esc)?(\w+)\s*(?:=|\+=|\?=|:=)# ||
 267             m#^\s*(?:$esc\:macro|define)\s+($esc)?(\S+)\s#) {
 268             $note_varref->($2,!!$1);
 269         }
 270         if (s#^\s*$esc\:changequote\s+(\S+)\s+$##) {
 271             $$esclitr = $1;
 272             $set_esc->();
 273             next;
 274         } elsif (s#^\s*$esc\:endm\s+$##) {
 275             $pop_nest->('macro');
 276             od "endef\n";
 277             next;
 278         } elsif (s#^\s*$esc\:warn\s+(\S.*)$##) {
 279             foreach my $wk (split /\s+/, $1) {
 280                 my $yes = $wk !~ s{^!}{};
 281                 if (defined $warn_ena{$wk}) {
 282                     $warn_ena{$wk} = $yes;
 283                     next;
 284                 } elsif ($yes) {
 285                     wrn 'unknown-warning',
 286                         "unknown warning $wk requested";
 287                 } else {
 288                     $warn_unk{$wk} //= "$f:$.";
 289                 }
 290             }
 291             next;
 292         } elsif (s#^\s*$esc\:local\+global\s+(\S.*)$##) {
 293             foreach my $vn (split /\s+/, $1) {
 294                 $vn =~ s{^$esc}{};
 295                 $varref{$vn}{NoWarn} = 1;
 296             }
 297             next;
 298         } elsif (s#^\s*$esc\:(?=(-?)include|macro)##) {
 299             $buffering_output='';
 300         } elsif (m#^\s*$esc\:([a-z][-+0-9a-z_]*)#) {
 301             err "unknown directive &:$1 or bad argumnt syntax";
 302         } elsif (s{^\s*${esc}TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
 303             my $t = $1 // 'all';
 304             my $vn = target_varname($var_prefix, $t);
 305             $note_varref->($vn,1);
 306             od $vn;
 307             $targets->{$t} //= [ ];
 308         }
 309         for (;;) {
 310             err 'cannot $-double &-processed RHS of directive'
 311                 if $ddbl && defined $buffering_output;
 312             unless ($nest[0][0] eq 'eval'
 313                     ? s{^(.*?)($esc|\$|[{}])}{}
 314                     : s{^(.*?)($esc|\$)}{}) { od $_; last; }
 315             od $1;
 316             if ($2 eq '{') {
 317                 od $2;
 318                 $evalcall_brackets++;
 319                 next;
 320             } elsif ($2 eq '}') {
 321                 od $2;
 322                 next if --$evalcall_brackets;
 323                 $pop_nest->('eval');
 324                 od '}';
 325                 next;
 326             } elsif ($2 eq '$') {
 327                 od $2;
 328                 if (s{^\$}{}) { od $&; }
 329                 elsif (m{^[a-zA-Z]\w}) {
 330                     wrn 'single-char-var',
 331                     'possibly confusing unbracketed single-char $-expansion';
 332                 }
 333                 elsif (m{^\(($esc)?([^()\$]+)\)} ||
 334                        m{^\{($esc)?([^{}\$]+)\}}) {
 335                     $note_varref->($2,!!$1);
 336                 }
 337                 next;
 338             }
 339             if (s{^\\$esc}{}) { od "$$esclitr" }
 340             elsif (s{^\\\$}{}) { oud '$' }
 341             elsif (s{^\\\s+$}{}) { }
 342             elsif (s{^$esc}{}) { od "$$esclitr$$esclitr" }
 343             elsif (m{^(?=$caps_re)}) { od $var_prefix }
 344             elsif (s{^\$([A-Za-z]\w+)}{}) {
 345                 $note_varref->($1,1);
 346                 od "\$(${var_prefix}$1)";
 347             }
 348             elsif (s{^([~^]?)(?=$lc_re)}{}) { od $pfxmap{$1} }
 349             elsif (s{^_}{}) { od $var_prefix }
 350             elsif (s{^=}{}) { od $var_prefix_name }
 351             elsif (s{^([~^]?)/}{}) { od $pfxmap{$1} }
 352             elsif (s{^\.}{}) { od $dir_name }
 353             elsif (s{^([~^])\.}{}) { od $srcdirmap{$1} }
 354             elsif (s{^\$\-}{}) { $ddbl=undef; }
 355             elsif (s{^\$\+}{}) { $ddbl=1; }
 356             elsif (s{^\$\(}{}) {
 357                 ddbl_only($&); oud "\$(";
 358                 $note_varref->($2,!!$1) if m{^($esc)?([^()\$]+\))};
 359             }
 360             elsif (s{^\$(\d+)}{}) { ddbl_only($&); oud "\$($1)"; }
 361             elsif (s{^\$\{}{}) {
 362                 err 'macro invocation cannot be re-$-doubled' if $ddbl;
 363                 od '${eval ${call ';
 364                 $evalcall_brackets = 1;
 365                 $push_nest->('eval',1, '&${...}');
 366                 $note_varref->($2,!!$1) if m{^\s*($esc)?([^,{}\$]+)};
 367             } elsif (s{^([~^]?)(?=[ \t])}{}) {
 368                 my $prefix = $pfxmap{$1} // die "internal error ($1?)";
 369                 my $after='';
 370                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
 371                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
 372                 od $_;
 373                 $_ = $after;
 374             } elsif (s{^\#}{}) {
 375                 $_ = '';
 376             } elsif (s{^![ \t]+}{}) {
 377                 od $_;
 378                 $_ = '';
 379             } else {
 380                 m{^.{0,5}};
 381                 err "bad &-escape \`$$esclitr$&'";
 382             }
 383         }
 384         if (defined $buffering_output) {
 385             $_=$buffering_output;
 386             $buffering_output=undef;
 387             if (m#^(-?)include\s+(\S+)\s+$#) {
 388                 my $subf = "$srcdir/$2";
 389                 process_input_mk($targets, $subf, $esclitr, $1);
 390                 od "\n";
 391             } elsif (m#^macro\s+(\S+)\s+$#) {
 392                 od "define $1\n";
 393                 $push_nest->('macro', 1, '&:macro');
 394             } else {
 395                 err "bad directive argument syntax";
 396             }
 397         }
 398     }
 399     die "subdirmk: $f:$nest[0][3]: unclosed $nest[0][0] ($nest[0][2])\n"
 400         if $nest[0][0];
 401     $input->error and die "read $f: $!\n";
 402     close $input or die "close $f: $!\n";
 403 }
 404
 405 sub filter_subdir_mk ($) {
 406     my ($targets) = @_;
 407
 408     #use Data::Dumper;
 409     #print STDERR "filter @_\n";
 410
 411     my $esclit = '&';
 412
 413     my $pi = sub {
 414         my ($f, $enoentok) = @_;
 415         process_input_mk($targets, "${srcdir}/$f", \$esclit, $enoentok);
 416     };
 417     $pi->("Prefix.sd.mk",           1);
 418     $pi->("${dir_prefix}Dir.sd.mk", 0);
 419     $pi->("Suffix.sd.mk",           1);
 420 }
 421
 422 sub process_subtree ($$);
 423 sub process_subtree ($$) {
 424     # => list of targets (in form SUBDIR/)
 425     # recursive, children first
 426     my ($node, $path) = @_;
 427
 428     #use Data::Dumper;
 429     #print STDERR Dumper(\@_);
 430
 431     my $dir_prefix = dir_prefix($path);
 432     # ^ this is the only var which we need before we come back from
 433     #   the recursion.
 434
 435     push @output_makefiles, "${dir_prefix}Dir.mk";
 436     write_makefile($dir_prefix, scalar @$path);
 437
 438     my %targets = (all => []);
 439     foreach my $child (@{ $node->[1] }) {
 440         my @childpath = (@$path, $child->[0]);
 441         my $child_subdir = join '/', @childpath;
 442         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!\n";
 443         local %warn_ena = @warn_ena_dfl;
 444         push @{ $targets{$_} }, $child_subdir foreach
 445             process_subtree($child, \@childpath);
 446     }
 447
 448     set_dir_vars($path);
 449     start_output_file("${dir_prefix}Dir.mk.tmp");
 450
 451     if ($node->[2]) {
 452         filter_subdir_mk(\%targets);
 453     } else {
 454         my $sdmk = "${dir_prefix}Dir.sd.mk";
 455         if (stat $sdmk) {
 456             die
 457  "subdirmk: $sdmk unexpectedly exists (${dir_prefix} not mentioned on subdirmk/generate command line, maybe directory is missing from SUBDIRMK_SUBDIRS)";
 458         } elsif ($!==ENOENT) {
 459         } else {
 460             die "stat $sdmk: $!\n";
 461         }
 462     }
 463
 464     oraw "\n";
 465
 466     my @targets = sort keys %targets;
 467     foreach my $target (@targets) {
 468         my $target_varname = target_varname($var_prefix, $target);
 469         oraw "${dir_prefix}${target}:: \$($target_varname)";
 470         foreach my $child_subdir (@{ $targets{$target} }) {
 471             oraw " $child_subdir/$target";
 472         }
 473         oraw "\n";
 474     }
 475     if (@targets) {
 476         oraw ".PHONY:";
 477         oraw " ${dir_prefix}${_}" foreach @targets;
 478         oraw "\n";
 479     }
 480
 481     return @targets;
 482 }
 483
 484 sub process_final ($) {
 485     my ($otargets) = @_;
 486     set_dir_vars([]);
 487     push @output_makefiles, "Final.mk";
 488     start_output_file("Final.mk.tmp");
 489     my %ntargets;
 490     my $esclit='&';
 491     process_input_mk(\%ntargets, "${srcdir}/Final.sd.mk", \$esclit, 1);
 492     delete $ntargets{$_} foreach @$otargets;
 493     my @ntargets = sort keys %ntargets;
 494     die "subdirmk: Final.sd.mk may not introduce new top-level targets".
 495         " (@ntargets)\n" if @ntargets;
 496 }
 497
 498 sub process_tree() {
 499     my @targets = process_subtree($root, [ ]);
 500     process_final(\@targets);
 501     start_output_file("main.mk.tmp");
 502     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
 503         oraw "$v=\@$v@\n";
 504     }
 505     oraw "SUBDIRMK_MAKEFILES :=\n";
 506     oraw "MAKEFILE_TEMPLATES :=\n";
 507     foreach my $mf (@output_makefiles) {
 508         oraw "SUBDIRMK_MAKEFILES += $mf\n";
 509     }
 510     foreach my $input (sort keys %input_files) {
 511         oraw "MAKEFILE_TEMPLATES += $input\n";
 512     }
 513     oraw "include \$(SUBDIRMK_MAKEFILES)\n";
 514 }
 515
 516 sub flmap ($) { local ($_) = @_; s{:(\d+)$}{ sprintf ":%10d", $1 }e; $_; }
 517
 518 sub print_varref_warnings () {
 519     foreach my $vn (sort keys %varref) {
 520         my $vv = $varref{$vn};
 521         next unless $vv->{''} && $vv->{1};
 522         next if $vv->{NoWarn};
 523         wrncore 'local+global', "saw both $vn and &$vn" or return;
 524         foreach my $amp ('', 1) {
 525             printf STDERR " saw %s%s at %s\n",
 526                 ($amp ? '&' : ''), $vn, $_
 527                 foreach
 528                 sort { flmap($a) cmp flmap($b) }
 529                 keys %{ $vv->{$amp} };
 530         }
 531     }
 532 }
 533
 534 sub print_warning_warnings () {
 535     return unless $warned;
 536     foreach my $wk (sort keys %warn_unk) {
 537         wrncore 'unknown-warning',
 538             "$warn_unk{$wk}: attempt to suppress unknown warning(s) \`$wk'";
 539     }
 540 }
 541
 542 build_tree();
 543 process_tree();
 544 print_varref_warnings();
 545 print_warning_warnings();
 546 install_output_files();