generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $facesf;
  21 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  22
  23 sub TAU { M_PI * 2.0; }
  24 sub MM2PT { 72.0 / 25.4; }
  25
  26 our $mid;
  27
  28 our $a4_w = 595;
  29 our $a4_h = 842;
  30 our $a3_h = 1190;
  31
  32 our $max_printeredge = 5.50;
  33
  34
  35 # ----- region names from plag, incl. reverse mapping -----
  36
  37 our %prs2region;
  38
  39 sub prep_region_rmap () {
  40   foreach my $rn (keys %region) {
  41     my $prs = plag_prs($rn);
  42     die if $prs2region{$prs};
  43     $prs2region{$prs} = $rn;
  44   }
  45 }
  46
  47 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  48
  49 sub prs2r ($) {
  50   # bodgery for the sea and land
  51   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  52   $prs2region{$_[0]} // confess "@_ ?"
  53 }
  54 sub prs2rr ($) { $region{prs2r($_[0])} }
  55
  56 #----- file reader for plag output -----
  57
  58 sub read_faces () {
  59   # Sets
  60   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  61   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  62   #  $region{NAME}{Polygon}{Pos}
  63   #  $region{NAME}{Special}
  64   #
  65   # also incidentally
  66   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  67   #  $region{NAME}{Polygon}{Adjoins}
  68   # which should be ignored
  69
  70   open P, "<", $facesf or die $!;
  71   while (<P>) { last if m/^\&faces$/; }
  72   my $rr;
  73   my @edges;
  74   my $process_rr = sub {
  75     my $last_ai;
  76     if ($rr->{Name} eq 'NZ') {
  77       # We combined L and NZ; now we must split them again
  78       # in fact, we just throw away L and L2 entirely.
  79       # Here, when processing NZ, we keep only vertices that
  80       # are part of NZ.
  81       @edges = grep {
  82         my $evxname = $_->{VxName};
  83         my @eregions = split / \| ?/, $evxname;
  84         grep { $_ eq 'NZ' } @eregions
  85       } @edges;
  86     }
  87     $rr->{Polygon} = [ @edges ];
  88     if ($rr->{Name} ne 'NZ') {
  89       for my $ei (0..$#edges) {
  90         if (!defined $last_ai) {
  91           my $ai;
  92           for my $ai (0..$#{ $rr->{Adj} }) {
  93             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  94             $last_ai = $ai+1;
  95           }
  96           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
  97         }
  98         my $ai = ($last_ai-1+@edges) % @edges;
  99         $last_ai = $ai;
 100         my $adj = $rr->{Adj}[$ai];
 101         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 102                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 103             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 104
 105         for my $endi (0..1) {
 106           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 107         }
 108       }
 109     }
 110     @edges = ();
 111     $rr = undef;
 112   };
 113   my $vxname;
 114   for (;;) {
 115     $!=0; $_=<P> // confess $!;
 116     last if m/^\&$/;
 117     if (m/^$sre$/) {
 118       my $new_face= $2;
 119       $process_rr->() if $rr;
 120       $rr= prs2rr($new_face);
 121     } elsif (m/^\s+$sre$/) {
 122       confess unless $rr;
 123       $vxname = $2;
 124       push @edges, { VxName => $vxname };
 125     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 126       $edges[-1]{Adjoins} = prs2r($2);
 127     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 128       my $pos = mkvec($1,$2);
 129       confess unless defined $vxname;
 130       $edges[-1]{Pos} = $pos;
 131       $vxname2pos{$vxname} = $pos;
 132     }
 133   }
 134   $process_rr->();
 135
 136   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 137 }
 138
 139 #----- geometry mangling -----
 140
 141 sub adj_ends ($) {
 142   my ($adj) = @_;
 143   map { $_->{Pos} } @{ $adj->{Ends} };
 144 }
 145
 146 sub calculate_centres () {
 147   # Sets
 148   #  $region{NAME}{Centre}
 149   foreach my $rr (values %region) {
 150     next if $rr->{Special};
 151     my $sum = Math::GSL::Vector->new(2);
 152     my $wsum = 0;
 153     foreach my $adj (@{ $rr->{Adj} }) {
 154       my @ends = adj_ends($adj);
 155       my $w = ($ends[1] - $ends[0])->norm();
 156       $sum += $w * $_ foreach @ends;
 157       $wsum += $w;
 158     }
 159     $rr->{Centre} = $sum * (0.5 / $wsum);
 160   }
 161 }
 162
 163 sub for_each_pos ($) {
 164   my ($f) = @_;
 165   my $call = sub {
 166     my ($pr,$rr,$why) = @_;
 167     return unless defined $$pr;
 168     $f->($pr,$rr,$why);
 169   };
 170   foreach my $rr (values %region) {
 171     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 172     foreach my $vertex (@{ $rr->{Polygon} }) {
 173       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 174     }
 175   }
 176 }
 177
 178 sub prvec ($) {
 179   my ($v) = @_;
 180   confess unless $v;
 181   sprintf "%g,%g", $v->get(0), $v->get(1);
 182 }
 183
 184 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 185 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 186
 187 sub transform_coordinates () {
 188   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 189   # until it's all in PostScript points
 190   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 191   my $dir = $or[1] - $or[0];
 192   my $theta = vec2atan($dir);
 193   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 194   my $s = sin($rotateby);
 195   my $c = cos($rotateby);
 196   my $transform = Math::GSL::Matrix->new(2,2);
 197   $transform->set_row(0, [  $c, -$s ]);
 198   $transform->set_row(1, [  $s,  $c ]);
 199   print STDERR "rotate was=",prvec($dir)," theta=$theta",
 200       " rotateby=$rotateby s=$s c=$c\n";
 201   my @lims;
 202   foreach my $topend (qw(0 1)) {
 203     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 204     $lims[$topend] = mkvec($v,$v);
 205   }
 206   for_each_pos(sub {
 207     my ($pr, $rr, $why) = @_;
 208     my $y = Math::GSL::Vector->new(2);
 209     gsl_blas_dgemv($CblasNoTrans,
 210                    1.0, $transform->raw,
 211                    $$pr->raw,
 212                    0, $y->raw)
 213         and confess;
 214     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 215     gsl_blas_dcopy($y->raw, $$pr->raw)
 216         and confess;
 217     foreach my $topend (qw(0 1)) {
 218       foreach my $xy (qw(0 1)) {
 219         my $now = $y->get($xy);
 220         my $lim = $lims[$topend]->get($xy);
 221         #print STDERR "?set $topend $xy $now $lim\n";
 222         next if $topend ? ($now <= $lim) : ($now >= $lim);
 223         $lims[$topend]->set([$xy], [$now]);
 224         #print STDERR "set $topend $xy $now\n";
 225       }
 226     }
 227   });
 228   print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 229   my $translate = -$lims[0];
 230   print STDERR "translate ",prvec($translate),"\n";
 231   my $scale = $c{GraphScale} * MM2PT;
 232   for_each_pos(sub {
 233     my ($pr) = @_;
 234     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 235     gsl_vector_scale($$pr->raw, $scale) and confess;
 236   });
 237   $mid = ($lims[1] - $lims[0]) * 0.5;
 238 }
 239
 240 sub adjust_nz() {
 241   my $poly = $region{NZ}{Polygon};
 242   my %occurs;
 243   foreach my $v (@$poly) {
 244     $occurs{$v->{VxName}}++
 245   }
 246   foreach my $v (@$poly) {
 247     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 248   }
 249   print STDERR " nz ".(scalar @$poly)."\n";
 250   my $occurs_m = sub {
 251     my ($ei) = @_;
 252     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 253   };
 254   for my $ei (0..$#$poly) {
 255     next if $occurs_m->($ei);
 256     next unless $occurs_m->($ei-1);
 257     next unless $occurs_m->($ei+1);
 258     print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 259     # adjust coord outwards
 260   }
 261   for my $ei (0..$#$poly) {
 262     next unless $occurs_m->($ei);
 263     print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 264     next unless $occurs_m->($ei-1);
 265     my $dleft = mkvec(-1000,0);
 266     foreach my $which (0,-1) {
 267       my $ej = ($ei +        $which + @$poly) % @$poly;
 268       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 269       my $posj = \ $poly->[$ej]{Pos};
 270       my $posk = \ $poly->[$ek]{Pos};
 271       my $dout = $$posk - $$posj;
 272       print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 273       print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 274       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 275         print STDERR " nz adj extra\n";
 276         $$posk = $$posj + 10 * mkvec(100,-50);
 277       }
 278       $$posj = $$posj + $dleft + $dout*10;
 279       $$posk = $$posk          + $dout*10;
 280     }
 281   }
 282 }
 283
 284 sub psvec ($) {
 285   my ($pos) = @_;
 286   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 287 }
 288
 289 sub face_path ($) {
 290   my ($rr) = @_;
 291   o("% $rr->{Name}\n");
 292   o("  newpath\n");
 293   my $xto = 'moveto';
 294   foreach my $vertex (@{ $rr->{Polygon} }) {
 295     my $pos = $vertex->{Pos};
 296     o(sprintf "    %s %s\n", psvec($pos), $xto);
 297     $xto = 'lineto';
 298   }
 299   o("    closepath\n");
 300 }
 301
 302 sub pscolour ($;$) {
 303   my ($spec, $adj1) = @_;
 304   confess unless defined $spec;
 305   my @rgb = map { hex($_) / 15.0 } split //, $spec;
 306   $adj1 //= sub { };
 307   $adj1->(@rgb);
 308   my $r = join ' ',
 309       (map { sprintf "%.6f ", $_ } @rgb
 310       ),
 311            'setrgbcolor';
 312   return $r;
 313 }
 314
 315 sub preamble() {
 316   my $tprinteredge = ($xopts =~ m/M/ ? $max_printeredge : 0) * MM2PT;
 317   my $xmax = $a4_h - $tprinteredge;
 318   my $ymax = ($a4_w + $a3_h) - 2 * $max_printeredge - $tprinteredge;
 319   o(<<END);
 320 %!PS-Adobe-3.0
 321 %%BoundingBox $tprinteredge $tprinteredge $xmax $ymax
 322 %%Pages: 1
 323 %%EndComments
 324 %%BeginProlog
 325 %%EndProlog
 326 %%BeginSetup
 327 /board {
 328   gsave
 329   40 -26 translate
 330 END
 331   # xxx split into pages
 332 }
 333
 334 sub postamble () {
 335   o(<<END);
 336   grestore
 337 } bind def
 338 %%EndSetup
 339 %%Page: 1
 340 %%BeginPageSetup
 341 /pgsave save def
 342 %%EndPageSetup
 343 board
 344 pgsave restore
 345 showpage
 346 %%EOF
 347 END
 348 }
 349
 350 sub lighterpscolour ($$) {
 351   my ($colourname, $retain) = @_;
 352   pscolour($c{Colours}{$colourname},
 353            sub { $_ = 1.0 - $retain * (1.0 - $_) foreach @_ })
 354 }
 355
 356 sub darkerpscolour ($$) {
 357   my ($colourname, $retain) = @_;
 358   pscolour($c{Colours}{$colourname},
 359            sub { $_ = $retain * $_ foreach @_ })
 360 }
 361
 362 sub facepscolour ($) {
 363   my ($colourname) = @_;
 364   $xopts =~ m/W/ ? '1 setgray' : lighterpscolour($colourname, 0.75);
 365 }
 366
 367 sub fill_faces() {
 368   o("clippath ", facepscolour('land'), " fill\n");
 369   foreach my $rr (values %region) {
 370     next if $rr->{Name} =~ m/^L2?$/;
 371     face_path($rr);
 372     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 373   }
 374 }
 375
 376 our $edge_lw = 5;
 377
 378 sub some_edge_faces (@) {
 379   o("$edge_lw setlinewidth 1 setlinejoin 0 setgray\n");
 380   foreach my $rr (@_) {
 381     next if $rr->{Name} =~ m/^L2?$/;
 382     face_path($rr);
 383     o("    stroke\n");
 384   }
 385 }
 386
 387 sub afsluitdijk() {
 388   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 389   my $dash = 20;
 390   my (@pos) = adj_ends($adj);
 391   my $mid = 0.5 * ($pos[0] + $pos[1]);
 392   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 393   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 394   %% Afsluitdijk
 395   %s %s %s 0 360 arc closepath fill
 396 END
 397   some_edge_faces(()); # just sets the colour
 398   o(sprintf <<END, map { psvec($_) } @pos);
 399   newpath %s moveto %s lineto
 400   [ $dash $dash ] $dash 0.5 mul setdash
 401   stroke
 402   [] 0 setdash
 403 END
 404   one_hs('purple', $mid);
 405 }
 406
 407 sub edge_faces() {
 408   some_edge_faces($region{'NZ'});
 409   afsluitdijk();
 410   some_edge_faces(grep {
 411     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 412   } values %region);
 413 }
 414
 415 our $hs_sz = 17 * MM2PT;
 416 our $hs_lw = 3;
 417
 418 our $text_sz = 18;
 419
 420 sub token_circle ($$$$;$$) {
 421   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 422   $sz //= $hs_sz;
 423   $lw //= $hs_lw;
 424   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 425    %% %s
 426    newpath %s
 427      %s %f 0 360 arc closepath gsave fill grestore
 428      %s $lw setlinewidth stroke
 429 END
 430 }
 431
 432 sub one_hs ($$;$$) {
 433   my ($colour, $hspos, $sz, $lw) = @_;
 434   token_circle("HS - $colour",
 435                $hspos,
 436                darkerpscolour($colour, 0.75),
 437                '0 setgray',
 438               $sz,$lw);
 439 }
 440
 441 our $cube_sz = 6 * MM2PT;
 442 our $cube_gap = $cube_sz * 0.2;
 443 our $cube_lw = ($cube_sz * 0.1);
 444
 445 sub label_faces() {
 446   my $sz = $text_sz;
 447   my $shadow = $sz * 0.1;
 448   o(<<END);
 449   /wordsshow {
 450     0 setgray 0 10 359 {
 451       dup  cos $shadow mul
 452       exch sin $shadow mul
 453       words pop pop
 454     } bind for
 455     1 setgray 0 0 words pop pop
 456   } def
 457 END
 458   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 459   my %hs = map { $_ => 1 } @{ $c{HS} };
 460   foreach my $rr (values %region) {
 461     next if $rr->{Name} =~ m/^L\d?$/;
 462     my $words = $rr->{DisplayName};
 463     my $pos;
 464     if ($rr->{Name} eq 'NZ') {
 465       $pos = mkvec(90, 1280);
 466     } else {
 467       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 468     }
 469     if ($hs{$rr->{Name}}) {
 470       print STDERR "adjust hs $rr->{Name}\n";
 471       $pos -= mkvec(0, -$hs_sz*
 472                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 473       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 474                                + $hs_sz*0.15);
 475       one_hs($rr->{Colour}, $hspos);
 476     }
 477     my $adjust = $c{TextAdjust}{$rr->{Name}};
 478     if ($adjust) {
 479       $pos += $sz * &mkvec(@$adjust);
 480     }
 481     my $w = $rr->{Water};
 482     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 483     if ($w) {
 484       print STDERR " water $w in $rr->{Name}\n";
 485       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 486       $pos -= mkvec(0, -0.5 * $down);
 487       my $cube_y = -($sz * @$words);
 488       if ($rr->{Name} eq 'Wieringermeer') {
 489         $pos -= mkvec(0,+$sz);
 490         $cube_y = 0;
 491         $down = 0;
 492       }
 493       o("  gsave\n");
 494       o("    ", psvec($pos), " translate\n");
 495       o("    0 ", $cube_y, " translate\n");
 496       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 497       water_cubes($w);
 498       o("  grestore\n");
 499     }
 500     o("  /words {\n");
 501     foreach my $word (@$words) {
 502       $pos += mkvec(0,-$sz);
 503       o("   ", psvec($pos), " moveto");
 504       o(<<END);
 505    2 copy rmoveto
 506    ($word) dup stringwidth pop     % word xw
 507      -0.5 mul 0 rmoveto             % word
 508      show
 509    0 -$sz rmoveto
 510 END
 511     }
 512     o(<<END);
 513   } bind def
 514   wordsshow
 515 END
 516   }
 517 }
 518
 519 sub water_cubes_sz($){
 520   my ($n) = @_;
 521   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 522 }
 523
 524 sub water_cubes($){
 525   my ($n) = @_;
 526   my $s = $cube_sz;
 527   for my $i (0..$n-1) {
 528     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 529     o("          $s  0  rlineto\n");
 530     o("           0 $s  rlineto\n");
 531     o("         -$s  0  rlineto  closepath\n");
 532     o("  gsave ", pscolour($c{Colours}{cube}), " fill grestore\n");
 533     o("  gsave ", '0 setgray ', $cube_lw,
 534       " setlinewidth stroke grestore \n");
 535   }
 536 }
 537
 538 my $deck_h = 89 * MM2PT;
 539
 540 sub decks(){
 541   my $lw = $edge_lw/2;
 542   o("  /deck1path {\n");
 543   my $w = 63 * MM2PT;
 544   my $h = $deck_h;
 545   my $r =  5 * MM2PT;
 546   o("      ",($w/2)," 0 moveto\n");
 547   my @p = ([ $w, 0 ],
 548            [ $w,$h ],
 549            [ 0, $h ],
 550            [ 0,  0 ]);
 551   foreach my $i (0..3) {
 552     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 553   }
 554   o("    closepath\n");
 555   o("  } bind def");
 556   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 557   o("    newpath         deck1path\n");
 558   o("    200 0 translate deck1path\n");
 559   o("  } bind def");
 560   o("  $lw setlinewidth 1 setgray\n");
 561   o("  gsave 407 50 translate deckpairpathx stroke grestore");
 562   o("  $lw setlinewidth ",pscolour($c{Colours}{dykefail}),"\n");
 563   o("  gsave 225 1355 translate 90 rotate deckpairpathx stroke grestore");
 564 }
 565
 566 sub sea_track(){
 567   o("% sea level track\n");
 568   o("  gsave 0 660 translate\n");
 569   my $track = $c{SeaTrack};
 570   my $token_sz = $hs_sz;
 571   my $dy = $token_sz * 1.25;
 572   my $dx = $token_sz * 1.25;
 573   my $linecolour = darkerpscolour('cube', 0.25);
 574   my @pos;
 575   for my $i (0..$#$track) {
 576     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 577   }
 578   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 579   o("  $prepline\n");
 580   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 581   for my $pos (@pos) {
 582     token_circle("SL", $pos,
 583                  pscolour($c{Colours}{cube}),
 584                  $linecolour);
 585   }
 586   my $last = 0;
 587   for my $i (0..$#pos) {
 588     my $differs = $track->[$i] != $last;
 589     $last = $track->[$i];
 590     next unless $differs;
 591     o("  $prepline\n");
 592     o("  gsave ",
 593       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 594
 595     my $t_sz = 24;
 596     my $shrink = ($hs_sz * 0.75 / $deck_h);
 597     o("    gsave % T M $i\n");
 598     o("      -43.5 -6.5 translate\n");
 599     o("      0.8 .8 scale \n");
 600     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 601     o("      gsave");
 602     o("        $shrink dup scale -90 rotate\n");
 603     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 604     o("         deck1path stroke\n");
 605     o("      grestore");
 606     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 607     o("      12 -21.5 moveto ($track->[$i]) show");
 608     o("    grestore\n");
 609
 610     if ($i > 0) {
 611       o("  0 -$dy moveto",
 612         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 613         " rlineto stroke\n");
 614     }
 615     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 616       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 617       " translate\n");
 618     my $bottom = int(($track->[$i+1] + 1) / 2);
 619     water_cubes($bottom);
 620     my $new_n = $track->[$i+1] - $bottom;
 621     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 622       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 623     water_cubes($new_n);
 624     o("  grestore\n");
 625   }
 626   o("  grestore\n");
 627 }
 628
 629 our $dyke_l = 25 * MM2PT;;
 630
 631 sub dykes(){
 632   my $l = $dyke_l;
 633   my $w = 5 * MM2PT;
 634   my $lw = $edge_lw * 0.50;
 635   my $l2 = $l/2;
 636   my $w2 = $w/2;
 637   o("  /dykepath {\n");
 638   o("            -$l2 -$w2 moveto\n");
 639   o("             $l2 -$w2 lineto\n");
 640   o("             $l2  $w2 lineto\n");
 641   o("            -$l2  $w2 lineto closepath\n");
 642   o("  } bind def\n");
 643   o("  /dyke {\n");
 644   o("    newpath dykepath\n");
 645   o("    gsave 0.50 setgray fill grestore\n");
 646   o("    gsave 0.00 setgray $lw setlinewidth stroke grestore\n");
 647   o("  } bind def\n");
 648   my $symbol_sz = $w * 1.50;
 649   my $t_sz = $symbol_sz * 1.0;
 650   my $t_at = sub {
 651     my ($ang) = @_;
 652     print STDERR "ANG $ang\n";
 653     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 654   };
 655   my @t0 = $t_at->((TAU) *  0.25         );
 656   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 657   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 658   o("  /dtriangle {\n");
 659   o("    newpath @t0 moveto\n");
 660   o("            @t1 lineto\n");
 661   o("            @t2 lineto closepath\n");
 662   o("    gsave ",pscolour($c{Colours}{dykeinit})," fill grestore\n");
 663   o("    gsave 0 setgray $lw setlinewidth stroke grestore\n");
 664   o("  } bind def\n");
 665   foreach my $rr (values %region) {
 666     next if $rr->{Special};
 667     next if $rr->{Name} eq 'ZZ';
 668     next if $rr->{Colour} eq 'high';
 669     foreach my $adj (@{ $rr->{Adj} }) {
 670       my $neigh = $adj->{Name};
 671       o("  % dyke $rr->{Name} --- $neigh\n");
 672       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 673       next if $region{$neigh}{Colour} eq 'high';
 674       my @ends = adj_ends($adj);
 675       my $dirn = $ends[1] - $ends[0];
 676       my $angle = vec2atan($dirn);
 677       $angle = $angle * 360 / TAU;
 678       o("  gsave\n");
 679       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 680       o("    $angle rotate\n");
 681       my $initial = $adj->{Dykes};
 682       for my $ys ($initial
 683                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 684                   : [0]) {
 685         foreach my $y (@$ys) {
 686           o("    gsave 0 ", $y * $w, " translate dyke ");
 687           o(" grestore\n");
 688         }
 689         my $nsymbols = $initial + !!$adj->{Deltawerk};
 690         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 691         my $trans = "  $symbol_sz 0 translate";
 692         if ($adj->{Deltawerk}) {
 693           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 694           o($trans);
 695         }
 696         foreach my $i (1..$initial) {
 697           o(" gsave $angle neg rotate dtriangle grestore\n");
 698           o($trans);
 699         }
 700       }
 701       o("  grestore\n");
 702     }
 703   }
 704 }
 705
 706 sub hs_initial_1 ($$$;$$$) {
 707   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 708   my $interval = $hs_sz * 1.75;
 709   my $demo_h = $hs_sz; #water_cubes_sz(3);
 710   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 711   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 712   o("  % HS I $colour\n");
 713   o("  gsave\n");
 714   o("    550 1705 translate\n");
 715   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 716   if ($fn) {
 717     o("  gsave");
 718     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 719     o("        ", facepscolour($colour), " stroke grestore\n");
 720   }
 721   one_hs($colour, mkvec(0,0));
 722   if ($fn) {
 723     o("    /words {");
 724     o("      2 copy moveto                      ($text) show");
 725     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show");
 726     o("    } bind def");
 727     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 728     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 729     $fn->();
 730   }
 731   o("  grestore\n");
 732 }
 733
 734 sub hs_initial () {
 735   hs_initial_1('red',     0,0);
 736   hs_initial_1('purple',  0,1);
 737   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 738     o("    ",(water_cubes_sz(1))," 0 translate\n");
 739     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 740     water_cubes(1);
 741   });
 742   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 743     o("    newpath dykepath\n");
 744     o("    gsave 0.50 setgray fill grestore\n");
 745     o("    gsave ",pscolour($c{Colours}{dykehsadd})," fill grestore\n");
 746   });
 747 }
 748
 749 sub play_hint () {
 750   my $sz = 20;
 751   o("  gsave 0 setgray 260 1715 translate");
 752   o("  /Helvetica-Bold findfont $sz scalefont setfont");
 753   my @t = split /\n/, $c{PlayHint};
 754   foreach my $i (0..$#t) {
 755     my $t = $t[$i];
 756     $t =~ s/[\\()]/\\$&/g;
 757     o("  0 ",(-$i * $sz)," moveto ($t) show");
 758   }
 759   o("  grestore");
 760 }
 761
 762 #----- main program -----
 763
 764 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 765
 766 ($facesf, @ARGV) = @ARGV or die;
 767 parse_input_graph();
 768 prep_region_rmap();
 769 read_faces();
 770 calculate_centres();
 771 transform_coordinates();
 772 adjust_nz();
 773
 774 preamble();
 775 fill_faces();
 776 edge_faces();
 777 dykes();
 778 label_faces();
 779 decks();
 780 sea_track();
 781 hs_initial();
 782 play_hint();
 783 postamble();
 784
 785 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 786
 787 # Local variables:
 788 # cperl-indent-level: 2
 789 # End.