#!/usr/bin/wish
# show your vessels on a map

# This is part of ypp-sc-tools, a set of third-party tools for assisting
# players of Yohoho Puzzle Pirates.
#
# Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.
#
# Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
# are used without permission.  This program is not endorsed or
# sponsored by Three Rings.



source yarrglib.tcl
source panner.tcl
package require http

#---------- general utilities ----------

set debug 0
proc debug {m} {
    global debug
    if {$debug} { puts "DEBUG $m" }
}

proc badusage {m} {
    puts stderr "where-vessels: bad usage: $m"
    exit 1
}

proc glset {n val} {
    upvar #0 $n var
    set var $val
}

#---------- expecting certain errors ----------

proc errexpect-setline {lno line} {
    glset errexpect_lno $lno
    glset errexpect_line $line
}

proc errexpect-error {m} {
    global errexpect_line errexpect_lno
    error $m "$errexpect_line\n" [list YARRG-ERREXPECT $errexpect_lno]
}

proc errexpect-arrayget {arrayvar key} {
    upvar 1 $arrayvar av
    upvar 1 ${arrayvar}($key) v
    if {[info exists v]} { return $v }
    errexpect-error "undefined $key"
}

proc errexpect-arrayget-boolean {arrayvar key} {
    switch -exact [uplevel 1 [list errexpect-arrayget $arrayvar $key]] {
    	true	{ return 1 }
	false	{ return 0 }
	default	{ errexpect-error "unexpected $key" }
    }
}

proc errexpect-catch {code} {
    global errorInfo errorCode
    set rc [catch {
	uplevel 1 $code
    } rv]
    debug "ERREXPECT CATCH |$rc|$rv|$errorCode|$errorInfo|"
    if {$rc==1 && ![string compare YARRG-ERREXPECT [lindex $errorCode 0]]} {
	return [list 1 $rv [lindex $errorCode 1] $errorInfo]
    } elseif {$rc==0} {
	return [list 0 $rv]
    } else {
	return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rv
    }
}

#---------- argument parsing ----------

proc nextarg {} {
    global ai argv
    if {$ai >= [llength $argv]} {
	badusage "option [lindex $argv [expr {$ai-1}]] needs a value"
    }
    set v [lindex $argv $ai]
    incr ai
    return $v
}

set notes_loc vessel-notes
set scraper {./yppedia-ocean-scraper --chart}
set info_cache _vessel-info-cache
set info_source rsync.yarrg.chiark.net::yarrg/vessel-info

proc parseargs {} {
    global ai argv
    global debug scraper
    set ai 0

    while {[regexp {^\-} [set arg [lindex $argv $ai]]]} {
	incr ai
	switch -exact -- $arg {
	    -- { break }
	    --pirate { glset pirate [string totitle [nextarg]] }
	    --ocean { glset ocean [string totitle [nextarg]] }
	    --clipboard-file { load-clipboard-file [nextarg] }
	    --local-html-dir { lappend scraper --local-html-dir=[nextarg] }
	    --notes { glset notes_loc [nextarg] }
	    --vessel-info-source { glset info_source [nextarg] }
	    --debug { incr debug }
	    default { badusage "unknown option $arg" }
	}
    }
    set argv [lrange $argv $ai end]
    if {[llength $argv]} { badusage "non-option args not allowed" }
}

proc argdefaults {} {
    global ocean notes_loc pirate scraper
    if {![info exists ocean] || ![info exists pirate]} {
	set cmd {./yarrg --find-window-only --quiet}
	if {[info exists ocean]} { lappend cmd --ocean $ocean }
	if {[info exists pirate]} { lappend cmd --pirate $pirate }
	manyset [split [eval exec $cmd] " "] ocean pirate
	if {![llength $ocean] || ![llength $pirate]} {
	    error "$ocean $pirate ?"
	}
    }
    lappend scraper $ocean
}


#---------- loading and parsing the vessel notes ----------

proc load-notes {} {
    global notes_loc notes_data
    if {[regexp {^\w+\:} $notes_loc]} {
	update
	debug "FETCHING NOTES $notes_loc"
	set req [::http::geturl $notes_loc]
	switch -glob [::http::status $req].[::http::ncode $req] {
	    ok.200 { }
	    ok.* { error "retrieving vessel-notes: [::http::code $req]" }
	    * { error "Retrieving vessel-notes: [::http::error $req]" }
	}
	set newdata [::http::data $req]
	::http::cleanup $req
    } else {
	debug "READING NOTES $notes_loc"
	set vn [open $notes_loc]
	set newdata [read $vn]
	close $vn
    }
    set notes_data $newdata
}

