yarrg/Commods.pm

   1 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   2 # players of Yohoho Puzzle Pirates.
   3 #
   4 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  20 # are used without permission.  This program is not endorsed or
  21 # sponsored by Three Rings.
  22
  23 package Commods;
  24 use IO::File;
  25 use HTTP::Request::Common ();
  26 use POSIX;
  27
  28 use strict;
  29 use warnings;
  30
  31 BEGIN {
  32     use Exporter ();
  33     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  34     $VERSION     = 1.00;
  35     @ISA         = qw(Exporter);
  36     @EXPORT      = qw(&parse_info_clientside &fetch_with_rsync
  37                       &parse_info_serverside &parse_info_serverside_ocean
  38                       %oceans %commods %clients %routes %route_mysteries
  39                       &parse_pctb_commodmap %pctb_commodmap @pctb_commodmap
  40                       &get_our_version &check_tsv_line
  41                       &pipethrough_prep &pipethrough_run
  42                       &pipethrough_run_along &pipethrough_run_finish
  43                       &pipethrough_run_gzip
  44                       &cgipostform &yarrgpostform &cgi_get_caller
  45                       &set_ctype_utf8);
  46     %EXPORT_TAGS = ( );
  47
  48     @EXPORT_OK   = qw();
  49 }
  50
  51 our %oceans; # eg $oceans{'Midnight'}{'Ruby'}{'Eta Island'}= $sources;
  52 our %clients; # eg $clients{'ypp-sc-tools'}= [ qw(last-page) ];
  53 our %routes; # eg $routes{'Midnight'}{'Orca'}{'Tinga'}= $sources  NB abbrevs!
  54 our %route_mysteries; # eg $route_mysteries{'Midnight'}{'Norse'}= 3
  55 # $sources = 's[l]b';
  56 #       's' = Special Circumstances; 'l' = local ; B = with Bleach
  57
  58 our %commods;
  59 # eg $commods{'Fine black cloth'}{Srcs}= $sources;
  60 # eg $commods{'Fine black cloth'}{Mass}= 700 [g]
  61 # eg $commods{'Fine black cloth'}{Volume}= 1000 [ml]
  62
  63 our (%pctb_commodmap,@pctb_commodmap);
  64
  65 my %colours; # eg $colours{'c'}{'black'}= $sources
  66 my @rawcm; # eg $rawcm[0]='fine rum'; $rawcm[1]='fine %c cloth'
  67
  68 sub parse_info1 ($$) {
  69     my ($mmfn,$src)= @_;
  70     my $mm= new IO::File $mmfn, 'r' or die "$mmfn $!";
  71     my @ctx= ();
  72     while (<$mm>) {
  73         next if m/^\s*\#/;
  74         next unless m/\S/;
  75         s/\s+$//;
  76         if (m/^\%(\w+)$/) {
  77             my $colourkind= $1;
  78             @ctx= (sub { $colours{$colourkind}{lc $_} .= $src; });
  79         } elsif (m/^commods$/) {
  80             @ctx= (sub { push @rawcm, lc $_; });
  81         } elsif (m/^ocean (\w+)$/) {
  82             my $ocean= $1;
  83             @ctx= (sub {
  84                 $ocean or die; # ref to $ocean needed to work
  85                                # around a perl bug
  86                 my $arch= $_;
  87                 $ctx[1]= sub {
  88                     $oceans{$ocean}{$arch}{$_} .= $src;
  89                 };
  90             });
  91         } elsif (m/^routes (\w+)$/) {
  92             my $ocean= $1;
  93             @ctx= (sub {
  94                 m/^(\S[^\t]*\S),\s*(\S[^\t]*\S),\s*([1-9][0-9]{0,2})$/ or die;
  95                 $routes{$ocean}{$1}{$2}= $3;
  96             });
  97         } elsif (m/^client (\S+.*\S)$/) {
  98             my $client= $1;
  99             $clients{$client}= [ ];
 100             @ctx= (sub {
 101                 my $bug= $_;
 102                 push @{ $clients{$client} }, $bug;
 103             });
 104         } elsif (s/^ +//) {
 105             my $indent= length $&;
 106             die "wrong indent $indent" unless defined $ctx[$indent-1];
 107             &{ $ctx[$indent-1] }();
 108         } else {
 109             die "bad syntax";
 110         }
 111     }
 112     $mm->error and die $!;
 113     close $mm or die $!;
 114
 115 #print Dumper(\%oceans);
 116 #print Dumper(\@rawcm);
 117
 118     %commods= ();
 119     my $ca;
 120     $ca= sub {
 121         my ($s,$ss) = @_;
 122 #print "ca($s)\n";
 123         if ($s !~ m/\%(\w+)/) {
 124             my ($name, $props) = $s =~
 125                 /^(\S[^\t]*\S)\t+(\S[^\t]*\S)$/
 126                 or die "bad commodspec $s";
 127             my $ucname= ucfirst $name;
 128             $commods{$ucname}{Srcs} .= $ss;
 129             my $c= $commods{$ucname};
 130             $c->{Volume}= 1000;
 131             foreach my $prop (split /\s+/, $props) {
 132                 if ($prop =~ m/^([1-9]\d*)(k?)g$/) {
 133                     $c->{Mass}= $1 * ($2 ? 1000 : 1);
 134                 } elsif ($prop =~m/^([1-9]\d*)l$/) {
 135                     $c->{Volume}= $1 * 1000;
 136                 } else {
 137                     die "unknown property $prop for $ucname";
 138                 }
 139             }
 140             die "no mass for $ucname" unless defined $c->{Mass};
 141             return;
 142         }
 143         die "unknown $&" unless defined $colours{$1};
 144         my ($lhs,$pctlet,$rhs)= ($`,$1,$');
 145         foreach my $c (keys %{ $colours{$pctlet} }) {
 146             &$ca($lhs.$c.$rhs, $ss .'%'. $colours{$pctlet}{$c});
 147         }
 148     };
 149     foreach (@rawcm) { &$ca($_,$src); }
 150
 151     foreach my $on (keys %routes) {
 152         my $routes= $routes{$on};
 153         my $ocean= $oceans{$on};
 154         die unless defined $ocean;
 155
 156         my @allislands;
 157         foreach my $an (sort keys %$ocean) {
 158             my $arch= $ocean->{$an};
 159             push @allislands, sort keys %$arch;
 160         }
 161         parse_info_maproutes($on, \@allislands, $routes);
 162         foreach my $route (values %$routes) {
 163             parse_info_maproutes($on, \@allislands, $route);
 164         }
 165     }
 166 }
 167
 168 sub parse_info_clientside () {
 169     my $yarrg= $ENV{'YPPSC_YARRG_DICT_UPDATE'};
 170     return unless $yarrg;
 171     my $master= fetch_with_rsync('info');
 172     parse_info1($master,'s');
 173     my $local= '_local-info.txt';
 174     if (stat $local) {
 175         parse_info1($local,'s');
 176     } else {
 177         die "$local $!" unless $! == &ENOENT;
 178     }
 179 }
 180
 181 sub fetch_with_rsync ($) {
 182     my ($stem) = @_;
 183
 184     my $rsync= $ENV{'YPPSC_YARRG_RSYNC'};
 185     $rsync= 'rsync' if !defined $rsync;
 186
 187     my $local= "_master-$stem.txt";
 188     my $src= $ENV{'YPPSC_YARRG_DICT_UPDATE'};
 189     if ($src) {
 190         my $remote= "$src/master-$stem.txt";
 191         $!=0; system 'rsync','-Lt','--',$remote,$local;
 192         die "$? $!" if $! or $?;
 193     }
 194     return $local;
 195 }
 196
 197 sub parse_info_maproutes ($$$) {
 198     my ($on, $allislands, $routemap) = @_;;
 199     foreach my $k (sort keys %$routemap) {
 200         my @ok= grep { index($_,$k) >= 0 } @$allislands;
 201         die "ambiguous $k" if @ok>1;
 202         if (!@ok) {
 203             $route_mysteries{$on}{$k}++;
 204             delete $routemap->{$k};
 205         } elsif ($ok[0] ne $k) {
 206             $routemap->{$ok[0]}= $routemap->{$k};
 207             delete $routemap->{$k};
 208         }
 209     }
 210 }
 211
 212 sub parse_info_serverside () {
 213     parse_info1('master-info.txt','s');
 214 }
 215 sub parse_info_serverside_ocean ($) {
 216     my ($oceanname) = @_;
 217     die "unknown ocean $oceanname ?" unless exists $oceans{$oceanname};
 218     parse_info1("ocean-".(lc $oceanname).".txt",'s');
 219 }
 220
 221 sub parse_pctb_commodmap () {
 222     undef %pctb_commodmap;
 223     foreach my $commod (keys %commods) { $commods{$commod}{Srcs} =~ s/b//; }
 224
 225     my $c= new IO::File '_commodmap.tsv';
 226     if (!$c) { $!==&ENOENT or die $!; return 0; }
 227
 228     while (<$c>) {
 229         m/^(\S.*\S)\t(\d+)\n$/ or die "$_";
 230         die if defined $pctb_commodmap{$1};  $pctb_commodmap{$1}= $2;
 231         die if defined $pctb_commodmap[$2];  $pctb_commodmap[$2]= $1;
 232         $commods{$1}{Srcs} .= 'b';
 233     }
 234     $c->error and die $!;
 235     close $c or die $!;
 236     return 1;
 237 }
 238
 239 sub get_our_version ($$) {
 240     my ($aref,$prefix) = @_;
 241     $aref->{"${prefix}name"}= 'ypp-sc-tools yarrg';
 242     $aref->{"${prefix}fixes"}= 'lastpage';
 243
 244     my $version= `git-describe --tags HEAD || echo 0unknown`; $? and die $?;
 245     chomp($version);
 246     $aref->{"${prefix}version"}= $version;
 247     return $aref;
 248     # clientname        "ypp-sc-tools"
 249     # clientversion     2.1-g2e06a26  [from git-describe --tags HEAD]
 250     # clientfixes       "lastpage"  [space separated list]
 251 }
 252
 253 sub pipethrough_prep () {
 254     my $tf= IO::File::new_tmpfile() or die $!;
 255     return $tf;
 256 }
 257
 258 sub pipethrough_run_along ($$$@) {
 259     my ($tf, $childprep, $cmd, @a) = @_;
 260     $tf->error and die $!;
 261     $tf->flush or die $!;
 262     $tf->seek(0,0) or die $!;
 263     my $fh= new IO::File;
 264     my $child= $fh->open("-|"); defined $child or die $!;
 265     if (!$child) {
 266         open STDIN, "<&", $tf;
 267         &$childprep() if defined $childprep;
 268         exec $cmd @a; die "@a $!";
 269     }
 270     return $fh;
 271 }
 272 sub pipethrough_run_finish ($$) {
 273     my ($fh, $what)= @_;
 274     $fh->error and die $!;
 275     close $fh or die "$what $! $?";  die $? if $?;
 276 }
 277
 278 sub pipethrough_run ($$$@) {
 279     my ($tf, $childprep, $cmd, @a) = @_;
 280     my $pt= pipethrough_run_along($tf,$childprep,$cmd,@a);
 281     my $r;
 282     { undef $/; $!=0; $r= <$pt>; }
 283     defined $r or die $!;
 284     pipethrough_run_finish($pt, "@a");
 285     return $r;
 286 }
 287 sub pipethrough_run_gzip ($) {
 288     pipethrough_run($_[0],undef,'gzip','gzip');
 289 }
 290
 291 sub yarrgpostform ($$) {
 292     my ($ua, $form) = @_;
 293     my $dest= $ENV{'YPPSC_YARRG_YARRG'};
 294     get_our_version($form, 'client');
 295     die unless $dest =~ m,/$,;
 296     return cgipostform($ua, "${dest}commod-update-receiver", $form);
 297 }
 298
 299 sub cgipostform ($$$) {
 300     my ($ua, $url, $form) = @_;
 301     my $req= HTTP::Request::Common::POST($url,
 302                                          Content => $form,
 303                                          Content_Type => 'form-data');
 304     if ($url =~ m,^\.?/,) {
 305         my $tf= pipethrough_prep();
 306         print $tf $req->content() or die $!;
 307 #print STDERR "[[[",$req->content(),"]]]";
 308         my $out= pipethrough_run($tf, sub {
 309             $ENV{'REQUEST_METHOD'}= 'POST';
 310             $ENV{'QUERY_STRING'}= '';
 311             $ENV{'PATH_TRANSLATED'}= $url;
 312             $ENV{'PATH_INFO'}= '';
 313             $ENV{'HTTP_HOST'}= 'localhost';
 314             $ENV{'REMOTE_ADDR'}= '127.0.0.1';
 315             $ENV{'GATEWAY_INTERFACE'}= 'CGI/1.1';
 316             $ENV{'DOCUMENT_ROOT'}= '.';
 317             $ENV{'SCRIPT_FILENAME'}= $url;
 318             $ENV{'SCRIPT_NAME'}= $url;
 319             $ENV{'HTTP_USER_AGENT'}= 'Commods.pm local test';
 320
 321             foreach my $f (qw(Content_Length Content_Type)) {
 322                 $ENV{uc $f}= $req->header($f);
 323             }
 324 #system 'printenv >&2';
 325         }, "$url", "$url");
 326         $out =~ s/\r\n/\n/g;
 327         $out =~ m,^Content-Type: text/plain.*\n\n, or die "$out ?";
 328         return $';
 329     } else {
 330         my $resp= $ua->request($req);
 331         die $resp->status_line."\n".$resp->content."\n "
 332             unless $resp->is_success;
 333         return $resp->content();
 334     }
 335 }
 336
 337 our %check_tsv_done;
 338
 339 sub check_tsv_line ($$) {
 340     my ($l, $bad_data_callback) = @_;
 341     my $bad_data= sub { &$bad_data_callback("bad data: line $.: $_[0]"); };
 342
 343     chomp($l) or &$bad_data('missing end-of-line');
 344
 345     $l !~ m/\P{IsPrint}/ or &$bad_data('nonprinting char(s)');
 346     my @v= split /\t/, $l, -1;
 347     @v==6 or &$bad_data('wrong number of fields');
 348     my ($commod,$stall) = @v;
 349
 350     !keys %commods or
 351         defined $commods{$commod} or
 352         &$bad_data("unknown commodity \`$commod'");
 353
 354     $stall =~ m/^\p{IsUpper}|^[0-9]/ or &$bad_data("stall not capitalised");
 355     !exists $check_tsv_done{$commod,$stall} or &$bad_data("repeated data");
 356     $check_tsv_done{$commod,$stall}= 1;
 357     foreach my $i (2..5) {
 358         my $f= $v[$i];
 359         $f =~ m/^(|0|[1-9][0-9]{0,5}|\>1000)$/ or &$bad_data("bad field $i");
 360         ($i % 2) or ($f !~ m/\>/) or &$bad_data("> in field $i price");
 361     }
 362
 363     foreach my $i (2,4) {
 364         &$bad_data("price with no qty or vice versa (field $i)")
 365             if length($v[$i]) xor length($v[$i+1]);
 366     }
 367     length($v[2]) or length($v[4]) or
 368         &$bad_data("commodity entry with no buy or sell offer");
 369
 370     return @v;
 371 }
 372
 373 sub cgi_get_caller () {
 374     my $caller= $ENV{'REMOTE_ADDR'};
 375     $caller= 'LOCAL' unless defined $caller;
 376
 377     my $fwdf= $ENV{'HTTP_X_FORWARDED_FOR'};
 378     if (defined $fwdf) {
 379         $fwdf =~ s/\s//g;
 380         $fwdf =~ s/[^0-9.,]/?/g;
 381         $caller= "$fwdf";
 382     }
 383     return $caller;
 384 }
 385
 386 sub set_ctype_utf8 () {
 387     setlocale(LC_CTYPE, "en.UTF-8");
 388 }
 389
 390 1;