chiark / gitweb /
where-vessels: smash sizes
[ypp-sc-tools.main.git] / yarrg / where-vessels
1 #!/usr/bin/wish
2 # show your vessels on a map
3
4 # This is part of ypp-sc-tools, a set of third-party tools for assisting
5 # players of Yohoho Puzzle Pirates.
6 #
7 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
8 #
9 # This program is free software: you can redistribute it and/or modify
10 # it under the terms of the GNU General Public License as published by
11 # the Free Software Foundation, either version 3 of the License, or
12 # (at your option) any later version.
13 #
14 # This program is distributed in the hope that it will be useful,
15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
17 # GNU General Public License for more details.
18 #
19 # You should have received a copy of the GNU General Public License
20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
21 #
22 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
23 # are used without permission.  This program is not endorsed or
24 # sponsored by Three Rings.
25
26
27
28 source yarrglib.tcl
29 source panner.tcl
30 package require http
31
32 #---------- general utilities ----------
33
34 set debug 0
35 proc debug {m} {
36     global debug
37     if {$debug} { puts "DEBUG $m" }
38 }
39
40 proc badusage {m} {
41     puts stderr "where-vessels: bad usage: $m"
42     exit 1
43 }
44
45 proc glset {n val} {
46     upvar #0 $n var
47     set var $val
48 }
49
50 #---------- expecting certain errors ----------
51
52 proc errexpect-setline {lno line} {
53     glset errexpect_lno $lno
54     glset errexpect_line $line
55 }
56
57 proc errexpect-error {m} {
58     global errexpect_line errexpect_lno
59     error $m "$errexpect_line\n" [list YARRG-ERREXPECT $errexpect_lno]
60 }
61
62 proc errexpect-arrayget {arrayvar key} {
63     upvar 1 $arrayvar av
64     upvar 1 ${arrayvar}($key) v
65     if {[info exists v]} { return $v }
66     errexpect-error "undefined $key"
67 }
68
69 proc errexpect-arrayget-boolean {arrayvar key} {
70     switch -exact [uplevel 1 [list errexpect-arrayget $arrayvar $key]] {
71         true    { return 1 }
72         false   { return 0 }
73         default { errexpect-error "unexpected $key" }
74     }
75 }
76
77 proc errexpect-catch {code} {
78     global errorInfo errorCode
79     set rc [catch {
80         uplevel 1 $code
81     } rv]
82     debug "ERREXPECT CATCH |$rc|$rv|$errorCode|$errorInfo|"
83     if {$rc==1 && ![string compare YARRG-ERREXPECT [lindex $errorCode 0]]} {
84         return [list 1 $rv [lindex $errorCode 1] $errorInfo]
85     } elseif {$rc==0} {
86         return [list 0 $rv]
87     } else {
88         return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rv
89     }
90 }
91
92 #---------- argument parsing ----------
93
94 proc nextarg {} {
95     global ai argv
96     if {$ai >= [llength $argv]} {
97         badusage "option [lindex $argv [expr {$ai-1}]] needs a value"
98     }
99     set v [lindex $argv $ai]
100     incr ai
101     return $v
102 }
103
104 set notes_loc vessel-notes
105 set scraper {./yppedia-ocean-scraper --chart}
106 set info_cache _vessel-info-cache
107 set info_source rsync.yarrg.chiark.net::yarrg/vessel-info
108
109 proc parseargs {} {
110     global ai argv
111     global debug scraper
112     set ai 0
113
114     while {[regexp {^\-} [set arg [lindex $argv $ai]]]} {
115         incr ai
116         switch -exact -- $arg {
117             -- { break }
118             --pirate { glset pirate [string totitle [nextarg]] }
119             --ocean { glset ocean [string totitle [nextarg]] }
120             --clipboard-file { load-clipboard-file [nextarg] }
121             --local-html-dir { lappend scraper --local-html-dir=[nextarg] }
122             --notes { glset notes_loc [nextarg] }
123             --vessel-info-source { glset info_source [nextarg] }
124             --debug { incr debug }
125             default { badusage "unknown option $arg" }
126         }
127     }
128     set argv [lrange $argv $ai end]
129     if {[llength $argv]} { badusage "non-option args not allowed" }
130 }
131
132 proc argdefaults {} {
133     global ocean notes_loc pirate scraper
134     if {![info exists ocean] || ![info exists pirate]} {
135         set cmd {./yarrg --find-window-only --quiet}
136         if {[info exists ocean]} { lappend cmd --ocean $ocean }
137         if {[info exists pirate]} { lappend cmd --pirate $pirate }
138         manyset [split [eval exec $cmd] " "] ocean pirate
139         if {![llength $ocean] || ![llength $pirate]} {
140             error "$ocean $pirate ?"
141         }
142     }
143     lappend scraper $ocean
144 }
145
146
147 #---------- loading and parsing the vessel notes ----------
148
149 proc load-notes {} {
150     global notes_loc notes_data
151     if {[regexp {^\w+\:} $notes_loc]} {
152         update
153         debug "FETCHING NOTES $notes_loc"
154         set req [::http::geturl $notes_loc]
155         switch -glob [::http::status $req].[::http::ncode $req] {
156             ok.200 { }
157             ok.* { error "retrieving vessel-notes: [::http::code $req]" }
158             * { error "Retrieving vessel-notes: [::http::error $req]" }
159         }
160         set newdata [::http::data $req]
161         ::http::cleanup $req
162     } else {
163         debug "READING NOTES $notes_loc"
164         set vn [open $notes_loc]
165         set newdata [read $vn]
166         close $vn
167     }
168     set notes_data $newdata
169 }
170
171 proc parse-notes {} {
172     global notes_data notes
173     catch { unset notes }
174
175     set lno 0
176     foreach l [split $notes_data "\n"] {
177         incr lno
178         errexpect-setline $lno $l
179         set l [string trim $l]
180         if {![string length $l]} continue
181         if {[regexp {^\#} $l]} continue
182         if {![regexp -expanded \
183                   {^ (\d+) (?: \s+([^=]*?) )? \s* =
184                       (?: \s* (\S+)
185                        (?: \s+ (\S+) )?)? $} \
186                   $l dummy vid vname owner note]} {
187               errexpect-error "badly formatted"
188         }
189         set vname [string trim $vname]
190         if {[info exists notes($vid)]} {
191             errexpect-error "duplicate vesselid $vid"
192         }
193         set notes($vid) [list $lno $vname $owner $note]
194     }
195 }
196
197 proc note-info {lno vid name island description} {
198     global note_infos
199     lappend note_infos [list $lno $vid $name $island $description]
200 }
201
202 proc display-note-infos {} {
203     global note_infos note_missings notes
204
205     set nmissing [llength $note_missings]
206     debug "display-note-infos $nmissing [array size notes]"
207
208     if {[llength $note_infos]} {
209         set tiny "[llength $note_infos] warning(s)"
210     } elseif {$nmissing && [array size notes]} {
211         set tiny "$nmissing missing"
212     } else {
213         return
214     }
215
216     set infodata {}
217
218     foreach info $note_infos {
219         manyset $info lno vid name island description
220         append infodata "vessel"
221         append infodata " $vid"
222         if {[string length $name]} { append infodata " $name" }
223         if {[string length $island]} { append infodata " ($island)" }
224         append infodata ": " $description "\n"
225     }
226
227     if {$nmissing} {
228         if {[string length $infodata]} { append infodata "\n" }
229         append infodata "$nmissing vessel(s) not mentioned in notes:\n"
230         set last_island {}
231         foreach info [lsort $note_missings] {
232             manyset $info island name vid
233             if {[string compare $island $last_island]} {
234                 append infodata "# $island:\n"
235                 set last_island $island
236             }
237             append infodata [format "%-9d %-29s =\n" $vid $name]
238         }
239     }
240
241     parser-control-failed-core .cp.ctrl.notes notes \
242         white blue 0 \
243         $tiny \
244         "[llength $note_infos] warning(s);\
245          $nmissing vessel(s) missing" \
246         "Full description of warnings and missing vessels:" \
247         $infodata
248 }
249
250 #---------- vessel properties ----------
251
252 proc info-cache-update {} {
253     global info_source info_cache
254     file mkdir $info_cache
255     exec sh -c "cp -u icons/* $info_cache/."
256
257     if {[string length $info_source]} {
258         set cmdl [list \
259                   rsync -udLKtOzm \
260                   --exclude=*~ --exclude=*.bak --exclude=.* --exclude=*.tmp \
261                   $info_source/ $info_cache 2>@ stderr]
262         debug "INFO-CACHE $cmdl"
263         eval exec $cmdl
264     }
265
266     set f [open $info_cache/vessel-info]
267     glset vessel_class_data [read $f]
268     close $f
269 }
270
271 proc vesselclasses-init {} {
272     global vc_game2code vc_code2abbrev vc_code2full vc_codes
273
274     global vessel_class_data
275     manyset $vessel_class_data classinfos subclassinfos
276
277     set vc_codes {}
278     foreach {game code abbrev full} $classinfos {
279         if {![regexp {^[a-z][a-z]$} $code code]} { error "bad code" }
280         if {![regexp {^[a-z][a-z]$} $abbrev abbrev]} { error "bad abbrev" }
281         lappend vc_codes $code
282         set vc_game2code($game) $code
283         set vc_code2abbrev($code) $abbrev
284         set vc_code2full($code) $full
285         load-icon $abbrev
286     }
287
288     global vsc_code2report
289     global vsc_game2code
290     set vsc_game2code(null) {}
291     set vsc_code2report() Ordinary
292     set vsc_code2report(!) "(Special/L.E.)"
293     foreach {game code full} $subclassinfos {
294         if {![regexp {^[A-Z]$} $code code]} { error "bad code" }
295         set vsc_game2code($game) $code
296         set vsc_code2report($code) $full
297     }
298
299     load-icon atsea
300     set owners {ours dot query}
301     foreach b $owners { load-icon $b }
302     foreach a {battle borrow dot} {
303         load-icon $a
304         foreach b $owners { load-icon-combine $a $b }
305     }
306 }
307
308 proc load-icon {icon} {
309     global info_cache
310     image create bitmap icon/$icon -file $info_cache/$icon.xbm
311 }
312
313 proc load-icon-combine {args} {
314     global info_cache
315     set cmd {}
316     set delim "pnmcat -lr "
317     foreach icon $args {
318         append cmd $delim " <(xbmtopbm $info_cache/$icon.xbm)"
319         set delim " <(pbmmake -white 1 1)"
320     }
321     append cmd " | pbmtoxbm"
322     debug "load-icon-combine $cmd"
323     image create bitmap icon/[join $args +] -data [exec bash -c $cmd]
324 }
325
326 proc code-lockown2icon {lockown} {
327     manyset [split $lockown ""] lock notown
328     set l "
329          [lindex {battle borrow dot} $lock]
330          [lindex {ours dot query {} {} dot} $notown]
331     "
332     if {[llength $l]} { return icon/[join $l +] } { return {} }
333 }
334
335 proc canvas-horiz-stack {xvar xoff y bind type args} {
336     upvar 1 $xvar x
337     upvar 1 canvas canvas
338     set id [eval $canvas create $type [expr {$x+$xoff}] $y $args]
339     set bbox [$canvas bbox $id]
340 #   debug "CANVAS-HORIZ-STACK $type $x $xoff $id $bbox [list $args]"
341     set x [lindex $bbox 2]
342     $canvas bind $id <ButtonPress> $bind
343     return $id
344 }
345
346 proc code2canvas {code canvas x yvar qty qtylen bind} {
347     global vc_code2abbrev
348     upvar 1 $yvar y
349
350     manyset [split $code _] inport class subclass lockown xabbrev
351
352     set stackx $x
353     incr stackx 2
354     set imy [expr {$y+2}]
355
356     if {!$inport} { incr qtylen -1 }
357     if {$qtylen<=0} { set qtylen {} }
358     set qty [format "%${qtylen}s" $qty]
359
360     set qtyid [canvas-horiz-stack stackx 0 $y $bind \
361                    text -anchor nw -font fixed -text $qty]
362
363     if {!$inport} {
364         canvas-horiz-stack stackx 0 $imy $bind \
365             image -anchor nw -image icon/atsea
366         incr stackx
367     }
368     
369     upvar #0 vc_code2abbrev($class) vcabb
370     if {![info exists vcabb]} {
371         set vcabb vc-$class
372         image create bitmap icon/$vcabb -data \
373             [exec pbmtext -builtin fixed $class | pnminvert | pnmcrop >t.pnm]
374     }
375     canvas-horiz-stack stackx -1 $imy $bind \
376             image -anchor nw -image icon/$vcabb
377
378     if {[string length $subclass]} {
379         canvas-horiz-stack stackx 0 $y $bind \
380             text -anchor nw -font fixed -text \
381             $subclass
382     }
383
384     incr stackx
385     set lockownicon [code-lockown2icon $lockown]
386     if {[string length $lockownicon]} {
387         canvas-horiz-stack stackx 0 $imy $bind \
388             image -anchor nw -image $lockownicon
389         incr stackx
390     }
391     
392     if {[string length $xabbrev]} {
393         canvas-horiz-stack stackx 0 $y $bind \
394             text -anchor nw -font fixed -text \
395             $xabbrev
396     }
397     
398     set bbox [$canvas bbox $qtyid]
399     set ny [lindex $bbox 3]
400     set bid [$canvas create rectangle \
401                  $x $y $stackx $ny \
402                  -fill white]
403
404     set y $ny
405     $canvas lower $bid $qtyid
406
407     $canvas bind $bid <ButtonPress> $bind
408 }
409
410 proc show-report-decode {code} {
411     global vc_code2full
412
413     manyset [split $code _] inport classcode subclass lockown xabbrev
414     manyset [split $lockown ""] lock notown
415     
416     report-set inport [lindex {{At Sea} {In port}} $inport]
417     report-set class $vc_code2full($classcode)
418
419     global smash_subclass
420     if {$smash_subclass >= 2} {
421         report-set subclass "(Any subclass)"
422     } elseif {[
423                upvar #0 vsc_code2report($subclass) subclass_report
424                info exists subclass_report
425               ]} {
426         report-set subclass $subclass_report
427     } else {
428         report-set subclass "Subclass \"$subclass\""
429     }
430
431     report-set lock [lindex {
432         {Battle ready} {Unlocked} {Locked}
433         {(All lock states)} {(Not battle ready)}
434     } $lock]
435
436     switch -exact $notown {
437         0 { report-set own "Yours" }
438         1 { report-set own "Other pirate's" }
439         2 { report-set own "Owner unknown" }
440         3 { report-set own "(All ownerships)" }
441         4 - 5 { report-set own "(Yours/unknown)" }
442         default { report-set own "?? $notown" }
443     }
444
445     if {[string length $xabbrev]} {
446         report-set xabbrev "Notes flags: $xabbrev"
447     } else {
448         report-set xabbrev "No flags in notes"
449     }
450 }
451
452 #---------- common to smashing and filtering ----------
453
454 proc make-control {parent ctrl label ekind} {
455     debug "MAKE-CONTROL [list $parent $ctrl $label $ekind]"
456     label $parent.lab_$ctrl -text $label -justify left
457     $ekind $parent.$ctrl
458     manyset [grid size $parent] dummy row
459     incr row
460     grid configure $parent.lab_$ctrl -row $row -column 0 -sticky nw -pady 4
461     grid configure $parent.$ctrl -row $row -column 1 -sticky w -pady 3
462     return $parent.$ctrl
463 }
464
465 proc begin-control-grid {cw count rows inrow} {
466     if {!$inrow} { set inrow [expr {($count + $rows) / $rows}] }
467     upvar #0 control_grid_properties($cw) props
468     set props [list $rows $inrow]
469     return $cw
470 }
471
472 proc make-control-grid-entry {cw kind ix ekind args} {
473     upvar #0 control_grid_properties($cw) props
474     manyset $props rows inrow
475
476     set ew $cw.$ix
477
478     debug "MAKE-CONTROL-GRID-ENTRY $cw $kind $ix $ekind $rows $inrow $ew"
479
480     eval [list $ekind $ew] $args
481
482     switch -exact $kind {
483         ix {
484             grid configure $ew -sticky sw \
485                 -row [expr {$ix / $inrow}] \
486                 -column [expr {$ix % $inrow}]
487         }
488         final {
489             grid configure $ew -sticky se \
490                 -row [expr {$rows-1}] \
491                 -column [expr {$inrow-1}]
492         }
493         default {
494             error "$kind ?"
495         }
496     }
497     return $ew
498 }
499
500 proc control-tickbox-flip {varsvn values} {
501     upvar #0 $varsvn vars
502     foreach val $values {
503         set vars($val) [expr {!$vars($val)}]
504     }
505     redraw-needed c.-tickbox-flip $varsvn $values
506 }
507
508 proc populate-control-grid-tickboxes {cw rows inrow varsvn values flipvalues
509                                     label_kind valvn default_get label_get} {
510     debug "POPULATE-CONTROL-GRID-TICKBOXES $cw $rows $inrow $varsvn\
511              [list $values] $label_kind $valvn"
512
513     upvar #0 $varsvn vars
514     upvar 1 $valvn val
515     set count [llength $values]
516
517     begin-control-grid $cw $count $rows $inrow
518
519     for {set ix 0} {$ix < $count} {incr ix} {
520         set val [lindex $values $ix]
521         set vars($val) [uplevel 1 $default_get]
522         set ew [make-control-grid-entry $cw ix $ix checkbutton \
523                     -variable ${varsvn}($val) \
524                     -font fixed \
525                     -command [list redraw-needed c.-g.-tickbox $cw $val]]
526         $ew configure -$label_kind [uplevel 1 $label_get]
527         switch -exact $label_kind {
528             image { $ew configure -height 16 }
529         }
530     }
531     [make-control-grid-entry $cw final invert button] \
532         configure \
533         -text flip -command [list control-tickbox-flip $varsvn $flipvalues] \
534         -padx 0 -pady 0
535 }
536
537 #---------- smashing ----------
538
539 set smash_subclass 0
540 set smash_owner 0
541
542 proc smash-code {code} {
543     manyset [split $code _] inport class subclass lockown xabbrev
544
545     upvar #0 smash_sizemap($class) smclass
546
547     global smash_subclass
548     if {$smash_subclass > 1} {
549         set subclass {}
550     } elseif {$smash_subclass && [string length $subclass]} {
551         set subclass !
552     }
553
554     global smash_owner
555     switch $smash_owner {
556         0 { }
557         1 { regsub {[12]$} $lockown 5 lockown }
558         2 {
559             if {[regexp {^0.} $lockown]} {
560                 # battle ready / all lock states
561                 set lockown 03
562             } elseif {[regexp {^.0} $lockown]} {
563                 # not battle ready / yours
564                 set lockown 40
565             } else {
566                 # state (not battle ready) / not known to be yours
567                 regsub {.$} $lockown 4 lockown
568             }
569         }
570         3 { regsub {.$} $lockown {3} lockown }
571         4 { set lockown 33 }
572     }
573
574     return [join [list $inport $smclass $subclass $lockown $xabbrev] _]
575 }
576
577 proc smash-prepare {} {
578     global vc_codes smash_sizemap smash_size
579     set mapto {}
580     foreach size $vc_codes {
581         if {!$smash_size($size)} { set mapto $size }
582         set smash_sizemap($size) $mapto
583     }
584 }
585
586 proc make-smasher {sma label ekind} {
587     return [make-control .smash $sma $label $ekind]
588 }
589
590 proc make-radio-smasher {sma label variable descs rows inrow} {
591     set w [make-smasher $sma $label frame]
592     begin-control-grid $w [llength $descs] $rows $inrow
593     for {set i 0} {$i < [llength $descs]} {incr i} {
594         make-control-grid-entry $w ix $i \
595             radiobutton \
596             -variable $variable -value $i -command redraw-needed \
597             -text [lindex $descs $i]
598     }
599 }
600
601 proc make-smashers {} {
602     global vc_codes vc_code2abbrev
603     set cw [make-smasher size "Size\n round\n down" frame]
604     populate-control-grid-tickboxes $cw 2 0 smash_size \
605         $vc_codes [lrange $vc_codes 1 end] \
606         image val { expr 0 } { expr {"icon/$vc_code2abbrev($val)"} }
607     $cw.0 configure -state disabled
608
609     make-radio-smasher subclass Subclass smash_subclass \
610         {Show Normal/LE Hide} 1 0
611
612     make-radio-smasher owner Owner smash_owner \
613         {Show Yours? {For you} Lock Hide} 2 3
614 }
615
616 #---------- filtering ----------
617
618 set filters {}
619
620 proc filter-values/size {} { global vc_codes; return $vc_codes }
621 proc filter-icon/size {code} {
622     upvar #0 vc_code2abbrev($code) abb
623     return icon/$abb
624 }
625 proc filter-default/size {code} { return 1 }
626 proc filter-says-yes/size {codel} {
627     set sizecode [lindex $codel 1]
628     upvar #0 filter_size($sizecode) yes
629     return $yes
630 }
631
632 proc filter-values/lockown {} {
633     foreach lv {0 1 2} {
634         foreach ov {0 1 2} {
635             lappend vals "$lv$ov"
636         }
637     }
638     return $vals
639 }
640 proc filter-icon/lockown {lockown} { return [code-lockown2icon $lockown] }
641 proc filter-default/lockown {lockown} {
642     return [regexp {^[01]|^2[^1]} $lockown]
643 }
644 proc filter-says-yes/lockown {codel} {
645     set lockown [lindex $codel 3]
646     upvar #0 filter_lockown($lockown) yes
647     debug "FILTER-SAYS-YES/LOCKOWN $codel $lockown $yes"
648     return $yes
649 }
650
651 proc filter-validate/xabbre {re} {
652     if {[catch {
653         regexp -- $re {}
654     } emsg]} {
655         regsub {^.*:\s*} $emsg {} emsg
656         regsub {^.*(.{30})$} $emsg {\1} emsg
657         return $emsg
658     }
659     return {}
660 }
661 proc filter-says-yes/xabbre {codel} {
662     global filter_xabbre
663     set xabbrev [lindex $codel 4]
664     return [regexp -- $filter_xabbre $xabbrev]
665 }
666
667 proc make-tickbox-filter {fil label rows inrow} {
668     set values [filter-values/$fil]
669
670     if {![catch { info args filter-icon/$fil }]} {
671         set label_get { filter-icon/$fil $val }
672         set label_kind image
673     } else {
674         set label_get { filter-map/$fil $val }
675         set label_kind text
676     }
677
678     set fw [make-filter $fil $label frame]
679
680     populate-control-grid-tickboxes $fw $rows $inrow filter_$fil \
681         $values $values \
682         $label_kind val { filter-default/$fil $val } $label_get
683 }
684
685 proc entry-filter-changed {fw fil n1 n2 op} {
686     global errorInfo
687     upvar #0 filter_$fil realvar
688     upvar #0 filterentered_$fil entryvar
689     global def_background
690     debug "entry-filter-changed $fw $fil $entryvar"
691     if {[catch {
692         set error [filter-validate/$fil $entryvar]
693         if {[string length $error]} {
694             $fw.error configure -text $error -foreground white -background red
695         } else {
696             $fw.error configure -text { } -background $def_background
697             set realvar $entryvar
698             redraw-needed
699         }
700     } emsg]} {
701         puts stderr "FILTER CHECK ERROR $emsg $errorInfo"
702     }
703 }
704
705 proc make-entry-filter {fil label def} {
706     global filterentered_$fil
707     upvar #0 filter_$fil realvar
708     set realvar $def
709     set fw [make-filter $fil $label frame]
710     entry $fw.entry -textvariable filterentered_$fil
711     label $fw.error
712     glset def_background [$fw.error cget -background]
713     trace add variable filterentered_$fil write \
714         [list entry-filter-changed $fw $fil]
715     pack $fw.entry $fw.error -side top -anchor w
716 }
717
718 proc make-filter {fil label ekind} {
719     global filters
720     lappend filters $fil
721     return [make-control .filter $fil $label $ekind]
722 }
723
724 proc make-filters {} {
725     make-tickbox-filter size Size 2 0
726     make-tickbox-filter lockown "Lock/\nowner" 2 6
727     make-entry-filter xabbre "Flags\n regexp" {}
728 }
729
730 proc filterstyle-changed {n1 n2 op} {
731     global filterstyle
732     debug "filterstyle-changed $filterstyle"
733     redraw-needed
734 }
735
736 proc filters-say-yes {code} {
737     global filters filterstyle
738     set codel [split $code _]
739     set lockown [lindex $codel 3]
740     switch -exact $filterstyle {
741         0 { return 1 }
742         1 { return [filter-default/lockown $lockown] }
743         2 { return [regexp {^.0} $lockown] }
744         3 { }
745         default { error $filterstyle }
746     }
747     
748     foreach fil $filters {
749         if {![filter-says-yes/$fil $codel]} {
750             debug "FILTERS-SAY-YES $code NO $fil"
751             return 0
752         }
753     }
754     debug "FILTERS-SAY-YES $code YES $filters"
755     return 1
756 }
757     
758 #---------- loading and parsing the clipboard (vessel locations) ----------
759
760 proc vessel {vin} {
761     global pirate notes_used note_missings newnotes
762     upvar 1 $vin vi
763
764     set codel {}
765     lappend codel [errexpect-arrayget-boolean vi inPort]
766
767     set gameclass [errexpect-arrayget vi vesselClass]
768     upvar #0 vc_game2code($gameclass) class
769     if {![info exists class]} {
770         set class "($gameclass)"
771         upvar #0 vc_code2abbrev($class) vcabb
772         set vcabb vc-$class
773         set data [exec pbmtext -builtin fixed " $gameclass " \
774                  | pnminvert | pnmcrop | pbmtoxbm]
775         debug "INVENTED ICON $vcabb $data"
776         image create bitmap icon/$vcabb -data $data
777             
778         global vc_code2full
779         set vc_code2full($class) "Type \"$gameclass\""
780     }
781     lappend codel $class
782
783     set gamesubclass [errexpect-arrayget vi vesselSubclass]
784     upvar #0 vsc_game2code($gamesubclass) subclass
785     if {[info exists subclass]} {
786         lappend codel $subclass
787     } else {
788         lappend codel ($gamesubclass)
789     }
790
791     switch -exact [errexpect-arrayget vi isLocked]/[ \
792                    errexpect-arrayget vi isBattleReady] {
793         true/false      { set lock 2 }
794         false/false     { set lock 1 }
795         false/true      { set lock 0 }
796         default         { errexpect-error "unexpected isLocked/isBattleReady" }
797     }
798
799     set vid [errexpect-arrayget vi vesselId]
800     upvar #0 notes($vid) note
801     set realname [errexpect-arrayget vi vesselName]
802     set island [errexpect-arrayget vi islandName]
803
804     set owner {}
805     set xabbrev {}
806     if {[info exists note]} {
807         manyset $note lno notename owner xabbrev
808         if {[string compare -nocase $realname $notename]} {
809             note-info $lno $vid $realname $island \
810                 "notes say name is $notename"
811         }
812         if {[string length $owner]} {
813             if {![string compare $owner $pirate]} {
814                 set notown 0
815             } else {
816                 set notown 1
817             }
818         } else {
819             set notown 2
820         }
821         append abbrev $xabbrev
822         set notes_used($vid) 1
823
824     } else {
825         set notown 2
826         lappend note_missings [list $island $realname $vid]
827     }
828
829     lappend codel "$lock$notown" $xabbrev
830     lappend newnotes [list $vid $realname $owner $xabbrev]
831     set kk "$island [join $codel _]"
832     upvar #0 found($kk) k
833     lappend k [list $vid $realname $owner]
834  
835     debug "CODED $kk $vid $realname"
836 }
837
838 set clipboard {}
839 proc parse-clipboard {} {
840     global clipboard found notes notes_used newnotes
841
842     catch { unset found }
843     catch { unset notes_used }
844     glset note_infos {}
845     glset note_missings {}
846
847     set newnotes {}
848     
849     set itemre { (\w+) = ([^=]*) }
850     set manyitemre "^\\\[ $itemre ( (?: ,\\ $itemre)* ) \\]\$"
851     debug $manyitemre
852
853     set lno 0
854     foreach l [split $clipboard "\n"] {
855         incr lno
856         errexpect-setline $lno $l
857         if {![string length $l]} continue
858         catch { unset vi }
859         while 1 {
860                 if {![regexp -expanded $manyitemre $l dummy \
861                         thiskey thisval rhs]} {
862                     errexpect-error "badly formatted"
863                 }
864                 set vi($thiskey) $thisval
865                 if {![string length $rhs]} break
866                 regsub {^, } $rhs {} rhs
867                 set l "\[$rhs\]"
868         }
869         vessel vi
870     }
871
872     if {[llength $newnotes]} {
873         foreach vid [lsort [array names notes]] {
874             if {![info exists notes_used($vid)]} {
875                 manyset $notes($vid) lno notename
876                 note-info $lno $vid $notename {} \
877                     "vessel in notes no longer found"
878             }
879         }
880     }
881 }
882
883 proc load-clipboard-file {fn} {
884     set f [open $fn]
885     glset clipboard [read $f]
886     close $f
887 }
888
889
890 #---------- loading and parsing the chart ----------
891
892 proc load-chart {} {
893     global chart scraper
894     debug "FETCHING CHART"
895     set chart [eval exec $scraper [list | perl -we {
896         use strict;
897         use CommodsScrape;
898         use IO::File;
899         use IO::Handle;
900         yppedia_chart_parse(\*STDIN, (new IO::File ">/dev/null"),
901                 sub { sprintf "%d %d", @_; },
902                 sub { printf "archlabel %d %d %s\n", @_; },
903                 sub { printf "island %s {%s} %s\n", @_; },
904                 sub { printf "league %s %s %s.\n", @_; },
905                 sub { printf STDERR "warning: %s: incomprehensible: %s", @_; }
906                         );
907         STDOUT->error and die $!;
908     }]]
909 }
910
911
912 set scale 16
913
914 proc coord {c} {
915         global scale
916         return [expr {$c * $scale}]
917 }
918
919 proc chart-got/archlabel {args} { }
920 proc chart-got/island {x y isle sizecol} {
921         debug "ISLE $x $y $isle $sizecol"
922         global canvas isleloc
923         set isleloc($isle) [list $x $y]
924         set sz 5
925 #       $canvas create oval \
926 #               [expr {[coord $x] - $sz}] [expr {[coord $y] - $sz}] \
927 #               [expr {[coord $x] + $sz}] [expr {[coord $y] + $sz}] \
928 #               -fill blue
929         set colour "#888"
930         if {[string match *_col $sizecol]} { set colour black }
931         $canvas create text [coord $x] [coord $y] \
932                 -text $isle -anchor s -fill $colour
933 }
934 proc chart-got/league {x1 y1 x2 y2 kind} {
935 #       debug "LEAGUE $x1 $y1 $x2 $y2 $kind"
936         global canvas
937         set l [$canvas create line \
938                 [coord $x1] [coord $y1] \
939                 [coord $x2] [coord $y2]]
940         if {![string compare $kind .]} {
941                 $canvas itemconfigure $l -dash .
942         }
943 }
944
945 proc debug-filter-array {array} {
946     upvar #0 $array a
947     set m " FILTER $array"
948     foreach k [lsort [array names a]] {
949         append m " $k=$a($k)"
950     }
951     debug $m
952 }
953
954 proc redraw-needed {args} {
955     global redraw_after
956     debug "REDRAW NEEDED $args"
957     if {[info exists redraw_after]} return
958
959     global filterstyle
960     debug " FILTER style $filterstyle"
961     debug-filter-array filter_size
962     debug-filter-array filter_lockown
963     global filter_xabbre
964     debug " FILTER xabbre $filter_xabbre"
965
966     set redraw_after [after 250 draw]
967 }
968
969 proc draw {} {
970     global chart found isleloc canvas redraw_after islandnames smfound
971
972     catch { after cancel $redraw_after }
973     catch { unset redraw_after }
974     
975     $canvas delete all
976
977     foreach l [split $chart "\n"] {
978 #       debug "CHART-GOT $l"
979         set proc [lindex $l 0]
980         eval chart-got/$proc [lrange $l 1 end]
981     }
982
983     smash-prepare
984
985     catch { unset smfound }
986     foreach key [lsort [array names found]] {
987         regexp {^(.*) (\S+)$} $key dummy islandname code
988
989         if {![filters-say-yes $code]} continue
990
991         set smcode [smash-code $code]
992         debug "smashed $code => $smcode"
993         set smkey "$islandname $smcode"
994         foreach vessel $found($key) { lappend smfound($smkey) $vessel }
995     }
996
997     set islandnames {}
998     set lastislandname {}
999     foreach smkey [lsort [array names smfound]] {
1000         set c [llength $smfound($smkey)]
1001         regexp {^(.*) (\S+)$} $smkey dummy islandname code
1002         debug "SHOWING [list $smkey $c $islandname $code l=$lastislandname]"
1003
1004         if {[string compare $lastislandname $islandname]} {
1005                 manyset $isleloc($islandname) x y
1006                 set x [coord $x]
1007                 set y [coord $y]
1008                 set lastislandname $islandname
1009                 lappend islandnames $islandname
1010 #               debug "START Y $y"
1011         }
1012
1013         if {$c > 1} { set qty [format %d $c] } else { set qty {} }
1014         code2canvas $code $canvas $x y $qty 2 \
1015             [list show-report $islandname $code]
1016 #       debug "NEW Y $y"
1017     }
1018
1019     panner::updatecanvas-bbox .cp.ctrl.pan
1020
1021     islandnames-update
1022 }
1023
1024
1025 #---------- parser error reporting ----------
1026
1027 proc parser-control-create {w base invokebuttontext etl_title} {
1028     frame $w
1029     button $w.do -text $invokebuttontext -command invoke_$base -pady 3
1030
1031     frame $w.resframe -width 120 -height 32
1032     button $w.resframe.res -text {} -anchor nw \
1033         -padx 1 -pady 1 -borderwidth 0 -justify left
1034     glset deffont_$base [$w.resframe.res cget -font]
1035     place $w.resframe.res -relx 0.5 -y 0 -anchor n
1036
1037     pack $w.do -side top
1038     pack $w.resframe -side top -expand y -fill both
1039
1040     set eb .err_$base
1041     toplevel $eb
1042     wm withdraw $eb
1043     wm title $eb "where-vessels - $etl_title"
1044     wm protocol $eb WM_DELETE_WINDOW [list wm withdraw $eb]
1045
1046     label $eb.title -text $etl_title
1047     pack $eb.title -side top
1048
1049     button $eb.close -text Close -command [list wm withdraw $eb]
1050     pack $eb.close -side bottom
1051
1052     frame $eb.emsg -bd 2 -relief groove
1053     label $eb.emsg.lab -anchor nw -text "Error:"
1054     text $eb.emsg.text -height 1
1055     pack $eb.emsg.text -side bottom -fill x
1056     pack $eb.emsg.lab -side left
1057
1058     pack $eb.emsg -side top -pady 2 -fill x
1059
1060     frame $eb.text -bd 2 -relief groove
1061     pack $eb.text -side bottom -pady 2 -fill both -expand y
1062     
1063     label $eb.text.lab -anchor nw
1064
1065     text $eb.text.text -width 85 \
1066         -xscrollcommand [list $eb.text.xscroll set] \
1067         -yscrollcommand [list $eb.text.yscroll set]
1068     $eb.text.text tag configure error \
1069         -background red -foreground white
1070
1071     scrollbar $eb.text.xscroll -orient horizontal \
1072         -command [list $eb.text.text xview]
1073     scrollbar $eb.text.yscroll -orient vertical \
1074         -command [list $eb.text.text yview]
1075
1076     grid configure $eb.text.lab -row 0 -column 0 -sticky w -columnspan 2
1077     grid configure $eb.text.text -row 1 -column 0 -sticky news
1078     grid configure $eb.text.yscroll -sticky ns -row 1 -column 1
1079     grid configure $eb.text.xscroll -sticky ew -row 2 -column 0
1080     grid rowconfigure $eb.text 0 -weight 0
1081     grid rowconfigure $eb.text 1 -weight 1
1082     grid rowconfigure $eb.text 2 -weight 0
1083     grid columnconfigure $eb.text 0 -weight 1
1084     grid columnconfigure $eb.text 1 -weight 0
1085 }
1086
1087 proc parser-control-ok-core {w base background show} {
1088     debug "parser-control-ok-core $w $base $background $show"
1089     upvar #0 deffont_$base deffont
1090     $w.resframe.res configure \
1091         -background $background -disabledforeground black -font $deffont \
1092         -state disabled -command {} \
1093         -text $show
1094 }    
1095 proc parser-control-ok {w base show} {
1096     parser-control-ok-core $w $base green $show
1097 }
1098 proc parser-control-none {w base show} {
1099     parser-control-ok-core $w $base blue $show
1100 }
1101 proc parser-control-failed-core {w base foreground background smallfont
1102                                  tiny summary fulldesc fulldata} {
1103     debug "parser-control-failed-core $w $base $summary $fulldesc"
1104     upvar #0 deffont_$base deffont
1105     set eb .err_$base
1106
1107     $eb.emsg.text delete 0.0 end
1108     $eb.emsg.text insert end $summary
1109
1110     $eb.text.lab configure -text $fulldesc
1111     $eb.text.text delete 0.0 end
1112     $eb.text.text insert end $fulldata
1113
1114     regsub -all {.{18}} $tiny "&\n" ewrap
1115
1116     if {$smallfont} {
1117         set font fixed
1118     } else {
1119         set font $deffont
1120     }
1121
1122     $w.resframe.res configure \
1123         -background $background -foreground $foreground -font $font \
1124         -state normal -command [list wm deiconify $eb] \
1125         -text $ewrap
1126 }
1127     
1128 proc parser-control-failed-expected {w base emsg lno ei fulldesc newdata} {
1129     set eb .err_$base
1130
1131     set line [lindex [split $ei "\n"] 0]
1132     debug "parser-control-failed-expected: $w $base: $lno: $emsg\n $line"
1133
1134     parser-control-failed-core $w $base \
1135         white red 1 \
1136         "err: [string trim $emsg]: \"$line\"" \
1137         "at line $lno: $emsg" \
1138         $fulldesc $newdata
1139
1140     $eb.text.text tag add error $lno.0 $lno.end
1141     $eb.text.text see $lno.0    
1142 }
1143 proc parser-control-failed-unexpected {w base emsg ei} {
1144     global errorInfo
1145     parser-control-failed-core $w $base \
1146         black yellow 1 \
1147         $emsg $emsg "Details and stack trace:" $ei
1148 }
1149
1150 proc reparse {base varname old fulldesc okshow noneshow parse ok} {
1151     upvar #0 $varname var
1152     manyset [errexpect-catch {
1153         uplevel 1 $parse
1154         if {[string length [string trim $var]]} {
1155             parser-control-ok .cp.ctrl.$base $base $okshow
1156         } else {
1157             parser-control-none .cp.ctrl.$base $base $noneshow
1158         }
1159     }] failed emsg lno ei
1160     if {$failed} {
1161         parser-control-failed-expected .cp.ctrl.$base $base \
1162             $emsg $lno $ei $fulldesc $var
1163         set var $old
1164         uplevel 1 $parse
1165     } else {
1166         uplevel 1 $ok
1167     }
1168 }
1169
1170 #---------- island names selection etc. ----------
1171
1172 proc islandnames-update {} {
1173     global islandnames
1174     .islands.count configure -text [format "ships at %d island(s)" \
1175                                         [llength $islandnames]]
1176 }
1177
1178 proc islandnames-select {} {
1179     .islands.clip configure -relief sunken -state disabled
1180     selection own -command islandnames-deselect .islands.clip
1181 }
1182 proc islandnames-deselect {} {
1183     .islands.clip configure -relief raised -state normal
1184 }
1185
1186 proc islandnames-handler {offset maxchars} {
1187     global islandnames
1188     return [string range [join $islandnames ", "] \
1189                 $offset [expr {$offset+$maxchars-1}]]
1190 }
1191
1192 #---------- main user interface ----------
1193
1194 proc widgets-setup {} {
1195     global canvas debug pirate ocean filterstyle
1196
1197     wm geometry . 1200x800
1198     wm title . "where-vessels - $pirate on the $ocean ocean"
1199
1200     #----- map -----
1201
1202     frame .f -border 1 -relief groove
1203     set canvas .f.c
1204     canvas $canvas
1205     pack $canvas -expand 1 -fill both
1206     pack .f -expand 1 -fill both -side left
1207
1208     #----- control panels and filter -----
1209
1210     frame .cp
1211     frame .smash -relief groove -bd 2 -padx 1
1212     frame .filter -relief groove -bd 2 -padx 1
1213     frame .islands -pady 2
1214     pack .cp .filter .islands .smash -side top
1215
1216     label .smash.title -text {Display/combine details}
1217     grid .smash.title -row 0 -column 0 -columnspan 2
1218
1219     set filterstyle 1
1220     trace add variable filterstyle write filterstyle-changed
1221
1222     frame .filter.title
1223     label .filter.title.title -text Show
1224     pack .filter.title.title -side left
1225     for {set fing 0} {$fing < 4} {incr fing} {
1226         radiobutton .filter.title.f$fing \
1227             -variable filterstyle -value $fing \
1228             -text [lindex {All Useable Mine These:} $fing]
1229         pack .filter.title.f$fing -side left
1230     }
1231
1232     grid configure .filter.title -row 0 -column 0 -columnspan 2
1233
1234     #----- control panel -----
1235
1236     frame .cp.ctrl
1237     pack .cp.ctrl -side left -anchor n
1238
1239     debug "BBOX [$canvas bbox all]"
1240
1241     panner::canvas-scroll-bbox .f.c
1242     panner::create .cp.ctrl.pan .f.c 120 120 $debug
1243
1244     pack .cp.ctrl.pan -side top -pady 0 -padx 5
1245     frame .cp.ctrl.zoom
1246     pack .cp.ctrl.zoom -side top
1247
1248     button .cp.ctrl.zoom.out -text - -font {Courier 16} -command {zoom /2} -pady 0
1249     button .cp.ctrl.zoom.in  -text + -font {Courier 16} -command {zoom *2} -pady 0
1250     pack .cp.ctrl.zoom.out .cp.ctrl.zoom.in -side left
1251
1252     parser-control-create .cp.ctrl.acquire \
1253         acquire Acquire \
1254         "Clipboard parsing error" \
1255         
1256     pack .cp.ctrl.acquire -side top -pady 2
1257
1258     parser-control-create .cp.ctrl.notes \
1259         notes "Reload notes" \
1260         "Vessel notes loading report" \
1261         
1262     pack .cp.ctrl.notes -side top -pady 2
1263
1264     #----- island name count and copy -----
1265
1266     label .islands.count
1267     button .islands.clip -text "copy island names" -pady 2 -padx 2 \
1268          -command islandnames-select
1269     selection handle .islands.clip islandnames-handler
1270     pack .islands.count .islands.clip -side left
1271
1272     #----- decoding etc. report -----
1273
1274     frame .cp.report
1275     pack .cp.report -side left -anchor n
1276
1277     label .cp.report.island -text { }
1278
1279     canvas .cp.report.abbrev -width 1 -height 15
1280
1281     frame .cp.report.code
1282     label .cp.report.code.lab -text Code:
1283     glset report_code { }
1284     entry .cp.report.code.code -state readonly \
1285         -textvariable report_code -width 15
1286     pack .cp.report.code.lab .cp.report.code.code -side left
1287     frame .cp.report.details -bd 2 -relief groove -padx 2 -pady 2
1288
1289     listbox .cp.report.list -height 5
1290
1291     pack .cp.report.island .cp.report.abbrev .cp.report.details \
1292         .cp.report.list -side top
1293     #pack .cp.report.code -side top
1294     pack configure .cp.report.details -fill x
1295
1296     foreach sw {inport class subclass lock own xabbrev} {
1297         label .cp.report.details.$sw -text { }
1298         pack .cp.report.details.$sw -side top -anchor w
1299     }
1300 }
1301
1302 proc report-set {sw val} { .cp.report.details.$sw configure -text $val }
1303
1304 proc show-report {islandname code} {
1305     .cp.report.island configure -text $islandname
1306
1307     .cp.report.abbrev delete all
1308     set y 2
1309     code2canvas $code .cp.report.abbrev 5 y {} 0 {}
1310     manyset [.cp.report.abbrev bbox all] minx dummy maxx dummy
1311     .cp.report.abbrev configure -width [expr {$maxx-$minx+4}]
1312
1313     glset report_code $code
1314     show-report-decode $code
1315
1316     set kk "$islandname $code"
1317     upvar #0 smfound($kk) k
1318
1319     .cp.report.list delete 0 end
1320
1321     foreach entry $k {
1322         manyset $entry vid name owner
1323         lappend owned($owner) $name
1324     }
1325
1326     foreach owner [lsort [array names owned]] {
1327         if {[string length $owner]} {
1328             set owndesc "$owner's"
1329         } else {
1330             set owndesc "Owner unknown"
1331         }
1332         .cp.report.list insert end "$owndesc:"
1333         foreach name $owned($owner) {
1334             .cp.report.list insert end " $name"
1335         }
1336     }
1337 }
1338
1339 proc zoom {extail} {
1340     global scale canvas
1341     set nscale [expr "\$scale $extail"]
1342     debug "ZOOM $scale $nscale"
1343     if {$nscale < 1 || $nscale > 200} return
1344     set scale $nscale
1345     draw
1346 }
1347
1348 proc invoke_acquire {} {
1349     global clipboard errorInfo
1350     set old $clipboard
1351
1352     if {[catch {
1353         set clipboard [clipboard get]
1354     } emsg]} {
1355         parser-control-failed-unexpected .cp.ctrl.acquire acquire \
1356             $emsg "fetching clipboard:\n\n$errorInfo"
1357         return
1358     }
1359
1360     reparse acquire \
1361         clipboard $old "Clipboard contents:" { acquired ok } { no vessels } {
1362             parse-clipboard
1363         } {
1364             display-note-infos
1365         }
1366     draw
1367 }
1368
1369 proc invoke_notes {} {
1370     global notes_data errorInfo notes_loc
1371     set old $notes_data
1372     
1373     if {[catch {
1374         load-notes
1375     } emsg]} {
1376         parser-control-failed-unexpected .cp.ctrl.notes notes \
1377             $emsg "loading $notes_loc:\n\n$errorInfo"
1378         return
1379     }
1380
1381     reparse notes \
1382         notes_data $old "Vessel notes:" "loaded ok" { no notes } {
1383             parse-notes
1384             parse-clipboard
1385         } {
1386             display-note-infos
1387         }
1388     draw
1389 }
1390
1391 #---------- main program ----------
1392
1393 parseargs
1394 argdefaults
1395 httpclientsetup where-vessels
1396 info-cache-update
1397 vesselclasses-init
1398 load-chart
1399 widgets-setup
1400 make-filters
1401 make-smashers
1402
1403 set notes_data {}
1404 if {[catch { parse-clipboard } emsg]} {
1405     puts stderr "$emsg\n$errorInfo"
1406     exit 1
1407 }
1408 after idle invoke_notes
1409
1410 draw
1411
1412 if {$debug} {
1413     package require Tclx
1414     commandloop -async \
1415         -prompt1 { return "where-vessels% " } \
1416         -prompt2 { return "> " }
1417 }
1418
1419 # rsync -r --exclude=\*~ yarrg/icons/. ijackson@chiark.greenend.org.uk:/home/ftp/users/ijackson/yarrg/vessel-info/.