yarrg/where-vessels

   1 #!/usr/bin/wish
   2 # show your vessels on a map
   3
   4 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   5 # players of Yohoho Puzzle Pirates.
   6 #
   7 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   8 #
   9 # This program is free software: you can redistribute it and/or modify
  10 # it under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation, either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  23 # are used without permission.  This program is not endorsed or
  24 # sponsored by Three Rings.
  25
  26
  27
  28 source yarrglib.tcl
  29 source panner.tcl
  30 package require http
  31
  32 #---------- general utilities ----------
  33
  34 set debug 0
  35 proc debug {m} {
  36     global debug
  37     if {$debug} { puts "DEBUG $m" }
  38 }
  39
  40 proc badusage {m} {
  41     puts stderr "where-vessels: bad usage: $m"
  42     exit 1
  43 }
  44
  45 proc glset {n val} {
  46     upvar #0 $n var
  47     set var $val
  48 }
  49
  50 #---------- expecting certain errors ----------
  51
  52 proc errexpect-setline {lno line} {
  53     glset errexpect_lno $lno
  54     glset errexpect_line $line
  55 }
  56
  57 proc errexpect-error {m} {
  58     global errexpect_line errexpect_lno
  59     error $m "$errexpect_line\n" [list YARRG-ERREXPECT $errexpect_lno]
  60 }
  61
  62 proc errexpect-arrayget {arrayvar key} {
  63     upvar 1 $arrayvar av
  64     upvar 1 ${arrayvar}($key) v
  65     if {[info exists v]} { return $v }
  66     errexpect-error "undefined $key"
  67 }
  68
  69 proc errexpect-arrayget-boolean {arrayvar key} {
  70     switch -exact [uplevel 1 [list errexpect-arrayget $arrayvar $key]] {
  71         true    { return 1 }
  72         false   { return 0 }
  73         default { errexpect-error "unexpected $key" }
  74     }
  75 }
  76
  77 proc errexpect-catch {code} {
  78     global errorInfo errorCode
  79     set rc [catch {
  80         uplevel 1 $code
  81     } rv]
  82     debug "ERREXPECT CATCH |$rc|$rv|$errorCode|$errorInfo|"
  83     if {$rc==1 && ![string compare YARRG-ERREXPECT [lindex $errorCode 0]]} {
  84         return [list 1 $rv [lindex $errorCode 1] $errorInfo]
  85     } elseif {$rc==0} {
  86         return [list 0 $rv]
  87     } else {
  88         return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rv
  89     }
  90 }
  91
  92 #---------- argument parsing ----------
  93
  94 proc nextarg {} {
  95     global ai argv
  96     if {$ai >= [llength $argv]} {
  97         badusage "option [lindex $argv [expr {$ai-1}]] needs a value"
  98     }
  99     set v [lindex $argv $ai]
 100     incr ai
 101     return $v
 102 }
 103
 104 set notes_loc vessel-notes
 105 set scraper {./yppedia-ocean-scraper --chart}
 106
 107 proc parseargs {} {
 108     global ai argv
 109     global debug scraper
 110     set ai 0
 111
 112     while {[regexp {^\-} [set arg [lindex $argv $ai]]]} {
 113         incr ai
 114         switch -exact -- $arg {
 115             -- { break }
 116             --pirate { glset pirate [string totitle [nextarg]] }
 117             --ocean { glset ocean [string totitle [nextarg]] }
 118             --clipboard-file { load-clipboard-file [nextarg] }
 119             --local-html-dir { lappend scraper --local-html-dir=[nextarg] }
 120             --notes { glset notes_loc [nextarg] }
 121             --debug { incr debug }
 122             default { badusage "unknown option $arg" }
 123         }
 124     }
 125     set argv [lrange $argv $ai end]
 126     if {[llength $argv]} { badusage "non-option args not allowed" }
 127 }
 128
 129 proc argdefaults {} {
 130     global ocean notes_loc pirate scraper
 131     if {![info exists ocean] || ![info exists pirate]} {
 132         set cmd {./yarrg --find-window-only --quiet}
 133         if {[info exists ocean]} { lappend cmd --ocean $ocean }
 134         if {[info exists pirate]} { lappend cmd --pirate $pirate }
 135         manyset [split [eval exec $cmd] " "] ocean pirate
 136     }
 137     lappend scraper $ocean
 138 }
 139
 140
 141 #---------- loading and parsing the vessel notes ----------
 142
 143 proc load-notes {} {
 144     global notes_loc notes_data
 145     if {[regexp {^\w+\:} $notes_loc]} {
 146         update
 147         debug "FETCHING NOTES $notes_loc"
 148         set req [::http::geturl $notes_loc]
 149         switch -glob [::http::status $req].[::http::ncode $req] {
 150             ok.200 { }
 151             ok.* { error "retrieving vessel-notes: [::http::code $req]" }
 152             * { error "Retrieving vessel-notes: [::http::error $req]" }
 153         }
 154         set newdata [::http::data $req]
 155         ::http::cleanup $req
 156     } else {
 157         debug "READING NOTES $notes_loc"
 158         set vn [open $notes_loc]
 159         set newdata [read $vn]
 160         close $vn
 161     }
 162     set notes_data $newdata
 163 }
 164
 165 proc parse-notes {} {
 166     global notes_data notes
 167     catch { unset notes }
 168
 169     set lno 0
 170     foreach l [split $notes_data "\n"] {
 171         incr lno
 172         errexpect-setline $lno $l
 173         set l [string trim $l]
 174         if {![string length $l]} continue
 175         if {[regexp {^\#} $l]} continue
 176         if {![regexp -expanded \
 177                   {^ (\d+) (?: \s+([^=]*?) )? \s* =
 178                       (?: \s* (\S+)
 179                        (?: \s+ (\S+) )?)? $} \
 180                   $l dummy vid vname owner note]} {
 181               errexpect-error "badly formatted"
 182         }
 183         set vname [string trim $vname]
 184         if {[info exists notes($vid)]} {
 185             errexpect-error "duplicate vesselid $vid"
 186         }
 187         set notes($vid) [list $lno $vname $owner $note]
 188     }
 189 }
 190
 191 proc note-info {lno vid name island description} {
 192     global note_infos
 193     lappend note_infos [list $lno $vid $name $island $description]
 194 }
 195
 196 proc display-note-infos {} {
 197     global note_infos note_missings notes
 198
 199     set nmissing [llength $note_missings]
 200     debug "display-note-infos $nmissing [array size notes]"
 201
 202     if {[llength $note_infos]} {
 203         set tiny "[llength $note_infos] warnings"
 204     } elseif {$nmissing && [array size notes]} {
 205         set tiny "$nmissing missing"
 206     } else {
 207         return
 208     }
 209
 210     set infodata {}
 211
 212     foreach info $note_infos {
 213         manyset $info lno vid name island description
 214         append infodata "vessel"
 215         append infodata " $vid"
 216         if {[string length $name]} { append infodata " $name" }
 217         if {[string length $island]} { append infodata " ($island)" }
 218         append infodata ": " $description "\n"
 219     }
 220
 221     if {$nmissing} {
 222         if {[string length $infodata]} { append infodata "\n" }
 223         append infodata "$nmissing vessel(s) not mentioned in notes:\n"
 224         set last_island {}
 225         foreach info [lsort $note_missings] {
 226             manyset $info island name vid
 227             if {[string compare $island $last_island]} {
 228                 append infodata "# $island:\n"
 229                 set last_island $island
 230             }
 231             append infodata [format "%-9d %-29s =\n" $vid $name]
 232         }
 233     }
 234
 235     parser-control-failed-core .ctrl.notes notes \
 236         white blue 0 \
 237         $tiny \
 238         "[llength $note_infos] warning(s);\
 239          $nmissing vessel(s) missing" \
 240         "Full description of warnings and missing vessels:" \
 241         $infodata
 242 }
 243
 244 #---------- vessel properties ----------
 245
 246 proc vesselclasses-init {} {
 247     global vc_game2code vc_code2abbrev vc_code2full
 248     foreach {game code abbrev full} {
 249         smsloop         am      sl      Sloop
 250         lgsloop         bm      ct      Cutter
 251         dhow            cm      dh      Dhow
 252         longship        dm      ls      Longship
 253         baghlah         em      bg      Baghlah
 254         merchbrig       fm      mb      {Merchant Brig}
 255         warbrig         gm      wb      {War Brig}
 256         xebec           hm      xe      Xebec
 257         warfrig         im      wf      {War Frigate}
 258         merchgal        jm      mg      {Merchant Galleon}
 259         grandfrig       km      gf      {Grand Frigate}
 260     } {
 261         set vc_game2code($game) $code
 262         set vc_code2abbrev($code) $abbrev
 263         set vc_code2full($code) $full
 264     }
 265 }
 266
 267 proc code2abbrev {code} {
 268     global vc_code2abbrev
 269
 270     manyset [split $code _] inport class subclass lockown xabbrev
 271     manyset [split $lockown ""] lock notown
 272
 273     set abbrev {}
 274     append abbrev [lindex {? {}} $inport]
 275     append abbrev $vc_code2abbrev($class)
 276     append abbrev $subclass
 277     append abbrev [lindex {* + -} $lock]
 278     append abbrev [lindex {= - ?} [regsub {\D} $notown 2]]
 279     append abbrev $xabbrev
 280
 281     debug "CODE2ABBREV $code $abbrev"
 282     return $abbrev
 283 }
 284
 285 proc show-report-decode {code} {
 286     global vc_code2full
 287
 288     manyset [split $code _] inport classcode subclass lockown xabbrev
 289     manyset [split $lockown ""] lock notown
 290
 291     report-set inport [lindex {{At Sea} {In port}} $inport]
 292     report-set class $vc_code2full($classcode)
 293
 294     switch -exact $subclass {
 295         {} { report-set subclass {Ordinary} }
 296         F { report-set subclass {"Frost class"} }
 297         default { report-set subclass "Subclass \"$subclass\"" }
 298     }
 299
 300     report-set lock [lindex {
 301         {Battle ready} {Unlocked} {Locked}
 302     } $lock]
 303
 304     switch -exact $notown {
 305         0 { report-set own "Yours" }
 306         1 { report-set own "Other pirate's" }
 307         U { report-set own "Owner not known" }
 308         M { report-set own "Missing from notes" }
 309         default { report-set own "?? $notown" }
 310     }
 311
 312     if {[string length $xabbrev]} {
 313         report-set xabbrev "Notes flags: $xabbrev"
 314     } else {
 315         report-set xabbrev "No flags in notes"
 316     }
 317 }
 318
 319 #---------- loading and parsing the clipboard (vessel locations) ----------
 320
 321 proc vessel {vin} {
 322     global pirate notes_used note_missings newnotes
 323     upvar 1 $vin vi
 324
 325     set codel {}
 326     lappend codel [errexpect-arrayget-boolean vi inPort]
 327
 328     set gameclass [errexpect-arrayget vi vesselClass]
 329     upvar #0 vc_game2code($gameclass) class
 330     if {![info exists class]} { errexpect-error "unexpected vesselClass"}
 331     lappend codel $class
 332
 333     set subclass [errexpect-arrayget vi vesselSubclass]
 334     switch -exact $subclass {
 335         null            { lappend codel {} }
 336         icy             { lappend codel F }
 337         default         { lappend codel ($subclass) }
 338     }
 339
 340     switch -exact [errexpect-arrayget vi isLocked]/[ \
 341                    errexpect-arrayget vi isBattleReady] {
 342         true/false      { set lock 2 }
 343         false/false     { set lock 1 }
 344         false/true      { set lock 0 }
 345         default         { errexpect-error "unexpected isLocked/isBattleReady" }
 346     }
 347
 348     set vid [errexpect-arrayget vi vesselId]
 349     upvar #0 notes($vid) note
 350     set realname [errexpect-arrayget vi vesselName]
 351     set island [errexpect-arrayget vi islandName]
 352
 353     set owner {}
 354     set xabbrev {}
 355     if {[info exists note]} {
 356         manyset $note lno notename owner xabbrev
 357         if {[string compare -nocase $realname $notename]} {
 358             note-info $lno $vid $realname $island \
 359                 "notes say name is $notename"
 360         }
 361         if {[string length $owner]} {
 362             if {![string compare $owner $pirate]} {
 363                 set notown 0
 364             } else {
 365                 set notown 1
 366             }
 367         } else {
 368             set notown U
 369         }
 370         append abbrev $xabbrev
 371         set notes_used($vid) 1
 372
 373     } else {
 374         set notown M
 375         lappend note_missings [list $island $realname $vid]
 376     }
 377
 378     lappend codel "$lock$notown" $xabbrev
 379     lappend newnotes [list $vid $realname $owner $xabbrev]
 380     set kk "$island [join $codel _]"
 381     upvar #0 found($kk) k
 382     lappend k [list $vid $realname]
 383
 384     debug "CODED $kk $vid $realname"
 385 }
 386
 387 set clipboard {}
 388 proc parse-clipboard {} {
 389     global clipboard found notes notes_used newnotes
 390
 391     catch { unset found }
 392     catch { unset notes_used }
 393     glset note_infos {}
 394     glset note_missings {}
 395
 396     set newnotes {}
 397
 398     set itemre { (\w+) = ([^=]*) }
 399     set manyitemre "^\\\[ $itemre ( (?: ,\\ $itemre)* ) \\]\$"
 400     debug $manyitemre
 401
 402     set lno 0
 403     foreach l [split $clipboard "\n"] {
 404         incr lno
 405         errexpect-setline $lno $l
 406         if {![string length $l]} continue
 407         catch { unset vi }
 408         while 1 {
 409                 if {![regexp -expanded $manyitemre $l dummy \
 410                         thiskey thisval rhs]} {
 411                     errexpect-error "badly formatted"
 412                 }
 413                 set vi($thiskey) $thisval
 414                 if {![string length $rhs]} break
 415                 regsub {^, } $rhs {} rhs
 416                 set l "\[$rhs\]"
 417         }
 418         vessel vi
 419     }
 420
 421     if {[llength $newnotes]} {
 422         foreach vid [lsort [array names notes]] {
 423             if {![info exists notes_used($vid)]} {
 424                 manyset $notes($vid) lno notename
 425                 note-info $lno $vid $notename {} \
 426                     "vessel in notes no longer found"
 427             }
 428         }
 429     }
 430 }
 431
 432 proc load-clipboard-file {fn} {
 433     set f [open $fn]
 434     glset clipboard [read $f]
 435     close $f
 436 }
 437
 438
 439 #---------- loading and parsing the chart ----------
 440
 441 proc load-chart {} {
 442     global chart scraper
 443     debug "FETCHING CHART"
 444     set chart [eval exec $scraper [list | perl -we {
 445         use strict;
 446         use CommodsScrape;
 447         use IO::File;
 448         use IO::Handle;
 449         yppedia_chart_parse(\*STDIN, (new IO::File ">/dev/null"),
 450                 sub { sprintf "%d %d", @_; },
 451                 sub { printf "archlabel %d %d %s\n", @_; },
 452                 sub { printf "island %s %s\n", @_; },
 453                 sub { printf "league %s %s %s.\n", @_; },
 454                 sub { printf STDERR "warning: %s: incomprehensible: %s", @_; }
 455                         );
 456         STDOUT->error and die $!;
 457     }]]
 458 }
 459
 460
 461 set scale 16
 462
 463 proc coord {c} {
 464         global scale
 465         return [expr {$c * $scale}]
 466 }
 467
 468 proc chart-got/archlabel {args} { }
 469 proc chart-got/island {x y args} {
 470 #       debug "ISLE $x $y $args"
 471         global canvas isleloc
 472         set isleloc($args) [list $x $y]
 473         set sz 5
 474 #       $canvas create oval \
 475 #               [expr {[coord $x] - $sz}] [expr {[coord $y] - $sz}] \
 476 #               [expr {[coord $x] + $sz}] [expr {[coord $y] + $sz}] \
 477 #               -fill blue
 478         $canvas create text [coord $x] [coord $y] \
 479                 -text $args -anchor s
 480 }
 481 proc chart-got/league {x1 y1 x2 y2 kind} {
 482 #       debug "LEAGUE $x1 $y1 $x2 $y2 $kind"
 483         global canvas
 484         set l [$canvas create line \
 485                 [coord $x1] [coord $y1] \
 486                 [coord $x2] [coord $y2]]
 487         if {![string compare $kind .]} {
 488                 $canvas itemconfigure $l -dash .
 489         }
 490 }
 491
 492 proc draw {} {
 493     global chart found isleloc canvas
 494
 495     $canvas delete all
 496
 497     foreach l [split $chart "\n"] {
 498 #       debug "CHART-GOT $l"
 499         set proc [lindex $l 0]
 500         eval chart-got/$proc [lrange $l 1 end]
 501     }
 502
 503     set lastislandname {}
 504     foreach key [lsort [array names found]] {
 505         set c [llength $found($key)]
 506 #       debug "SHOWING $key $c"
 507         regexp {^(.*) (\S+)$} $key dummy islandname code
 508
 509         set abbrev [code2abbrev $code]
 510
 511         if {[string compare $lastislandname $islandname]} {
 512                 manyset $isleloc($islandname) x y
 513                 set x [coord $x]
 514                 set y [coord $y]
 515                 set lastislandname $islandname
 516 #               debug "START Y $y"
 517         }
 518         set text $abbrev
 519         regsub -all {[0-9]} $text {} text
 520         if {$c > 1} {
 521                 set text [format "%2d%s" $c $text]
 522         } else {
 523                 set text [format "  %s" $text]
 524         }
 525         set id [$canvas create text $x $y \
 526                 -anchor nw -font fixed \
 527                 -text $text]
 528         set bbox [$canvas bbox $id]
 529         set bid [eval $canvas create rectangle $bbox -fill white]
 530         $canvas lower $bid $id
 531         $canvas bind $id <ButtonPress> [list show-report $islandname $code]
 532         $canvas bind $bid <ButtonPress> [list show-report $islandname $code]
 533         manyset $bbox dummy dummy dummy y
 534 #       debug "NEW Y $y"
 535     }
 536
 537     panner::updatecanvas-bbox .ctrl.pan
 538 }
 539
 540
 541 #---------- parser error reporting ----------
 542
 543 proc parser-control-create {w base invokebuttontext etl_title} {
 544     frame $w
 545     button $w.do -text $invokebuttontext -command invoke_$base
 546
 547     frame $w.resframe -width 120 -height 32
 548     button $w.resframe.res -text {} -anchor nw \
 549         -padx 1 -pady 1 -borderwidth 0 -justify left
 550     glset deffont_$base [$w.resframe.res cget -font]
 551     place $w.resframe.res -relx 0.5 -y 0 -anchor n
 552
 553     pack $w.do -side top
 554     pack $w.resframe -side top -expand y -fill both
 555
 556     set eb .err_$base
 557     toplevel $eb
 558     wm withdraw $eb
 559     wm title $eb "where-vessels - $etl_title"
 560
 561     label $eb.title -text $etl_title
 562     pack $eb.title -side top
 563
 564     button $eb.close -text Close -command [list wm withdraw $eb]
 565     pack $eb.close -side bottom
 566
 567     frame $eb.emsg -bd 2 -relief groove
 568     label $eb.emsg.lab -text "Error:"
 569     text $eb.emsg.text -height 1
 570     pack $eb.emsg.text -side bottom
 571     pack $eb.emsg.lab -side left
 572
 573     pack $eb.emsg -side top -pady 2
 574
 575     frame $eb.text -bd 2 -relief groove
 576     pack $eb.text -side bottom -pady 2
 577
 578     label $eb.text.lab
 579
 580     text $eb.text.text -width 85 \
 581         -xscrollcommand [list $eb.text.xscroll set] \
 582         -yscrollcommand [list $eb.text.yscroll set]
 583     $eb.text.text tag configure error \
 584         -background red -foreground white
 585
 586     scrollbar $eb.text.xscroll -orient horizontal \
 587         -command [list $eb.text.text xview]
 588     scrollbar $eb.text.yscroll -orient vertical \
 589         -command [list $eb.text.text yview]
 590
 591     grid configure $eb.text.lab -row 0 -column 0 -sticky w
 592     grid configure $eb.text.text -row 1 -column 0
 593     grid configure $eb.text.yscroll -sticky ns -row 1 -column 1
 594     grid configure $eb.text.xscroll -sticky ew -row 2 -column 0
 595 }
 596
 597 proc parser-control-ok-core {w base background show} {
 598     debug "parser-control-ok-core $w $base $background $show"
 599     upvar #0 deffont_$base deffont
 600     $w.resframe.res configure \
 601         -background $background -disabledforeground black -font $deffont \
 602         -state disabled -command {} \
 603         -text $show
 604 }
 605 proc parser-control-ok {w base show} {
 606     parser-control-ok-core $w $base green $show
 607 }
 608 proc parser-control-none {w base show} {
 609     parser-control-ok-core $w $base blue $show
 610 }
 611 proc parser-control-failed-core {w base foreground background smallfont
 612                                  tiny summary fulldesc fulldata} {
 613     debug "parser-control-failed-core $w $base $summary $fulldesc"
 614     upvar #0 deffont_$base deffont
 615     set eb .err_$base
 616
 617     $eb.emsg.text delete 0.0 end
 618     $eb.emsg.text insert end $summary
 619
 620     $eb.text.lab configure -text $fulldesc
 621     $eb.text.text delete 0.0 end
 622     $eb.text.text insert end $fulldata
 623
 624     regsub -all {.{18}} $tiny "&\n" ewrap
 625
 626     if {$smallfont} {
 627         set font fixed
 628     } else {
 629         set font $deffont
 630     }
 631
 632     $w.resframe.res configure \
 633         -background $background -foreground $foreground -font $font \
 634         -state normal -command [list wm deiconify $eb] \
 635         -text $ewrap
 636 }
 637
 638 proc parser-control-failed-expected {w base emsg lno ei fulldesc newdata} {
 639     set eb .err_$base
 640
 641     set line [lindex [split $ei "\n"] 0]
 642     debug "parser-control-failed-expected: $w $base: $lno: $emsg\n $line"
 643
 644     parser-control-failed-core $w $base \
 645         white red 1 \
 646         "err: [string trim $emsg]: \"$line\"" \
 647         "at line $lno: $emsg" \
 648         $fulldesc $newdata
 649
 650     $eb.text.text tag add error $lno.0 $lno.end
 651     $eb.text.text see $lno.0
 652 }
 653 proc parser-control-failed-unexpected {w base emsg ei} {
 654     global errorInfo
 655     parser-control-failed-core $w $base \
 656         black yellow 1 \
 657         $emsg $emsg "Details and stack trace:" $ei
 658 }
 659
 660 proc reparse {base varname old fulldesc okshow noneshow parse ok} {
 661     upvar #0 $varname var
 662     manyset [errexpect-catch {
 663         uplevel 1 $parse
 664         if {[string length [string trim $var]]} {
 665             parser-control-ok .ctrl.$base $base $okshow
 666         } else {
 667             parser-control-none .ctrl.$base $base $noneshow
 668         }
 669     }] failed emsg lno ei
 670     if {$failed} {
 671         parser-control-failed-expected .ctrl.$base $base \
 672             $emsg $lno $ei $fulldesc $var
 673         set var $old
 674         uplevel 1 $parse
 675     } else {
 676         uplevel 1 $ok
 677     }
 678 }
 679
 680 #---------- main user interface ----------
 681
 682 proc widgets-setup {} {
 683     global canvas debug pirate ocean
 684
 685     wm geometry . 1024x480
 686     wm title . "where-vessels - $pirate on the $ocean ocean"
 687
 688     #----- map -----
 689
 690     frame .f -border 1 -relief groove
 691     set canvas .f.c
 692     canvas $canvas
 693     pack $canvas -expand 1 -fill both
 694     pack .f -expand 1 -fill both -side left
 695
 696     #----- control panel -----
 697
 698     frame .ctrl
 699     pack .ctrl -side left -anchor n
 700
 701     debug "BBOX [$canvas bbox all]"
 702
 703     panner::canvas-scroll-bbox .f.c
 704     panner::create .ctrl.pan .f.c 120 120 $debug
 705
 706     pack .ctrl.pan -side top -pady 10 -padx 5
 707     frame .ctrl.zoom
 708     pack .ctrl.zoom -side top
 709
 710     button .ctrl.zoom.out -text - -font {Courier 16} -command {zoom /2}
 711     button .ctrl.zoom.in  -text + -font {Courier 16} -command {zoom *2}
 712     pack .ctrl.zoom.out .ctrl.zoom.in -side left
 713
 714     parser-control-create .ctrl.acquire \
 715         acquire Acquire \
 716         "Clipboard parsing error" \
 717
 718     pack .ctrl.acquire -side top -pady 2
 719
 720     parser-control-create .ctrl.notes \
 721         notes "Reload notes" \
 722         "Vessel notes loading report" \
 723
 724     pack .ctrl.notes -side top -pady 2
 725
 726     #----- decoding etc. report -----
 727
 728     frame .report
 729     pack .report -side left -anchor n
 730
 731     label .report.island -text { }
 732
 733     frame .report.abbrev -background black
 734     glset report_abbrev {         }
 735     entry .report.abbrev.abbrev -state readonly \
 736         -textvariable report_abbrev \
 737         -borderwidth 0 -relief flat -width 0 \
 738         -highlightbackground white \
 739         -readonlybackground white -foreground black
 740     pack .report.abbrev.abbrev -side left -padx 1 -pady 1
 741
 742     frame .report.code
 743     label .report.code.lab -text Code:
 744     glset report_code { }
 745     entry .report.code.code -state readonly -textvariable report_code -width 15
 746     pack .report.code.lab .report.code.code -side left
 747     frame .report.details -bd 2 -relief groove -padx 2 -pady 2
 748
 749     listbox .report.list -height 5
 750
 751     pack .report.island .report.abbrev .report.details \
 752         .report.list .report.code -side top
 753     pack configure .report.details -fill x
 754
 755     foreach sw {inport class subclass lock own xabbrev} {
 756         label .report.details.$sw -text { }
 757         pack .report.details.$sw -side top -anchor w
 758     }
 759 }
 760
 761 proc report-set {sw val} { .report.details.$sw configure -text $val }
 762
 763 proc show-report {islandname code} {
 764     .report.island configure -text $islandname
 765     glset report_code $code
 766     glset report_abbrev [code2abbrev $code]
 767
 768     show-report-decode $code
 769
 770     set kk "$islandname $code"
 771     upvar #0 found($kk) k
 772
 773     .report.list delete 0 end
 774
 775     foreach entry $k {
 776         manyset $entry vid name
 777         .report.list insert end $name
 778     }
 779 }
 780
 781 proc zoom {extail} {
 782     global scale canvas
 783     set nscale [expr "\$scale $extail"]
 784     debug "ZOOM $scale $nscale"
 785     if {$nscale < 1 || $nscale > 200} return
 786     set scale $nscale
 787     draw
 788 }
 789
 790 proc invoke_acquire {} {
 791     global clipboard errorInfo
 792     set old $clipboard
 793
 794     if {[catch {
 795         set clipboard [clipboard get]
 796     } emsg]} {
 797         parser-control-failed-unexpected .ctrl.acquire acquire \
 798             $emsg "fetching clipboard:\n\n$errorInfo"
 799         return
 800     }
 801
 802     reparse acquire \
 803         clipboard $old "Clipboard contents:" { acquired ok } { no vessels } {
 804             parse-clipboard
 805         } {
 806             display-note-infos
 807         }
 808     draw
 809 }
 810
 811 proc invoke_notes {} {
 812     global notes_data errorInfo notes_loc
 813     set old $notes_data
 814
 815     if {[catch {
 816         load-notes
 817     } emsg]} {
 818         parser-control-failed-unexpected .ctrl.notes notes \
 819             $emsg "loading $notes_loc:\n\n$errorInfo"
 820         return
 821     }
 822
 823     reparse notes \
 824         notes_data $old "Vessel notes:" "loaded ok" { no notes } {
 825             parse-notes
 826             parse-clipboard
 827         } {
 828             display-note-infos
 829         }
 830     draw
 831 }
 832
 833 #---------- main program ----------
 834
 835 vesselclasses-init
 836
 837 parseargs
 838 argdefaults
 839 httpclientsetup where-vessels
 840 load-chart
 841 widgets-setup
 842
 843 set notes_data {}
 844 if {[catch { parse-clipboard } emsg]} {
 845     puts stderr "$emsg\n$errorInfo"
 846     exit 1
 847 }
 848 after idle invoke_notes
 849
 850 draw