#!/usr/bin/perl

use strict (qw(vars));
use warnings;

use Graph::Undirected;
use Commods;
use CommodsDatabase;

my $ocean= 'Midnight';


my $widists= Graph::Undirected->new();
my $wiarchs= Graph::Undirected->new();
my @wiarchlabels;
my %wiisland2node;
my %winode2island;
my %winode2lines;
my %wiccix2arch;
my $wialldists;

my $dbdists= Graph::Undirected->new();
my %dbisland2arch;

my %msgs;
sub pmsg ($$) { push @{ $msgs{$_[0]} }, "$_[0]: $_[1]\n"; }
sub warning ($) { pmsg("warning",$_[0]); }
sub error   ($) { pmsg("error",  $_[0]); }
sub change  ($) { pmsg("change", $_[0]); }
sub print_messages () {
    foreach my $k (qw(change warning error)) {
	my $m= $msgs{$k};
	next unless $m;
	print sort @$m or die $!;
    }
}

if (@ARGV && $ARGV[0] eq '--debug') {
    shift @ARGV;
    open DEBUG, ">&STDOUT" or die $!;
    select(DEBUG); $|=1;
} else {
    open DEBUG, ">/dev/null" or die $!;
}
select(STDOUT); $|=1;

my $parity;
sub nn_xy ($$) {
    my ($x,$y) = @_;
    my $tp= (0+$x ^ 0+$y) & 1;
    defined $parity or $parity=$tp;
    $tp==$parity or warning("line $.: parity error $x,$y is $tp not $parity");
    my $n= "$_[0],$_[1]";
    $winode2lines{$n}{$.}++;
    return $n;
}

