generate

   1 #!/usr/bin/perl -w
   2 #
   3 # subdirmk - &-filter (makefile generation program)
   4 #  Copyright 2019 Ian Jackson
   5 # SPDX-License-Identifier: LGPL-2.0-or-later
   6 #
   7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
   8 #
   9 # generates in each subdirectory        from in each subdirectory
  10 #     Subdir.mk.tmp                         Subdir.sd.mk
  11 #     Makefile                          and included files
  12 # and in toplevel                       and in toplevel
  13 #     main.mk.tmp                           Perdir.sd.mk
  14
  15 use strict;
  16 use POSIX;
  17
  18 print "$0 @ARGV\n" or die $!;
  19
  20 our $srcdir='.';
  21
  22 while (@ARGV && $ARGV[0] =~ m/^-/) {
  23     $_ = shift @ARGV;
  24     last if $_ eq '--';
  25     if (s/^--srcdir=//) {
  26         $srcdir=$';
  27     } else {
  28         die "$0: unknown option \`$_'\n";
  29     }
  30 }
  31 our @subdirs = @ARGV;
  32
  33 s{/+$}{} foreach @subdirs;
  34
  35 our $root = [ '.', [ ] ];
  36 # each node is [ 'relative subdir name', \@children ]
  37
  38 sub build_tree () {
  39     foreach my $subdir (@subdirs) {
  40         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
  41         my $node = $root;
  42         foreach my $d (@path) {
  43             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
  44             if (!$c) {
  45                 $c = [ $d, [ ] ];
  46                 push @{ $node->[1] }, $c;
  47             }
  48             $node = $c;
  49         }
  50     }
  51 }
  52
  53 sub target_varname ($$) {
  54     my ($var_prefix, $target) = @_;
  55     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
  56 }
  57
  58 our $writing_output;
  59 our $buffering_output;
  60 our %output_files;
  61 our %input_files;
  62
  63 sub close_any_output_file() {
  64     return unless defined $writing_output;
  65     O->error and die "error writing $writing_output.tmp: $! (?)\n";
  66     close O or die "error closing $writing_output.tmp: $!\n";
  67     $writing_output = undef;
  68 }
  69
  70 sub o {
  71     if (defined $buffering_output) {
  72         $buffering_output .= $_ foreach @_;
  73         return;
  74     }
  75     die unless defined $writing_output;
  76     print O @_ or die "error writing $writing_output.tmp: $!\n";
  77 }
  78
  79 sub start_output_file ($) {
  80     close_any_output_file();
  81     ($writing_output) = @_;
  82     die "$writing_output ?" if $output_files{$writing_output}++;
  83     my $tmp = "$writing_output.tmp";
  84     open O, ">", $tmp or die "create $tmp: $!\n";
  85     o "# autogenerated - do not edit\n";
  86 }
  87
  88 sub install_output_files () {
  89     close_any_output_file();
  90     foreach my $f (sort keys %output_files) {
  91         rename "$f.tmp", $f or die "install new $f: $!\n";
  92     }
  93 }
  94
  95 sub write_makefile ($$) {
  96     my ($dir_prefix,$depth) = @_;
  97     #print STDERR "write_makefile @_\n";
  98     start_output_file("${dir_prefix}Makefile");
  99     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
 100     o <<END;
 101 default: all
 102 \$(filter-out all,\$(MAKECMDGOALS)) all: run-main.mk
 103         \@:
 104 subdirmk_targets:=\$(or \$(MAKECMDGOALS),all)
 105 Makefile run-main.mk:
 106         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(subdirmk_targets))
 107 .SUFFIXES:
 108 .PHONY: run-main.mk
 109 END
 110 }
 111
 112 sub process_input_mk ($$$$$$$$);
 113 sub process_input_mk ($$$$$$$$) {
 114     my ($dir_prefix, $dir_suffix, $dir_name,
 115         $var_prefix, $targets,
 116         $f, $esclitr, $enoent_ok) = @_;
 117
 118     my $caps_re = qr{[A-Z]};
 119     my $lc_re = qr{[a-z]};
 120
 121     my $esc;
 122     my $set_esc = sub {
 123         $esc = $$esclitr;
 124         $esc =~ s/\W/\\$&/g;
 125     };
 126     $set_esc->();
 127
 128     my $input = new IO::File $f, '<';
 129     if (!$input) {
 130         die "open $f: $!\n" unless $!==ENOENT && $enoent_ok;
 131         return;
 132     }
 133     $input_files{$f}++;
 134
 135     my %pfxmap = (
 136                   ''  => $dir_prefix,
 137                   '^' => "\$(top_srcdir)${dir_suffix}/",
 138                   '~' => "\$(top_srcdir)/",
 139                  );
 140
 141     while (<$input>) {
 142         if (s#^\s*$esc\:##) {
 143             $buffering_output='';
 144         }
 145         for (;;) {
 146             unless (s{^(.*?)(\\)?(?=$esc)}{}) { o $_; last; }
 147             o $1;
 148             if ($2) { s#^$esc##; o $$esclitr; next; }
 149             s{^$esc}{} or die "$_ ?";
 150             if (s{^$esc}{}) { o "$$esclitr$$esclitr" }
 151             elsif (s{^TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
 152                 my $t = $1 // 'all';
 153                 o target_varname($var_prefix, $t);
 154                 $targets->{$t} //= [ ];
 155             }
 156             elsif (m{^(?=$caps_re)}) { o $var_prefix }
 157             elsif (s{^([~^]?)(?=$lc_re)}{}) { o $pfxmap{$1} }
 158             elsif (s{^_}{}) { o $var_prefix }
 159             elsif (s{^=_}{}) { o $var_prefix }
 160             elsif (s{^([~^]?)/}{}) { o $pfxmap{$1} }
 161             elsif (s{^=/}{}) { o $dir_name }
 162             elsif (s{^([~^]?)(?=[ \t])}{}) {
 163                 my $prefix = $pfxmap{$1} // die;
 164                 my $after='';
 165                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
 166                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
 167                 o $_;
 168                 $_ = $after;
 169             } elsif (s{^\#}{}) {
 170                 $_ = '';
 171             } elsif (s{^![ \t]+}{}) {
 172                 o $_;
 173                 $_ = '';
 174             } elsif (s{^!(\S+)(?:[ \t]+|$)}{}) {
 175                 $$esclitr = $1;
 176                 $set_esc->();
 177             } else {
 178                 die "bad escape $$esclitr$_ ";
 179             }
 180         }
 181         if (defined $buffering_output) {
 182             $_=$buffering_output;
 183             $buffering_output=undef;
 184             if (m#^(-?)include\s+(\S+)\s+$#) {
 185                 my $subf = "$srcdir/$2";
 186                 process_input_mk($dir_prefix, $dir_suffix, $dir_name,
 187                                  $var_prefix, $targets,
 188                                  $subf, $esclitr, $1);
 189                 o "\n";
 190             } else {
 191                 die "unknown directive $_ ";
 192             }
 193         }
 194     }
 195     $input->error and die "read $f: $!\n";
 196     close $input or die "close $f: $!\n";
 197 }
 198
 199 sub filter_subdir_mk ($$$$$) {
 200     my ($dir_prefix, $dir_suffix, $dir_name,
 201         $var_prefix, $targets) = @_;
 202
 203     #use Data::Dumper;
 204     #print STDERR "filter @_\n";
 205
 206     my $esclit = '&';
 207
 208     my $pi = sub {
 209         my ($f, $enoentok) = @_;
 210         process_input_mk($dir_prefix, $dir_suffix, $dir_name,
 211                          $var_prefix, $targets,
 212                          "${srcdir}/$f", \$esclit, $enoentok);
 213     };
 214     $pi->("${dir_prefix}Subdir.sd.mk", 0);
 215     $pi->("Perdir.sd.mk",              1);
 216 }
 217
 218 sub process_subtree ($$);
 219 sub process_subtree ($$) {
 220     # => list of descendants (in form SUBDIR/)
 221     # recursive, children first
 222     my ($node, $path) = @_;
 223
 224     #use Data::Dumper;
 225     #print STDERR Dumper(\@_);
 226
 227     my $dir_prefix = join '', map { "$_/" } @$path;
 228     my $dir_suffix = join '', map { "/$_" } @$path;
 229     my $dir_name = join '/', @$path ? @$path : '.';
 230     my $var_prefix = join '', map { "${_}_" } @$path ? @$path : qw(TOP);
 231
 232     write_makefile($dir_prefix, scalar @$path);
 233
 234     my %targets = (all => []);
 235     foreach my $child (@{ $node->[1] }) {
 236         my @childpath = (@$path, $child->[0]);
 237         my $child_subdir = join '/', @childpath;
 238         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!";
 239         push @{ $targets{$_} }, $child_subdir foreach
 240             process_subtree($child, \@childpath);
 241     }
 242     start_output_file("${dir_prefix}Subdir.mk.tmp");
 243
 244     filter_subdir_mk($dir_prefix, $dir_suffix, $dir_name,
 245                      $var_prefix, \%targets);
 246
 247     o "\n";
 248
 249     my @targets = sort keys %targets;
 250     foreach my $target (@targets) {
 251         my $target_varname = target_varname($var_prefix, $target);
 252         print O "${dir_prefix}${target}:: \$($target_varname)";
 253         foreach my $child_subdir (@{ $targets{$target} }) {
 254             print O " $child_subdir/$target";
 255         }
 256         print O "\n";
 257     }
 258
 259     return @targets;
 260 }
 261
 262 sub process_tree() {
 263     process_subtree($root, [ ]);
 264     start_output_file("main.mk.tmp");
 265     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
 266         o "$v=\@$v@\n";
 267     }
 268     o "SUBDIRMK_MAKEFILES :=\n";
 269     o "MAKEFILE_TEMPLATES :=\n";
 270     o "SUBDIRMK_MAKEFILES += Subdir.mk\n";
 271     foreach my $subdir (@subdirs) {
 272         o "SUBDIRMK_MAKEFILES += $subdir/Subdir.mk\n";
 273     }
 274     foreach my $input (sort keys %input_files) {
 275         o "MAKEFILE_TEMPLATES += $input\n";
 276     }
 277     o "include \$(SUBDIRMK_MAKEFILES)";
 278 }
 279
 280 build_tree();
 281 process_tree();
 282 install_output_files();