generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24 our $maxpaper = 'a3';
  25
  26 sub TAU { M_PI * 2.0; }
  27 sub MM2PT { 72.0 / 25.4; }
  28
  29 our $mid;
  30
  31 our $a4_w = 595;
  32 our $a4_h = 842;
  33 our $a3_h = 1190;
  34
  35 our $max_printeredge = 5.50 * MM2PT;
  36
  37
  38 # ----- region names from plag, incl. reverse mapping -----
  39
  40 our %prs2region;
  41
  42 sub prep_region_rmap () {
  43   foreach my $rn (keys %region) {
  44     my $prs = plag_prs($rn);
  45     die if $prs2region{$prs};
  46     $prs2region{$prs} = $rn;
  47   }
  48 }
  49
  50 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  51
  52 sub prs2r ($) {
  53   # bodgery for the sea and land
  54   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  55   $prs2region{$_[0]} // confess "@_ ?"
  56 }
  57 sub prs2rr ($) { $region{prs2r($_[0])} }
  58
  59 #----- file reader for plag output -----
  60
  61 sub read_faces () {
  62   # Sets
  63   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  64   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  65   #  $region{NAME}{Polygon}{Pos}
  66   #  $region{NAME}{Special}
  67   #
  68   # also incidentally
  69   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  70   #  $region{NAME}{Polygon}{Adjoins}
  71   # which should be ignored
  72
  73   open P, "<", $facesf or die $!;
  74   while (<P>) { last if m/^\&faces$/; }
  75   my $rr;
  76   my @edges;
  77   my $process_rr = sub {
  78     my $last_ai;
  79     if ($rr->{Name} eq 'NZ') {
  80       # We combined L and NZ; now we must split them again
  81       # in fact, we just throw away L and L2 entirely.
  82       # Here, when processing NZ, we keep only vertices that
  83       # are part of NZ.
  84       @edges = grep {
  85         my $evxname = $_->{VxName};
  86         my @eregions = split / \| ?/, $evxname;
  87         grep { $_ eq 'NZ' } @eregions
  88       } @edges;
  89     }
  90     $rr->{Polygon} = [ @edges ];
  91     if ($rr->{Name} ne 'NZ') {
  92       for my $ei (0..$#edges) {
  93         if (!defined $last_ai) {
  94           my $ai;
  95           for my $ai (0..$#{ $rr->{Adj} }) {
  96             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  97             $last_ai = $ai+1;
  98           }
  99           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
 100         }
 101         my $ai = ($last_ai-1+@edges) % @edges;
 102         $last_ai = $ai;
 103         my $adj = $rr->{Adj}[$ai];
 104         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 105                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 106             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 107
 108         for my $endi (0..1) {
 109           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 110         }
 111       }
 112     }
 113     @edges = ();
 114     $rr = undef;
 115   };
 116   my $vxname;
 117   for (;;) {
 118     $!=0; $_=<P> // confess $!;
 119     last if m/^\&$/;
 120     if (m/^$sre$/) {
 121       my $new_face= $2;
 122       $process_rr->() if $rr;
 123       $rr= prs2rr($new_face);
 124     } elsif (m/^\s+$sre$/) {
 125       confess unless $rr;
 126       $vxname = $2;
 127       push @edges, { VxName => $vxname };
 128     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 129       $edges[-1]{Adjoins} = prs2r($2);
 130     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 131       my $pos = mkvec($1,$2);
 132       confess unless defined $vxname;
 133       $edges[-1]{Pos} = $pos;
 134       $vxname2pos{$vxname} = $pos;
 135     }
 136   }
 137   $process_rr->();
 138
 139   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 140 }
 141
 142 #----- geometry mangling -----
 143
 144 sub adj_ends ($) {
 145   my ($adj) = @_;
 146   map { $_->{Pos} } @{ $adj->{Ends} };
 147 }
 148
 149 sub calculate_centres () {
 150   # Sets
 151   #  $region{NAME}{Centre}
 152   foreach my $rr (values %region) {
 153     next if $rr->{Special};
 154     my $sum = Math::GSL::Vector->new(2);
 155     my $wsum = 0;
 156     foreach my $adj (@{ $rr->{Adj} }) {
 157       my @ends = adj_ends($adj);
 158       my $w = ($ends[1] - $ends[0])->norm();
 159       $sum += $w * $_ foreach @ends;
 160       $wsum += $w;
 161     }
 162     $rr->{Centre} = $sum * (0.5 / $wsum);
 163   }
 164 }
 165
 166 sub for_each_pos ($) {
 167   my ($f) = @_;
 168   my $call = sub {
 169     my ($pr,$rr,$why) = @_;
 170     return unless defined $$pr;
 171     $f->($pr,$rr,$why);
 172   };
 173   foreach my $rr (values %region) {
 174     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 175     foreach my $vertex (@{ $rr->{Polygon} }) {
 176       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 177     }
 178   }
 179 }
 180
 181 sub prvec ($) {
 182   my ($v) = @_;
 183   confess unless $v;
 184   sprintf "%g,%g", $v->get(0), $v->get(1);
 185 }
 186
 187 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 188 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 189
 190 sub transform_coordinates () {
 191   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 192   # until it's all in PostScript points
 193   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 194   my $dir = $or[1] - $or[0];
 195   my $theta = vec2atan($dir);
 196   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 197   my $s = sin($rotateby);
 198   my $c = cos($rotateby);
 199   my $transform = Math::GSL::Matrix->new(2,2);
 200   $transform->set_row(0, [  $c, -$s ]);
 201   $transform->set_row(1, [  $s,  $c ]);
 202   #  print STDERR "rotate was=",prvec($dir)," theta=$theta",
 203   #    " rotateby=$rotateby s=$s c=$c\n";
 204   my @lims;
 205   foreach my $topend (qw(0 1)) {
 206     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 207     $lims[$topend] = mkvec($v,$v);
 208   }
 209   for_each_pos(sub {
 210     my ($pr, $rr, $why) = @_;
 211     my $y = Math::GSL::Vector->new(2);
 212     gsl_blas_dgemv($CblasNoTrans,
 213                    1.0, $transform->raw,
 214                    $$pr->raw,
 215                    0, $y->raw)
 216         and confess;
 217     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 218     gsl_blas_dcopy($y->raw, $$pr->raw)
 219         and confess;
 220     foreach my $topend (qw(0 1)) {
 221       foreach my $xy (qw(0 1)) {
 222         my $now = $y->get($xy);
 223         my $lim = $lims[$topend]->get($xy);
 224         #print STDERR "?set $topend $xy $now $lim\n";
 225         next if $topend ? ($now <= $lim) : ($now >= $lim);
 226         $lims[$topend]->set([$xy], [$now]);
 227         #print STDERR "set $topend $xy $now\n";
 228       }
 229     }
 230   });
 231   #print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 232   my $translate = -$lims[0];
 233   #print STDERR "translate ",prvec($translate),"\n";
 234   my $scale = $c{GraphScale} * MM2PT;
 235   for_each_pos(sub {
 236     my ($pr) = @_;
 237     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 238     gsl_vector_scale($$pr->raw, $scale) and confess;
 239   });
 240   $mid = ($lims[1] - $lims[0]) * 0.5;
 241 }
 242
 243 sub adjust_nz() {
 244   my $poly = $region{NZ}{Polygon};
 245   my %occurs;
 246   foreach my $v (@$poly) {
 247     $occurs{$v->{VxName}}++
 248   }
 249   foreach my $v (@$poly) {
 250     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 251   }
 252   #print STDERR " nz ".(scalar @$poly)."\n";
 253   my $occurs_m = sub {
 254     my ($ei) = @_;
 255     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 256   };
 257   for my $ei (0..$#$poly) {
 258     next if $occurs_m->($ei);
 259     next unless $occurs_m->($ei-1);
 260     next unless $occurs_m->($ei+1);
 261     #print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 262     # adjust coord outwards
 263   }
 264   for my $ei (0..$#$poly) {
 265     next unless $occurs_m->($ei);
 266     #print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 267     next unless $occurs_m->($ei-1);
 268     my $dleft = mkvec(-1000,0);
 269     foreach my $which (0,-1) {
 270       my $ej = ($ei +        $which + @$poly) % @$poly;
 271       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 272       my $posj = \ $poly->[$ej]{Pos};
 273       my $posk = \ $poly->[$ek]{Pos};
 274       my $dout = $$posk - $$posj;
 275       #print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 276       #print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 277       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 278         #print STDERR " nz adj extra\n";
 279         $$posk = $$posj + 10 * mkvec(100,-50);
 280       }
 281       $$posj = $$posj + $dleft + $dout*10;
 282       $$posk = $$posk          + $dout*10;
 283     }
 284   }
 285 }
 286
 287 sub psvec ($) {
 288   my ($pos) = @_;
 289   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 290 }
 291
 292 sub face_path ($) {
 293   my ($rr) = @_;
 294   o("% $rr->{Name}\n");
 295   o("  newpath\n");
 296   my $xto = 'moveto';
 297   foreach my $vertex (@{ $rr->{Polygon} }) {
 298     my $pos = $vertex->{Pos};
 299     o(sprintf "    %s %s\n", psvec($pos), $xto);
 300     $xto = 'lineto';
 301   }
 302   o("    closepath\n");
 303 }
 304
 305 sub computeboundings() {
 306   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 307   $bb{PageB} = [ 0,0, $a4_h, $a4_w ];
 308   my $page2minprintable = sub {
 309     my (@p) = @{ $_[0] };
 310     [ $p[0] + $max_printeredge,
 311       $p[1] + $max_printeredge,
 312       $p[2] - $max_printeredge,
 313       $p[3] - $max_printeredge ];
 314   };
 315   $bb{PrintableB} = $page2minprintable->($bb{PageB});
 316   my $somepage = sub {
 317     my $id = shift @_;
 318     print STDERR "defining page Page$id\n";
 319     $bb{"Page$id"} = [ @_ ];
 320     $bb{"Printable$id"} = $page2minprintable->($bb{"Page$id"});
 321   };
 322   if ($maxpaper eq 'a3') {
 323     my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 324     $somepage->('MT', 0, $mt_offset, $a4_h, $mt_offset + $a3_h );
 325     $bb{PrintableAll} = [
 326                          @{ $bb{PrintableB} }[0..1],
 327                          @{ $bb{PrintableMT} }[2..3],
 328                         ];
 329   } elsif ($maxpaper eq 'a4') {
 330     my $m_offset = $bb{PrintableB}[3] - $max_printeredge;
 331     $somepage->('M', 0, $m_offset, $a4_h, $m_offset + $a4_w );
 332     my $t_offset = $bb{PrintableM}[3] - $max_printeredge;
 333     $somepage->('T', 0, $t_offset, $a4_h, $t_offset + $a4_w );
 334     $bb{PrintableAll} = [
 335                          @{ $bb{PrintableB} }[0..1],
 336                          @{ $bb{PrintableT} }[2..3],
 337                         ];
 338   } else {
 339     confess;
 340   }
 341 }
 342
 343 sub showboundings () {
 344   return unless $xopts =~ m/B/;
 345   o("  grestore gsave\n");
 346   my $i = 0;
 347   my $on = 2;
 348   my $off = 9;
 349   foreach my $bname (sort keys %bb) {
 350     o(sprintf "   1 %d %d setrgbcolor\n",
 351       !!($bname =~ m/^Page/),
 352       !!($bname =~ m/B$/),
 353      );
 354     o("    % $bname\n");
 355     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 356     my @p = @{ $bb{$bname} };
 357     o("    $p[0] $p[1] moveto\n");
 358     o("    $p[2] $p[1] lineto\n");
 359     o("    $p[2] $p[3] lineto\n");
 360     o("    $p[0] $p[3] lineto\n");
 361     o("    closepath stroke\n");
 362     $i++;
 363   }
 364 }
 365
 366 sub o_amble (@) {
 367   # CPerl-mode does a really awful thing with %s in the preamble
 368   # and postamble, causing constant useless flashing
 369   # So we write & in the here docs and transform them back:
 370   my ($t) = join '', @_;
 371   $t =~ s/^\&+/ '%' x length $& /mge;
 372   o($t);
 373 }
 374
 375 sub preamble() {
 376   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 377   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 378   o_amble(<<END);
 379 &!PS-Adobe-3.0
 380 &&BoundingBox @$bb
 381 &&Pages: 1
 382 &&EndComments
 383 &&BeginProlog
 384 &&EndProlog
 385 &&BeginSetup
 386 << /PageSize [ @$sz ] >> setpagedevice
 387 /board {
 388   gsave
 389   34 -15 translate
 390 END
 391   if ($maxpaper eq 'a4') {
 392     o("0 -17 translate\n");
 393   }
 394   # xxx split into pages
 395 }
 396
 397 sub postamble () {
 398   o_amble(<<END);
 399   grestore
 400 } bind def
 401 &&EndSetup
 402 &&Page: 1
 403 &&BeginPageSetup
 404 /pgsave save def
 405 &&EndPageSetup
 406 board
 407 pgsave restore
 408 showpage
 409 &&EOF
 410 END
 411 }
 412
 413 sub pscolour ($$$$) {
 414   my ($colourname, $cmykix,$rgbmul,$rgbadd) = @_;
 415   my $spec = $c{Colours}{$colourname};
 416   confess unless defined $spec;
 417
 418   # check that we have only one lighter/darker retain value for each one
 419   our %colour_occurred;
 420   $colour_occurred{$colourname}{$cmykix}{$rgbmul,$rgbadd} = 1;
 421   keys %{ $colour_occurred{$colourname}{$cmykix} } == 1 or confess;
 422
 423   my @r;
 424   my $rw;
 425   if ($spec =~ m/^[0-9a-f]+$/) {
 426     my $le = (length $spec)/3;
 427     my $re = ("(.{$le})") x 3;
 428     my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 429     @rgb = map { hex($_) / (16**$le -1) } @rgb;
 430     foreach (@rgb) { $_ *= $rgbmul; $_ += $rgbadd; }
 431     @r = @rgb;
 432     $rw = 'setrgbcolor';
 433   } elsif ($spec =~ m/[CMYK]/) {
 434     my @specs = split /\//, $spec;
 435     if ($cmykix==1 && @specs==1) {
 436       $spec = $specs[0];
 437     } else {
 438       $spec = $specs[$cmykix];
 439       confess unless defined $spec;
 440     }
 441     my %cmyk;
 442     foreach (split /(?=[A-Z])/, $spec) {
 443       m/^([CMYK])([0-7](?:\.\d*)?|8)_?$/ or confess $_.' ?';
 444       confess if defined $cmyk{$1};
 445       $cmyk{$1} = $2 / 8.;
 446       #print STDERR " CMYK $1 $2\n";
 447     }
 448     @r = map { $cmyk{$_} // 0 } qw(C M Y K);
 449     $rw = 'setcmykcolor';
 450   } else {
 451     confess $spec.' ?';
 452   }
 453   my $r = join ' ',
 454       (map { sprintf "%.6f ", $_ } @r
 455       ),
 456           $rw;
 457   return $r;
 458 }
 459
 460 sub lighterpscolour ($$) {
 461   my ($colourname, $retain) = @_;
 462   #print STDERR "COLOUR LIGHTER $retain $colourname\n";
 463   pscolour($colourname, 0, $retain, 1-$retain);
 464 }
 465
 466 sub darkerpscolour ($$) {
 467   my ($colourname, $retain) = @_;
 468   #print STDERR "COLOUR DARKER $retain $colourname\n";
 469   pscolour($colourname, 2, $retain, 0);
 470 }
 471
 472 sub facepscolour ($) {
 473   my ($colourname) = @_;
 474   $xopts =~ m/W/ ? '1 setgray' : lighterpscolour($colourname, 0.75);
 475 }
 476
 477 sub miscpscolour ($) {
 478   my ($colourname) = @_;
 479   #print STDERR "COLOUR MISC $colourname\n";
 480   pscolour($colourname, 1, 1,0);
 481 }
 482
 483 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 484
 485 sub fill_faces() {
 486   o("clippath ", facepscolour('land'), " fill\n");
 487   foreach my $rr (values %region) {
 488     next if $rr->{Name} =~ m/^L2?$/;
 489     face_path($rr);
 490     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 491   }
 492 }
 493
 494 our $edge_lw = 5;
 495
 496 sub some_edge_faces (@) {
 497   o("$edge_lw setlinewidth 1 setlinejoin ",miscpscolour('edge'),"\n");
 498   foreach my $rr (@_) {
 499     next if $rr->{Name} =~ m/^L2?$/;
 500     face_path($rr);
 501     o("    stroke\n");
 502   }
 503 }
 504
 505 sub afsluitdijk() {
 506   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 507   my $dash = 20;
 508   my (@pos) = adj_ends($adj);
 509   my $mid = 0.5 * ($pos[0] + $pos[1]);
 510   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 511   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 512   %% Afsluitdijk
 513   %s %s %s 0 360 arc closepath fill
 514 END
 515   some_edge_faces(()); # just sets the colour
 516   o(sprintf <<END, map { psvec($_) } @pos);
 517   newpath %s moveto %s lineto
 518   [ $dash $dash ] $dash 0.5 mul setdash
 519   stroke
 520   [] 0 setdash
 521 END
 522   one_hs('purple', $mid);
 523 }
 524
 525 sub edge_faces() {
 526   some_edge_faces($region{'NZ'});
 527   afsluitdijk();
 528   some_edge_faces(grep {
 529     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 530   } values %region);
 531 }
 532
 533 our $hs_sz = 17 * MM2PT;
 534 our $hs_lw = 3;
 535
 536 our $text_sz = 18;
 537
 538 sub token_circle ($$$$;$$) {
 539   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 540   $sz //= $hs_sz;
 541   $lw //= $hs_lw;
 542   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 543    %% %s
 544    newpath %s
 545      %s %f 0 360 arc closepath gsave fill grestore
 546      %s $lw setlinewidth stroke
 547 END
 548 }
 549
 550 sub one_hs ($$;$$) {
 551   my ($colour, $hspos, $sz, $lw) = @_;
 552   token_circle("HS - $colour",
 553                $hspos,
 554                darkerpscolour($colour, 0.75),
 555                miscpscolour('edge'),
 556               $sz,$lw);
 557 }
 558
 559 our $cube_sz = 6 * MM2PT;
 560 our $cube_gap = $cube_sz * 0.2;
 561 our $cube_lw = ($cube_sz * 0.1);
 562
 563 sub label_faces() {
 564   my $sz = $text_sz;
 565   my $shadow = $sz * 0.1;
 566   my $textc   = miscpscolour('text');
 567   my $shadowc = miscpscolour('textshadow');
 568   o(<<END);
 569   /wordsshow {
 570     $shadowc 0 10 359 {
 571       dup  cos $shadow mul
 572       exch sin $shadow mul
 573       words pop pop
 574     } bind for
 575     $textc 0 0 words pop pop
 576   } def
 577 END
 578   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 579   my %hs = map { $_ => 1 } @{ $c{HS} };
 580   foreach my $rr (values %region) {
 581     next if $rr->{Name} =~ m/^L\d?$/;
 582     my $words = $rr->{DisplayName};
 583     my $pos;
 584     if ($rr->{Name} eq 'NZ') {
 585       $pos = mkvec(90, 1280);
 586     } else {
 587       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 588     }
 589     if ($hs{$rr->{Name}}) {
 590       #print STDERR "adjust hs $rr->{Name}\n";
 591       $pos -= mkvec(0, -$hs_sz*
 592                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 593       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 594                                + $hs_sz*0.15);
 595       one_hs($rr->{Colour}, $hspos);
 596     }
 597     my $adjust = $c{TextAdjust}{$rr->{Name}};
 598     if ($adjust) {
 599       $pos += $sz * &mkvec(@$adjust);
 600     }
 601     my $w = $rr->{Water};
 602     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 603     if ($w) {
 604       #print STDERR " water $w in $rr->{Name}\n";
 605       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 606       $pos -= mkvec(0, -0.5 * $down);
 607       my $cube_y = -($sz * @$words);
 608       if ($rr->{Name} eq 'Wieringermeer') {
 609         $pos -= mkvec(0,+$sz);
 610         $cube_y = 0;
 611         $down = 0;
 612       }
 613       o("  gsave\n");
 614       o("    ", psvec($pos), " translate\n");
 615       o("    0 ", $cube_y, " translate\n");
 616       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 617       water_cubes($w, miscpscolour('edge'));
 618       o("  grestore\n");
 619     }
 620     o("  /words {\n");
 621     foreach my $word (@$words) {
 622       $pos += mkvec(0,-$sz);
 623       o("   ", psvec($pos), " moveto");
 624       o(<<END);
 625    2 copy rmoveto
 626    ($word) dup stringwidth pop     % word xw
 627      -0.5 mul 0 rmoveto             % word
 628      show
 629    0 -$sz rmoveto
 630 END
 631     }
 632     o(<<END);
 633   } bind def
 634   wordsshow
 635 END
 636   }
 637 }
 638
 639 sub water_cubes_sz($){
 640   my ($n) = @_;
 641   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 642 }
 643
 644 sub water_cubes($$){
 645   my ($n, $edgecolour) = @_;
 646   my $s = $cube_sz;
 647   for my $i (0..$n-1) {
 648     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 649     o("          $s  0  rlineto\n");
 650     o("           0 $s  rlineto\n");
 651     o("         -$s  0  rlineto  closepath\n");
 652     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 653     o("  gsave ", $edgecolour, " ", $cube_lw,
 654       " setlinewidth stroke grestore \n");
 655   }
 656 }
 657
 658 my $deck_h = 89 * MM2PT;
 659
 660 sub decks(){
 661   my $lw = $edge_lw/2;
 662   o("  /deck1path {\n");
 663   my $w = 63 * MM2PT;
 664   my $h = $deck_h;
 665   my $r =  5 * MM2PT;
 666   o("      ",($w/2)," 0 moveto\n");
 667   my @p = ([ $w, 0 ],
 668            [ $w,$h ],
 669            [ 0, $h ],
 670            [ 0,  0 ]);
 671   foreach my $i (0..3) {
 672     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 673   }
 674   o("    closepath\n");
 675   o("  } bind def");
 676   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 677   o("    newpath         deck1path\n");
 678   o("    200 0 translate deck1path\n");
 679   o("  } bind def");
 680   o("  $lw setlinewidth ",miscpscolour('playerdeck'),"\n");
 681   o("  gsave 401 44 translate deckpairpathx stroke grestore");
 682   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 683   o("  gsave 242 1363 translate 90 rotate deckpairpathx stroke grestore");
 684 }
 685
 686 sub sea_track(){
 687   o("% sea level track\n");
 688   o("  gsave 11 700 translate\n");
 689   my $track = $c{SeaTrack};
 690   my $token_sz = $hs_sz;
 691   my $dy = $token_sz * 1.25;
 692   my $dx = $token_sz * 1.25;
 693   my $linecolour = seatrackedgepscolour();
 694   my @pos;
 695   for my $i (0..$#$track) {
 696     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 697   }
 698   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 699   o("  $prepline\n");
 700   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 701   for my $pos (@pos) {
 702     token_circle("SL", $pos,
 703                  miscpscolour('cube'),
 704                  $linecolour);
 705   }
 706   my $last = 0;
 707   my $cubeedgecolour = seatrackedgepscolour();
 708   for my $i (0..$#pos) {
 709     my $differs = $track->[$i] != $last;
 710     $last = $track->[$i];
 711     next unless $differs;
 712     o("  $prepline\n");
 713     o("  gsave ",
 714       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 715
 716     my $t_sz = 24;
 717     my $shrink = ($hs_sz * 0.75 / $deck_h);
 718     o("    gsave % T M $i\n");
 719     o("      -43.5 -6.5 translate\n");
 720     o("      0.8 .8 scale \n");
 721     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 722     o("      gsave");
 723     o("        $shrink dup scale -90 rotate\n");
 724     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 725     o("         deck1path stroke\n");
 726     o("      grestore");
 727     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 728     o("      12 -21.5 moveto ($track->[$i]) show");
 729     o("    grestore\n");
 730
 731     if ($i > 0) {
 732       o("  0 -$dy moveto",
 733         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 734         " rlineto stroke\n");
 735     }
 736     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 737       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 738       " translate\n");
 739     my $bottom = int(($track->[$i+1] + 1) / 2);
 740     water_cubes($bottom, $cubeedgecolour);
 741     my $new_n = $track->[$i+1] - $bottom;
 742     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 743       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 744     water_cubes($new_n, $cubeedgecolour);
 745     o("  grestore\n");
 746   }
 747   o("  grestore\n");
 748 }
 749
 750 our $dyke_l = 25 * MM2PT;;
 751
 752 sub dykes(){
 753   my $l = $dyke_l;
 754   my $w = 5 * MM2PT;
 755   my $lw = $edge_lw * 0.50;
 756   my $l2 = $l/2;
 757   my $w2 = $w/2;
 758   o("  /dykepath {\n");
 759   o("            -$l2 -$w2 moveto\n");
 760   o("             $l2 -$w2 lineto\n");
 761   o("             $l2  $w2 lineto\n");
 762   o("            -$l2  $w2 lineto closepath\n");
 763   o("  } bind def\n");
 764   o("  /dyke {\n");
 765   o("    newpath dykepath\n");
 766   o("    gsave ",miscpscolour('dykefill')," fill grestore\n");
 767   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 768   o("  } bind def\n");
 769   my $symbol_sz = $w * 1.50;
 770   my $t_sz = $symbol_sz * 1.0;
 771   my $t_at = sub {
 772     my ($ang) = @_;
 773     #print STDERR "ANG $ang\n";
 774     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 775   };
 776   my @t0 = $t_at->((TAU) *  0.25         );
 777   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 778   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 779   o("  /dtriangle {\n");
 780   o("    newpath @t0 moveto\n");
 781   o("            @t1 lineto\n");
 782   o("            @t2 lineto closepath\n");
 783   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 784   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 785   o("  } bind def\n");
 786   foreach my $rr (values %region) {
 787     next if $rr->{Special};
 788     next if $rr->{Name} eq 'ZZ';
 789     next if $rr->{Colour} eq 'high';
 790     foreach my $adj (@{ $rr->{Adj} }) {
 791       my $neigh = $adj->{Name};
 792       o("  % dyke $rr->{Name} --- $neigh\n");
 793       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 794       next if $region{$neigh}{Colour} eq 'high';
 795       my @ends = adj_ends($adj);
 796       my $dirn = $ends[1] - $ends[0];
 797       my $angle = vec2atan($dirn);
 798       $angle = $angle * 360 / TAU;
 799       o("  gsave\n");
 800       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 801       o("    $angle rotate\n");
 802       my $initial = $adj->{Dykes};
 803       for my $ys ($initial
 804                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 805                   : [0]) {
 806         foreach my $y (@$ys) {
 807           o("    gsave 0 ", $y * $w, " translate dyke ");
 808           o(" grestore\n");
 809         }
 810         my $nsymbols = $initial + !!$adj->{Deltawerk};
 811         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 812         my $trans = "  $symbol_sz 0 translate";
 813         if ($adj->{Deltawerk}) {
 814           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 815           o($trans);
 816         }
 817         foreach my $i (1..$initial) {
 818           o(" gsave $angle neg rotate dtriangle grestore\n");
 819           o($trans);
 820         }
 821       }
 822       o("  grestore\n");
 823     }
 824   }
 825 }
 826
 827 sub hs_initial_1 ($$$;$$$) {
 828   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 829   my $interval = $hs_sz * 1.75;
 830   my $demo_h = $hs_sz; #water_cubes_sz(3);
 831   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 832   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 833   o("  % HS I $colour\n");
 834   o("  gsave\n");
 835   o("    550 1705 translate\n");
 836   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 837   if ($fn) {
 838     o("  gsave\n");
 839     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 840     o("        ", facepscolour($colour), " stroke grestore\n");
 841   }
 842   one_hs($colour, mkvec(0,0));
 843   if ($fn) {
 844     o("    /words {\n");
 845     o("      2 copy moveto                      ($text) show\n");
 846     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show\n");
 847     o("    } bind def\n");
 848     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 849     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 850     $fn->();
 851   }
 852   o("  grestore\n");
 853 }
 854
 855 sub hs_initial () {
 856   hs_initial_1('red',     0,0);
 857   hs_initial_1('purple',  0,1);
 858   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 859     o("    ",(water_cubes_sz(1))," 0 translate\n");
 860     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 861     water_cubes(1, miscpscolour('edge'));
 862   });
 863   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 864     o("    newpath dykepath\n");
 865     o("    gsave ",miscpscolour('edge')," stroke grestore\n");
 866     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 867   });
 868 }
 869
 870 sub play_hint () {
 871   my $sz = 20;
 872   o("  gsave ",miscpscolour('hinttext')," 260 1715 translate\n");
 873   o("  /Helvetica-Bold findfont $sz scalefont setfont\n");
 874   my @t = split /\n/, $c{PlayHint};
 875   foreach my $i (0..$#t) {
 876     my $t = $t[$i];
 877     $t =~ s/[\\()]/\\$&/g;
 878     o("  0 ",(-$i * $sz)," moveto ($t) show\n");
 879   }
 880   o("  grestore");
 881 }
 882
 883 #----- main program -----
 884
 885 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 886 $bounding = $1 if $xopts =~ s/b(\w+)//;
 887 $maxpaper = $1 if $xopts =~ s/p(\w+)//;
 888 $maxpaper =~ m/^a[134]$/ or confess;
 889
 890 ($facesf, @ARGV) = @ARGV or die;
 891 parse_input_graph();
 892 prep_region_rmap();
 893 read_faces();
 894 calculate_centres();
 895 transform_coordinates();
 896 adjust_nz();
 897
 898 computeboundings();
 899 preamble();
 900 fill_faces();
 901 edge_faces();
 902 dykes();
 903 label_faces();
 904 decks();
 905 sea_track();
 906 hs_initial();
 907 play_hint();
 908 showboundings();
 909 postamble();
 910
 911 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 912
 913 # Local variables:
 914 # cperl-indent-level: 2
 915 # End.