proc parse-notes {} {
    global notes_data notes
    catch { unset notes }

    set lno 0
    foreach l [split $notes_data "\n"] {
	incr lno
	errexpect-setline $lno $l
	set l [string trim $l]
	if {![string length $l]} continue
	if {[regexp {^\#} $l]} continue
	if {![regexp -expanded \
		  {^ (\d+) (?: \s+([^=]*?) )? \s* =
		      (?: \s* (\S+)
		       (?: \s+ (\S+) )?)? $} \
		  $l dummy vid vname owner note]} {
	      errexpect-error "badly formatted"
	}
	set vname [string trim $vname]
	if {[info exists notes($vid)]} {
	    errexpect-error "duplicate vesselid $vid"
	}
	set notes($vid) [list $lno $vname $owner $note]
    }
}

proc note-info {lno vid name island description} {
    global note_infos
    lappend note_infos [list $lno $vid $name $island $description]
}

proc display-note-infos {} {
    global note_infos note_missings notes

    set nmissing [llength $note_missings]
    debug "display-note-infos $nmissing [array size notes]"

    if {[llength $note_infos]} {
	set tiny "[llength $note_infos] warning(s)"
    } elseif {$nmissing && [array size notes]} {
	set tiny "$nmissing missing"
    } else {
	return
    }

    set infodata {}

    foreach info $note_infos {
	manyset $info lno vid name island description
	append infodata "vessel"
	append infodata " $vid"
	if {[string length $name]} { append infodata " $name" }
	if {[string length $island]} { append infodata " ($island)" }
	append infodata ": " $description "\n"
    }

    if {$nmissing} {
	if {[string length $infodata]} { append infodata "\n" }
	append infodata "$nmissing vessel(s) not mentioned in notes:\n"
	set last_island {}
	foreach info [lsort $note_missings] {
	    manyset $info island name vid
	    if {[string compare $island $last_island]} {
		append infodata "# $island:\n"
		set last_island $island
	    }
	    append infodata [format "%-9d %-29s =\n" $vid $name]
	}
    }

    parser-control-failed-core .cp.ctrl.notes notes \
	white blue 0 \
	$tiny \
	"[llength $note_infos] warning(s);\
         $nmissing vessel(s) missing" \
	"Full description of warnings and missing vessels:" \
	$infodata
}

#---------- vessel properties ----------

proc info-cache-update {} {
    global info_source info_cache
    file mkdir $info_cache
    exec sh -c "cp -u icons/* $info_cache/."

    if {[string length $info_source]} {
	set cmdl [list \
		  rsync -udLKtOzm \
		  --exclude=*~ --exclude=*.bak --exclude=.* --exclude=*.tmp \
		  $info_source/ $info_cache 2>@ stderr]
	debug "INFO-CACHE $cmdl"
	eval exec $cmdl
    }

    set f [open $info_cache/vessel-info]
    glset vessel_class_data [read $f]
    close $f
}

proc vesselclasses-init {} {
    global vc_game2code vc_code2abbrev vc_code2full vc_codes

    global vessel_class_data
    manyset $vessel_class_data classinfos subclassinfos

    set vc_codes {}
    foreach {game code abbrev full} $classinfos {
	if {![regexp {^[a-z][a-z]$} $code code]} { error "bad code" }
	if {![regexp {^[a-z][a-z]$} $abbrev abbrev]} { error "bad abbrev" }
	lappend vc_codes $code
	set vc_game2code($game) $code
	set vc_code2abbrev($code) $abbrev
	set vc_code2full($code) $full
	load-icon $abbrev
    }

    global vsc_code2report
    global vsc_game2code
    set vsc_game2code(null) {}
    set vsc_code2report() Ordinary
    set vsc_code2report(!) "(Special/L.E.)"
    foreach {game code full} $subclassinfos {
	if {![regexp {^[A-Z]$} $code code]} { error "bad code" }
	set vsc_game2code($game) $code
	set vsc_code2report($code) $full
    }

    load-icon atsea
    set owners {ours dot query}
    foreach b $owners { load-icon $b }
    foreach a {battle borrow dot} {
	load-icon $a
	foreach b $owners { load-icon-combine $a $b }
    }
}

proc load-icon {icon} {
    global info_cache
    image create bitmap icon/$icon -file $info_cache/$icon.xbm
}

proc load-icon-combine {args} {
    global info_cache
    set cmd {}
    set delim "pnmcat -lr "
    foreach icon $args {
	append cmd $delim " <(xbmtopbm $info_cache/$icon.xbm)"
	set delim " <(pbmmake -white 1 1)"
    }
    append cmd " | pbmtoxbm"
    debug "load-icon-combine $cmd"
    image create bitmap icon/[join $args +] -data [exec bash -c $cmd]
}

proc code-lockown2icon {lockown} {
    manyset [split $lockown ""] lock notown
    set l "
	 [lindex {battle borrow dot} $lock]
         [lindex {ours dot query {} {} dot} $notown]
    "
    if {[llength $l]} { return icon/[join $l +] } { return {} }
}

proc canvas-horiz-stack {xvar xoff y bind type args} {
    upvar 1 $xvar x
    upvar 1 canvas canvas
    set id [eval $canvas create $type [expr {$x+$xoff}] $y $args]
    set bbox [$canvas bbox $id]
#   debug "CANVAS-HORIZ-STACK $type $x $xoff $id $bbox [list $args]"
    set x [lindex $bbox 2]
    $canvas bind $id <ButtonPress> $bind
    return $id
}

proc code2canvas {code canvas x yvar qty qtylen bind} {
    global vc_code2abbrev
    upvar 1 $yvar y

    manyset [split $code _] inport class subclass lockown xabbrev

    set stackx $x
    incr stackx 2
    set imy [expr {$y+2}]

    if {!$inport} { incr qtylen -1 }
    if {$qtylen<=0} { set qtylen {} }
    set qty [format "%${qtylen}s" $qty]

    set qtyid [canvas-horiz-stack stackx 0 $y $bind \
		   text -anchor nw -font fixed -text $qty]

    if {!$inport} {
	canvas-horiz-stack stackx 0 $imy $bind \
	    image -anchor nw -image icon/atsea
	incr stackx
    }
    
    upvar #0 vc_code2abbrev($class) vcabb
    if {![info exists vcabb]} {
	set vcabb vc-$class
	image create bitmap icon/$vcabb -data \
	    [exec pbmtext -builtin fixed $class | pnminvert | pnmcrop >t.pnm]
    }
    canvas-horiz-stack stackx -1 $imy $bind \
	    image -anchor nw -image icon/$vcabb

    if {[string length $subclass]} {
	canvas-horiz-stack stackx 0 $y $bind \
	    text -anchor nw -font fixed -text \
	    $subclass
    }

    incr stackx
    set lockownicon [code-lockown2icon $lockown]
    if {[string length $lockownicon]} {
	canvas-horiz-stack stackx 0 $imy $bind \
	    image -anchor nw -image $lockownicon
	incr stackx
    }
    
    if {[string length $xabbrev]} {
	canvas-horiz-stack stackx 0 $y $bind \
	    text -anchor nw -font fixed -text \
	    $xabbrev
    }
    
    set bbox [$canvas bbox $qtyid]
    set ny [lindex $bbox 3]
    set bid [$canvas create rectangle \
		 $x $y $stackx $ny \
		 -fill white]

    set y $ny
    $canvas lower $bid $qtyid

    $canvas bind $bid <ButtonPress> $bind
}

proc show-report-decode {code} {
    global vc_code2full

    manyset [split $code _] inport classcode subclass lockown xabbrev
    manyset [split $lockown ""] lock notown
    
    report-set inport [lindex {{At Sea} {In port}} $inport]
    report-set class $vc_code2full($classcode)

    global smash_subclass
    if {$smash_subclass >= 2} {
	report-set subclass "(Any subclass)"
    } elseif {[
	       upvar #0 vsc_code2report($subclass) subclass_report
	       info exists subclass_report
	      ]} {
	report-set subclass $subclass_report
    } else {
	report-set subclass "Subclass \"$subclass\""
    }

    report-set lock [lindex {
	{Battle ready} {Unlocked} {Locked}
	{(All lock states)} {(Not battle ready)}
    } $lock]

    switch -exact $notown {
	0 { report-set own "Yours" }
	1 { report-set own "Other pirate's" }
	2 { report-set own "Owner unknown" }
	3 { report-set own "(All ownerships)" }
	4 - 5 { report-set own "(Yours/unknown)" }
	default { report-set own "?? $notown" }
    }

    if {[string length $xabbrev]} {
	report-set xabbrev "Notes flags: $xabbrev"
    } else {
	report-set xabbrev "No flags in notes"
    }
}

#---------- common to smashing and filtering ----------

proc make-control {parent ctrl label ekind} {
    debug "MAKE-CONTROL [list $parent $ctrl $label $ekind]"
    label $parent.lab_$ctrl -text $label -justify left
    $ekind $parent.$ctrl
    manyset [grid size $parent] dummy row
    incr row
    grid configure $parent.lab_$ctrl -row $row -column 0 -sticky nw -pady 4
    grid configure $parent.$ctrl -row $row -column 1 -sticky w -pady 3
    return $parent.$ctrl
}

proc begin-control-grid {cw count rows inrow} {
    if {!$inrow} { set inrow [expr {($count + $rows) / $rows}] }
    upvar #0 control_grid_properties($cw) props
    set props [list $rows $inrow]
    return $cw
}

proc make-control-grid-entry {cw kind ix ekind args} {
    upvar #0 control_grid_properties($cw) props
    manyset $props rows inrow

    set ew $cw.$ix

    debug "MAKE-CONTROL-GRID-ENTRY $cw $kind $ix $ekind $rows $inrow $ew"

    eval [list $ekind $ew] $args

    switch -exact $kind {
	ix {
	    grid configure $ew -sticky sw \
		-row [expr {$ix / $inrow}] \
		-column [expr {$ix % $inrow}]
	}
	final {
	    grid configure $ew -sticky se \
		-row [expr {$rows-1}] \
		-column [expr {$inrow-1}]
	}
	default {
	    error "$kind ?"
	}
    }
    return $ew
}

proc control-tickbox-flip {varsvn values} {
    upvar #0 $varsvn vars
    foreach val $values {
	set vars($val) [expr {!$vars($val)}]
    }
    redraw-needed c.-tickbox-flip $varsvn $values
}

proc populate-control-grid-tickboxes {cw rows inrow varsvn values flipvalues
				    label_kind valvn default_get label_get} {
    debug "POPULATE-CONTROL-GRID-TICKBOXES $cw $rows $inrow $varsvn\
             [list $values] $label_kind $valvn"

    upvar #0 $varsvn vars
    upvar 1 $valvn val
    set count [llength $values]

    begin-control-grid $cw $count $rows $inrow

    for {set ix 0} {$ix < $count} {incr ix} {
	set val [lindex $values $ix]
	set vars($val) [uplevel 1 $default_get]
	set ew [make-control-grid-entry $cw ix $ix checkbutton \
		    -variable ${varsvn}($val) \
		    -font fixed \
		    -command [list redraw-needed c.-g.-tickbox $cw $val]]
	$ew configure -$label_kind [uplevel 1 $label_get]
	switch -exact $label_kind {
	    image { $ew configure -height 16 }
	}
    }
    [make-control-grid-entry $cw final invert button] \
	configure \
	-text flip -command [list control-tickbox-flip $varsvn $flipvalues] \
	-padx 0 -pady 0
}

#---------- smashing ----------

set smash_subclass 0
set smash_owner 0

proc smash-code {code} {
    manyset [split $code _] inport class subclass lockown xabbrev

    upvar #0 smash_sizemap($class) smclass

    global smash_subclass
    if {$smash_subclass > 1} {
	set subclass {}
    } elseif {$smash_subclass && [string length $subclass]} {
	set subclass !
    }

    global smash_owner
    switch $smash_owner {
	0 { }
	1 { regsub {[12]$} $lockown 5 lockown }
	2 {
	    if {[regexp {^0.} $lockown]} {
		# battle ready / all lock states
		set lockown 03
	    } elseif {[regexp {^.0} $lockown]} {
		# not battle ready / yours
		set lockown 40
	    } else {
		# state (not battle ready) / not known to be yours
		regsub {.$} $lockown 4 lockown
	    }
	}
	3 { regsub {.$} $lockown {3} lockown }
	4 { set lockown 33 }
    }

    return [join [list $inport $smclass $subclass $lockown $xabbrev] _]
}

proc smash-prepare {} {
    global vc_codes smash_sizemap smash_size
    set mapto {}
    foreach size $vc_codes {
	if {!$smash_size($size)} { set mapto $size }
	set smash_sizemap($size) $mapto
    }
}

proc make-smasher {sma label ekind} {
    return [make-control .smash $sma $label $ekind]
}

proc make-radio-smasher {sma label variable descs rows inrow} {
    set w [make-smasher $sma $label frame]
    begin-control-grid $w [llength $descs] $rows $inrow
    for {set i 0} {$i < [llength $descs]} {incr i} {
	make-control-grid-entry $w ix $i \
	    radiobutton \
	    -variable $variable -value $i -command redraw-needed \
	    -text [lindex $descs $i]
    }
}

proc make-smashers {} {
    global vc_codes vc_code2abbrev
    set cw [make-smasher size "Size\n round\n down" frame]
    populate-control-grid-tickboxes $cw 2 0 smash_size \
	$vc_codes [lrange $vc_codes 1 end] \
	image val { expr 0 } { expr {"icon/$vc_code2abbrev($val)"} }
    $cw.0 configure -state disabled

    make-radio-smasher subclass Subclass smash_subclass \
	{Show Normal/LE Hide} 1 0

    make-radio-smasher owner Owner smash_owner \
	{Show Yours? {For you} Lock Hide} 2 3
}

#---------- filtering ----------

set filters {}

proc filter-values/size {} { global vc_codes; return $vc_codes }
proc filter-icon/size {code} {
    upvar #0 vc_code2abbrev($code) abb
    return icon/$abb
}
proc filter-default/size {code} { return 1 }
proc filter-says-yes/size {codel} {
    set sizecode [lindex $codel 1]
    upvar #0 filter_size($sizecode) yes
    return $yes
}

proc filter-values/lockown {} {
    foreach lv {0 1 2} {
	foreach ov {0 1 2} {
	    lappend vals "$lv$ov"
	}
    }
    return $vals
}
proc filter-icon/lockown {lockown} { return [code-lockown2icon $lockown] }
proc filter-default/lockown {lockown} {
    return [regexp {^[01]|^2[^1]} $lockown]
}
proc filter-says-yes/lockown {codel} {
    set lockown [lindex $codel 3]
    upvar #0 filter_lockown($lockown) yes
    debug "FILTER-SAYS-YES/LOCKOWN $codel $lockown $yes"
    return $yes
}

proc filter-validate/xabbre {re} {
    if {[catch {
	regexp -- $re {}
    } emsg]} {
	regsub {^.*:\s*} $emsg {} emsg
	regsub {^.*(.{30})$} $emsg {\1} emsg
	return $emsg
    }
    return {}
}
proc filter-says-yes/xabbre {codel} {
    global filter_xabbre
    set xabbrev [lindex $codel 4]
    return [regexp -- $filter_xabbre $xabbrev]
}

proc make-tickbox-filter {fil label rows inrow} {
    set values [filter-values/$fil]

    if {![catch { info args filter-icon/$fil }]} {
	set label_get { filter-icon/$fil $val }
	set label_kind image
    } else {
	set label_get { filter-map/$fil $val }
	set label_kind text
    }

    set fw [make-filter $fil $label frame]

    populate-control-grid-tickboxes $fw $rows $inrow filter_$fil \
	$values $values \
	$label_kind val { filter-default/$fil $val } $label_get
}

proc entry-filter-changed {fw fil n1 n2 op} {
    global errorInfo
    upvar #0 filter_$fil realvar
    upvar #0 filterentered_$fil entryvar
    global def_background
    debug "entry-filter-changed $fw $fil $entryvar"
    if {[catch {
	set error [filter-validate/$fil $entryvar]
	if {[string length $error]} {
	    $fw.error configure -text $error -foreground white -background red
	} else {
	    $fw.error configure -text { } -background $def_background
	    set realvar $entryvar
	    redraw-needed
	}
    } emsg]} {
	puts stderr "FILTER CHECK ERROR $emsg $errorInfo"
    }
}

proc make-entry-filter {fil label def} {
    global filterentered_$fil
    upvar #0 filter_$fil realvar
    set realvar $def
    set fw [make-filter $fil $label frame]
    entry $fw.entry -textvariable filterentered_$fil
    label $fw.error
    glset def_background [$fw.error cget -background]
    trace add variable filterentered_$fil write \
	[list entry-filter-changed $fw $fil]
    pack $fw.entry $fw.error -side top -anchor w
}

proc make-filter {fil label ekind} {
    global filters
    lappend filters $fil
    return [make-control .filter $fil $label $ekind]
}

proc make-filters {} {
    make-tickbox-filter size Size 2 0
    make-tickbox-filter lockown "Lock/\nowner" 2 6
    make-entry-filter xabbre "Flags\n regexp" {}
}

proc filterstyle-changed {n1 n2 op} {
    global filterstyle
    debug "filterstyle-changed $filterstyle"
    redraw-needed
}

proc filters-say-yes {code} {
    global filters filterstyle
    set codel [split $code _]
    set lockown [lindex $codel 3]
    switch -exact $filterstyle {
	0 { return 1 }
	1 { return [filter-default/lockown $lockown] }
	2 { return [regexp {^.0} $lockown] }
	3 { }
	default { error $filterstyle }
    }
    
    foreach fil $filters {
	if {![filter-says-yes/$fil $codel]} {
	    debug "FILTERS-SAY-YES $code NO $fil"
	    return 0
	}
    }
    debug "FILTERS-SAY-YES $code YES $filters"
    return 1
}
    
#---------- loading and parsing the clipboard (vessel locations) ----------

proc vessel {vin} {
    global pirate notes_used note_missings newnotes
    upvar 1 $vin vi

    set codel {}
    lappend codel [errexpect-arrayget-boolean vi inPort]

    set gameclass [errexpect-arrayget vi vesselClass]
    upvar #0 vc_game2code($gameclass) class
    if {![info exists class]} {
	set class "($gameclass)"
	upvar #0 vc_code2abbrev($class) vcabb
	set vcabb vc-$class
	set data [exec pbmtext -builtin fixed " $gameclass " \
		 | pnminvert | pnmcrop | pbmtoxbm]
	debug "INVENTED ICON $vcabb $data"
	image create bitmap icon/$vcabb -data $data
	    
	global vc_code2full
	set vc_code2full($class) "Type \"$gameclass\""
    }
    lappend codel $class

    set gamesubclass [errexpect-arrayget vi vesselSubclass]
    upvar #0 vsc_game2code($gamesubclass) subclass
    if {[info exists subclass]} {
	lappend codel $subclass
    } else {
	lappend codel ($gamesubclass)
    }

    switch -exact [errexpect-arrayget vi isLocked]/[ \
                   errexpect-arrayget vi isBattleReady] {
	true/false	{ set lock 2 }
	false/false	{ set lock 1 }
	false/true	{ set lock 0 }
	default		{ errexpect-error "unexpected isLocked/isBattleReady" }
    }

    set vid [errexpect-arrayget vi vesselId]
    upvar #0 notes($vid) note
    set realname [errexpect-arrayget vi vesselName]
    set island [errexpect-arrayget vi islandName]

    set owner {}
    set xabbrev {}
    if {[info exists note]} {
	manyset $note lno notename owner xabbrev
	if {[string compare -nocase $realname $notename]} {
	    note-info $lno $vid $realname $island \
		"notes say name is $notename"
	}
	if {[string length $owner]} {
	    if {![string compare $owner $pirate]} {
		set notown 0
	    } else {
		set notown 1
	    }
	} else {
	    set notown 2
	}
	append abbrev $xabbrev
	set notes_used($vid) 1

    } else {
	set notown 2
	lappend note_missings [list $island $realname $vid]
    }

    lappend codel "$lock$notown" $xabbrev
    lappend newnotes [list $vid $realname $owner $xabbrev]
    set kk "$island [join $codel _]"
    upvar #0 found($kk) k
    lappend k [list $vid $realname $owner]
 
    debug "CODED $kk $vid $realname"
}

set clipboard {}
proc parse-clipboard {} {
    global clipboard found notes notes_used newnotes

    catch { unset found }
    catch { unset notes_used }
    glset note_infos {}
    glset note_missings {}

    set newnotes {}
    
    set itemre { (\w+) = ([^=]*) }
    set manyitemre "^\\\[ $itemre ( (?: ,\\ $itemre)* ) \\]\$"
    debug $manyitemre

    set lno 0
    foreach l [split $clipboard "\n"] {
	incr lno
	errexpect-setline $lno $l
	if {![string length $l]} continue
	catch { unset vi }
	while 1 {
		if {![regexp -expanded $manyitemre $l dummy \
			thiskey thisval rhs]} {
		    errexpect-error "badly formatted"
		}
		set vi($thiskey) $thisval
		if {![string length $rhs]} break
		regsub {^, } $rhs {} rhs
		set l "\[$rhs\]"
	}
	vessel vi
    }

    if {[llength $newnotes]} {
	foreach vid [lsort [array names notes]] {
	    if {![info exists notes_used($vid)]} {
		manyset $notes($vid) lno notename
		note-info $lno $vid $notename {} \
		    "vessel in notes no longer found"
	    }
	}
    }
}

proc load-clipboard-file {fn} {
    set f [open $fn]
    glset clipboard [read $f]
    close $f
}


#---------- loading and parsing the chart ----------

proc load-chart {} {
    global chart scraper
    debug "FETCHING CHART"
    set chart [eval exec $scraper [list | perl -we {
	use strict;
	use CommodsScrape;
	use IO::File;
	use IO::Handle;
	yppedia_chart_parse(\*STDIN, (new IO::File ">/dev/null"),
		sub { sprintf "%d %d", @_; },
		sub { printf "archlabel %d %d %s\n", @_; },
		sub { printf "island %s {%s} %s\n", @_; },
		sub { printf "league %s %s %s.\n", @_; },
		sub { printf STDERR "warning: %s: incomprehensible: %s", @_; }
			);
	STDOUT->error and die $!;
    }]]
}


set scale 16

proc coord {c} {
	global scale
	return [expr {$c * $scale}]
}

proc chart-got/archlabel {args} { }
proc chart-got/island {x y isle sizecol} {
	debug "ISLE $x $y $isle $sizecol"
	global canvas isleloc
	set isleloc($isle) [list $x $y]
	set sz 5
#	$canvas create oval \
#		[expr {[coord $x] - $sz}] [expr {[coord $y] - $sz}] \
#		[expr {[coord $x] + $sz}] [expr {[coord $y] + $sz}] \
#		-fill blue
	set colour "#888"
	if {[string match *_col $sizecol]} { set colour black }
	$canvas create text [coord $x] [coord $y] \
		-text $isle -anchor s -fill $colour
}
proc chart-got/league {x1 y1 x2 y2 kind} {
#	debug "LEAGUE $x1 $y1 $x2 $y2 $kind"
	global canvas
	set l [$canvas create line \
		[coord $x1] [coord $y1] \
		[coord $x2] [coord $y2]]
	if {![string compare $kind .]} {
		$canvas itemconfigure $l -dash .
	}
}

proc debug-filter-array {array} {
    upvar #0 $array a
    set m " FILTER $array"
    foreach k [lsort [array names a]] {
	append m " $k=$a($k)"
    }
    debug $m
}

proc redraw-needed {args} {
    global redraw_after
    debug "REDRAW NEEDED $args"
    if {[info exists redraw_after]} return

    global filterstyle
    debug " FILTER style $filterstyle"
    debug-filter-array filter_size
    debug-filter-array filter_lockown
    global filter_xabbre
    debug " FILTER xabbre $filter_xabbre"

    set redraw_after [after 250 draw]
}

proc draw {} {
    global chart found isleloc canvas redraw_after islandnames smfound

    catch { after cancel $redraw_after }
    catch { unset redraw_after }
    
    $canvas delete all

    foreach l [split $chart "\n"] {
#	debug "CHART-GOT $l"
	set proc [lindex $l 0]
	eval chart-got/$proc [lrange $l 1 end]
    }

    smash-prepare

    catch { unset smfound }
    foreach key [lsort [array names found]] {
	regexp {^(.*) (\S+)$} $key dummy islandname code

	if {![filters-say-yes $code]} continue

	set smcode [smash-code $code]
	debug "smashed $code => $smcode"
	set smkey "$islandname $smcode"
	foreach vessel $found($key) { lappend smfound($smkey) $vessel }
    }

    set islandnames {}
    set lastislandname {}
    foreach smkey [lsort [array names smfound]] {
	set c [llength $smfound($smkey)]
	regexp {^(.*) (\S+)$} $smkey dummy islandname code
	debug "SHOWING [list $smkey $c $islandname $code l=$lastislandname]"

	if {[string compare $lastislandname $islandname]} {
		manyset $isleloc($islandname) x y
		set x [coord $x]
		set y [coord $y]
		set lastislandname $islandname
	        lappend islandnames $islandname
#		debug "START Y $y"
	}

	if {$c > 1} { set qty [format %d $c] } else { set qty {} }
	code2canvas $code $canvas $x y $qty 2 \
	    [list show-report $islandname $code]
#	debug "NEW Y $y"
    }

    panner::updatecanvas-bbox .cp.ctrl.pan

    islandnames-update
}


#---------- parser error reporting ----------

proc parser-control-create {w base invokebuttontext etl_title} {
    frame $w
    button $w.do -text $invokebuttontext -command invoke_$base -pady 3

    frame $w.resframe -width 120 -height 32
    button $w.resframe.res -text {} -anchor nw \
	-padx 1 -pady 1 -borderwidth 0 -justify left
    glset deffont_$base [$w.resframe.res cget -font]
    place $w.resframe.res -relx 0.5 -y 0 -anchor n

    pack $w.do -side top
    pack $w.resframe -side top -expand y -fill both

    set eb .err_$base
    toplevel $eb
    wm withdraw $eb
    wm title $eb "where-vessels - $etl_title"
    wm protocol $eb WM_DELETE_WINDOW [list wm withdraw $eb]

    label $eb.title -text $etl_title
    pack $eb.title -side top

    button $eb.close -text Close -command [list wm withdraw $eb]
    pack $eb.close -side bottom

    frame $eb.emsg -bd 2 -relief groove
    label $eb.emsg.lab -anchor nw -text "Error:"
    text $eb.emsg.text -height 1
    pack $eb.emsg.text -side bottom -fill x
    pack $eb.emsg.lab -side left

    pack $eb.emsg -side top -pady 2 -fill x

    frame $eb.text -bd 2 -relief groove
    pack $eb.text -side bottom -pady 2 -fill both -expand y
    
    label $eb.text.lab -anchor nw

    text $eb.text.text -width 85 \
	-xscrollcommand [list $eb.text.xscroll set] \
	-yscrollcommand [list $eb.text.yscroll set]
    $eb.text.text tag configure error \
	-background red -foreground white

    scrollbar $eb.text.xscroll -orient horizontal \
	-command [list $eb.text.text xview]
    scrollbar $eb.text.yscroll -orient vertical \
	-command [list $eb.text.text yview]

    grid configure $eb.text.lab -row 0 -column 0 -sticky w -columnspan 2
    grid configure $eb.text.text -row 1 -column 0 -sticky news
    grid configure $eb.text.yscroll -sticky ns -row 1 -column 1
    grid configure $eb.text.xscroll -sticky ew -row 2 -column 0
    grid rowconfigure $eb.text 0 -weight 0
    grid rowconfigure $eb.text 1 -weight 1
    grid rowconfigure $eb.text 2 -weight 0
    grid columnconfigure $eb.text 0 -weight 1
    grid columnconfigure $eb.text 1 -weight 0
}

proc parser-control-ok-core {w base background show} {
    debug "parser-control-ok-core $w $base $background $show"
    upvar #0 deffont_$base deffont
    $w.resframe.res configure \
	-background $background -disabledforeground black -font $deffont \
	-state disabled -command {} \
	-text $show
}    
proc parser-control-ok {w base show} {
    parser-control-ok-core $w $base green $show
}
proc parser-control-none {w base show} {
    parser-control-ok-core $w $base blue $show
}
proc parser-control-failed-core {w base foreground background smallfont
				 tiny summary fulldesc fulldata} {
    debug "parser-control-failed-core $w $base $summary $fulldesc"
    upvar #0 deffont_$base deffont
    set eb .err_$base

    $eb.emsg.text delete 0.0 end
    $eb.emsg.text insert end $summary

    $eb.text.lab configure -text $fulldesc
    $eb.text.text delete 0.0 end
    $eb.text.text insert end $fulldata

    regsub -all {.{18}} $tiny "&\n" ewrap

    if {$smallfont} {
	set font fixed
    } else {
	set font $deffont
    }

    $w.resframe.res configure \
	-background $background -foreground $foreground -font $font \
	-state normal -command [list wm deiconify $eb] \
	-text $ewrap
}
    
proc parser-control-failed-expected {w base emsg lno ei fulldesc newdata} {
    set eb .err_$base

    set line [lindex [split $ei "\n"] 0]
    debug "parser-control-failed-expected: $w $base: $lno: $emsg\n $line"

    parser-control-failed-core $w $base \
	white red 1 \
	"err: [string trim $emsg]: \"$line\"" \
	"at line $lno: $emsg" \
	$fulldesc $newdata

    $eb.text.text tag add error $lno.0 $lno.end
    $eb.text.text see $lno.0	
}
proc parser-control-failed-unexpected {w base emsg ei} {
    global errorInfo
    parser-control-failed-core $w $base \
	black yellow 1 \
	$emsg $emsg "Details and stack trace:" $ei
}

proc reparse {base varname old fulldesc okshow noneshow parse ok} {
    upvar #0 $varname var
    manyset [errexpect-catch {
	uplevel 1 $parse
	if {[string length [string trim $var]]} {
	    parser-control-ok .cp.ctrl.$base $base $okshow
	} else {
	    parser-control-none .cp.ctrl.$base $base $noneshow
	}
    }] failed emsg lno ei
    if {$failed} {
	parser-control-failed-expected .cp.ctrl.$base $base \
	    $emsg $lno $ei $fulldesc $var
	set var $old
	uplevel 1 $parse
    } else {
	uplevel 1 $ok
    }
}

#---------- island names selection etc. ----------

proc islandnames-update {} {
    global islandnames
    .islands.count configure -text [format "ships at %d island(s)" \
					[llength $islandnames]]
}

proc islandnames-select {} {
    .islands.clip configure -relief sunken -state disabled
    selection own -command islandnames-deselect .islands.clip
}
proc islandnames-deselect {} {
    .islands.clip configure -relief raised -state normal
}

proc islandnames-handler {offset maxchars} {
    global islandnames
    return [string range [join $islandnames ", "] \
		$offset [expr {$offset+$maxchars-1}]]
}

#---------- main user interface ----------

proc widgets-setup {} {
    global canvas debug pirate ocean filterstyle

    wm geometry . 1200x800
    wm title . "where-vessels - $pirate on the $ocean ocean"

    #----- map -----

    frame .f -border 1 -relief groove
    set canvas .f.c
    canvas $canvas
    pack $canvas -expand 1 -fill both
    pack .f -expand 1 -fill both -side left

    #----- control panels and filter -----

    frame .cp
    frame .smash -relief groove -bd 2 -padx 1
    frame .filter -relief groove -bd 2 -padx 1
    frame .islands -pady 2
    pack .cp .filter .islands .smash -side top

    label .smash.title -text {Display/combine details}
    grid .smash.title -row 0 -column 0 -columnspan 2

    set filterstyle 1
    trace add variable filterstyle write filterstyle-changed

    frame .filter.title
    label .filter.title.title -text Show
    pack .filter.title.title -side left
    for {set fing 0} {$fing < 4} {incr fing} {
	radiobutton .filter.title.f$fing \
	    -variable filterstyle -value $fing \
	    -text [lindex {All Useable Mine These:} $fing]
	pack .filter.title.f$fing -side left
    }

    grid configure .filter.title -row 0 -column 0 -columnspan 2

    #----- control panel -----

    frame .cp.ctrl
    pack .cp.ctrl -side left -anchor n

    debug "BBOX [$canvas bbox all]"

    panner::canvas-scroll-bbox .f.c
    panner::create .cp.ctrl.pan .f.c 120 120 $debug

    pack .cp.ctrl.pan -side top -pady 0 -padx 5
    frame .cp.ctrl.zoom
    pack .cp.ctrl.zoom -side top

    button .cp.ctrl.zoom.out -text - -font {Courier 16} -command {zoom /2} -pady 0
    button .cp.ctrl.zoom.in  -text + -font {Courier 16} -command {zoom *2} -pady 0
    pack .cp.ctrl.zoom.out .cp.ctrl.zoom.in -side left

    parser-control-create .cp.ctrl.acquire \
	acquire Acquire \
	"Clipboard parsing error" \
	
    pack .cp.ctrl.acquire -side top -pady 2

    parser-control-create .cp.ctrl.notes \
	notes "Reload notes" \
	"Vessel notes loading report" \
	
    pack .cp.ctrl.notes -side top -pady 2

    #----- island name count and copy -----

    label .islands.count
    button .islands.clip -text "copy island names" -pady 2 -padx 2 \
	 -command islandnames-select
    selection handle .islands.clip islandnames-handler
    pack .islands.count .islands.clip -side left

    #----- decoding etc. report -----

    frame .cp.report
    pack .cp.report -side left -anchor n

    label .cp.report.island -text { }

    canvas .cp.report.abbrev -width 1 -height 15

    frame .cp.report.code
    label .cp.report.code.lab -text Code:
    glset report_code { }
    entry .cp.report.code.code -state readonly \
	-textvariable report_code -width 15
    pack .cp.report.code.lab .cp.report.code.code -side left
    frame .cp.report.details -bd 2 -relief groove -padx 2 -pady 2

    listbox .cp.report.list -height 5

    pack .cp.report.island .cp.report.abbrev .cp.report.details \
	.cp.report.list -side top
    #pack .cp.report.code -side top
    pack configure .cp.report.details -fill x

    foreach sw {inport class subclass lock own xabbrev} {
	label .cp.report.details.$sw -text { }
	pack .cp.report.details.$sw -side top -anchor w
    }
}

proc report-set {sw val} { .cp.report.details.$sw configure -text $val }

proc show-report {islandname code} {
    .cp.report.island configure -text $islandname

    .cp.report.abbrev delete all
    set y 2
    code2canvas $code .cp.report.abbrev 5 y {} 0 {}
    manyset [.cp.report.abbrev bbox all] minx dummy maxx dummy
    .cp.report.abbrev configure -width [expr {$maxx-$minx+4}]

    glset report_code $code
    show-report-decode $code

    set kk "$islandname $code"
    upvar #0 smfound($kk) k

    .cp.report.list delete 0 end

    foreach entry $k {
	manyset $entry vid name owner
	lappend owned($owner) $name
    }

    foreach owner [lsort [array names owned]] {
	if {[string length $owner]} {
	    set owndesc "$owner's"
	} else {
	    set owndesc "Owner unknown"
	}
	.cp.report.list insert end "$owndesc:"
	foreach name $owned($owner) {
	    .cp.report.list insert end " $name"
	}
    }
}

proc zoom {extail} {
    global scale canvas
    set nscale [expr "\$scale $extail"]
    debug "ZOOM $scale $nscale"
    if {$nscale < 1 || $nscale > 200} return
    set scale $nscale
    draw
}

proc invoke_acquire {} {
    global clipboard errorInfo
    set old $clipboard

    if {[catch {
	set clipboard [clipboard get]
    } emsg]} {
	parser-control-failed-unexpected .cp.ctrl.acquire acquire \
	    $emsg "fetching clipboard:\n\n$errorInfo"
	return
    }

    reparse acquire \
	clipboard $old "Clipboard contents:" { acquired ok } { no vessels } {
	    parse-clipboard
	} {
	    display-note-infos
	}
    draw
}

proc invoke_notes {} {
    global notes_data errorInfo notes_loc
    set old $notes_data
    
    if {[catch {
	load-notes
    } emsg]} {
	parser-control-failed-unexpected .cp.ctrl.notes notes \
	    $emsg "loading $notes_loc:\n\n$errorInfo"
	return
    }

    reparse notes \
	notes_data $old "Vessel notes:" "loaded ok" { no notes } {
	    parse-notes
	    parse-clipboard
	} {
	    display-note-infos
	}
    draw
}

#---------- main program ----------

parseargs
argdefaults
httpclientsetup where-vessels
info-cache-update
vesselclasses-init
load-chart
widgets-setup
make-filters
make-smashers

set notes_data {}
if {[catch { parse-clipboard } emsg]} {
    puts stderr "$emsg\n$errorInfo"
    exit 1
}
after idle invoke_notes

draw

if {$debug} {
    package require Tclx
    commandloop -async \
	-prompt1 { return "where-vessels% " } \
	-prompt2 { return "> " }
}

# rsync -r --exclude=\*~ yarrg/icons/. ijackson@chiark.greenend.org.uk:/home/ftp/users/ijackson/yarrg/vessel-info/.