sub yppedia_chart_parse () {
    # We don't even bother with tag soup; instead we do line-oriented parsing.

    while (<>) {
	s/\<--.*--\>//g;
	s/^\s*//; chomp; s/\s+$//; s/\s+/ /g;
	s/\<\/?(?:b|em)\>//g;
	s/\{\{Chart\ style\|[^{}]*\}\}//g;
	next unless m/\{\{/; # only interested in chart template stuff

	my ($x,$y, $arch,$island,$solid,$dirn);
	my $nn= sub { return nn_xy($x,$y) };
    
	if (($x,$y,$arch) =
	    m/^\{\{ chart\ label \|(\d+)\|(\d+)\| .*
		    \'\[\[ [^][\']* \| (\S+)\ archipelago \]\]\'*\}\}$/xi) {
	    printf DEBUG "%2d,%-2d arch %s\n", $x,$y,$arch;
	    push @wiarchlabels, [ $x,$y,$arch ];
	} elsif (($x,$y,$island) =
	    m/^\{\{ chart\ island\ icon \|(\d+)\|(\d+)\|
		    ([^| ][^|]*[^| ]) \| .*\}\}$/xi) {
	    my $n= $nn->();
	    $wiisland2node{$island}= $n;
	    $winode2island{$n}= $island;
	    $widists->add_vertex($n);
	    $wiarchs->add_vertex($n);
#print "\$g->add_vertex('$n');\n";
	    printf DEBUG "%2d,%-2d island %s\n", $x,$y,$island;
	} elsif (($solid,$x,$y,$dirn) =
	    m/^\{\{ chart\ league((?:\ solid)?) \|(\d+)\|(\d+)\|
		    ([-\/\\o]) \| .*\}\}$/xi) {
	    next if $dirn eq 'o';

	    my ($bx,$by) = ($x,$y);
	    if ($dirn eq '-') { $bx+=2; }
	    elsif ($dirn eq '\\') { $bx++; $by++; }
	    elsif ($dirn eq '/') { $x++; $by++; }
	    else { die; }

	    $widists->add_weighted_edge($nn->(), nn_xy($bx,$by), 1);
	    $wiarchs->add_edge($nn->(), nn_xy($bx,$by)) if $solid;
	    $wiarchs->add_edge($nn->(), nn_xy($bx,$by)) if $solid;
#print "\$g->add_edge('".$nn->()."','".nn_xy($bx,$by)."');\n" if $solid;

	    printf DEBUG "%2d,%-2d league %-6s %s\n", $x,$y,
	        $solid?'solid':'dotted', $dirn;
	} elsif (
	    m/^\{\{ chart\ head \}\}$/xi
		 ) {
	    next;
	} else {
	    warning("line $.: ignoring incomprehensible: $_");
	}
    }
}

sub database_fetch_ocean () {
    my ($row,$sth);
    $sth= $dbh->prepare('SELECT islandname, archipelago FROM islands');
    $sth->execute();
    while ($row= $sth->fetchrow_hashref) {
	print DEBUG "database-island $row->{'islandname'}".
	             " $row->{'archipelago'}\n";
	$dbisland2arch{$row->{'islandname'}}= $row->{'archipelago'};
    }
    $sth= $dbh->prepare('SELECT dist, a.islandname a, b.islandname b
 				FROM dists
				JOIN islands AS a ON dists.aiid==a.islandid
				JOIN islands AS b ON dists.biid==b.islandid');
    $sth->execute();
    while ($row= $sth->fetchrow_hashref) {
	$dbdists->add_weighted_edge($row->{'a'}, $row->{'b'}, $row->{'dist'});
    }
}			 

sub yppedia_graphs_prune_boring () {
    # Prune the LP database by eliminating boring intermediate vertices
    foreach my $delete ($widists->vertices()) {
	next if exists $winode2island{$delete};
	my @neigh= $widists->neighbours($delete);
	next unless @neigh==2;
	my $weight= 0;
	map { $weight += $widists->get_edge_weight($delete, $_) } @neigh;
	$widists->add_weighted_edge(@neigh, $weight);
	$widists->delete_vertex($delete);
	printf DEBUG "%-5s elide %5s %-5s %2d\n", $delete, @neigh, $weight;
    }
}

sub yppedia_graphs_check () {
    # Check that it's connected.
    foreach my $cc ($widists->connected_components()) {
	next if 2*@$cc > $widists->vertices();
	my $m= "disconnected league point(s):";
	foreach my $n (@$cc) {
	    $m .= "\n    LP $n, def. yppedia line(s): ".
		join(',', sort keys %{ $winode2lines{$n} });
	}
	warning($m);
    }
}

sub yppedia_archs_sourceinfo () {
    # Assign archipelagoes according to the source-info file
    foreach my $arch (sort keys %{ $oceans{$ocean} }) {
	foreach my $islename (sort keys %{ $oceans{$ocean}{$arch} }) {
	    my $islenode= $wiisland2node{$islename};
	    defined $islenode or
		error("island $islename in source-info but not in WP map");
	    my $ccix= $wiarchs->connected_component_by_vertex($islenode);
	    my $oldarch= $wiccix2arch{$ccix};
	    error("island $islename in $arch in source-info".
		  " connected to $oldarch as well")
		if defined $oldarch && $oldarch ne $arch;
	    printf DEBUG "%-5s force-island-arch cc%-2d %-10s %s\n",
	        $islenode, $ccix, $arch, $islename;
	    $wiccix2arch{$ccix}= $arch;
	}
    }
}

sub yppedia_archs_chart_labels () {
    # Assign archipelago labels to groups of islands
    #
    foreach my $label (@wiarchlabels) {
	my ($ax,$ay,$arch) = @$label;
	my $best_ccmulti= -1;
	my $best_d2= 0;
	my $best_n;
#	print DEBUG "$ax,$ay arch-island-search $arch\n";
	$ay += 1;  $ax += 2;  # coords are rather to the top left of label
	foreach my $vertex ($wiarchs->vertices()) {
	    next unless exists $winode2island{$vertex};
	    my $ccix= $wiarchs->connected_component_by_vertex($vertex);
	    my @cc= $wiarchs->connected_component_by_index($ccix);
	    my $ccmulti= @cc > 1;
	    my ($vx,$vy) = split /,/, $vertex;
	    my $d2= ($vx-$ax)*($vx-$ax) + ($vy-$ay)*($vy-$ay);
	    my $cmp= $ccmulti <=> $best_ccmulti
		||   $best_d2 <=> $d2;
	    printf DEBUG "%2d,%-2d arch-island-search %5s d2=%4d cc%-2d".
		         " #cc=%2d ccmulti=%d cmp=%2d %s\n",
	        $ax,$ay, $vertex, $d2, $ccix, scalar(@cc), $ccmulti, $cmp,
	        $winode2island{$vertex};
	    next unless $cmp > 0;
	    $best_n=       $vertex;
	    $best_d2=      $d2;
	    $best_ccmulti= $ccmulti;
	}
	die 'no island vertices?!' unless defined $best_n;
	my $ccix= $wiarchs->connected_component_by_vertex($best_n);
	printf DEBUG
	    "%2d,%-2d arch-island-select %-5s d2=%4d cc%-2d     %-10s %s\n",
	    $ax,$ay, $best_n, $ccix, $best_d2, $arch, $winode2island{$best_n};
	my $desc= join "\n", map {
	    my $in= $winode2island{$_};
	    "    LP $_". (defined $in ? ", $in" : "");
	} sort $wiarchs->connected_component_by_index($ccix);

	if (exists $wiccix2arch{$ccix} and $wiccix2arch{$ccix} ne $arch) {
	    error("archipelago determination failed, wrongly merged:\n".
		  "    archipelago $arch\n".
		  "    archipelago $wiccix2arch{$ccix}\n".
		  $desc);
	    next;
	}
	$wiccix2arch{$ccix}= $arch;
#	print "$ccix $arch ::\n$desc\n";
    }
}

sub yppedia_archs_fillbynearest() {
    # Assign islands not labelled above to archipelagoes.
    #
    # We do this by, for each connected component (set of islands
    # linked by purchaseable charts), searching for the nearest other
    # connected component which has already been assigned an arch.
    # `Nearest' means shortest distance of unpurchaseable charts, in
    # leagues.
    #
    # we need only consider vertices which weren't `boring intermediate
    # vertices' (removed during optimisation as being of order 2)
    my @ccs_useful= map {
	[ grep { $widists->has_vertex($_) } @$_ ]
    } $wiarchs->connected_components();

    my @assignments;

    foreach my $sourceccix (0..$#ccs_useful) {
	next if defined $wiccix2arch{$sourceccix};
	next unless $ccs_useful[$sourceccix];

	my @sourcecc= $wiarchs->connected_component_by_index($sourceccix);
	my @islandnodes= grep { $winode2island{$_} } @sourcecc;
	next unless @islandnodes; # don't care, then

	foreach my $islandnode (@islandnodes) {
	    printf DEBUG "%-5s arch-join-need cc%-2d             %s\n",
	        $islandnode, $sourceccix, $winode2island{$islandnode};
	}
	my $best_dist= 9999999;
	my ($best_target, $best_targetccix, $best_source);
	foreach my $targetccix (0..$#ccs_useful) {
	    next unless defined $wiccix2arch{$targetccix}; # not helpful
	    next unless $ccs_useful[$targetccix];
	    foreach my $target ($wiarchs->
			 connected_component_by_index($targetccix)) {
		foreach my $source (@sourcecc) {
		    my $target_dist= $wialldists->path_length($target,$source);
		    next unless defined $target_dist;
		    next if $target_dist >= $best_dist;
		    $best_dist= $target_dist;
		    $best_source= $source;
		    $best_target= $target;
		    $best_targetccix= $targetccix;
		}
	    }
	}
	die "no possible target ?!" unless defined $best_target;

	my $arch= $wiccix2arch{$best_targetccix};
	my $best_island= $winode2island{$best_target};
	printf DEBUG "%-5s arch-join-to %-5s dist=%2d cc%-2d  %-10s %s\n",
	    $best_source, $best_target, $best_dist,
	    $best_targetccix, $arch,
	    defined($best_island) ? $best_island : "-";

	push @assignments, [ $sourceccix, $arch ];
    }
    foreach my $assign (@assignments) {
	$wiccix2arch{$assign->[0]}= $assign->[1];
    }
}

sub winode2arch ($) {
    my ($node) = @_;
    my $ccix= $wiarchs->connected_component_by_vertex($node);
    return $wiccix2arch{$ccix};
}
sub wiisland2arch ($) {
    my ($island) = @_;
    my $node= $wiisland2node{$island};
    die "$island ?" unless defined $node;
    return winode2arch($node);
}

sub compare_island_lists () {
    foreach my $island (sort keys %dbisland2arch) {
	my $node= $wiisland2node{$island};
	if (!defined $node) {
	    error("would delete island: $island");
	    next;
	}
	my $wiarch= winode2arch($node);
	if (!defined $wiarch) {
	    error("island has no arch: $island");
	    next;
	}
	my $dbarch= $dbisland2arch{$island};
	if ($wiarch ne $dbarch) {
	    change("change archipelago from $dbarch to $wiarch".
		   " for island $island");
	}
    }
    foreach my $island (sort keys %wiisland2node) {
	my $dbarch= $dbisland2arch{$island};
	if (!defined $dbarch) {
	    my $wiarch= wiisland2arch($island);
	    if (!defined $wiarch) {
		error("new island has no arch: $island");
		next;
		# We check arches of non-new islands above
	    }
	    change("new island in $wiarch: $island");
	}
    }
}

sub compare_distances () {
    foreach my $ia (sort keys %dbisland2arch) {
	my $na= $wiisland2node{$ia};
	next unless defined $na;
	foreach my $ib (sort keys %dbisland2arch) {
	    next unless $ia le $ib; # do every pair only once
	    my $nb= $wiisland2node{$ib};
	    next unless defined $nb;
	    my $dbdist= $dbdists->get_edge_weight($ia,$ib);
	    my $widist= $wialldists->path_length($na,$nb);
	    if (!defined $dbdist) {
		change(sprintf "define distance %2d for %s..%s",
		       $widist, $ia,$ib);
	    } elsif ($dbdist != $widist) {
		change(sprintf "change distance %2d to %2d for %s..%s",
		       $dbdist, $widist, $ia,$ib);
	    }
	}
    }
}

parse_info_serverside();

db_setocean($ocean);
db_connect();
database_fetch_ocean();

yppedia_chart_parse();
yppedia_graphs_prune_boring();
yppedia_graphs_check();
yppedia_archs_sourceinfo();
$wialldists= $widists->APSP_Floyd_Warshall();
yppedia_archs_chart_labels();
yppedia_archs_fillbynearest();

compare_island_lists();
compare_distances();

print_messages();