generate

   1 #!/usr/bin/perl -w
   2 #
   3 # subdirmk - &-filter (makefile generation program)
   4 #  Copyright 2019 Ian Jackson
   5 # SPDX-License-Identifier: LGPL-2.0-or-later
   6 #
   7 # $(srcdir)/subdirmk/generate [--srcdir=SRCDIR] [--] SUBDIR...
   8 #
   9 # generates in each subdirectory
  10 #     Dir.mk.tmp
  11 #     Makefile
  12 # and in toplevel
  13 #     main.mk.tmp
  14
  15 use strict;
  16 use POSIX;
  17
  18 print "$0 @ARGV\n" or die $!;
  19
  20 our $srcdir='.';
  21
  22 # error handling methods:
  23 #
  24 # Error in input file, while $err_file and $. set, eg in most of
  25 # process_input_mk:
  26 #         err "message";
  27 #
  28 # Other input or usage errors:
  29 #         die "subdirmk: $file:$lno: problem\n";
  30 #         die "subdirmk: some problem not locatable in that way\n";
  31 #
  32 # Usage error:
  33 #         die "subdirmk $0: explanation of problem\n";
  34 #
  35 # System call error (not ENOENT) accessing input/output files:
  36 #         die "description of problem eg maybe erbing noun: $!\n";
  37 #
  38 # Bug detedcted in `generate':
  39 #         die "internal error (some information)?"; # or similar
  40
  41 while (@ARGV && $ARGV[0] =~ m/^-/) {
  42     $_ = shift @ARGV;
  43     last if $_ eq '--';
  44     if (s/^--srcdir=//) {
  45         $srcdir=$';
  46     } else {
  47         die "subdirmk $0: unknown option \`$_'\n";
  48     }
  49 }
  50 our @subdirs = @ARGV;
  51
  52 s{/+$}{} foreach @subdirs;
  53
  54 our $root = [ '.', [ ], 1 ];
  55 # each node is [ 'relative subdir name', \@children, $mentioned ]
  56
  57 sub build_tree () {
  58     foreach my $subdir (@subdirs) {
  59         my @path = $subdir eq '.' ? () : split m{/+}, $subdir;
  60         my $node = $root;
  61         foreach my $d (@path) {
  62             my ($c,) = grep { $_->[0] eq $d } @{ $node->[1] };
  63             if (!$c) {
  64                 $c = [ $d, [ ] ];
  65                 push @{ $node->[1] }, $c;
  66             }
  67             $node = $c;
  68         }
  69         $node->[2] = 1;
  70     }
  71 }
  72
  73 sub target_varname ($$) {
  74     my ($var_prefix, $target) = @_;
  75     return $var_prefix.'TARGETS'.($target eq 'all' ? '' : "_$target");
  76 }
  77
  78 our $writing_output;
  79 our $buffering_output;
  80 our %output_files;
  81 our %input_files;
  82 our @output_makefiles;
  83
  84 sub close_any_output_file() {
  85     return unless defined $writing_output;
  86     O->error and die "error writing $writing_output.tmp: $! (?)\n";
  87     close O or die "error closing $writing_output.tmp: $!\n";
  88     $writing_output = undef;
  89 }
  90
  91 sub oraw {
  92     die 'internal error' unless defined $writing_output;
  93     print O @_ or die "error writing $writing_output.tmp: $!\n";
  94 }
  95
  96 sub oud { # undoubled
  97     if (defined $buffering_output) {
  98         $buffering_output .= $_ foreach @_;
  99         return;
 100     }
 101     oraw @_;
 102 }
 103
 104 our $ddbl;
 105
 106 sub od { # maybe $-doubled
 107     if (!$ddbl) {
 108         oud @_;
 109         return;
 110     }
 111     foreach (@_) {
 112         my $e = $_;
 113         $e =~ s{\$}{\$\$}g;
 114         oud $e;
 115     }
 116 }
 117
 118 sub start_output_file ($) {
 119     close_any_output_file();
 120     ($writing_output) = @_;
 121     die "internal error ($writing_output?)"
 122         if $output_files{$writing_output}++;
 123     my $tmp = "$writing_output.tmp";
 124     open O, ">", $tmp or die "create $tmp: $!\n";
 125     oraw "# autogenerated - do not edit\n";
 126 }
 127
 128 sub install_output_files () {
 129     close_any_output_file();
 130     foreach my $f (sort keys %output_files) {
 131         rename "$f.tmp", $f or die "install new $f: $!\n";
 132     }
 133 }
 134
 135 sub write_makefile ($$) {
 136     my ($dir_prefix,$depth) = @_;
 137     #print STDERR "write_makefile @_\n";
 138     start_output_file("${dir_prefix}Makefile");
 139     my $cd = $depth ? join('/', ('..',) x $depth) : '.';
 140     my $suppress_templates=
 141         '$(if $(filter-out clean real-clean, $(subdirmk_targets)),,'.
 142         ' MAKEFILE_TEMPLATES=)';
 143     oraw <<END;
 144 default: all
 145 \$(filter-out all,\$(MAKECMDGOALS)) all: run-main.mk
 146         \@:
 147 subdirmk_targets:=\$(or \$(MAKECMDGOALS),all)
 148 Makefile run-main.mk:
 149         \$(MAKE) -C $cd -f main.mk \$(addprefix ${dir_prefix},\$(subdirmk_targets))$suppress_templates
 150 .SUFFIXES:
 151 .PHONY: run-main.mk
 152 END
 153 }
 154
 155 our %varref;
 156 our %varref_exp;
 157
 158 our ($dir_prefix, $dir_suffix, $dir_name,
 159      $var_prefix, $var_prefix_name);
 160
 161 sub dir_prefix ($) {
 162     my ($path) = @_;
 163     join '', map { "$_/" } @$path;
 164 }
 165
 166 sub set_dir_vars ($) {
 167     my ($path) = @_;
 168     $dir_prefix = dir_prefix($path);
 169     $dir_suffix = join '', map { "/$_" } @$path;
 170     $dir_name = join '/', @$path ? @$path : '.';
 171     $var_prefix_name = join '_', @$path ? @$path : qw(TOP);
 172     $var_prefix = "${var_prefix_name}_";
 173 }
 174
 175 our $err_file;
 176
 177 our @warn_ena_dfl = map { $_ => 1 } qw(
 178     local+global
 179     single-char-var
 180     unknown-warning
 181     broken-var-ref
 182 );
 183 our %warn_ena = @warn_ena_dfl;
 184
 185 our $warned;
 186 our %warn_unk;
 187
 188 sub err ($) {
 189     my ($m) = @_;
 190     die "subdirmk: ${err_file}:$.: $m\n";
 191 }
 192
 193 sub wrncore ($$) {
 194     my ($wk,$m) = @_;
 195     return 0 unless $warn_ena{$wk} // warn "internal error $wk ?";
 196     $warned++;
 197     print STDERR "subdirmk: warning ($wk): $m\n";
 198     return 1;
 199 }
 200
 201 sub wrn ($$) {
 202     my ($wk,$m) = @_;
 203     our %warn_dedupe;
 204     return 0 if $warn_dedupe{$err_file,$.,$wk,$m}++;
 205     wrncore($wk, "${err_file}:$.: $m");
 206 }
 207
 208 sub ddbl_only ($) {
 209     my ($e) = @_;
 210     return if $ddbl;
 211     err "escape &$e is valid only during \$-doubling";
 212 }
 213
 214 sub process_input_mk ($$$$);
 215 sub process_input_mk ($$$$) {
 216     my ($targets, $f, $esclitr, $enoent_ok) = @_;
 217
 218     my $caps_re = qr{[A-Z]};
 219     my $lc_re = qr{[a-z]};
 220
 221     my $esc;
 222     my $set_esc = sub {
 223         $esc = $$esclitr;
 224         $esc =~ s/\W/\\$&/g;
 225     };
 226     $set_esc->();
 227
 228     my $input = new IO::File $f, '<';
 229     if (!$input) {
 230         err "open $f: $!" unless $!==ENOENT && $enoent_ok;
 231         return;
 232     }
 233     $input_files{$f}++;
 234
 235     local $err_file=$f;
 236
 237     my %srcdirmap = (
 238                   '^' => "\${top_srcdir}${dir_suffix}",
 239                   '~' => "\${top_srcdir}",
 240                     );
 241     my %pfxmap = (
 242                   ''  => $dir_prefix,
 243                  );
 244     $pfxmap{$_} = $srcdirmap{$_}.'/' foreach keys %srcdirmap;
 245
 246     local $ddbl;
 247     my @nest = (['']);
 248     my $evalcall_brackets;
 249
 250     my $push_nest = sub {
 251         my ($nk, $nndbl, $what) = @_;
 252         unshift @nest, [ $nk, $ddbl, $what, $. ];
 253         $ddbl = $nndbl;
 254     };
 255     my $pop_nest = sub {
 256         my ($nk) = @_;
 257         err "unexpectedly closed $nk in middle of $nest[0][0] ($nest[0][2])"
 258             unless $nest[0][0] eq $nk;
 259         $ddbl = (shift @nest)[1];
 260     };
 261
 262     # Our detection of variable settings does not have to be completely
 263     # accurate, since it is only going to be used for advice to the user.
 264     my $note_varref = sub {
 265         my ($vn,$amp) = @_;
 266         return if $varref_exp{$vn}{$amp};
 267         $varref{$vn}{$amp}{"$f:$."} = 1;
 268     };
 269
 270     while (<$input>) {
 271         if (m#^\s*($esc)?(\w+)\s*(?:=|\+=|\?=|:=)# ||
 272             m#^\s*(?:$esc\:macro|define)\s+($esc)?(\S+)\s#) {
 273             $note_varref->($2,!!$1);
 274         }
 275         if (s#^\s*$esc\:changequote\s+(\S+)\s+$##) {
 276             $$esclitr = $1;
 277             $set_esc->();
 278             next;
 279         } elsif (s#^\s*$esc\:endm\s+$##) {
 280             $pop_nest->('macro');
 281             od "endef\n";
 282             next;
 283         } elsif (s#^\s*$esc\:warn\s+(\S.*)$##) {
 284             foreach my $wk (split /\s+/, $1) {
 285                 my $yes = $wk !~ s{^!}{};
 286                 if (defined $warn_ena{$wk}) {
 287                     $warn_ena{$wk} = $yes;
 288                     next;
 289                 } elsif ($yes) {
 290                     wrn 'unknown-warning',
 291                         "unknown warning $wk requested";
 292                 } else {
 293                     $warn_unk{$wk} //= "$f:$.";
 294                 }
 295             }
 296             next;
 297         } elsif (s#^\s*$esc\:local\+global\s+(\S.*)$##) {
 298             foreach my $vn (split /\s+/, $1) {
 299                 my $pos = !($vn =~ s{^!}{});
 300                 my $amp = $vn =~ s{^$esc}{};
 301                 $varref_exp{$vn}{!!$amp} = $pos;
 302             }
 303             next;
 304         } elsif (s#^\s*$esc\:(?=(-?)include|macro)##) {
 305             $buffering_output='';
 306         } elsif (m#^\s*$esc\:([a-z][-+0-9a-z_]*)#) {
 307             err "unknown directive &:$1 or bad argumnt syntax";
 308         } elsif (s{^\s*${esc}TARGETS(?:_([0-9a-zA-Z_]+))?(?=\W)}{}) {
 309             my $t = $1 // 'all';
 310             my $vn = target_varname($var_prefix, $t);
 311             $note_varref->($vn,1);
 312             od $vn;
 313             $targets->{$t} //= [ ];
 314         }
 315         for (;;) {
 316             err 'cannot $-double &-processed RHS of directive'
 317                 if $ddbl && defined $buffering_output;
 318             unless ($nest[0][0] eq 'eval'
 319                     ? s{^(.*?)($esc|\$|[{}])}{}
 320                     : s{^(.*?)($esc|\$)}{}) { od $_; last; }
 321             od $1;
 322             if ($2 eq '{') {
 323                 od $2;
 324                 $evalcall_brackets++;
 325                 next;
 326             } elsif ($2 eq '}') {
 327                 od $2;
 328                 next if --$evalcall_brackets;
 329                 $pop_nest->('eval');
 330                 od '}';
 331                 next;
 332             } elsif ($2 eq '$') {
 333                 od $2;
 334                 if (s{^\$}{}) { od $&; }
 335                 elsif (m{^[a-zA-Z]\w}) {
 336                     wrn 'single-char-var',
 337                     'possibly confusing unbracketed single-char $-expansion';
 338                 }
 339                 elsif (m{^$esc}) {
 340                     wrn 'broken-var-ref',
 341                     'broken $&... expansion; you probably meant &$';
 342                 }
 343                 elsif (m{^\(($esc)?([^()\$]+)\)} ||
 344                        m{^\{($esc)?([^{}\$]+)\}}) {
 345                     $note_varref->($2,!!$1);
 346                 }
 347                 next;
 348             }
 349             if (s{^\\$esc}{}) { od "$$esclitr" }
 350             elsif (s{^\\\$}{}) { oud '$' }
 351             elsif (s{^\\\s+$}{}) { }
 352             elsif (s{^$esc}{}) { od "$$esclitr$$esclitr" }
 353             elsif (m{^(?=$caps_re)}) { od $var_prefix }
 354             elsif (s{^\$([A-Za-z]\w+)}{}) {
 355                 $note_varref->($1,1);
 356                 od "\${${var_prefix}$1}";
 357             }
 358             elsif (s{^([~^]?)(?=$lc_re)}{}) { od $pfxmap{$1} }
 359             elsif (s{^_}{}) { od $var_prefix }
 360             elsif (s{^=}{}) { od $var_prefix_name }
 361             elsif (s{^([~^]?)/}{}) { od $pfxmap{$1} }
 362             elsif (s{^\.}{}) { od $dir_name }
 363             elsif (s{^([~^])\.}{}) { od $srcdirmap{$1} }
 364             elsif (s{^\$\-}{}) { $ddbl=undef; }
 365             elsif (s{^\$\+}{}) { $ddbl=1; }
 366             elsif (s{^\$\(}{}) {
 367                 ddbl_only($&); oud "\${";
 368                 $note_varref->($2,!!$1) if m{^($esc)?([^()\$]+\))};
 369             }
 370             elsif (s{^\$(\d+)}{}) { ddbl_only($&); oud "\${$1}"; }
 371             elsif (s{^\$\{}{}) {
 372                 err 'macro invocation cannot be re-$-doubled' if $ddbl;
 373                 od '${eval ${call ';
 374                 $evalcall_brackets = 1;
 375                 $push_nest->('eval',1, '&${...}');
 376                 $note_varref->($2,!!$1) if m{^\s*($esc)?([^,{}\$]+)};
 377             } elsif (s{^([~^]?)(?=[ \t])}{}) {
 378                 my $prefix = $pfxmap{$1} // die "internal error ($1?)";
 379                 my $after='';
 380                 if (m{([ \t])$esc}) { ($_,$after) = ($`, $1.$'); }
 381                 s{(?<=[ \t])(?=\S)(?!\\\s*$)}{$prefix}g;
 382                 od $_;
 383                 $_ = $after;
 384             } elsif (s{^\#}{}) {
 385                 $_ = '';
 386             } elsif (s{^![ \t]+}{}) {
 387                 od $_;
 388                 $_ = '';
 389             } else {
 390                 m{^.{0,5}};
 391                 err "bad &-escape \`$$esclitr$&'";
 392             }
 393         }
 394         if (defined $buffering_output) {
 395             $_=$buffering_output;
 396             $buffering_output=undef;
 397             if (m#^(-?)include\s+(\S+)\s+$#) {
 398                 my $subf = "$srcdir/$2";
 399                 process_input_mk($targets, $subf, $esclitr, $1);
 400                 od "\n";
 401             } elsif (m#^macro\s+(\S+)\s+$#) {
 402                 od "define $1\n";
 403                 $push_nest->('macro', 1, '&:macro');
 404             } else {
 405                 err "bad directive argument syntax";
 406             }
 407         }
 408     }
 409     die "subdirmk: $f:$nest[0][3]: unclosed $nest[0][0] ($nest[0][2])\n"
 410         if $nest[0][0];
 411     $input->error and die "read $f: $!\n";
 412     close $input or die "close $f: $!\n";
 413 }
 414
 415 sub filter_subdir_mk ($) {
 416     my ($targets) = @_;
 417
 418     #use Data::Dumper;
 419     #print STDERR "filter @_\n";
 420
 421     my $esclit = '&';
 422
 423     my $pi = sub {
 424         my ($f, $enoentok) = @_;
 425         process_input_mk($targets, "${srcdir}/$f", \$esclit, $enoentok);
 426     };
 427     $pi->("Prefix.sd.mk",           1);
 428     $pi->("${dir_prefix}Dir.sd.mk", 0);
 429     $pi->("Suffix.sd.mk",           1);
 430 }
 431
 432 sub process_subtree ($$);
 433 sub process_subtree ($$) {
 434     # => list of targets (in form SUBDIR/)
 435     # recursive, children first
 436     my ($node, $path) = @_;
 437
 438     #use Data::Dumper;
 439     #print STDERR Dumper(\@_);
 440
 441     local %varref_exp;
 442
 443     my $dir_prefix = dir_prefix($path);
 444     # ^ this is the only var which we need before we come back from
 445     #   the recursion.
 446
 447     push @output_makefiles, "${dir_prefix}Dir.mk";
 448     write_makefile($dir_prefix, scalar @$path);
 449
 450     my %targets = (all => []);
 451     foreach my $child (@{ $node->[1] }) {
 452         my @childpath = (@$path, $child->[0]);
 453         my $child_subdir = join '/', @childpath;
 454         mkdir $child_subdir or $!==EEXIST or die "mkdir $child_subdir: $!\n";
 455         local %warn_ena = @warn_ena_dfl;
 456         push @{ $targets{$_} }, $child_subdir foreach
 457             process_subtree($child, \@childpath);
 458     }
 459
 460     set_dir_vars($path);
 461     start_output_file("${dir_prefix}Dir.mk.tmp");
 462
 463     if ($node->[2]) {
 464         filter_subdir_mk(\%targets);
 465     } else {
 466         my $sdmk = "${dir_prefix}Dir.sd.mk";
 467         if (stat $sdmk) {
 468             die
 469  "subdirmk: $sdmk unexpectedly exists (${dir_prefix} not mentioned on subdirmk/generate command line, maybe directory is missing from SUBDIRMK_SUBDIRS)";
 470         } elsif ($!==ENOENT) {
 471         } else {
 472             die "stat $sdmk: $!\n";
 473         }
 474     }
 475
 476     oraw "\n";
 477
 478     my @targets = sort keys %targets;
 479     foreach my $target (@targets) {
 480         my $target_varname = target_varname($var_prefix, $target);
 481         oraw "${dir_prefix}${target}:: \$($target_varname)";
 482         foreach my $child_subdir (@{ $targets{$target} }) {
 483             oraw " $child_subdir/$target";
 484         }
 485         oraw "\n";
 486     }
 487     if (@targets) {
 488         oraw ".PHONY:";
 489         oraw " ${dir_prefix}${_}" foreach @targets;
 490         oraw "\n";
 491     }
 492
 493     return @targets;
 494 }
 495
 496 sub process_final ($) {
 497     my ($otargets) = @_;
 498     set_dir_vars([]);
 499     push @output_makefiles, "Final.mk";
 500     start_output_file("Final.mk.tmp");
 501     my %ntargets;
 502     my $esclit='&';
 503     process_input_mk(\%ntargets, "${srcdir}/Final.sd.mk", \$esclit, 1);
 504     delete $ntargets{$_} foreach @$otargets;
 505     my @ntargets = sort keys %ntargets;
 506     die "subdirmk: Final.sd.mk may not introduce new top-level targets".
 507         " (@ntargets)\n" if @ntargets;
 508 }
 509
 510 sub process_tree() {
 511     my @targets = process_subtree($root, [ ]);
 512     process_final(\@targets);
 513     start_output_file("main.mk.tmp");
 514     foreach my $v (qw(top_srcdir abs_top_srcdir)) {
 515         oraw "$v=\@$v@\n";
 516     }
 517     oraw "SUBDIRMK_MAKEFILES :=\n";
 518     oraw "MAKEFILE_TEMPLATES :=\n";
 519     foreach my $mf (@output_makefiles) {
 520         oraw "SUBDIRMK_MAKEFILES += $mf\n";
 521     }
 522     foreach my $input (sort keys %input_files) {
 523         oraw "MAKEFILE_TEMPLATES += $input\n";
 524     }
 525     oraw "include \$(SUBDIRMK_MAKEFILES)\n";
 526 }
 527
 528 sub flmap ($) { local ($_) = @_; s{:(\d+)$}{ sprintf ":%10d", $1 }e; $_; }
 529
 530 sub print_varref_warnings () {
 531     foreach my $vn (sort keys %varref) {
 532         my $vv = $varref{$vn};
 533         next unless $vv->{''} && $vv->{1};
 534         wrncore 'local+global', "saw both $vn and &$vn" or return;
 535         foreach my $amp ('', 1) {
 536             printf STDERR " saw %s%s at %s\n",
 537                 ($amp ? '&' : ''), $vn, $_
 538                 foreach
 539                 sort { flmap($a) cmp flmap($b) }
 540                 keys %{ $vv->{$amp} };
 541         }
 542     }
 543 }
 544
 545 sub print_warning_warnings () {
 546     return unless $warned;
 547     foreach my $wk (sort keys %warn_unk) {
 548         wrncore 'unknown-warning',
 549             "$warn_unk{$wk}: attempt to suppress unknown warning(s) \`$wk'";
 550     }
 551 }
 552
 553 build_tree();
 554 process_tree();
 555 print_varref_warnings();
 556 print_warning_warnings();
 557 install_output_files();