chiark / gitweb /
c6ed2536399a8e713efce419bf04e3d052678b68
[ypp-sc-tools.main.git] / yarrg / Commods.pm
1 # This is part of ypp-sc-tools, a set of third-party tools for assisting
2 # players of Yohoho Puzzle Pirates.
3 #
4 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
5 #
6 # This program is free software: you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation, either version 3 of the License, or
9 # (at your option) any later version.
10 #
11 # This program is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
18 #
19 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
20 # are used without permission.  This program is not endorsed or
21 # sponsored by Three Rings.
22
23 package Commods;
24 use IO::File;
25 use IO::Pipe;
26 use HTTP::Request::Common ();
27 use POSIX;
28 use LWP::UserAgent;
29
30 use strict;
31 use warnings;
32
33 BEGIN {
34     use Exporter ();
35     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
36     $VERSION     = 1.00;
37     @ISA         = qw(Exporter);
38     @EXPORT      = qw(&parse_info_clientside &fetch_with_rsync
39                       &parse_info_serverside &parse_info_serverside_ocean
40                       %oceans %commods %clients %commodclasses
41                       %vessels %shotname2damage
42                       &parse_pctb_commodmap %pctb_commodmap @pctb_commodmap
43                       &get_our_version &check_tsv_line
44                       &pipethrough_prep &pipethrough_run
45                       &pipethrough_run_along &pipethrough_run_finish
46                       &pipethrough_run_gzip &http_useragent &version_core
47                       &http_useragent_string_map
48                       &cgipostform &yarrgpostform &cgi_get_caller
49                       &set_ctype_utf8 $masterinfoversion
50                       &source_tarball);
51     %EXPORT_TAGS = ( );
52
53     @EXPORT_OK   = qw();
54 }
55
56 our $masterinfoversion= 2; # version we understand.
57 #
58 # To extend the source-info.txt format:
59 #
60 #    * Commods.pm:parse_info1
61 #       add code to parse new version
62 #
63 #    * source-info.txt
64 #       add new information
65 #
66 # If new data should NOT be in master-info.txt too:
67 #
68 #    * update-master-info:process_some_info
69 #       check that code for converting source-info to master-info
70 #       removes the extra info; add code to remove it if necessary
71 #
72 #    * db-idempotent-populate
73 #       if database schema is extended, add code to copy data
74 #
75 # If new data DOES need to be in master-info.txt too:
76 #
77 #    * Commods.pm:$masterinfoversion
78 #       increment
79 #
80 #    * update-master-info:process_some_info
81 #       add code to convert new version to old, by removing
82 #       extra info conditionally depending on version
83
84 our %oceans; # eg $oceans{'Midnight'}{'Ruby'}{'Eta Island'}= $sources;
85 our %clients; # eg $clients{'ypp-sc-tools'}= [ qw(last-page) ];
86 our %vessels; # eg $vessels{'War Brig'}{Shot}='medium'
87               #    $vessels{'War Brig'}{Volume}= 81000
88               #    $vessels{'War Brig'}{Mass}= 54000
89 our %shotname2damage; # eg $shotname2damage{'medium'}= 3;
90 # $sources = 's[l]b';
91 #       's' = Special Circumstances; 'l' = local ; B = with Bleach
92
93 our %commods;
94 # eg $commods{'Fine black cloth'}{Srcs}= $sources;
95 # eg $commods{'Fine black cloth'}{Mass}= 700 [g]
96 # eg $commods{'Fine black cloth'}{Volume}= 1000 [ml]
97 # eg $commods{'Fine black cloth'}{Ordval}= 203921
98
99 our (%pctb_commodmap,@pctb_commodmap);
100
101 my %colours; # eg $colours{'c'}{'black'}= $sources
102 my (@rawcm, @nocm); # eg $rawcm[0]='fine rum'; $rawcm[1]='fine %c cloth'
103
104 my %colour_ordvals; # $colour_ordvals{'c'}{'green'}= '30';
105 my %commodclasses; # $commodclasses{'dye'}= '3';
106
107 # IMPORTANT
108 #  when extending the format of source-info in a non-backward
109 #  compatible way, be sure to update update-master-info too.
110
111 sub parse_info1 ($$$) {
112     my ($mmfn,$src,$enoentok)= @_;
113     my $mm= new IO::File $mmfn, 'r';
114     if (!$mm) {
115         return if $enoentok && $!==&ENOENT;
116         die "$mmfn $!";
117     }
118     my @ctx= ();
119     while (<$mm>) {
120         next if m/^\s*\#/;
121         next unless m/\S/;
122         s/\s+$//;
123         if (m/^\%(\w+)$/) {
124             my $colourkind= $1;
125             @ctx= (sub {
126                 m/^(\S[^\t@]*\S)(?:\t+\@(\d+\+?))?$/ or die "$_ ?";
127                 my ($colour,$order)=($1,$2);
128                 $colours{$colourkind}{$colour} .= $src;
129                 if (defined $order) {
130                     $order =~ s/^(\d+)\+$/ $1  + $. * 10 /e;
131                     $colour_ordvals{$colourkind}{$colour}= $order;
132                 }
133             });
134         } elsif (m/^commods$/) {
135             @ctx= (sub { push @rawcm, lc $_; });
136         } elsif (m/^nocommods$/) {
137             @ctx= (sub { push @nocm, lc $_; });
138         } elsif (m/^commodclasses$/) {
139             @ctx= (sub {
140                 die unless m/^\*([-a-z]+)$/;
141                 $commodclasses{$1}= scalar keys %commodclasses;
142             });
143         } elsif (m/^ocean (\w+)$/) {
144             my $ocean= $1;
145             keys %{ $oceans{$ocean} };
146             @ctx= (sub {
147                 $ocean or die; # ref to $ocean needed to work
148                                # around a perl bug
149                 my $arch= $_;
150                 keys %{ $oceans{$ocean}{$arch} };
151                 $ctx[1]= sub {
152                     $oceans{$ocean}{$arch}{$_} .= $src;
153                 };
154             });
155         } elsif (m/^vessels$/) {
156             @ctx= (sub {
157                 return if m/^[-+|]+$/;
158                 m/^ \| \s* ([A-Z][a-z\ ]+[a-z]) \s*
159                     \| \s* (small|medium|large) \s*
160                     \| \s* ([1-9][0-9,]+) \s*
161                     \| \s* ([1-9][0-9,]+) \s*
162                     \| $/x
163                     or die;
164                 my $name= $1;
165                 my $v= { Shot => $2, Volume => $3, Mass => $4 };
166                 foreach my $vm (qw(Volume Mass)) { $v->{$vm} =~ s/,//g; }
167                 $vessels{$name}= $v;
168             });
169         } elsif (m/^shot$/) {
170             @ctx= (sub {
171                 m/^ ([a-z]+) \s+ (\d+) $/x or die;
172                 $shotname2damage{$1}= $2;
173             });
174         } elsif (m/^client (\S+.*\S)$/) {
175             my $client= $1;
176             $clients{$client}= [ ];
177             @ctx= (sub {
178                 my $bug= $_;
179                 push @{ $clients{$client} }, $bug;
180             });
181         } elsif (s/^ +//) {
182             my $indent= length $&;
183             die "wrong indent $indent" unless defined $ctx[$indent-1];
184             &{ $ctx[$indent-1] }();
185         } else {
186             die "bad syntax";
187         }
188     }
189     $mm->error and die $!;
190     close $mm or die $!;
191
192 #print Dumper(\%oceans);
193 #print Dumper(\@rawcm);
194         
195     %commods= ();
196     my $ca;
197     my $lnoix=0;
198     $ca= sub {
199         my ($s,$ss,$ordbase) = @_;
200 #print STDERR "ca($s,,".(defined $ordbase ? $ordbase : '?').")\n";
201         if ($s !~ m/\%(\w+)/) {
202             my ($name, $props) = $s =~
203                 /^(\S[^\t]*\S)(?:\t+(\S.*\S))?$/
204                 or die "bad commodspec $s";
205             return if grep { $name eq $_ } @nocm;
206             my $ucname= ucfirst $name;
207             $commods{$ucname}{Srcs} .= $ss;
208             my $c= $commods{$ucname};
209             $c->{Volume}= 1000;
210             my ($ordval, $ordclassval);
211             foreach my $prop (defined $props ? split /\s+/, $props : ()) {
212                 if ($prop =~ m/^([1-9]\d*)(k?)g$/) {
213                     $c->{Mass}= $1 * ($2 ? 1000 : 1);
214                 } elsif ($prop =~ m/^([1-9]\d*)l$/) {
215                     $c->{Volume}= $1 * 1000;
216                 } elsif ($prop =~ m/^\*([-a-z]+)$/) {
217                     $c->{Class}= $1;
218                     die "$1" unless exists $commodclasses{$1};
219                     $ordclassval= 1e7 + $commodclasses{$1} * 1e7;
220                 } elsif ($prop =~ m/^\@(\d+\+?)$/) {
221                     $ordval= $1;
222                     $ordval =~ s/^(\d+)\+$/ $1 + $lnoix * 10 /e;
223                 } else {
224                     die "unknown property $prop for $ucname";
225                 }
226             }
227             if (defined $ordbase && defined $ordval && defined $ordclassval) {
228                 my $ordvalout= $ordbase + $ordval + $ordclassval;
229                 $c->{Ordval}= $ordvalout;
230 #print STDERR "ordval $ordvalout $name OV=$ordval OB=$ordbase OCV=$ordclassval\n";
231             } else {
232 #print STDERR "ordval NONE $name\n";
233             }
234             return;
235         }
236         die "unknown $&" unless defined $colours{$1};
237         my ($lhs,$pctlet,$rhs)= ($`,$1,$');
238         foreach my $c (keys %{ $colours{$pctlet} }) {
239             my $ordcolour= $colour_ordvals{$pctlet}{$c};
240             &$ca($lhs.$c.$rhs,
241                  $ss .'%'. $colours{$pctlet}{$c},
242                  defined($ordbase) && defined($ordcolour)
243                      ? $ordbase+$ordcolour : undef);
244         }
245     };
246     foreach (@rawcm) { $lnoix++; &$ca($_,$src,0); }
247 }
248
249 sub parse_info_clientside () {
250     my $master= fetch_with_rsync("info-v$masterinfoversion");
251     parse_info1($master,'s',1);
252     parse_info1('_local-info.txt','s',1);
253 }
254
255 sub fetch_with_rsync ($) {
256     my ($stem) = @_;
257
258     my $rsync= $ENV{'YPPSC_YARRG_RSYNC'};
259     $rsync= 'rsync' if !defined $rsync;
260
261     my $local= "_master-$stem.txt";
262     my $src= $ENV{'YPPSC_YARRG_DICT_UPDATE'};
263     if ($src) {
264         my $remote= "$src/master-$stem.txt";
265         $!=0; system 'rsync','-Lt','--',$remote,$local;
266         die "$? $!" if $! or $?;
267     }
268     return $local;
269 }
270
271 sub parse_info_serverside () {
272     parse_info1('source-info.txt','s',0);
273     parse_info1('tree-info.txt','t',1);
274 }
275 sub parse_info_serverside_ocean ($) {
276     my ($oceanname) = @_;
277     die "unknown ocean $oceanname ?" unless exists $oceans{$oceanname};
278     parse_info1("_ocean-".(lc $oceanname).".txt", 's',0);
279 }
280
281 sub parse_pctb_commodmap () {
282     undef %pctb_commodmap;
283     foreach my $commod (keys %commods) { $commods{$commod}{Srcs} =~ s/b//; }
284
285     my $c= new IO::File '_commodmap.tsv';
286     if (!$c) { $!==&ENOENT or die $!; return 0; }
287
288     while (<$c>) {
289         m/^(\S.*\S)\t(\d+)\n$/ or die "$_";
290         die if defined $pctb_commodmap{$1};  $pctb_commodmap{$1}= $2;
291         die if defined $pctb_commodmap[$2];  $pctb_commodmap[$2]= $1;
292         $commods{$1}{Srcs} .= 'b';
293     }
294     $c->error and die $!;
295     close $c or die $!;
296     return 1;
297 }
298
299 sub get_our_version ($$) {
300     my ($aref,$prefix) = @_;
301     $aref->{"${prefix}name"}= 'ypp-sc-tools yarrg';
302     $aref->{"${prefix}fixes"}= 'lastpage checkpager';
303     $aref->{"${prefix}version"}= version_core();
304     return $aref;
305     # clientname        "ypp-sc-tools"
306     # clientversion     2.1-g2e06a26  [from git-describe --tags HEAD]
307     # clientfixes       "lastpage"  [space separated list]
308 }
309
310 sub version_core () {
311     my $version= `
312         if type -p git-describe >/dev/null 2>&1; then
313                 gd=git-describe
314         else
315                 gd="git describe"
316         fi
317         \$gd --tags HEAD || echo 0unknown
318     `; $? and die $?;
319     chomp($version);
320     return $version;
321 }
322
323 sub pipethrough_prep () {
324     my $tf= IO::File::new_tmpfile() or die $!;
325     return $tf;
326 }
327
328 sub pipethrough_run_along ($$$@) {
329     my ($tf, $childprep, $cmd, @a) = @_;
330     $tf->error and die $!;
331     $tf->flush or die $!;
332     $tf->seek(0,0) or die $!;
333     my $fh= new IO::File;
334     my $child= $fh->open("-|"); defined $child or die $!;
335     if (!$child) {
336         open STDIN, "<&", $tf;
337         &$childprep() if defined $childprep;
338         exec $cmd @a; die "@a $!";
339     }
340     return $fh;
341 }
342 sub pipethrough_run_finish ($$) {
343     my ($fh, $what)= @_;
344     $fh->error and die $!;
345     close $fh or die "$what $! $?";  die $? if $?;
346 }
347
348 sub pipethrough_run ($$$@) {
349     my ($tf, $childprep, $cmd, @a) = @_;
350     my $pt= pipethrough_run_along($tf,$childprep,$cmd,@a);
351     my $r;
352     { undef $/; $!=0; $r= <$pt>; }
353     defined $r or die $!;
354     pipethrough_run_finish($pt, "@a");
355     return $r;
356 }
357 sub pipethrough_run_gzip ($) {
358     pipethrough_run($_[0],undef,'gzip','gzip');
359 }
360
361 sub yarrgpostform ($$) {
362     my ($ua, $form) = @_;
363     my $dest= $ENV{'YPPSC_YARRG_YARRG'};
364     get_our_version($form, 'client');
365     die unless $dest =~ m,/$,;
366     return cgipostform($ua, "${dest}commod-update-receiver", $form);
367 }    
368
369 sub cgipostform ($$$) {
370     my ($ua, $url, $form) = @_;
371     my $req= HTTP::Request::Common::POST($url,
372                                          Content => $form,
373                                          Content_Type => 'form-data');
374     if ($url =~ m,^\.?/,) {
375         my $tf= pipethrough_prep();
376         print $tf $req->content() or die $!;
377 #print STDERR "[[[",$req->content(),"]]]";
378         my $out= pipethrough_run($tf, sub {
379             $ENV{'REQUEST_METHOD'}= 'POST';
380             $ENV{'QUERY_STRING'}= '';
381             $ENV{'PATH_TRANSLATED'}= $url;
382             $ENV{'PATH_INFO'}= '';
383             $ENV{'HTTP_HOST'}= 'localhost';
384             $ENV{'REMOTE_ADDR'}= '127.0.0.1';
385             $ENV{'GATEWAY_INTERFACE'}= 'CGI/1.1';
386             $ENV{'DOCUMENT_ROOT'}= '.';
387             $ENV{'SCRIPT_FILENAME'}= $url;
388             $ENV{'SCRIPT_NAME'}= $url;
389             $ENV{'HTTP_USER_AGENT'}= 'Commods.pm local test';
390
391             foreach my $f (qw(Content_Length Content_Type)) {
392                 $ENV{uc $f}= $req->header($f);
393             }
394 #system 'printenv >&2';
395         }, "$url", "$url");
396         $out =~ s/\r\n/\n/g;
397         $out =~ m,^Content-Type: text/plain.*\n\n, or die "$out ?";
398         return $';
399     } else {
400         my $resp= $ua->request($req);
401         die $resp->status_line."\n".$resp->content."\n "
402             unless $resp->is_success;
403         return $resp->content();
404     }
405 }
406
407 our %check_tsv_done;
408
409 sub check_tsv_line ($$) {
410     my ($l, $bad_data_callback) = @_;
411     my $bad_data= sub { &$bad_data_callback("bad data: line $.: $_[0]"); };
412     
413     chomp($l) or &$bad_data('missing end-of-line');
414
415     $l !~ m/\P{IsPrint}/ or &$bad_data('nonprinting char(s)');
416     my @v= split /\t/, $l, -1;
417     @v==6 or &$bad_data('wrong number of fields');
418     my ($commod,$stall) = @v;
419
420     !keys %commods or
421         defined $commods{$commod} or
422         &$bad_data("unknown commodity \`$commod'");
423     
424     $stall =~ m/^\p{IsUpper}|^[0-9]/ or &$bad_data("stall not capitalised");
425     !exists $check_tsv_done{$commod,$stall} or &$bad_data("repeated data");
426     $check_tsv_done{$commod,$stall}= 1;
427     foreach my $i (2..5) {
428         my $f= $v[$i];
429         $f =~ m/^(|0|[1-9][0-9]{0,5}|\>1000)$/ or &$bad_data("bad field $i");
430         ($i % 2) or ($f !~ m/\>/) or &$bad_data("> in field $i price");
431     }
432
433     foreach my $i (2,4) {
434         &$bad_data("price with no qty or vice versa (field $i)")
435             if length($v[$i]) xor length($v[$i+1]);
436     }
437     length($v[2]) or length($v[4]) or
438         &$bad_data("commodity entry with no buy or sell offer");
439     
440     return @v;
441 }
442
443 sub cgi_get_caller () {
444     my $caller= $ENV{'REMOTE_ADDR'};
445     $caller= 'LOCAL' unless defined $caller;
446
447     my $fwdf= $ENV{'HTTP_X_FORWARDED_FOR'};
448     if (defined $fwdf) {
449         $fwdf =~ s/\s//g;
450         $fwdf =~ s/[^0-9.,]/?/g;
451         $caller= "$fwdf";
452     }
453     return $caller;
454 }
455
456 sub set_ctype_utf8 () {
457     setlocale(LC_CTYPE, "en.UTF-8");
458 }
459
460 sub http_useragent_string_map ($$) {
461     my ($caller_lib_agent, $reason_style_or_caller) = @_;
462     $caller_lib_agent =~ y/A-Za-z/N-ZA-Mn-za-m/;
463     $caller_lib_agent =~ s/\s/_/g;
464     my $version= version_core();
465     return "yarrg/$version ($reason_style_or_caller)".
466            " $caller_lib_agent".
467            " (http://yarrg.chiark.net/intro)";
468 }
469
470 sub http_useragent ($) {
471     my ($who) = @_;
472     my $ua= LWP::UserAgent->new;
473     my $base= $ua->_agent();
474     $ua->agent(http_useragent_string_map($base, $who));
475     return $ua;
476 }
477
478 sub source_tarball ($$) {
479     my ($sourcebasedir,$spitoutfn) = @_;
480
481     my $pipe= new IO::Pipe or die $!;
482     my $pid= fork();  defined $pid or die $!;
483     if (!$pid) {
484         $ENV{'YPPSC_YARRG_SRCBASE'}= $sourcebasedir;
485         $pipe->writer();
486         exec '/bin/sh','-c','
487                 cd -P "$YPPSC_YARRG_SRCBASE"
488                 (
489                  git-ls-files -z;
490                  git-ls-files -z --others --exclude-from=.gitignore;
491                  if test -d .git; then find .git -print0; fi
492                 ) | (
493                  cpio -Hustar -o --quiet -0 -R 1000:1000 || \
494                  cpio -Hustar -o --quiet -0
495                 ) | gzip
496         ';
497         die $!;
498     }
499     $pipe->reader();
500
501     my ($d, $l);
502     while ($l= read $pipe, $d, 65536) {
503         $spitoutfn->($d);
504     }
505     waitpid $pid,0;
506     defined $l or die "read pipe $!";
507     $pipe->error and die "pipe error $!";
508     close $pipe;
509     # deliberately ignore errors
510 }
511
512 1;