chiark / gitweb /
where-vessels: filtering filters
[ypp-sc-tools.web-live.git] / yarrg / where-vessels
1 #!/usr/bin/wish
2 # show your vessels on a map
3
4 # This is part of ypp-sc-tools, a set of third-party tools for assisting
5 # players of Yohoho Puzzle Pirates.
6 #
7 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
8 #
9 # This program is free software: you can redistribute it and/or modify
10 # it under the terms of the GNU General Public License as published by
11 # the Free Software Foundation, either version 3 of the License, or
12 # (at your option) any later version.
13 #
14 # This program is distributed in the hope that it will be useful,
15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17 # GNU General Public License for more details.
18 #
19 # You should have received a copy of the GNU General Public License
20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
21 #
22 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
23 # are used without permission.  This program is not endorsed or
24 # sponsored by Three Rings.
25
26
27
28 source yarrglib.tcl
29 source panner.tcl
30 package require http
31
32 #---------- general utilities ----------
33
34 set debug 0
35 proc debug {m} {
36     global debug
37     if {$debug} { puts "DEBUG $m" }
38 }
39
40 proc badusage {m} {
41     puts stderr "where-vessels: bad usage: $m"
42     exit 1
43 }
44
45 proc glset {n val} {
46     upvar #0 $n var
47     set var $val
48 }
49
50 #---------- expecting certain errors ----------
51
52 proc errexpect-setline {lno line} {
53     glset errexpect_lno $lno
54     glset errexpect_line $line
55 }
56
57 proc errexpect-error {m} {
58     global errexpect_line errexpect_lno
59     error $m "$errexpect_line\n" [list YARRG-ERREXPECT $errexpect_lno]
60 }
61
62 proc errexpect-arrayget {arrayvar key} {
63     upvar 1 $arrayvar av
64     upvar 1 ${arrayvar}($key) v
65     if {[info exists v]} { return $v }
66     errexpect-error "undefined $key"
67 }
68
69 proc errexpect-arrayget-boolean {arrayvar key} {
70     switch -exact [uplevel 1 [list errexpect-arrayget $arrayvar $key]] {
71         true    { return 1 }
72         false   { return 0 }
73         default { errexpect-error "unexpected $key" }
74     }
75 }
76
77 proc errexpect-catch {code} {
78     global errorInfo errorCode
79     set rc [catch {
80         uplevel 1 $code
81     } rv]
82     debug "ERREXPECT CATCH |$rc|$rv|$errorCode|$errorInfo|"
83     if {$rc==1 && ![string compare YARRG-ERREXPECT [lindex $errorCode 0]]} {
84         return [list 1 $rv [lindex $errorCode 1] $errorInfo]
85     } elseif {$rc==0} {
86         return [list 0 $rv]
87     } else {
88         return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rv
89     }
90 }
91
92 #---------- argument parsing ----------
93
94 proc nextarg {} {
95     global ai argv
96     if {$ai >= [llength $argv]} {
97         badusage "option [lindex $argv [expr {$ai-1}]] needs a value"
98     }
99     set v [lindex $argv $ai]
100     incr ai
101     return $v
102 }
103
104 set notes_loc vessel-notes
105 set scraper {./yppedia-ocean-scraper --chart}
106
107 proc parseargs {} {
108     global ai argv
109     global debug scraper
110     set ai 0
111
112     while {[regexp {^\-} [set arg [lindex $argv $ai]]]} {
113         incr ai
114         switch -exact -- $arg {
115             -- { break }
116             --pirate { glset pirate [string totitle [nextarg]] }
117             --ocean { glset ocean [string totitle [nextarg]] }
118             --clipboard-file { load-clipboard-file [nextarg] }
119             --local-html-dir { lappend scraper --local-html-dir=[nextarg] }
120             --notes { glset notes_loc [nextarg] }
121             --debug { incr debug }
122             default { badusage "unknown option $arg" }
123         }
124     }
125     set argv [lrange $argv $ai end]
126     if {[llength $argv]} { badusage "non-option args not allowed" }
127 }
128
129 proc argdefaults {} {
130     global ocean notes_loc pirate scraper
131     if {![info exists ocean] || ![info exists pirate]} {
132         set cmd {./yarrg --find-window-only --quiet}
133         if {[info exists ocean]} { lappend cmd --ocean $ocean }
134         if {[info exists pirate]} { lappend cmd --pirate $pirate }
135         manyset [split [eval exec $cmd] " "] ocean pirate
136     }
137     lappend scraper $ocean
138 }
139
140
141 #---------- loading and parsing the vessel notes ----------
142
143 proc load-notes {} {
144     global notes_loc notes_data
145     if {[regexp {^\w+\:} $notes_loc]} {
146         update
147         debug "FETCHING NOTES $notes_loc"
148         set req [::http::geturl $notes_loc]
149         switch -glob [::http::status $req].[::http::ncode $req] {
150             ok.200 { }
151             ok.* { error "retrieving vessel-notes: [::http::code $req]" }
152             * { error "Retrieving vessel-notes: [::http::error $req]" }
153         }
154         set newdata [::http::data $req]
155         ::http::cleanup $req
156     } else {
157         debug "READING NOTES $notes_loc"
158         set vn [open $notes_loc]
159         set newdata [read $vn]
160         close $vn
161     }
162     set notes_data $newdata
163 }
164
165 proc parse-notes {} {
166     global notes_data notes
167     catch { unset notes }
168
169     set lno 0
170     foreach l [split $notes_data "\n"] {
171         incr lno
172         errexpect-setline $lno $l
173         set l [string trim $l]
174         if {![string length $l]} continue
175         if {[regexp {^\#} $l]} continue
176         if {![regexp -expanded \
177                   {^ (\d+) (?: \s+([^=]*?) )? \s* =
178                       (?: \s* (\S+)
179                        (?: \s+ (\S+) )?)? $} \
180                   $l dummy vid vname owner note]} {
181               errexpect-error "badly formatted"
182         }
183         set vname [string trim $vname]
184         if {[info exists notes($vid)]} {
185             errexpect-error "duplicate vesselid $vid"
186         }
187         set notes($vid) [list $lno $vname $owner $note]
188     }
189 }
190
191 proc note-info {lno vid name island description} {
192     global note_infos
193     lappend note_infos [list $lno $vid $name $island $description]
194 }
195
196 proc display-note-infos {} {
197     global note_infos note_missings notes
198
199     set nmissing [llength $note_missings]
200     debug "display-note-infos $nmissing [array size notes]"
201
202     if {[llength $note_infos]} {
203         set tiny "[llength $note_infos] warnings"
204     } elseif {$nmissing && [array size notes]} {
205         set tiny "$nmissing missing"
206     } else {
207         return
208     }
209
210     set infodata {}
211
212     foreach info $note_infos {
213         manyset $info lno vid name island description
214         append infodata "vessel"
215         append infodata " $vid"
216         if {[string length $name]} { append infodata " $name" }
217         if {[string length $island]} { append infodata " ($island)" }
218         append infodata ": " $description "\n"
219     }
220
221     if {$nmissing} {
222         if {[string length $infodata]} { append infodata "\n" }
223         append infodata "$nmissing vessel(s) not mentioned in notes:\n"
224         set last_island {}
225         foreach info [lsort $note_missings] {
226             manyset $info island name vid
227             if {[string compare $island $last_island]} {
228                 append infodata "# $island:\n"
229                 set last_island $island
230             }
231             append infodata [format "%-9d %-29s =\n" $vid $name]
232         }
233     }
234
235     parser-control-failed-core .ctrl.notes notes \
236         white blue 0 \
237         $tiny \
238         "[llength $note_infos] warning(s);\
239          $nmissing vessel(s) missing" \
240         "Full description of warnings and missing vessels:" \
241         $infodata
242 }
243
244 #---------- vessel properties ----------
245
246 proc vesselclasses-init {} {
247     global vc_game2code vc_code2abbrev vc_code2full vc_codes
248     set vcl {
249         smsloop         am      sl      Sloop
250         lgsloop         bm      ct      Cutter
251         dhow            cm      dh      Dhow
252         longship        dm      ls      Longship
253         baghlah         em      bg      Baghlah
254         merchbrig       fm      mb      {Merchant Brig}
255         warbrig         gm      wb      {War Brig}
256         xebec           hm      xe      Xebec
257         warfrig         im      wf      {War Frigate}
258         merchgal        jm      mg      {Merchant Galleon}
259         grandfrig       km      gf      {Grand Frigate}
260     }
261     set vc_codes {}
262     foreach {game code abbrev full} $vcl {
263         lappend vc_codes $code
264         set vc_game2code($game) $code
265         set vc_code2abbrev($code) $abbrev
266         set vc_code2full($code) $full
267     }
268 }
269
270 proc code2abbrev-lock {lockown} {
271     manyset [split $lockown ""] lock notown
272     append abbrev [lindex {* + -} $lock]
273     append abbrev [lindex {= - ?} [regsub {\D} $notown 2]]
274 }    
275
276 proc code2abbrev {code} {
277     global vc_code2abbrev
278
279     manyset [split $code _] inport class subclass lockown xabbrev
280
281     set abbrev {}
282     append abbrev [lindex {? {}} $inport]
283     append abbrev $vc_code2abbrev($class)
284     append abbrev $subclass
285     append abbrev [code2abbrev-lock $lockown]
286     append abbrev $xabbrev
287
288     debug "CODE2ABBREV $code $abbrev"
289     return $abbrev
290 }
291
292 proc show-report-decode {code} {
293     global vc_code2full
294
295     manyset [split $code _] inport classcode subclass lockown xabbrev
296     manyset [split $lockown ""] lock notown
297     
298     report-set inport [lindex {{At Sea} {In port}} $inport]
299     report-set class $vc_code2full($classcode)
300
301     switch -exact $subclass {
302         {} { report-set subclass {Ordinary} }
303         F { report-set subclass {"Frost class"} }
304         default { report-set subclass "Subclass \"$subclass\"" }
305     }
306
307     report-set lock [lindex {
308         {Battle ready} {Unlocked} {Locked}
309     } $lock]
310
311     switch -exact $notown {
312         0 { report-set own "Yours" }
313         1 { report-set own "Other pirate's" }
314         U { report-set own "Owner not known" }
315         M { report-set own "Missing from notes" }
316         default { report-set own "?? $notown" }
317     }
318
319     if {[string length $xabbrev]} {
320         report-set xabbrev "Notes flags: $xabbrev"
321     } else {
322         report-set xabbrev "No flags in notes"
323     }
324 }
325
326 #---------- filtering ----------
327
328 set filters {}
329
330 proc filter-values/size {} { global vc_codes; return $vc_codes }
331 proc filter-map/size {code} { upvar #0 vc_code2abbrev($code) abb; return $abb }
332 proc filter-default/size {code} { return 1 }
333 proc filter-says-yes/size {codel} {
334     set sizecode [lindex $codel 1]
335     upvar #0 filter_size($sizecode) yes
336     return $yes
337 }
338
339 proc filter-values/lockown {} {
340     foreach lv {0 1 2} {
341         foreach ov {0 1 X} {
342             lappend vals "$lv$ov"
343         }
344     }
345     return $vals
346 }
347 proc filter-map/lockown {lockown} { return [code2abbrev-lock $lockown] }
348 proc filter-default/lockown {lockown} {
349     return [regexp {^[01]|^2[^1]} $lockown]
350 }
351 proc filter-says-yes/lockown {codel} {
352     set lockown [lindex $codel 3]
353     regsub -all {\D} $lockown X lockown
354     upvar #0 filter_lockown($lockown) yes
355     return $yes
356 }
357
358 proc filter-validate/xabbre {re} {
359     if {[catch {
360         regexp -- $re {}
361     } emsg]} {
362         regsub {^.*:\s*} $emsg {} emsg
363         regsub {^.*(.{30})$} $emsg {\1} emsg
364         return $emsg
365     }
366     return {}
367 }
368 proc filter-says-yes/xabbre {codel} {
369     global filter_xabbre
370     set xabbrev [lindex $codel 4]
371     return [regexp -- $filter_xabbre $xabbrev]
372 }
373
374 proc filter-tickbox-flip {fil} {
375     upvar #0 filter_$fil vars
376     set values [filter-values/$fil]
377     foreach val $values {
378         set vars($val) [expr {!$vars($val)}]
379     }
380     redraw-needed
381 }
382
383 proc make-tickbox-filter {fil label rows inrow} {
384     upvar #0 filter_$fil vars
385     set fw [make-filter tickbox $fil $label frame]
386     set values [filter-values/$fil]
387     set nvalues [llength $values]
388     if {!$inrow} {
389         set inrow [expr {($nvalues + $rows) / $rows}]
390     }
391
392     for {set ix 0} {$ix < $nvalues} {incr ix} {
393         set val [lindex $values $ix]
394         set vars($val) [filter-default/$fil $val]
395         checkbutton $fw.$ix -variable filter_${fil}($val) \
396             -text [filter-map/$fil $val] -font fixed \
397             -command redraw-needed
398         grid configure $fw.$ix -sticky sw \
399             -row [expr {$ix / $inrow}] \
400             -column [expr {$ix % $inrow}]
401     }
402     button $fw.invert -text flip -command [list filter-tickbox-flip $fil] \
403         -padx 0 -pady 0
404     grid configure $fw.invert -sticky se \
405         -row [expr {$rows-1}] \
406         -column [expr {$inrow-1}]
407 }
408
409 proc entry-filter-changed {fw fil n1 n2 op} {
410     global errorInfo
411     upvar #0 filter_$fil realvar
412     upvar #0 filterentered_$fil entryvar
413     global def_background
414     debug "entry-filter-changed $fw $fil $entryvar"
415     if {[catch {
416         set error [filter-validate/$fil $entryvar]
417         if {[string length $error]} {
418             $fw.error configure -text $error -foreground white -background red
419         } else {
420             $fw.error configure -text { } -background $def_background
421             set realvar $entryvar
422             redraw-needed
423         }
424     } emsg]} {
425         puts stderr "FILTER CHECK ERROR $emsg $errorInfo"
426     }
427 }
428
429 proc make-entry-filter {fil label def} {
430     global filterentered_$fil
431     upvar #0 filter_$fil realvar
432     set realvar $def
433     set fw [make-filter entry $fil $label frame]
434     entry $fw.entry -textvariable filterentered_$fil
435     label $fw.error
436     glset def_background [$fw.error cget -background]
437     trace add variable filterentered_$fil write \
438         [list entry-filter-changed $fw $fil]
439     pack $fw.entry $fw.error -side top -anchor w
440 }
441
442 proc make-filter {kind fil label ekind} {
443     global filters
444     label .filter.lab_$fil -text $label -justify left
445     $ekind .filter.$fil
446     lappend filters $fil
447     set nfilters [llength $filters]
448     grid configure .filter.lab_$fil -row $nfilters -column 0 -sticky nw -pady 4
449     grid configure .filter.$fil -row $nfilters -column 1 -sticky w -pady 3
450     return .filter.$fil
451 }
452
453 proc make-filters {} {
454     make-tickbox-filter size Size 2 0
455     make-tickbox-filter lockown "Lock/\nowner" 2 6
456     make-entry-filter xabbre "Flags\n regexp" {}
457 }
458
459 proc filters-say-yes {code} {
460     global filters
461     debug "filters-say-yes $code"
462     foreach fil $filters {
463         if {![filter-says-yes/$fil [split $code _]]} { return 0 }
464     }
465     return 1
466 }
467     
468 #---------- loading and parsing the clipboard (vessel locations) ----------
469
470 proc vessel {vin} {
471     global pirate notes_used note_missings newnotes
472     upvar 1 $vin vi
473
474     set codel {}
475     lappend codel [errexpect-arrayget-boolean vi inPort]
476
477     set gameclass [errexpect-arrayget vi vesselClass]
478     upvar #0 vc_game2code($gameclass) class
479     if {![info exists class]} { errexpect-error "unexpected vesselClass"}
480     lappend codel $class
481
482     set subclass [errexpect-arrayget vi vesselSubclass]
483     switch -exact $subclass {
484         null            { lappend codel {} }
485         icy             { lappend codel F }
486         default         { lappend codel ($subclass) }
487     }
488
489     switch -exact [errexpect-arrayget vi isLocked]/[ \
490                    errexpect-arrayget vi isBattleReady] {
491         true/false      { set lock 2 }
492         false/false     { set lock 1 }
493         false/true      { set lock 0 }
494         default         { errexpect-error "unexpected isLocked/isBattleReady" }
495     }
496
497     set vid [errexpect-arrayget vi vesselId]
498     upvar #0 notes($vid) note
499     set realname [errexpect-arrayget vi vesselName]
500     set island [errexpect-arrayget vi islandName]
501
502     set owner {}
503     set xabbrev {}
504     if {[info exists note]} {
505         manyset $note lno notename owner xabbrev
506         if {[string compare -nocase $realname $notename]} {
507             note-info $lno $vid $realname $island \
508                 "notes say name is $notename"
509         }
510         if {[string length $owner]} {
511             if {![string compare $owner $pirate]} {
512                 set notown 0
513             } else {
514                 set notown 1
515             }
516         } else {
517             set notown U
518         }
519         append abbrev $xabbrev
520         set notes_used($vid) 1
521
522     } else {
523         set notown M
524         lappend note_missings [list $island $realname $vid]
525     }
526
527     lappend codel "$lock$notown" $xabbrev
528     lappend newnotes [list $vid $realname $owner $xabbrev]
529     set kk "$island [join $codel _]"
530     upvar #0 found($kk) k
531     lappend k [list $vid $realname]
532  
533     debug "CODED $kk $vid $realname"
534 }
535
536 set clipboard {}
537 proc parse-clipboard {} {
538     global clipboard found notes notes_used newnotes
539
540     catch { unset found }
541     catch { unset notes_used }
542     glset note_infos {}
543     glset note_missings {}
544
545     set newnotes {}
546     
547     set itemre { (\w+) = ([^=]*) }
548     set manyitemre "^\\\[ $itemre ( (?: ,\\ $itemre)* ) \\]\$"
549     debug $manyitemre
550
551     set lno 0
552     foreach l [split $clipboard "\n"] {
553         incr lno
554         errexpect-setline $lno $l
555         if {![string length $l]} continue
556         catch { unset vi }
557         while 1 {
558                 if {![regexp -expanded $manyitemre $l dummy \
559                         thiskey thisval rhs]} {
560                     errexpect-error "badly formatted"
561                 }
562                 set vi($thiskey) $thisval
563                 if {![string length $rhs]} break
564                 regsub {^, } $rhs {} rhs
565                 set l "\[$rhs\]"
566         }
567         vessel vi
568     }
569
570     if {[llength $newnotes]} {
571         foreach vid [lsort [array names notes]] {
572             if {![info exists notes_used($vid)]} {
573                 manyset $notes($vid) lno notename
574                 note-info $lno $vid $notename {} \
575                     "vessel in notes no longer found"
576             }
577         }
578     }
579 }
580
581 proc load-clipboard-file {fn} {
582     set f [open $fn]
583     glset clipboard [read $f]
584     close $f
585 }
586
587
588 #---------- loading and parsing the chart ----------
589
590 proc load-chart {} {
591     global chart scraper
592     debug "FETCHING CHART"
593     set chart [eval exec $scraper [list | perl -we {
594         use strict;
595         use CommodsScrape;
596         use IO::File;
597         use IO::Handle;
598         yppedia_chart_parse(\*STDIN, (new IO::File ">/dev/null"),
599                 sub { sprintf "%d %d", @_; },
600                 sub { printf "archlabel %d %d %s\n", @_; },
601                 sub { printf "island %s %s\n", @_; },
602                 sub { printf "league %s %s %s.\n", @_; },
603                 sub { printf STDERR "warning: %s: incomprehensible: %s", @_; }
604                         );
605         STDOUT->error and die $!;
606     }]]
607 }
608
609
610 set scale 16
611
612 proc coord {c} {
613         global scale
614         return [expr {$c * $scale}]
615 }
616
617 proc chart-got/archlabel {args} { }
618 proc chart-got/island {x y args} {
619 #       debug "ISLE $x $y $args"
620         global canvas isleloc
621         set isleloc($args) [list $x $y]
622         set sz 5
623 #       $canvas create oval \
624 #               [expr {[coord $x] - $sz}] [expr {[coord $y] - $sz}] \
625 #               [expr {[coord $x] + $sz}] [expr {[coord $y] + $sz}] \
626 #               -fill blue
627         $canvas create text [coord $x] [coord $y] \
628                 -text $args -anchor s
629 }
630 proc chart-got/league {x1 y1 x2 y2 kind} {
631 #       debug "LEAGUE $x1 $y1 $x2 $y2 $kind"
632         global canvas
633         set l [$canvas create line \
634                 [coord $x1] [coord $y1] \
635                 [coord $x2] [coord $y2]]
636         if {![string compare $kind .]} {
637                 $canvas itemconfigure $l -dash .
638         }
639 }
640
641 proc redraw-needed {} {
642     global redraw_after
643     debug "REDRAW NEEDED"
644     if {[info exists redraw_after]} return
645     set redraw_after [after 250 draw]
646 }
647
648 proc draw {} {
649     global chart found isleloc canvas redraw_after
650
651     catch { after cancel $redraw_after }
652     catch { unset redraw_after }
653     
654     $canvas delete all
655
656     foreach l [split $chart "\n"] {
657 #       debug "CHART-GOT $l"
658         set proc [lindex $l 0]
659         eval chart-got/$proc [lrange $l 1 end]
660     }
661
662     set lastislandname {}
663     foreach key [lsort [array names found]] {
664         set c [llength $found($key)]
665 #       debug "SHOWING $key $c"
666         regexp {^(.*) (\S+)$} $key dummy islandname code
667
668         if {![filters-say-yes $code]} continue
669
670         set abbrev [code2abbrev $code]
671         
672         if {[string compare $lastislandname $islandname]} {
673                 manyset $isleloc($islandname) x y
674                 set x [coord $x]
675                 set y [coord $y]
676                 set lastislandname $islandname
677 #               debug "START Y $y"
678         }
679         set text $abbrev
680         regsub -all {[0-9]} $text {} text
681         if {$c > 1} {
682                 set text [format "%2d%s" $c $text]
683         } else {
684                 set text [format "  %s" $text]
685         }
686         set id [$canvas create text $x $y \
687                 -anchor nw -font fixed \
688                 -text $text]
689         set bbox [$canvas bbox $id]
690         set bid [eval $canvas create rectangle $bbox -fill white]
691         $canvas lower $bid $id
692         $canvas bind $id <ButtonPress> [list show-report $islandname $code]
693         $canvas bind $bid <ButtonPress> [list show-report $islandname $code]
694         manyset $bbox dummy dummy dummy y
695 #       debug "NEW Y $y"
696     }
697
698     panner::updatecanvas-bbox .ctrl.pan
699 }
700
701
702 #---------- parser error reporting ----------
703
704 proc parser-control-create {w base invokebuttontext etl_title} {
705     frame $w
706     button $w.do -text $invokebuttontext -command invoke_$base
707
708     frame $w.resframe -width 120 -height 32
709     button $w.resframe.res -text {} -anchor nw \
710         -padx 1 -pady 1 -borderwidth 0 -justify left
711     glset deffont_$base [$w.resframe.res cget -font]
712     place $w.resframe.res -relx 0.5 -y 0 -anchor n
713
714     pack $w.do -side top
715     pack $w.resframe -side top -expand y -fill both
716
717     set eb .err_$base
718     toplevel $eb
719     wm withdraw $eb
720     wm title $eb "where-vessels - $etl_title"
721
722     label $eb.title -text $etl_title
723     pack $eb.title -side top
724
725     button $eb.close -text Close -command [list wm withdraw $eb]
726     pack $eb.close -side bottom
727
728     frame $eb.emsg -bd 2 -relief groove
729     label $eb.emsg.lab -text "Error:"
730     text $eb.emsg.text -height 1
731     pack $eb.emsg.text -side bottom
732     pack $eb.emsg.lab -side left
733
734     pack $eb.emsg -side top -pady 2
735
736     frame $eb.text -bd 2 -relief groove
737     pack $eb.text -side bottom -pady 2
738     
739     label $eb.text.lab
740
741     text $eb.text.text -width 85 \
742         -xscrollcommand [list $eb.text.xscroll set] \
743         -yscrollcommand [list $eb.text.yscroll set]
744     $eb.text.text tag configure error \
745         -background red -foreground white
746
747     scrollbar $eb.text.xscroll -orient horizontal \
748         -command [list $eb.text.text xview]
749     scrollbar $eb.text.yscroll -orient vertical \
750         -command [list $eb.text.text yview]
751
752     grid configure $eb.text.lab -row 0 -column 0 -sticky w
753     grid configure $eb.text.text -row 1 -column 0
754     grid configure $eb.text.yscroll -sticky ns -row 1 -column 1
755     grid configure $eb.text.xscroll -sticky ew -row 2 -column 0
756 }
757
758 proc parser-control-ok-core {w base background show} {
759     debug "parser-control-ok-core $w $base $background $show"
760     upvar #0 deffont_$base deffont
761     $w.resframe.res configure \
762         -background $background -disabledforeground black -font $deffont \
763         -state disabled -command {} \
764         -text $show
765 }    
766 proc parser-control-ok {w base show} {
767     parser-control-ok-core $w $base green $show
768 }
769 proc parser-control-none {w base show} {
770     parser-control-ok-core $w $base blue $show
771 }
772 proc parser-control-failed-core {w base foreground background smallfont
773                                  tiny summary fulldesc fulldata} {
774     debug "parser-control-failed-core $w $base $summary $fulldesc"
775     upvar #0 deffont_$base deffont
776     set eb .err_$base
777
778     $eb.emsg.text delete 0.0 end
779     $eb.emsg.text insert end $summary
780
781     $eb.text.lab configure -text $fulldesc
782     $eb.text.text delete 0.0 end
783     $eb.text.text insert end $fulldata
784
785     regsub -all {.{18}} $tiny "&\n" ewrap
786
787     if {$smallfont} {
788         set font fixed
789     } else {
790         set font $deffont
791     }
792
793     $w.resframe.res configure \
794         -background $background -foreground $foreground -font $font \
795         -state normal -command [list wm deiconify $eb] \
796         -text $ewrap
797 }
798     
799 proc parser-control-failed-expected {w base emsg lno ei fulldesc newdata} {
800     set eb .err_$base
801
802     set line [lindex [split $ei "\n"] 0]
803     debug "parser-control-failed-expected: $w $base: $lno: $emsg\n $line"
804
805     parser-control-failed-core $w $base \
806         white red 1 \
807         "err: [string trim $emsg]: \"$line\"" \
808         "at line $lno: $emsg" \
809         $fulldesc $newdata
810
811     $eb.text.text tag add error $lno.0 $lno.end
812     $eb.text.text see $lno.0    
813 }
814 proc parser-control-failed-unexpected {w base emsg ei} {
815     global errorInfo
816     parser-control-failed-core $w $base \
817         black yellow 1 \
818         $emsg $emsg "Details and stack trace:" $ei
819 }
820
821 proc reparse {base varname old fulldesc okshow noneshow parse ok} {
822     upvar #0 $varname var
823     manyset [errexpect-catch {
824         uplevel 1 $parse
825         if {[string length [string trim $var]]} {
826             parser-control-ok .ctrl.$base $base $okshow
827         } else {
828             parser-control-none .ctrl.$base $base $noneshow
829         }
830     }] failed emsg lno ei
831     if {$failed} {
832         parser-control-failed-expected .ctrl.$base $base \
833             $emsg $lno $ei $fulldesc $var
834         set var $old
835         uplevel 1 $parse
836     } else {
837         uplevel 1 $ok
838     }
839 }
840
841 #---------- main user interface ----------
842
843 proc widgets-setup {} {
844     global canvas debug pirate ocean
845
846     wm geometry . 1024x480
847     wm title . "where-vessels - $pirate on the $ocean ocean"
848
849     #----- map -----
850
851     frame .f -border 1 -relief groove
852     set canvas .f.c
853     canvas $canvas
854     pack $canvas -expand 1 -fill both
855     pack .f -expand 1 -fill both -side left
856
857     #----- filter -----
858
859     frame .filter -relief groove -bd 2
860     pack .filter -side bottom
861
862     label .filter.title -text Filter
863     grid configure .filter.title -row 0 -column 0 -columnspan 2
864
865     #----- control panel -----
866
867     frame .ctrl
868     pack .ctrl -side left -anchor n
869
870     debug "BBOX [$canvas bbox all]"
871
872     panner::canvas-scroll-bbox .f.c
873     panner::create .ctrl.pan .f.c 120 120 $debug
874
875     pack .ctrl.pan -side top -pady 10 -padx 5
876     frame .ctrl.zoom
877     pack .ctrl.zoom -side top
878
879     button .ctrl.zoom.out -text - -font {Courier 16} -command {zoom /2}
880     button .ctrl.zoom.in  -text + -font {Courier 16} -command {zoom *2}
881     pack .ctrl.zoom.out .ctrl.zoom.in -side left
882
883     parser-control-create .ctrl.acquire \
884         acquire Acquire \
885         "Clipboard parsing error" \
886         
887     pack .ctrl.acquire -side top -pady 2
888
889     parser-control-create .ctrl.notes \
890         notes "Reload notes" \
891         "Vessel notes loading report" \
892         
893     pack .ctrl.notes -side top -pady 2
894
895     #----- decoding etc. report -----
896
897     frame .report
898     pack .report -side left -anchor n
899
900     label .report.island -text { }
901
902     frame .report.abbrev -background black
903     glset report_abbrev {         }
904     entry .report.abbrev.abbrev -state readonly \
905         -textvariable report_abbrev \
906         -borderwidth 0 -relief flat -width 0 \
907         -highlightbackground white \
908         -readonlybackground white -foreground black
909     pack .report.abbrev.abbrev -side left -padx 1 -pady 1
910
911     frame .report.code
912     label .report.code.lab -text Code:
913     glset report_code { }
914     entry .report.code.code -state readonly -textvariable report_code -width 15
915     pack .report.code.lab .report.code.code -side left
916     frame .report.details -bd 2 -relief groove -padx 2 -pady 2
917
918     listbox .report.list -height 5
919
920     pack .report.island .report.abbrev .report.details \
921         .report.list .report.code -side top
922     pack configure .report.details -fill x
923
924     foreach sw {inport class subclass lock own xabbrev} {
925         label .report.details.$sw -text { }
926         pack .report.details.$sw -side top -anchor w
927     }
928 }
929
930 proc report-set {sw val} { .report.details.$sw configure -text $val }
931
932 proc show-report {islandname code} {
933     .report.island configure -text $islandname
934     glset report_code $code
935     glset report_abbrev [code2abbrev $code]
936
937     show-report-decode $code
938
939     set kk "$islandname $code"
940     upvar #0 found($kk) k
941
942     .report.list delete 0 end
943
944     foreach entry $k {
945         manyset $entry vid name
946         .report.list insert end $name
947     }
948 }
949
950 proc zoom {extail} {
951     global scale canvas
952     set nscale [expr "\$scale $extail"]
953     debug "ZOOM $scale $nscale"
954     if {$nscale < 1 || $nscale > 200} return
955     set scale $nscale
956     draw
957 }
958
959 proc invoke_acquire {} {
960     global clipboard errorInfo
961     set old $clipboard
962
963     if {[catch {
964         set clipboard [clipboard get]
965     } emsg]} {
966         parser-control-failed-unexpected .ctrl.acquire acquire \
967             $emsg "fetching clipboard:\n\n$errorInfo"
968         return
969     }
970
971     reparse acquire \
972         clipboard $old "Clipboard contents:" { acquired ok } { no vessels } {
973             parse-clipboard
974         } {
975             display-note-infos
976         }
977     draw
978 }
979
980 proc invoke_notes {} {
981     global notes_data errorInfo notes_loc
982     set old $notes_data
983     
984     if {[catch {
985         load-notes
986     } emsg]} {
987         parser-control-failed-unexpected .ctrl.notes notes \
988             $emsg "loading $notes_loc:\n\n$errorInfo"
989         return
990     }
991
992     reparse notes \
993         notes_data $old "Vessel notes:" "loaded ok" { no notes } {
994             parse-notes
995             parse-clipboard
996         } {
997             display-note-infos
998         }
999     draw
1000 }
1001
1002 #---------- main program ----------
1003
1004 vesselclasses-init
1005
1006 parseargs
1007 argdefaults
1008 httpclientsetup where-vessels
1009 load-chart
1010 widgets-setup
1011 make-filters
1012
1013 set notes_data {}
1014 if {[catch { parse-clipboard } emsg]} {
1015     puts stderr "$emsg\n$errorInfo"
1016     exit 1
1017 }
1018 after idle invoke_notes
1019
1020 draw