chiark / gitweb /
doctests: Test in sub/dir too
[subdirmk.git] / generate
1 #!/usr/bin/perl -w
2 #
3 # subdirmk - &-filter (makefile generation program)
4 #  Copyright 2019 Ian Jackson
5 # SPDX-License-Identifier: LGPL-2.0-or-later
6 #
7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
8 #
9 # generates in each subdirectory        from in each subdirectory
10 #     Subdir.mk.tmp                         Subdir.sd.mk
11 #     Makefile                          and included files
12 # and in toplevel                       and in toplevel
13 #     main.mk.tmp                           Perdir.sd.mk
14
15 use strict;
16 use POSIX;
17
18 print "$0 @ARGV\n" or die $!;
19
20 our $srcdir='.';
21
22 while (@ARGV && $ARGV[0] =~ m/^-/) {
23     $_ = shift @ARGV;
24     last if $_ eq '--';
25     if (s/^--srcdir=//) {
26         $srcdir=$';
27     } else {
28         die "$0: unknown option \`$_'\n";
29     }
30 }
31 our @subdirs = @ARGV;
32
33 s{/+$}{} foreach @subdirs;
34
35 our $root = [ '.', [ ], 1 ];
36 # each node is [ 'relative subdir name', \@children, $mentioned ]
37
38 sub build_tree () {
39     foreach my $subdir (@subdirs) {
40         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
41         my $node = $root;
42         foreach my $d (@path) {
43             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
44             if (!$c) {
45                 $c = [ $d, [ ] ];
46                 push @{ $node->[1] }, $c;
47             }
48             $node = $c;
49         }
50         $node->[2] = 1;
51     }
52 }
53
54 sub target_varname ($$) {
55     my ($var_prefix, $target) = @_;
56     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
57 }
58
59 our $writing_output;
60 our $buffering_output;
61 our %output_files;
62 our %input_files;
63 our @output_makefiles;
64
65 sub close_any_output_file() {
66     return unless defined $writing_output;
67     O->error and die "error writing $writing_output.tmp: $! (?)\n";
68     close O or die "error closing $writing_output.tmp: $!\n";
69     $writing_output = undef;
70 }
71
72 sub o {
73     if (defined $buffering_output) {
74         $buffering_output .= $_ foreach @_;
75         return;
76     }
77     die unless defined $writing_output;
78     print O @_ or die "error writing $writing_output.tmp: $!\n";
79 }
80
81 sub start_output_file ($) {
82     close_any_output_file();
83     ($writing_output) = @_;
84     die "$writing_output ?" if $output_files{$writing_output}++;
85     my $tmp = "$writing_output.tmp";
86     open O, ">", $tmp or die "create $tmp: $!\n";
87     o "# autogenerated - do not edit\n";
88 }
89
90 sub install_output_files () {
91     close_any_output_file();
92     foreach my $f (sort keys %output_files) {
93         rename "$f.tmp", $f or die "install new $f: $!\n";
94     }
95 }
96
97 sub write_makefile ($$) {
98     my ($dir_prefix,$depth) = @_;
99     #print STDERR "write_makefile @_\n";
100     start_output_file("${dir_prefix}Makefile");
101     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
102     my $suppress_templates=
103         '$(if $(filter-out clean real-clean, $(subdirmk_targets)),,'.
104         ' MAKEFILE_TEMPLATES=)';
105     o <<END;
106 default: all
107 \$(filter-out all,\$(MAKECMDGOALS)) all: run-main.mk
108         \@:
109 subdirmk_targets:=\$(or \$(MAKECMDGOALS),all)
110 Makefile run-main.mk:
111         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(subdirmk_targets))$suppress_templates
112 .SUFFIXES:
113 .PHONY: run-main.mk
114 END
115 }
116
117 sub process_input_mk ($$$$$$$$$);
118 sub process_input_mk ($$$$$$$$$) {
119     my ($dir_prefix, $dir_suffix, $dir_name,
120         $var_prefix, $var_prefix_name, $targets,
121         $f, $esclitr, $enoent_ok) = @_;
122
123     my $caps_re = qr{[A-Z]};
124     my $lc_re = qr{[a-z]};
125
126     my $esc;
127     my $set_esc = sub {
128         $esc = $$esclitr;
129         $esc =~ s/\W/\\$&/g;
130     };
131     $set_esc->();
132
133     my $input = new IO::File $f, '<';
134     if (!$input) {
135         die "open $f: $!\n" unless $!==ENOENT && $enoent_ok;
136         return;
137     }
138     $input_files{$f}++;
139
140     my %srcdirmap = (
141                   '^' => "\$(top_srcdir)${dir_suffix}",
142                   '~' => "\$(top_srcdir)",
143                     );
144     my %pfxmap = (
145                   ''  => $dir_prefix,
146                  );
147     $pfxmap{$_} = $srcdirmap{$_}.'/' foreach keys %srcdirmap;
148
149     while (<$input>) {
150         if (s#^\s*$esc\:##) {
151             $buffering_output='';
152         }
153         for (;;) {
154             unless (s{^(.*?)$esc}{}) { o $_; last; }
155             o $1;
156             if (s{^\\$esc}{}) { o "$$esclitr" }
157             elsif (s{^\\\$}{}) { o '$' }
158             elsif (s{^$esc}{}) { o "$$esclitr$$esclitr" }
159             elsif (s{^TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
160                 my $t = $1 // 'all';
161                 o target_varname($var_prefix, $t);
162                 $targets->{$t} //= [ ];
163             }
164             elsif (m{^(?=$caps_re)}) { o $var_prefix }
165             elsif (s{^([~^]?)(?=$lc_re)}{}) { o $pfxmap{$1} }
166             elsif (s{^_}{}) { o $var_prefix }
167             elsif (s{^=}{}) { o $var_prefix_name }
168             elsif (s{^([~^]?)/}{}) { o $pfxmap{$1} }
169             elsif (s{^\.}{}) { o $dir_name }
170             elsif (s{^([~^])\.}{}) { o $srcdirmap{$1} }
171             elsif (s{^([~^]?)(?=[ \t])}{}) {
172                 my $prefix = $pfxmap{$1} // die;
173                 my $after='';
174                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
175                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
176                 o $_;
177                 $_ = $after;
178             } elsif (s{^\#}{}) {
179                 $_ = '';
180             } elsif (s{^![ \t]+}{}) {
181                 o $_;
182                 $_ = '';
183             } else {
184                 die "bad escape $$esclitr$_ ";
185             }
186         }
187         if (defined $buffering_output) {
188             $_=$buffering_output;
189             $buffering_output=undef;
190             if (m#^(-?)include\s+(\S+)\s+$#) {
191                 my $subf = "$srcdir/$2";
192                 process_input_mk($dir_prefix, $dir_suffix, $dir_name,
193                                  $var_prefix, $var_prefix_name, $targets,
194                                  $subf, $esclitr, $1);
195                 o "\n";
196             } elsif (m#^changequote\s+(\S+)\s+$#) {
197                 $$esclitr = $1;
198                 $set_esc->();
199             } else {
200                 die "unknown directive $_ ";
201             }
202         }
203     }
204     $input->error and die "read $f: $!\n";
205     close $input or die "close $f: $!\n";
206 }
207
208 sub filter_subdir_mk ($$$$$$) {
209     my ($dir_prefix, $dir_suffix, $dir_name,
210         $var_prefix, $var_prefix_name, $targets) = @_;
211
212     #use Data::Dumper;
213     #print STDERR "filter @_\n";
214
215     my $esclit = '&';
216
217     my $pi = sub {
218         my ($f, $enoentok) = @_;
219         process_input_mk($dir_prefix, $dir_suffix, $dir_name,
220                          $var_prefix, $var_prefix_name, $targets,
221                          "${srcdir}/$f", \$esclit, $enoentok);
222     };
223     $pi->("${dir_prefix}Subdir.sd.mk", 0);
224     $pi->("Perdir.sd.mk",              1);
225 }
226
227 sub process_subtree ($$);
228 sub process_subtree ($$) {
229     # => list of descendants (in form SUBDIR/)
230     # recursive, children first
231     my ($node, $path) = @_;
232
233     #use Data::Dumper;
234     #print STDERR Dumper(\@_);
235
236     my $dir_prefix = join '', map { "$_/" } @$path;
237     my $dir_suffix = join '', map { "/$_" } @$path;
238     my $dir_name = join '/', @$path ? @$path : '.';
239     my $var_prefix_name = join '_', @$path ? @$path : qw(TOP);
240     my $var_prefix = "${var_prefix_name}_";
241
242     push @output_makefiles, "${dir_prefix}Subdir.mk";
243     write_makefile($dir_prefix, scalar @$path);
244
245     my %targets = (all => []);
246     foreach my $child (@{ $node->[1] }) {
247         my @childpath = (@$path, $child->[0]);
248         my $child_subdir = join '/', @childpath;
249         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!";
250         push @{ $targets{$_} }, $child_subdir foreach
251             process_subtree($child, \@childpath);
252     }
253     start_output_file("${dir_prefix}Subdir.mk.tmp");
254
255     if ($node->[2]) {
256         filter_subdir_mk($dir_prefix, $dir_suffix, $dir_name,
257                          $var_prefix, $var_prefix_name, \%targets);
258     } else {
259         my $sdmk = "${dir_prefix}Subdir.sd.mk";
260         if (stat $sdmk) {
261             die "$sdmk unexpectedly exists (${dir_prefix} not mentioned)";
262         } elsif ($!==ENOENT) {
263         } else {
264             die "stat $sdmk: $!";
265         }
266     }
267
268     o "\n";
269
270     my @targets = sort keys %targets;
271     foreach my $target (@targets) {
272         my $target_varname = target_varname($var_prefix, $target);
273         print O "${dir_prefix}${target}:: \$($target_varname)";
274         foreach my $child_subdir (@{ $targets{$target} }) {
275             print O " $child_subdir/$target";
276         }
277         print O "\n";
278     }
279     if (@targets) {
280         print O ".PHONY:";
281         print O " ${dir_prefix}${_}" foreach @targets;
282         print O "\n";
283     }
284
285     return @targets;
286 }
287
288 sub process_tree() {
289     process_subtree($root, [ ]);
290     start_output_file("main.mk.tmp");
291     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
292         o "$v=\@$v@\n";
293     }
294     o "SUBDIRMK_MAKEFILES :=\n";
295     o "MAKEFILE_TEMPLATES :=\n";
296     foreach my $mf (@output_makefiles) {
297         o "SUBDIRMK_MAKEFILES += $mf\n";
298     }
299     foreach my $input (sort keys %input_files) {
300         o "MAKEFILE_TEMPLATES += $input\n";
301     }
302     o "include \$(SUBDIRMK_MAKEFILES)\n";
303 }
304
305 build_tree();
306 process_tree();
307 install_output_files();