SUBT    Debugging routines and macros => &.Hdr.HostDebug
OldOpt  SETA    {OPT}
        OPT     OptNoList+OptNoP1List

; ***********************************
; ***    C h a n g e   L i s t    ***
; ***********************************

; Date       Name  Description
; ----       ----  -----------
; 11-Mar-88  SKS   Created

; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
; Use of hdr.HostDebug: r13 MUST be a FD stack pointer. Do not use otherwise

;       GET     &.Hdr.Debug
;       GET     &.Hdr.HostDebug

; ... defs, etc ...

;       InsertDebugRoutines             ; ensure this is after module header !
;       InsertHostDebugRoutines         ; conventional to have this just before
;       END

; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

        MACRO
$label  dreg    $reg,$str,$cc,$type
$label  Push    lr
        BL      Tutu_HostVdu
 [ $reg = lr
        LDR     lr, [sp]
 ]
        DREG    $reg,"$str",$cc,$type
        BL      Tutu_TubeVdu
        Pull    lr
        MEND


        MACRO
$label  dline   $str, $cc
$label  Push    lr
        BL      Tutu_HostVdu
        DLINE   "$str",$cc
        BL      Tutu_TubeVdu
        Pull    lr
        MEND


        MACRO
$label  dstring $reg, $str, $cc
$label  Push    lr
        BL      Tutu_HostVdu
 [ $reg = lr
        LDR     lr, [sp]
 ]
        DSTRING $reg,"$str",$cc
        BL      Tutu_TubeVdu
        Pull    lr
        MEND


        MACRO
$label  InsertHostDebugRoutines
$label
; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
; More Tutu debugging!

Tutu_HostVdu ROUT

        Push    "r0, lr"
        ADR     r0, %FT99
        SWI     XOS_CLI
        Pull    "r0, pc",,^
99
        DCB     "HostVdu", 0
        ALIGN

; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

Tutu_TubeVdu ROUT

        Push    "r0, lr"
        ADR     r0, %FT99
        SWI     XOS_CLI
        Pull    "r0, pc",,^
99
        DCB     "TubeVdu", 0
        ALIGN

; +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
        MEND

        OPT     OldOpt
        END