generate-board

   1 #!/usr/bin/perl -w
   2
   3 use strict;
   4 use Carp;
   5 use Data::Dumper;
   6 use Math::GSL::Vector qw/:all/;
   7 use Math::GSL::Matrix qw/:all/;
   8 use Math::GSL::Const;
   9 use Math::GSL::BLAS qw/:all/;
  10 use Math::GSL::CBLAS qw/:all/;
  11 use Math::GSL::Machine qw/:all/;
  12
  13 use POSIX qw(M_PI);
  14
  15 BEGIN { unshift @INC, qw(.); }
  16
  17 use Parse;
  18
  19 our $xopts = '';
  20 our $bounding = 'Entire';
  21 our $facesf;
  22 our %vxname2pos; # $vxname2pos{VXNAME} = Math::GSL::Vector
  23 our %bb; # $r{Bounding...}[0..3] = points
  24 our $maxpaper = 'a3';
  25
  26 sub TAU { M_PI * 2.0; }
  27 sub MM2PT { 72.0 / 25.4; }
  28
  29 our $mid;
  30
  31 our $a4_w = 595;
  32 our $a4_h = 842;
  33 our $a3_h = 1190;
  34 our $a1_w = 1684;
  35 our $a1_h = 2384;
  36
  37 our $max_printeredge = 5.50 * MM2PT;
  38
  39
  40 # ----- region names from plag, incl. reverse mapping -----
  41
  42 our %prs2region;
  43
  44 sub prep_region_rmap () {
  45   foreach my $rn (keys %region) {
  46     my $prs = plag_prs($rn);
  47     die if $prs2region{$prs};
  48     $prs2region{$prs} = $rn;
  49   }
  50 }
  51
  52 our $sre = qr{(?:(\")|(?=\w))(.*)\1$}; # 2 captures, $2 is the name
  53
  54 sub prs2r ($) {
  55   # bodgery for the sea and land
  56   return 'NZ' if m/ \| / && !grep { !m{^(?:NZ|L2?)$} } split / \| /, $_[0];
  57   $prs2region{$_[0]} // confess "@_ ?"
  58 }
  59 sub prs2rr ($) { $region{prs2r($_[0])} }
  60
  61 #----- file reader for plag output -----
  62
  63 sub read_faces () {
  64   # Sets
  65   #  $region{NAME}{Adj}[]{Ends}[]{VxName}
  66   #  $region{NAME}{Adj}[]{Ends}[]{Pos}
  67   #  $region{NAME}{Polygon}{Pos}
  68   #  $region{NAME}{Special}
  69   #
  70   # also incidentally
  71   #  $region{NAME}{Adj}[]{Ends}[]{Adjoins}
  72   #  $region{NAME}{Polygon}{Adjoins}
  73   # which should be ignored
  74
  75   open P, "<", $facesf or die $!;
  76   while (<P>) { last if m/^\&faces$/; }
  77   my $rr;
  78   my @edges;
  79   my $process_rr = sub {
  80     my $last_ai;
  81     if ($rr->{Name} eq 'NZ') {
  82       # We combined L and NZ; now we must split them again
  83       # in fact, we just throw away L and L2 entirely.
  84       # Here, when processing NZ, we keep only vertices that
  85       # are part of NZ.
  86       @edges = grep {
  87         my $evxname = $_->{VxName};
  88         my @eregions = split / \| ?/, $evxname;
  89         grep { $_ eq 'NZ' } @eregions
  90       } @edges;
  91     }
  92     $rr->{Polygon} = [ @edges ];
  93     if ($rr->{Name} ne 'NZ') {
  94       for my $ei (0..$#edges) {
  95         if (!defined $last_ai) {
  96           my $ai;
  97           for my $ai (0..$#{ $rr->{Adj} }) {
  98             next unless $rr->{Adj}[$ai]{Name} eq $edges[$ei]{Adjoins};
  99             $last_ai = $ai+1;
 100           }
 101           confess $edges[$ei]{Adjoins}.' ?' unless defined $last_ai;
 102         }
 103         my $ai = ($last_ai-1+@edges) % @edges;
 104         $last_ai = $ai;
 105         my $adj = $rr->{Adj}[$ai];
 106         confess Dumper($adj->{Name}, $edges[$ei]{Adjoins},
 107                        $rr, \@edges, $ei, $adj, $last_ai, $ai)." ?"
 108             unless $adj->{Name} eq $edges[$ei]{Adjoins};
 109
 110         for my $endi (0..1) {
 111           $adj->{Ends}[$endi] = $edges[ ($ei + $endi) % @edges ];
 112         }
 113       }
 114     }
 115     @edges = ();
 116     $rr = undef;
 117   };
 118   my $vxname;
 119   for (;;) {
 120     $!=0; $_=<P> // confess $!;
 121     last if m/^\&$/;
 122     if (m/^$sre$/) {
 123       my $new_face= $2;
 124       $process_rr->() if $rr;
 125       $rr= prs2rr($new_face);
 126     } elsif (m/^\s+$sre$/) {
 127       confess unless $rr;
 128       $vxname = $2;
 129       push @edges, { VxName => $vxname };
 130     } elsif (m/^\s+\^adjoins\s+$sre$/) {
 131       $edges[-1]{Adjoins} = prs2r($2);
 132     } elsif (m/^\s+\^\@([-e.0-9]+)\,([-e.0-9]+)$/) {
 133       my $pos = mkvec($1,$2);
 134       confess unless defined $vxname;
 135       $edges[-1]{Pos} = $pos;
 136       $vxname2pos{$vxname} = $pos;
 137     }
 138   }
 139   $process_rr->();
 140
 141   $region{$_}{Special} = 1 foreach qw(NZ L L2);
 142 }
 143
 144 #----- geometry mangling -----
 145
 146 sub adj_ends ($) {
 147   my ($adj) = @_;
 148   map { $_->{Pos} } @{ $adj->{Ends} };
 149 }
 150
 151 sub calculate_centres () {
 152   # Sets
 153   #  $region{NAME}{Centre}
 154   foreach my $rr (values %region) {
 155     next if $rr->{Special};
 156     my $sum = Math::GSL::Vector->new(2);
 157     my $wsum = 0;
 158     foreach my $adj (@{ $rr->{Adj} }) {
 159       my @ends = adj_ends($adj);
 160       my $w = ($ends[1] - $ends[0])->norm();
 161       $sum += $w * $_ foreach @ends;
 162       $wsum += $w;
 163     }
 164     $rr->{Centre} = $sum * (0.5 / $wsum);
 165   }
 166 }
 167
 168 sub for_each_pos ($) {
 169   my ($f) = @_;
 170   my $call = sub {
 171     my ($pr,$rr,$why) = @_;
 172     return unless defined $$pr;
 173     $f->($pr,$rr,$why);
 174   };
 175   foreach my $rr (values %region) {
 176     $call->( \ $rr->{Centre}, $rr, $rr->{Name}." C" );
 177     foreach my $vertex (@{ $rr->{Polygon} }) {
 178       $call->( \ $vertex->{Pos}, $rr, $rr->{Name}." | ".$vertex->{Adjoins} );
 179     }
 180   }
 181 }
 182
 183 sub prvec ($) {
 184   my ($v) = @_;
 185   confess unless $v;
 186   sprintf "%g,%g", $v->get(0), $v->get(1);
 187 }
 188
 189 sub mkvec ($$) { Math::GSL::Vector->new(\@_) }
 190 sub vec2atan ($) { my ($dir) = @_; atan2 $dir->get(1), $dir->get(0); }
 191
 192 sub transform_coordinates () {
 193   # Adjusts coordinates in graph to be [0,0] .. top right (scaled)
 194   # until it's all in PostScript points
 195   my @or = map { $region{$_}{Centre} } @{ $c{OrientRegions} };
 196   my $dir = $or[1] - $or[0];
 197   my $theta = vec2atan($dir);
 198   my $rotateby = (90. - $c{OrientBearing}) * ((TAU)/360.) - $theta;
 199   my $s = sin($rotateby);
 200   my $c = cos($rotateby);
 201   my $transform = Math::GSL::Matrix->new(2,2);
 202   $transform->set_row(0, [  $c, -$s ]);
 203   $transform->set_row(1, [  $s,  $c ]);
 204   #  print STDERR "rotate was=",prvec($dir)," theta=$theta",
 205   #    " rotateby=$rotateby s=$s c=$c\n";
 206   my @lims;
 207   foreach my $topend (qw(0 1)) {
 208     my $v = $topend ? -$GSL_DBL_MAX : $GSL_DBL_MAX;
 209     $lims[$topend] = mkvec($v,$v);
 210   }
 211   for_each_pos(sub {
 212     my ($pr, $rr, $why) = @_;
 213     my $y = Math::GSL::Vector->new(2);
 214     gsl_blas_dgemv($CblasNoTrans,
 215                    1.0, $transform->raw,
 216                    $$pr->raw,
 217                    0, $y->raw)
 218         and confess;
 219     #print STDERR "gsl_blas_dgemv ",prvec($$pr)," => ",prvec($y),"\n";
 220     gsl_blas_dcopy($y->raw, $$pr->raw)
 221         and confess;
 222     foreach my $topend (qw(0 1)) {
 223       foreach my $xy (qw(0 1)) {
 224         my $now = $y->get($xy);
 225         my $lim = $lims[$topend]->get($xy);
 226         #print STDERR "?set $topend $xy $now $lim\n";
 227         next if $topend ? ($now <= $lim) : ($now >= $lim);
 228         $lims[$topend]->set([$xy], [$now]);
 229         #print STDERR "set $topend $xy $now\n";
 230       }
 231     }
 232   });
 233   #print STDERR "lims ",prvec($lims[0])," .. ",prvec($lims[1]),"\n";
 234   my $translate = -$lims[0];
 235   #print STDERR "translate ",prvec($translate),"\n";
 236   my $scale = $c{GraphScale} * MM2PT;
 237   for_each_pos(sub {
 238     my ($pr) = @_;
 239     gsl_vector_add($$pr->raw, $translate->raw) and confess;
 240     gsl_vector_scale($$pr->raw, $scale) and confess;
 241   });
 242   $mid = ($lims[1] - $lims[0]) * 0.5;
 243 }
 244
 245 sub adjust_nz() {
 246   my $poly = $region{NZ}{Polygon};
 247   my %occurs;
 248   foreach my $v (@$poly) {
 249     $occurs{$v->{VxName}}++
 250   }
 251   foreach my $v (@$poly) {
 252     $v->{NZ_Occurs} = $occurs{$v->{VxName}};
 253   }
 254   #print STDERR " nz ".(scalar @$poly)."\n";
 255   my $occurs_m = sub {
 256     my ($ei) = @_;
 257     $poly->[($ei+@$poly) % @$poly]{NZ_Occurs} > 1
 258   };
 259   for my $ei (0..$#$poly) {
 260     next if $occurs_m->($ei);
 261     next unless $occurs_m->($ei-1);
 262     next unless $occurs_m->($ei+1);
 263     #print STDERR " nz would adjust $poly->[$ei]{VxName}\n";
 264     # adjust coord outwards
 265   }
 266   for my $ei (0..$#$poly) {
 267     next unless $occurs_m->($ei);
 268     #print STDERR " nz occurs_m $ei $poly->[$ei]{VxName}\n";
 269     next unless $occurs_m->($ei-1);
 270     my $dleft = mkvec(-1000,0);
 271     foreach my $which (0,-1) {
 272       my $ej = ($ei +        $which + @$poly) % @$poly;
 273       my $ek = ($ei + +1 + 3*$which + @$poly) % @$poly;
 274       my $posj = \ $poly->[$ej]{Pos};
 275       my $posk = \ $poly->[$ek]{Pos};
 276       my $dout = $$posk - $$posj;
 277       #print STDERR " nz adj j=$ej ",prvec($$posj)," $poly->[$ej]{VxName}\n";
 278       #print STDERR " nz adj k=$ek ",prvec($$posk)," $poly->[$ek]{VxName}\n";
 279       if ($poly->[$ej]{VxName} =~ /Noorderzijlvest/) {
 280         #print STDERR " nz adj extra\n";
 281         $$posk = $$posj + 10 * mkvec(100,-50);
 282       }
 283       $$posj = $$posj + $dleft + $dout*10;
 284       $$posk = $$posk          + $dout*10;
 285     }
 286   }
 287 }
 288
 289 sub psvec ($) {
 290   my ($pos) = @_;
 291   sprintf "%20.6f %20.6f", $pos->get(0),$pos->get(1)
 292 }
 293
 294 sub face_path ($) {
 295   my ($rr) = @_;
 296   o("% $rr->{Name}\n");
 297   o("  newpath\n");
 298   my $xto = 'moveto';
 299   foreach my $vertex (@{ $rr->{Polygon} }) {
 300     my $pos = $vertex->{Pos};
 301     o(sprintf "    %s %s\n", psvec($pos), $xto);
 302     $xto = 'lineto';
 303   }
 304   o("    closepath\n");
 305 }
 306
 307 sub computeboundings() {
 308   $bb{Entire} = [ 0,0, $a4_h, $a4_w + $a3_h ];
 309   my $page2minprintable = sub {
 310     my (@p) = @{ $_[0] };
 311     [ $p[0] + $max_printeredge,
 312       $p[1] + $max_printeredge,
 313       $p[2] - $max_printeredge,
 314       $p[3] - $max_printeredge ];
 315   };
 316   my $somepage = sub {
 317     my $id = shift @_;
 318     print STDERR "defining page Page$id\n";
 319     $bb{"Page$id"} = [ @_ ];
 320     $bb{"Printable$id"} = $page2minprintable->($bb{"Page$id"});
 321   };
 322   my $pageb_a4 = sub {
 323     $somepage->('B', 0,0, $a4_h, $a4_w );
 324   };
 325   if ($maxpaper eq 'a3') {
 326     $pageb_a4->();
 327     my $mt_offset = $bb{PrintableB}[3] - $max_printeredge;
 328     $somepage->('MT', 0, $mt_offset, $a4_h, $mt_offset + $a3_h );
 329     $bb{PrintableAll} = [
 330                          @{ $bb{PrintableB} }[0..1],
 331                          @{ $bb{PrintableMT} }[2..3],
 332                         ];
 333   } elsif ($maxpaper eq 'a4') {
 334     $pageb_a4->();
 335     my $m_offset = $bb{PrintableB}[3] - $max_printeredge;
 336     $somepage->('M', 0, $m_offset, $a4_h, $m_offset + $a4_w );
 337     my $t_offset = $bb{PrintableM}[3] - $max_printeredge;
 338     $somepage->('T', 0, $t_offset, $a4_h, $t_offset + $a4_w );
 339     $bb{PrintableAll} = [
 340                          @{ $bb{PrintableB} }[0..1],
 341                          @{ $bb{PrintableT} }[2..3],
 342                         ];
 343   } elsif ($maxpaper eq 'a1') {
 344     $somepage->('P', 0,0, $a1_w, $a1_h);
 345   } else {
 346     confess;
 347   }
 348 }
 349
 350 sub showboundings () {
 351   return unless $xopts =~ m/B/;
 352   o("  grestore gsave\n");
 353   my $i = 0;
 354   my $on = 2;
 355   my $off = 9;
 356   foreach my $bname (sort keys %bb) {
 357     o(sprintf "   1 %d %d setrgbcolor\n",
 358       !!($bname =~ m/^Page/),
 359       !!($bname =~ m/B$/),
 360      );
 361     o("    % $bname\n");
 362     o("    [ $on $off ] ".($i * ($on+$off))," setdash newpath\n");
 363     my @p = @{ $bb{$bname} };
 364     o("    $p[0] $p[1] moveto\n");
 365     o("    $p[2] $p[1] lineto\n");
 366     o("    $p[2] $p[3] lineto\n");
 367     o("    $p[0] $p[3] lineto\n");
 368     o("    closepath stroke\n");
 369     $i++;
 370   }
 371 }
 372
 373 sub o_amble (@) {
 374   # CPerl-mode does a really awful thing with %s in the preamble
 375   # and postamble, causing constant useless flashing
 376   # So we write & in the here docs and transform them back:
 377   my ($t) = join '', @_;
 378   $t =~ s/^\&+/ '%' x length $& /mge;
 379   o($t);
 380 }
 381
 382 sub preamble() {
 383   my $bb = $bb{$bounding}; confess $bounding unless $bb;
 384   my $sz = [ $bb->[2] - $bb->[0], $bb->[3] - $bb->[1] ];
 385   o_amble(<<END);
 386 &!PS-Adobe-3.0
 387 &&BoundingBox @$bb
 388 &&Pages: 1
 389 &&EndComments
 390 &&BeginProlog
 391 &&EndProlog
 392 &&BeginSetup
 393 << /PageSize [ @$sz ] >> setpagedevice
 394 /board {
 395   gsave
 396   34 -15 translate
 397 END
 398   if ($maxpaper eq 'a4') {
 399     o("0 -17 translate\n");
 400   }
 401   # xxx split into pages
 402 }
 403
 404 sub postamble () {
 405   o_amble(<<END);
 406   grestore
 407 } bind def
 408 &&EndSetup
 409 &&Page: 1
 410 &&BeginPageSetup
 411 /pgsave save def
 412 &&EndPageSetup
 413 board
 414 pgsave restore
 415 showpage
 416 &&EOF
 417 END
 418 }
 419
 420 sub pscolour ($$$$) {
 421   my ($colourname, $cmykix,$rgbmul,$rgbadd) = @_;
 422   my $spec = $c{Colours}{$colourname};
 423   confess unless defined $spec;
 424
 425   # check that we have only one lighter/darker retain value for each one
 426   our %colour_occurred;
 427   $colour_occurred{$colourname}{$cmykix}{$rgbmul,$rgbadd} = 1;
 428   keys %{ $colour_occurred{$colourname}{$cmykix} } == 1 or confess;
 429
 430   my @r;
 431   my $rw;
 432   if ($spec =~ m/^[0-9a-f]+$/) {
 433     my $le = (length $spec)/3;
 434     my $re = ("(.{$le})") x 3;
 435     my @rgb = $spec =~ m/^$re$/;  @rgb or confess "$re ?";
 436     @rgb = map { hex($_) / (16**$le -1) } @rgb;
 437     foreach (@rgb) { $_ *= $rgbmul; $_ += $rgbadd; }
 438     @r = @rgb;
 439     $rw = 'setrgbcolor';
 440   } elsif ($spec =~ m/[CMYK]/) {
 441     my @specs = split /\//, $spec;
 442     if ($cmykix==1 && @specs==1) {
 443       $spec = $specs[0];
 444     } else {
 445       $spec = $specs[$cmykix];
 446       confess unless defined $spec;
 447     }
 448     my %cmyk;
 449     foreach (split /(?=[A-Z])/, $spec) {
 450       m/^([CMYK])([0-7](?:\.\d*)?|8)_?$/ or confess $_.' ?';
 451       confess if defined $cmyk{$1};
 452       $cmyk{$1} = $2 / 8.;
 453       #print STDERR " CMYK $1 $2\n";
 454     }
 455     @r = map { $cmyk{$_} // 0 } qw(C M Y K);
 456     $rw = 'setcmykcolor';
 457   } else {
 458     confess $spec.' ?';
 459   }
 460   my $r = join ' ',
 461       (map { sprintf "%.6f ", $_ } @r
 462       ),
 463           $rw;
 464   return $r;
 465 }
 466
 467 sub lighterpscolour ($$) {
 468   my ($colourname, $retain) = @_;
 469   #print STDERR "COLOUR LIGHTER $retain $colourname\n";
 470   pscolour($colourname, 0, $retain, 1-$retain);
 471 }
 472
 473 sub darkerpscolour ($$) {
 474   my ($colourname, $retain) = @_;
 475   #print STDERR "COLOUR DARKER $retain $colourname\n";
 476   pscolour($colourname, 2, $retain, 0);
 477 }
 478
 479 sub facepscolour ($) {
 480   my ($colourname) = @_;
 481   $xopts =~ m/W/ ? '1 setgray' : lighterpscolour($colourname, 0.75);
 482 }
 483
 484 sub miscpscolour ($) {
 485   my ($colourname) = @_;
 486   #print STDERR "COLOUR MISC $colourname\n";
 487   pscolour($colourname, 1, 1,0);
 488 }
 489
 490 sub seatrackedgepscolour () { darkerpscolour('cube', 0.25) }
 491
 492 sub fill_faces() {
 493   o("clippath ", facepscolour('land'), " fill\n");
 494   foreach my $rr (values %region) {
 495     next if $rr->{Name} =~ m/^L2?$/;
 496     face_path($rr);
 497     o(" ", facepscolour($rr->{Colour}), " eofill\n");
 498   }
 499 }
 500
 501 our $edge_lw = 5;
 502
 503 sub some_edge_faces (@) {
 504   o("$edge_lw setlinewidth 1 setlinejoin ",miscpscolour('edge'),"\n");
 505   foreach my $rr (@_) {
 506     next if $rr->{Name} =~ m/^L2?$/;
 507     face_path($rr);
 508     o("    stroke\n");
 509   }
 510 }
 511
 512 sub afsluitdijk() {
 513   my ($adj) = grep { $_->{Name} eq 'NZ' } @{ $region{'ZZ'}{Adj} };
 514   my $dash = 20;
 515   my (@pos) = adj_ends($adj);
 516   my $mid = 0.5 * ($pos[0] + $pos[1]);
 517   my $r = 0.5 * ($pos[1] - $pos[0])->norm();
 518   o(sprintf <<'END', facepscolour('sea'), psvec($mid), $r);
 519   %% Afsluitdijk
 520   %s %s %s 0 360 arc closepath fill
 521 END
 522   some_edge_faces(()); # just sets the colour
 523   o(sprintf <<END, map { psvec($_) } @pos);
 524   newpath %s moveto %s lineto
 525   [ $dash $dash ] $dash 0.5 mul setdash
 526   stroke
 527   [] 0 setdash
 528 END
 529   one_hs('purple', $mid);
 530 }
 531
 532 sub edge_faces() {
 533   some_edge_faces($region{'NZ'});
 534   afsluitdijk();
 535   some_edge_faces(grep {
 536     $_->{Name} !~ m{^(?:L2?|NZ|ZZ)$}
 537   } values %region);
 538 }
 539
 540 our $hs_sz = 17 * MM2PT;
 541 our $hs_lw = 3;
 542
 543 our $text_sz = 18;
 544
 545 sub token_circle ($$$$;$$) {
 546   my ($what, $pos, $fillcolour, $edgecolour, $sz,$lw) = @_;
 547   $sz //= $hs_sz;
 548   $lw //= $hs_lw;
 549   o(sprintf <<END, $what, $fillcolour, psvec($pos), $sz/2, $edgecolour);
 550    %% %s
 551    newpath %s
 552      %s %f 0 360 arc closepath gsave fill grestore
 553      %s $lw setlinewidth stroke
 554 END
 555 }
 556
 557 sub one_hs ($$;$$) {
 558   my ($colour, $hspos, $sz, $lw) = @_;
 559   token_circle("HS - $colour",
 560                $hspos,
 561                darkerpscolour($colour, 0.75),
 562                miscpscolour('edge'),
 563               $sz,$lw);
 564 }
 565
 566 our $cube_sz = 6 * MM2PT;
 567 our $cube_gap = $cube_sz * 0.2;
 568 our $cube_lw = ($cube_sz * 0.1);
 569
 570 sub label_faces() {
 571   my $sz = $text_sz;
 572   my $shadow = $sz * 0.1;
 573   my $textc   = miscpscolour('text');
 574   my $shadowc = miscpscolour('textshadow');
 575   o(<<END);
 576   /wordsshow {
 577     $shadowc 0 10 359 {
 578       dup  cos $shadow mul
 579       exch sin $shadow mul
 580       words pop pop
 581     } bind for
 582     $textc 0 0 words pop pop
 583   } def
 584 END
 585   o("  /Helvetica-Bold findfont  $sz scalefont setfont\n");
 586   my %hs = map { $_ => 1 } @{ $c{HS} };
 587   foreach my $rr (values %region) {
 588     next if $rr->{Name} =~ m/^L\d?$/;
 589     my $words = $rr->{DisplayName};
 590     my $pos;
 591     if ($rr->{Name} eq 'NZ') {
 592       $pos = mkvec(90, 1280);
 593     } else {
 594       $pos = $rr->{Centre} + mkvec( 0, 0.5 * $sz * @$words );
 595     }
 596     if ($hs{$rr->{Name}}) {
 597       #print STDERR "adjust hs $rr->{Name}\n";
 598       $pos -= mkvec(0, -$hs_sz*
 599                     ( $rr->{Colour} eq 'green' ? 0.25 : 0.65 ));
 600       my $hspos = $pos - mkvec(0, $sz * @$words + $hs_sz/2 + $hs_lw
 601                                + $hs_sz*0.15);
 602       one_hs($rr->{Colour}, $hspos);
 603     }
 604     my $adjust = $c{TextAdjust}{$rr->{Name}};
 605     if ($adjust) {
 606       $pos += $sz * &mkvec(@$adjust);
 607     }
 608     my $w = $rr->{Water};
 609     $w = 2 if $rr->{Special} || $rr->{Name} eq 'ZZ';
 610     if ($w) {
 611       #print STDERR " water $w in $rr->{Name}\n";
 612       my $down = water_cubes_sz(2) - water_cubes_sz(1) + $cube_gap;
 613       $pos -= mkvec(0, -0.5 * $down);
 614       my $cube_y = -($sz * @$words);
 615       if ($rr->{Name} eq 'Wieringermeer') {
 616         $pos -= mkvec(0,+$sz);
 617         $cube_y = 0;
 618         $down = 0;
 619       }
 620       o("  gsave\n");
 621       o("    ", psvec($pos), " translate\n");
 622       o("    0 ", $cube_y, " translate\n");
 623       o("    ", -0.5 * water_cubes_sz($w)," ", -$down, " translate\n");
 624       water_cubes($w, miscpscolour('edge'));
 625       o("  grestore\n");
 626     }
 627     o("  /words {\n");
 628     foreach my $word (@$words) {
 629       $pos += mkvec(0,-$sz);
 630       o("   ", psvec($pos), " moveto");
 631       o(<<END);
 632    2 copy rmoveto
 633    ($word) dup stringwidth pop     % word xw
 634      -0.5 mul 0 rmoveto             % word
 635      show
 636    0 -$sz rmoveto
 637 END
 638     }
 639     o(<<END);
 640   } bind def
 641   wordsshow
 642 END
 643   }
 644 }
 645
 646 sub water_cubes_sz($){
 647   my ($n) = @_;
 648   ($cube_sz + $cube_lw) * $n + ($cube_gap * ($n-1));
 649 }
 650
 651 sub water_cubes($$){
 652   my ($n, $edgecolour) = @_;
 653   my $s = $cube_sz;
 654   for my $i (0..$n-1) {
 655     o("  newpath  ", $i * ($cube_sz + $cube_lw + $cube_gap),"  0  moveto\n");
 656     o("          $s  0  rlineto\n");
 657     o("           0 $s  rlineto\n");
 658     o("         -$s  0  rlineto  closepath\n");
 659     o("  gsave ", miscpscolour('cube'), " fill grestore\n");
 660     o("  gsave ", $edgecolour, " ", $cube_lw,
 661       " setlinewidth stroke grestore \n");
 662   }
 663 }
 664
 665 my $deck_h = 89 * MM2PT;
 666
 667 sub decks(){
 668   my $lw = $edge_lw/2;
 669   o("  /deck1path {\n");
 670   my $w = 63 * MM2PT;
 671   my $h = $deck_h;
 672   my $r =  5 * MM2PT;
 673   o("      ",($w/2)," 0 moveto\n");
 674   my @p = ([ $w, 0 ],
 675            [ $w,$h ],
 676            [ 0, $h ],
 677            [ 0,  0 ]);
 678   foreach my $i (0..3) {
 679     o("    @{ $p[$i] }  @{ $p[($i + 1) % 4] }  $r  arct\n");
 680   }
 681   o("    closepath\n");
 682   o("  } bind def");
 683   o("  /deckpairpathx {\n"); # x because it leaves matrix changed
 684   o("    newpath         deck1path\n");
 685   o("    200 0 translate deck1path\n");
 686   o("  } bind def");
 687   o("  $lw setlinewidth ",miscpscolour('playerdeck'),"\n");
 688   o("  gsave 401 44 translate deckpairpathx stroke grestore");
 689   o("  $lw setlinewidth ",miscpscolour('dykefail'),"\n");
 690   o("  gsave 242 1363 translate 90 rotate deckpairpathx stroke grestore");
 691 }
 692
 693 sub sea_track(){
 694   o("% sea level track\n");
 695   o("  gsave 11 700 translate\n");
 696   my $track = $c{SeaTrack};
 697   my $token_sz = $hs_sz;
 698   my $dy = $token_sz * 1.25;
 699   my $dx = $token_sz * 1.25;
 700   my $linecolour = seatrackedgepscolour();
 701   my @pos;
 702   for my $i (0..$#$track) {
 703     $pos[$i] = mkvec(0, ($i - 0.5 * @$track) * $dy);
 704   }
 705   my $prepline = "$linecolour $hs_lw setlinewidth newpath";
 706   o("  $prepline\n");
 707   o("    ",psvec($pos[0])," moveto ",psvec($pos[-1])," lineto stroke\n");
 708   for my $pos (@pos) {
 709     token_circle("SL", $pos,
 710                  miscpscolour('cube'),
 711                  $linecolour);
 712   }
 713   my $last = 0;
 714   my $cubeedgecolour = seatrackedgepscolour();
 715   for my $i (0..$#pos) {
 716     my $differs = $track->[$i] != $last;
 717     $last = $track->[$i];
 718     next unless $differs;
 719     o("  $prepline\n");
 720     o("  gsave ",
 721       psvec($pos[$i] + mkvec(-0.0 * $token_sz, $dy/2))," translate\n");
 722
 723     my $t_sz = 24;
 724     my $shrink = ($hs_sz * 0.75 / $deck_h);
 725     o("    gsave % T M $i\n");
 726     o("      -43.5 -6.5 translate\n");
 727     o("      0.8 .8 scale \n");
 728     o("      ",0.6 * $dx, " ", -0.28 * $dy," translate\n");
 729     o("      gsave");
 730     o("        $shrink dup scale -90 rotate\n");
 731     o("        newpath ", ($hs_lw / $shrink)," setlinewidth\n");
 732     o("         deck1path stroke\n");
 733     o("      grestore");
 734     o("      /Helvetica-Bold findfont $t_sz scalefont setfont\n");
 735     o("      12 -21.5 moveto ($track->[$i]) show");
 736     o("    grestore\n");
 737
 738     if ($i > 0) {
 739       o("  0 -$dy moveto",
 740         " ",psvec(mkvec( $dx + $cube_sz, 0 )),
 741         " rlineto stroke\n");
 742     }
 743     o("  ",($token_sz * 0.6 + $cube_gap)," ",
 744       (-$dy * 0.5 - 0.5 * (water_cubes_sz(2))),
 745       " translate\n");
 746     my $bottom = int(($track->[$i+1] + 1) / 2);
 747     water_cubes($bottom, $cubeedgecolour);
 748     my $new_n = $track->[$i+1] - $bottom;
 749     o("  ", 0.5 * (water_cubes_sz($bottom) - water_cubes_sz($new_n)),
 750       "  ",       (water_cubes_sz(2)-water_cubes_sz(1)), " translate\n");
 751     water_cubes($new_n, $cubeedgecolour);
 752     o("  grestore\n");
 753   }
 754   o("  grestore\n");
 755 }
 756
 757 our $dyke_l = 25 * MM2PT;;
 758
 759 sub dykes(){
 760   my $l = $dyke_l;
 761   my $w = 5 * MM2PT;
 762   my $lw = $edge_lw * 0.50;
 763   my $l2 = $l/2;
 764   my $w2 = $w/2;
 765   o("  /dykepath {\n");
 766   o("            -$l2 -$w2 moveto\n");
 767   o("             $l2 -$w2 lineto\n");
 768   o("             $l2  $w2 lineto\n");
 769   o("            -$l2  $w2 lineto closepath\n");
 770   o("  } bind def\n");
 771   o("  /dyke {\n");
 772   o("    newpath dykepath\n");
 773   o("    gsave ",miscpscolour('dykefill')," fill grestore\n");
 774   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 775   o("  } bind def\n");
 776   my $symbol_sz = $w * 1.50;
 777   my $t_sz = $symbol_sz * 1.0;
 778   my $t_at = sub {
 779     my ($ang) = @_;
 780     #print STDERR "ANG $ang\n";
 781     map { $t_sz * 0.5 * $_ } cos($ang), sin($ang);
 782   };
 783   my @t0 = $t_at->((TAU) *  0.25         );
 784   my @t1 = $t_at->((TAU) * (0.25 + 1./3) );
 785   my @t2 = $t_at->((TAU) * (0.25 + 2./3) );
 786   o("  /dtriangle {\n");
 787   o("    newpath @t0 moveto\n");
 788   o("            @t1 lineto\n");
 789   o("            @t2 lineto closepath\n");
 790   o("    gsave ",miscpscolour('dykeinit')," fill grestore\n");
 791   o("    gsave ",miscpscolour('edge')," $lw setlinewidth stroke grestore\n");
 792   o("  } bind def\n");
 793   foreach my $rr (values %region) {
 794     next if $rr->{Special};
 795     next if $rr->{Name} eq 'ZZ';
 796     next if $rr->{Colour} eq 'high';
 797     foreach my $adj (@{ $rr->{Adj} }) {
 798       my $neigh = $adj->{Name};
 799       o("  % dyke $rr->{Name} --- $neigh\n");
 800       next if $neigh lt $rr->{Name} && !$region{$neigh}{Special};
 801       next if $region{$neigh}{Colour} eq 'high';
 802       my @ends = adj_ends($adj);
 803       my $dirn = $ends[1] - $ends[0];
 804       my $angle = vec2atan($dirn);
 805       $angle = $angle * 360 / TAU;
 806       o("  gsave\n");
 807       o("    ", psvec( 0.5 * ($ends[0] + $ends[1]) )," translate\n");
 808       o("    $angle rotate\n");
 809       my $initial = $adj->{Dykes};
 810       for my $ys ($initial
 811                   ? [ map { $_ - 0.5 * ($initial-1) } 0..$initial-1 ]
 812                   : [0]) {
 813         foreach my $y (@$ys) {
 814           o("    gsave 0 ", $y * $w, " translate dyke ");
 815           o(" grestore\n");
 816         }
 817         my $nsymbols = $initial + !!$adj->{Deltawerk};
 818         o("   ", -0.5 * $symbol_sz * ($nsymbols-1)," 0 translate\n");
 819         my $trans = "  $symbol_sz 0 translate";
 820         if ($adj->{Deltawerk}) {
 821           one_hs('red', mkvec(0,0), $symbol_sz * 0.8, $lw);
 822           o($trans);
 823         }
 824         foreach my $i (1..$initial) {
 825           o(" gsave $angle neg rotate dtriangle grestore\n");
 826           o($trans);
 827         }
 828       }
 829       o("  grestore\n");
 830     }
 831   }
 832 }
 833
 834 sub hs_initial_1 ($$$;$$$) {
 835   my ($colour, $xi,$yi, $text, $text2, $fn) = @_;
 836   my $interval = $hs_sz * 1.75;
 837   my $demo_h = $hs_sz; #water_cubes_sz(3);
 838   my $demo_x0 = $hs_sz * 0.75 + $dyke_l * 0.60;
 839   my $demo_w = $demo_x0 + $dyke_l * 0.60;
 840   o("  % HS I $colour\n");
 841   o("  gsave\n");
 842   o("    550 1705 translate\n");
 843   o("    ", ($xi*$interval), " ", (($yi-1)*$interval), " translate\n");
 844   if ($fn) {
 845     o("  gsave\n");
 846     o("        $demo_h setlinewidth 0 0 moveto $demo_w 0 rlineto\n");
 847     o("        ", facepscolour($colour), " stroke grestore\n");
 848   }
 849   one_hs($colour, mkvec(0,0));
 850   if ($fn) {
 851     o("    /words {\n");
 852     o("      2 copy moveto                      ($text) show\n");
 853     o("      2 copy moveto 0 -$text_sz rmoveto ($text2) show\n");
 854     o("    } bind def\n");
 855     o("    gsave ".($hs_sz * 0.8)." $cube_gap translate wordsshow grestore\n");
 856     o("    $demo_x0 ",($hs_sz * -0.25)," translate\n");
 857     $fn->();
 858   }
 859   o("  grestore\n");
 860 }
 861
 862 sub hs_initial () {
 863   hs_initial_1('red',     0,0);
 864   hs_initial_1('purple',  0,1);
 865   hs_initial_1('green',   1,0, 'up to 6', 'fewer', sub {
 866     o("    ",(water_cubes_sz(1))," 0 translate\n");
 867     o("    0 ",(-water_cubes_sz(1) * 0.3)," translate\n");
 868     water_cubes(1, miscpscolour('edge'));
 869   });
 870   hs_initial_1('yellow',  1,1, 'up to 4', '', sub {
 871     o("    newpath dykepath\n");
 872     o("    gsave ",miscpscolour('edge')," stroke grestore\n");
 873     o("    gsave ",miscpscolour('dykehsadd')," fill grestore\n");
 874   });
 875 }
 876
 877 sub play_hint () {
 878   my $sz = 20;
 879   o("  gsave ",miscpscolour('hinttext')," 260 1715 translate\n");
 880   o("  /Helvetica-Bold findfont $sz scalefont setfont\n");
 881   my @t = split /\n/, $c{PlayHint};
 882   foreach my $i (0..$#t) {
 883     my $t = $t[$i];
 884     $t =~ s/[\\()]/\\$&/g;
 885     o("  0 ",(-$i * $sz)," moveto ($t) show\n");
 886   }
 887   o("  grestore");
 888 }
 889
 890 #----- main program -----
 891
 892 $xopts = shift @ARGV if $ARGV[0] =~ s/^-X//;
 893 $bounding = $1 if $xopts =~ s/b(\w+)//;
 894 $maxpaper = $1 if $xopts =~ s/p(\w+)//;
 895 $maxpaper =~ m/^a[134]$/ or confess;
 896
 897 ($facesf, @ARGV) = @ARGV or die;
 898 parse_input_graph();
 899 prep_region_rmap();
 900 read_faces();
 901 calculate_centres();
 902 transform_coordinates();
 903 adjust_nz();
 904
 905 computeboundings();
 906 preamble();
 907 fill_faces();
 908 edge_faces();
 909 dykes();
 910 label_faces();
 911 decks();
 912 sea_track();
 913 hs_initial();
 914 play_hint();
 915 showboundings();
 916 postamble();
 917
 918 print STDERR Dumper(\%region) if $ENV{'GENERATE_BOARD_DUP'};
 919
 920 # Local variables:
 921 # cperl-indent-level: 2
 922 # End.