yarrg/where-vessels

   1 #!/usr/bin/wish
   2 # show your vessels on a map
   3
   4 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   5 # players of Yohoho Puzzle Pirates.
   6 #
   7 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   8 #
   9 # This program is free software: you can redistribute it and/or modify
  10 # it under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation, either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  23 # are used without permission.  This program is not endorsed or
  24 # sponsored by Three Rings.
  25
  26
  27
  28 source yarrglib.tcl
  29 source panner.tcl
  30 package require http
  31
  32 #---------- general utilities ----------
  33
  34 set debug 0
  35 proc debug {m} {
  36     global debug
  37     if {$debug} { puts "DEBUG $m" }
  38 }
  39
  40 proc badusage {m} {
  41     puts stderr "where-vessels: bad usage: $m"
  42     exit 1
  43 }
  44
  45 proc glset {n val} {
  46     upvar #0 $n var
  47     set var $val
  48 }
  49
  50 #---------- expecting certain errors ----------
  51
  52 proc errexpect-setline {lno line} {
  53     glset errexpect_lno $lno
  54     glset errexpect_line $line
  55 }
  56
  57 proc errexpect-error {m} {
  58     global errexpect_line errexpect_lno
  59     error $m "$errexpect_line\n" [list YARRG-ERREXPECT $errexpect_lno]
  60 }
  61
  62 proc errexpect-arrayget {arrayvar key} {
  63     upvar 1 $arrayvar av
  64     upvar 1 ${arrayvar}($key) v
  65     if {[info exists v]} { return $v }
  66     errexpect-error "undefined $key"
  67 }
  68
  69 proc errexpect-arrayget-boolean {arrayvar key} {
  70     switch -exact [uplevel 1 [list errexpect-arrayget $arrayvar $key]] {
  71         true    { return 1 }
  72         false   { return 0 }
  73         default { errexpect-error "unexpected $key" }
  74     }
  75 }
  76
  77 proc errexpect-catch {code} {
  78     global errorInfo errorCode
  79     set rc [catch {
  80         uplevel 1 $code
  81     } rv]
  82     debug "ERREXPECT CATCH |$rc|$rv|$errorCode|$errorInfo|"
  83     if {$rc==1 && ![string compare YARRG-ERREXPECT [lindex $errorCode 0]]} {
  84         return [list 1 $rv [lindex $errorCode 1] $errorInfo]
  85     } elseif {$rc==0} {
  86         return [list 0 $rv]
  87     } else {
  88         return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rv
  89     }
  90 }
  91
  92 #---------- argument parsing ----------
  93
  94 proc nextarg {} {
  95     global ai argv
  96     if {$ai >= [llength $argv]} {
  97         badusage "option [lindex $argv [expr {$ai-1}]] needs a value"
  98     }
  99     set v [lindex $argv $ai]
 100     incr ai
 101     return $v
 102 }
 103
 104 set notes_loc vessel-notes
 105 set scraper {./yppedia-ocean-scraper --chart}
 106
 107 proc parseargs {} {
 108     global ai argv
 109     global debug scraper
 110     set ai 0
 111
 112     while {[regexp {^\-} [set arg [lindex $argv $ai]]]} {
 113         incr ai
 114         switch -exact -- $arg {
 115             -- { break }
 116             --pirate { glset pirate [string totitle [nextarg]] }
 117             --ocean { glset ocean [string totitle [nextarg]] }
 118             --clipboard-file { load-clipboard-file [nextarg] }
 119             --local-html-dir { lappend scraper --local-html-dir=[nextarg] }
 120             --notes { glset notes_loc [nextarg] }
 121             --debug { incr debug }
 122             default { badusage "unknown option $arg" }
 123         }
 124     }
 125     set argv [lrange $argv $ai end]
 126     if {[llength $argv]} { badusage "non-option args not allowed" }
 127 }
 128
 129 proc argdefaults {} {
 130     global ocean notes_loc pirate scraper
 131     if {![info exists ocean] || ![info exists pirate]} {
 132         set cmd {./yarrg --find-window-only --quiet}
 133         if {[info exists ocean]} { lappend cmd --ocean $ocean }
 134         if {[info exists pirate]} { lappend cmd --pirate $pirate }
 135         manyset [split [eval exec $cmd] " "] ocean pirate
 136         if {![llength $ocean] || ![llength $pirate]} {
 137             error "$ocean $pirate ?"
 138         }
 139     }
 140     lappend scraper $ocean
 141 }
 142
 143
 144 #---------- loading and parsing the vessel notes ----------
 145
 146 proc load-notes {} {
 147     global notes_loc notes_data
 148     if {[regexp {^\w+\:} $notes_loc]} {
 149         update
 150         debug "FETCHING NOTES $notes_loc"
 151         set req [::http::geturl $notes_loc]
 152         switch -glob [::http::status $req].[::http::ncode $req] {
 153             ok.200 { }
 154             ok.* { error "retrieving vessel-notes: [::http::code $req]" }
 155             * { error "Retrieving vessel-notes: [::http::error $req]" }
 156         }
 157         set newdata [::http::data $req]
 158         ::http::cleanup $req
 159     } else {
 160         debug "READING NOTES $notes_loc"
 161         set vn [open $notes_loc]
 162         set newdata [read $vn]
 163         close $vn
 164     }
 165     set notes_data $newdata
 166 }
 167
 168 proc parse-notes {} {
 169     global notes_data notes
 170     catch { unset notes }
 171
 172     set lno 0
 173     foreach l [split $notes_data "\n"] {
 174         incr lno
 175         errexpect-setline $lno $l
 176         set l [string trim $l]
 177         if {![string length $l]} continue
 178         if {[regexp {^\#} $l]} continue
 179         if {![regexp -expanded \
 180                   {^ (\d+) (?: \s+([^=]*?) )? \s* =
 181                       (?: \s* (\S+)
 182                        (?: \s+ (\S+) )?)? $} \
 183                   $l dummy vid vname owner note]} {
 184               errexpect-error "badly formatted"
 185         }
 186         set vname [string trim $vname]
 187         if {[info exists notes($vid)]} {
 188             errexpect-error "duplicate vesselid $vid"
 189         }
 190         set notes($vid) [list $lno $vname $owner $note]
 191     }
 192 }
 193
 194 proc note-info {lno vid name island description} {
 195     global note_infos
 196     lappend note_infos [list $lno $vid $name $island $description]
 197 }
 198
 199 proc display-note-infos {} {
 200     global note_infos note_missings notes
 201
 202     set nmissing [llength $note_missings]
 203     debug "display-note-infos $nmissing [array size notes]"
 204
 205     if {[llength $note_infos]} {
 206         set tiny "[llength $note_infos] warning(s)"
 207     } elseif {$nmissing && [array size notes]} {
 208         set tiny "$nmissing missing"
 209     } else {
 210         return
 211     }
 212
 213     set infodata {}
 214
 215     foreach info $note_infos {
 216         manyset $info lno vid name island description
 217         append infodata "vessel"
 218         append infodata " $vid"
 219         if {[string length $name]} { append infodata " $name" }
 220         if {[string length $island]} { append infodata " ($island)" }
 221         append infodata ": " $description "\n"
 222     }
 223
 224     if {$nmissing} {
 225         if {[string length $infodata]} { append infodata "\n" }
 226         append infodata "$nmissing vessel(s) not mentioned in notes:\n"
 227         set last_island {}
 228         foreach info [lsort $note_missings] {
 229             manyset $info island name vid
 230             if {[string compare $island $last_island]} {
 231                 append infodata "# $island:\n"
 232                 set last_island $island
 233             }
 234             append infodata [format "%-9d %-29s =\n" $vid $name]
 235         }
 236     }
 237
 238     parser-control-failed-core .cp.ctrl.notes notes \
 239         white blue 0 \
 240         $tiny \
 241         "[llength $note_infos] warning(s);\
 242          $nmissing vessel(s) missing" \
 243         "Full description of warnings and missing vessels:" \
 244         $infodata
 245 }
 246
 247 #---------- vessel properties ----------
 248
 249 proc vesselclasses-init {} {
 250     global vc_game2code vc_code2abbrev vc_code2full vc_codes
 251     set vcl {
 252         smsloop         am      sl      Sloop
 253         lgsloop         bm      ct      Cutter
 254         dhow            cm      dh      Dhow
 255         longship        dm      ls      Longship
 256         baghlah         em      bg      Baghlah
 257         merchbrig       fm      mb      {Merchant Brig}
 258         warbrig         gm      wb      {War Brig}
 259         xebec           hm      xe      Xebec
 260         merchgal        jm      mg      {Merchant Galleon}
 261         warfrig         im      wf      {War Frigate}
 262         grandfrig       km      gf      {Grand Frigate}
 263     }
 264     set vc_codes {}
 265     foreach {game code abbrev full} $vcl {
 266         lappend vc_codes $code
 267         set vc_game2code($game) $code
 268         set vc_code2abbrev($code) $abbrev
 269         set vc_code2full($code) $full
 270         load-icon $abbrev
 271     }
 272
 273     load-icon atsea
 274     foreach a {battle borrow dot} {
 275         foreach b {ours dot query} {
 276             load-icon-combine $a $b
 277         }
 278     }
 279 }
 280
 281 proc load-icon {icon} {
 282     image create bitmap icon/$icon -file icons/$icon.xbm
 283 }
 284
 285 proc load-icon-combine {args} {
 286     set cmd {}
 287     set delim "pnmcat -lr "
 288     foreach icon $args {
 289         append cmd $delim " <(xbmtopbm icons/$icon.xbm)"
 290         set delim " <(pbmmake -white 1 1)"
 291     }
 292     append cmd " | pbmtoxbm"
 293     debug "load-icon-combine $cmd"
 294     image create bitmap icon/[join $args +] -data [exec bash -c $cmd]
 295 }
 296
 297 proc code-lockown2icon {lockown} {
 298     manyset [split $lockown ""] lock notown
 299     return icon/[
 300                  lindex {battle borrow dot} $lock
 301                 ]+[
 302                    lindex {ours dot query} $notown
 303                   ]
 304 }
 305
 306 proc canvas-horiz-stack {xvar xoff y bind type args} {
 307     upvar 1 $xvar x
 308     upvar 1 canvas canvas
 309     set id [eval $canvas create $type [expr {$x+$xoff}] $y $args]
 310     set bbox [$canvas bbox $id]
 311     set x [lindex $bbox 2]
 312     $canvas bind $id <ButtonPress> $bind
 313     return $id
 314 }
 315
 316 proc code2canvas {code canvas x yvar qty qtylen bind} {
 317     global vc_code2abbrev
 318     upvar 1 $yvar y
 319
 320     manyset [split $code _] inport class subclass lockown xabbrev
 321
 322     set stackx $x
 323     incr stackx 2
 324     set imy [expr {$y+2}]
 325
 326     if {!$inport} { incr qtylen -1 }
 327     if {$qtylen<=0} { set qtylen {} }
 328     set qty [format "%${qtylen}s" $qty]
 329
 330     set qtyid [canvas-horiz-stack stackx 0 $y $bind \
 331                    text -anchor nw -font fixed -text $qty]
 332
 333     if {!$inport} {
 334         canvas-horiz-stack stackx 0 $imy $bind \
 335             image -anchor nw -image icon/atsea
 336         incr stackx
 337     }
 338
 339     canvas-horiz-stack stackx -1 $imy $bind \
 340             image -anchor nw -image icon/$vc_code2abbrev($class)
 341
 342     if {[string length $subclass]} {
 343         canvas-horiz-stack stackx 0 $y $bind \
 344             text -anchor nw -font fixed -text \
 345             $subclass
 346     }
 347
 348     incr stackx
 349     canvas-horiz-stack stackx 0 $imy $bind \
 350         image -anchor nw -image [code-lockown2icon $lockown]
 351     incr stackx
 352
 353     if {[string length $xabbrev]} {
 354         canvas-horiz-stack stackx 0 $y $bind \
 355             text -anchor nw -font fixed -text \
 356             $xabbrev
 357     }
 358
 359     set bbox [$canvas bbox $qtyid]
 360     set ny [lindex $bbox 3]
 361     set bid [$canvas create rectangle \
 362                  $x $y $stackx $ny \
 363                  -fill white]
 364
 365     set y $ny
 366     $canvas lower $bid $qtyid
 367
 368     $canvas bind $bid <ButtonPress> $bind
 369 }
 370
 371 proc show-report-decode {code} {
 372     global vc_code2full
 373
 374     manyset [split $code _] inport classcode subclass lockown xabbrev
 375     manyset [split $lockown ""] lock notown
 376
 377     report-set inport [lindex {{At Sea} {In port}} $inport]
 378     report-set class $vc_code2full($classcode)
 379
 380     switch -exact $subclass {
 381         {} { report-set subclass {Ordinary} }
 382         F { report-set subclass {"Frost class"} }
 383         default { report-set subclass "Subclass \"$subclass\"" }
 384     }
 385
 386     report-set lock [lindex {
 387         {Battle ready} {Unlocked} {Locked}
 388     } $lock]
 389
 390     switch -exact $notown {
 391         0 { report-set own "Yours" }
 392         1 { report-set own "Other pirate's" }
 393         2 { report-set own "Owner unknown" }
 394         default { report-set own "?? $notown" }
 395     }
 396
 397     if {[string length $xabbrev]} {
 398         report-set xabbrev "Notes flags: $xabbrev"
 399     } else {
 400         report-set xabbrev "No flags in notes"
 401     }
 402 }
 403
 404 #---------- filtering ----------
 405
 406 set filters {}
 407
 408 proc filter-values/size {} { global vc_codes; return $vc_codes }
 409 proc filter-icon/size {code} {
 410     upvar #0 vc_code2abbrev($code) abb
 411     return icon/$abb
 412 }
 413 proc filter-default/size {code} { return 1 }
 414 proc filter-says-yes/size {codel} {
 415     set sizecode [lindex $codel 1]
 416     upvar #0 filter_size($sizecode) yes
 417     return $yes
 418 }
 419
 420 proc filter-values/lockown {} {
 421     foreach lv {0 1 2} {
 422         foreach ov {0 1 2} {
 423             lappend vals "$lv$ov"
 424         }
 425     }
 426     return $vals
 427 }
 428 proc filter-icon/lockown {lockown} { return [code-lockown2icon $lockown] }
 429 proc filter-default/lockown {lockown} {
 430     return [regexp {^[01]|^2[^1]} $lockown]
 431 }
 432 proc filter-says-yes/lockown {codel} {
 433     set lockown [lindex $codel 3]
 434     upvar #0 filter_lockown($lockown) yes
 435     return $yes
 436 }
 437
 438 proc filter-validate/xabbre {re} {
 439     if {[catch {
 440         regexp -- $re {}
 441     } emsg]} {
 442         regsub {^.*:\s*} $emsg {} emsg
 443         regsub {^.*(.{30})$} $emsg {\1} emsg
 444         return $emsg
 445     }
 446     return {}
 447 }
 448 proc filter-says-yes/xabbre {codel} {
 449     global filter_xabbre
 450     set xabbrev [lindex $codel 4]
 451     return [regexp -- $filter_xabbre $xabbrev]
 452 }
 453
 454 proc filter-tickbox-flip {fil} {
 455     upvar #0 filter_$fil vars
 456     set values [filter-values/$fil]
 457     foreach val $values {
 458         set vars($val) [expr {!$vars($val)}]
 459     }
 460     redraw-needed
 461 }
 462
 463 proc make-tickbox-filter {fil label rows inrow} {
 464     upvar #0 filter_$fil vars
 465     set fw [make-filter tickbox $fil $label frame]
 466     set values [filter-values/$fil]
 467     set nvalues [llength $values]
 468     if {!$inrow} {
 469         set inrow [expr {($nvalues + $rows) / $rows}]
 470     }
 471     set noicons [catch { info args filter-icon/$fil }]
 472     for {set ix 0} {$ix < $nvalues} {incr ix} {
 473         set val [lindex $values $ix]
 474         set vars($val) [filter-default/$fil $val]
 475         checkbutton $fw.$ix -variable filter_${fil}($val) \
 476             -font fixed -command redraw-needed
 477         if {!$noicons} {
 478             $fw.$ix configure -image [filter-icon/$fil $val] -height 16
 479         } else {
 480             $fw.$ix configure -text [filter-map/$fil $val]
 481         }
 482         grid configure $fw.$ix -sticky sw \
 483             -row [expr {$ix / $inrow}] \
 484             -column [expr {$ix % $inrow}]
 485     }
 486     button $fw.invert -text flip -command [list filter-tickbox-flip $fil] \
 487         -padx 0 -pady 0
 488     grid configure $fw.invert -sticky se \
 489         -row [expr {$rows-1}] \
 490         -column [expr {$inrow-1}]
 491 }
 492
 493 proc entry-filter-changed {fw fil n1 n2 op} {
 494     global errorInfo
 495     upvar #0 filter_$fil realvar
 496     upvar #0 filterentered_$fil entryvar
 497     global def_background
 498     debug "entry-filter-changed $fw $fil $entryvar"
 499     if {[catch {
 500         set error [filter-validate/$fil $entryvar]
 501         if {[string length $error]} {
 502             $fw.error configure -text $error -foreground white -background red
 503         } else {
 504             $fw.error configure -text { } -background $def_background
 505             set realvar $entryvar
 506             redraw-needed
 507         }
 508     } emsg]} {
 509         puts stderr "FILTER CHECK ERROR $emsg $errorInfo"
 510     }
 511 }
 512
 513 proc make-entry-filter {fil label def} {
 514     global filterentered_$fil
 515     upvar #0 filter_$fil realvar
 516     set realvar $def
 517     set fw [make-filter entry $fil $label frame]
 518     entry $fw.entry -textvariable filterentered_$fil
 519     label $fw.error
 520     glset def_background [$fw.error cget -background]
 521     trace add variable filterentered_$fil write \
 522         [list entry-filter-changed $fw $fil]
 523     pack $fw.entry $fw.error -side top -anchor w
 524 }
 525
 526 proc make-filter {kind fil label ekind} {
 527     global filters
 528     label .filter.lab_$fil -text $label -justify left
 529     $ekind .filter.$fil
 530     lappend filters $fil
 531     set nfilters [llength $filters]
 532     grid configure .filter.lab_$fil -row $nfilters -column 0 -sticky nw -pady 4
 533     grid configure .filter.$fil -row $nfilters -column 1 -sticky w -pady 3
 534     return .filter.$fil
 535 }
 536
 537 proc make-filters {} {
 538     make-tickbox-filter size Size 2 0
 539     make-tickbox-filter lockown "Lock/\nowner" 2 6
 540     make-entry-filter xabbre "Flags\n regexp" {}
 541 }
 542
 543 proc filterstyle-changed {n1 n2 op} {
 544     global filterstyle
 545     debug "filterstyle-changed $filterstyle"
 546     redraw-needed
 547 }
 548
 549 proc filters-say-yes {code} {
 550     global filters filterstyle
 551     debug "filters-say-yes $code"
 552     set codel [split $code _]
 553     set lockown [lindex $codel 3]
 554     switch -exact $filterstyle {
 555         0 { return 1 }
 556         1 { return [filter-default/lockown $lockown] }
 557         2 { return [regexp {^.0} $lockown] }
 558         3 { }
 559         default { error $filterstyle }
 560     }
 561
 562     foreach fil $filters {
 563         if {![filter-says-yes/$fil $codel]} { return 0 }
 564     }
 565     return 1
 566 }
 567
 568 #---------- loading and parsing the clipboard (vessel locations) ----------
 569
 570 proc vessel {vin} {
 571     global pirate notes_used note_missings newnotes
 572     upvar 1 $vin vi
 573
 574     set codel {}
 575     lappend codel [errexpect-arrayget-boolean vi inPort]
 576
 577     set gameclass [errexpect-arrayget vi vesselClass]
 578     upvar #0 vc_game2code($gameclass) class
 579     if {![info exists class]} { errexpect-error "unexpected vesselClass"}
 580     lappend codel $class
 581
 582     set subclass [errexpect-arrayget vi vesselSubclass]
 583     switch -exact $subclass {
 584         null            { lappend codel {} }
 585         icy             { lappend codel F }
 586         default         { lappend codel ($subclass) }
 587     }
 588
 589     switch -exact [errexpect-arrayget vi isLocked]/[ \
 590                    errexpect-arrayget vi isBattleReady] {
 591         true/false      { set lock 2 }
 592         false/false     { set lock 1 }
 593         false/true      { set lock 0 }
 594         default         { errexpect-error "unexpected isLocked/isBattleReady" }
 595     }
 596
 597     set vid [errexpect-arrayget vi vesselId]
 598     upvar #0 notes($vid) note
 599     set realname [errexpect-arrayget vi vesselName]
 600     set island [errexpect-arrayget vi islandName]
 601
 602     set owner {}
 603     set xabbrev {}
 604     if {[info exists note]} {
 605         manyset $note lno notename owner xabbrev
 606         if {[string compare -nocase $realname $notename]} {
 607             note-info $lno $vid $realname $island \
 608                 "notes say name is $notename"
 609         }
 610         if {[string length $owner]} {
 611             if {![string compare $owner $pirate]} {
 612                 set notown 0
 613             } else {
 614                 set notown 1
 615             }
 616         } else {
 617             set notown 2
 618         }
 619         append abbrev $xabbrev
 620         set notes_used($vid) 1
 621
 622     } else {
 623         set notown 2
 624         lappend note_missings [list $island $realname $vid]
 625     }
 626
 627     lappend codel "$lock$notown" $xabbrev
 628     lappend newnotes [list $vid $realname $owner $xabbrev]
 629     set kk "$island [join $codel _]"
 630     upvar #0 found($kk) k
 631     lappend k [list $vid $realname $owner]
 632
 633     debug "CODED $kk $vid $realname"
 634 }
 635
 636 set clipboard {}
 637 proc parse-clipboard {} {
 638     global clipboard found notes notes_used newnotes
 639
 640     catch { unset found }
 641     catch { unset notes_used }
 642     glset note_infos {}
 643     glset note_missings {}
 644
 645     set newnotes {}
 646
 647     set itemre { (\w+) = ([^=]*) }
 648     set manyitemre "^\\\[ $itemre ( (?: ,\\ $itemre)* ) \\]\$"
 649     debug $manyitemre
 650
 651     set lno 0
 652     foreach l [split $clipboard "\n"] {
 653         incr lno
 654         errexpect-setline $lno $l
 655         if {![string length $l]} continue
 656         catch { unset vi }
 657         while 1 {
 658                 if {![regexp -expanded $manyitemre $l dummy \
 659                         thiskey thisval rhs]} {
 660                     errexpect-error "badly formatted"
 661                 }
 662                 set vi($thiskey) $thisval
 663                 if {![string length $rhs]} break
 664                 regsub {^, } $rhs {} rhs
 665                 set l "\[$rhs\]"
 666         }
 667         vessel vi
 668     }
 669
 670     if {[llength $newnotes]} {
 671         foreach vid [lsort [array names notes]] {
 672             if {![info exists notes_used($vid)]} {
 673                 manyset $notes($vid) lno notename
 674                 note-info $lno $vid $notename {} \
 675                     "vessel in notes no longer found"
 676             }
 677         }
 678     }
 679 }
 680
 681 proc load-clipboard-file {fn} {
 682     set f [open $fn]
 683     glset clipboard [read $f]
 684     close $f
 685 }
 686
 687
 688 #---------- loading and parsing the chart ----------
 689
 690 proc load-chart {} {
 691     global chart scraper
 692     debug "FETCHING CHART"
 693     set chart [eval exec $scraper [list | perl -we {
 694         use strict;
 695         use CommodsScrape;
 696         use IO::File;
 697         use IO::Handle;
 698         yppedia_chart_parse(\*STDIN, (new IO::File ">/dev/null"),
 699                 sub { sprintf "%d %d", @_; },
 700                 sub { printf "archlabel %d %d %s\n", @_; },
 701                 sub { printf "island %s %s\n", @_; },
 702                 sub { printf "league %s %s %s.\n", @_; },
 703                 sub { printf STDERR "warning: %s: incomprehensible: %s", @_; }
 704                         );
 705         STDOUT->error and die $!;
 706     }]]
 707 }
 708
 709
 710 set scale 16
 711
 712 proc coord {c} {
 713         global scale
 714         return [expr {$c * $scale}]
 715 }
 716
 717 proc chart-got/archlabel {args} { }
 718 proc chart-got/island {x y args} {
 719 #       debug "ISLE $x $y $args"
 720         global canvas isleloc
 721         set isleloc($args) [list $x $y]
 722         set sz 5
 723 #       $canvas create oval \
 724 #               [expr {[coord $x] - $sz}] [expr {[coord $y] - $sz}] \
 725 #               [expr {[coord $x] + $sz}] [expr {[coord $y] + $sz}] \
 726 #               -fill blue
 727         $canvas create text [coord $x] [coord $y] \
 728                 -text $args -anchor s
 729 }
 730 proc chart-got/league {x1 y1 x2 y2 kind} {
 731 #       debug "LEAGUE $x1 $y1 $x2 $y2 $kind"
 732         global canvas
 733         set l [$canvas create line \
 734                 [coord $x1] [coord $y1] \
 735                 [coord $x2] [coord $y2]]
 736         if {![string compare $kind .]} {
 737                 $canvas itemconfigure $l -dash .
 738         }
 739 }
 740
 741 proc redraw-needed {} {
 742     global redraw_after
 743     debug "REDRAW NEEDED"
 744     if {[info exists redraw_after]} return
 745     set redraw_after [after 250 draw]
 746 }
 747
 748 proc draw {} {
 749     global chart found isleloc canvas redraw_after islandnames
 750
 751     catch { after cancel $redraw_after }
 752     catch { unset redraw_after }
 753
 754     $canvas delete all
 755
 756     foreach l [split $chart "\n"] {
 757 #       debug "CHART-GOT $l"
 758         set proc [lindex $l 0]
 759         eval chart-got/$proc [lrange $l 1 end]
 760     }
 761
 762     set islandnames {}
 763     set lastislandname {}
 764     foreach key [lsort [array names found]] {
 765         set c [llength $found($key)]
 766 #       debug "SHOWING $key $c"
 767         regexp {^(.*) (\S+)$} $key dummy islandname code
 768
 769         if {![filters-say-yes $code]} continue
 770
 771         if {[string compare $lastislandname $islandname]} {
 772                 manyset $isleloc($islandname) x y
 773                 set x [coord $x]
 774                 set y [coord $y]
 775                 set lastislandname $islandname
 776                 lappend islandnames $islandname
 777 #               debug "START Y $y"
 778         }
 779
 780         if {$c > 1} { set qty [format %d $c] } else { set qty {} }
 781         code2canvas $code $canvas $x y $qty 2 \
 782             [list show-report $islandname $code]
 783 #       debug "NEW Y $y"
 784     }
 785
 786     panner::updatecanvas-bbox .cp.ctrl.pan
 787
 788     islandnames-update
 789 }
 790
 791
 792 #---------- parser error reporting ----------
 793
 794 proc parser-control-create {w base invokebuttontext etl_title} {
 795     frame $w
 796     button $w.do -text $invokebuttontext -command invoke_$base -pady 3
 797
 798     frame $w.resframe -width 120 -height 32
 799     button $w.resframe.res -text {} -anchor nw \
 800         -padx 1 -pady 1 -borderwidth 0 -justify left
 801     glset deffont_$base [$w.resframe.res cget -font]
 802     place $w.resframe.res -relx 0.5 -y 0 -anchor n
 803
 804     pack $w.do -side top
 805     pack $w.resframe -side top -expand y -fill both
 806
 807     set eb .err_$base
 808     toplevel $eb
 809     wm withdraw $eb
 810     wm title $eb "where-vessels - $etl_title"
 811     wm protocol $eb WM_DELETE_WINDOW [list wm withdraw $eb]
 812
 813     label $eb.title -text $etl_title
 814     pack $eb.title -side top
 815
 816     button $eb.close -text Close -command [list wm withdraw $eb]
 817     pack $eb.close -side bottom
 818
 819     frame $eb.emsg -bd 2 -relief groove
 820     label $eb.emsg.lab -anchor nw -text "Error:"
 821     text $eb.emsg.text -height 1
 822     pack $eb.emsg.text -side bottom -fill x
 823     pack $eb.emsg.lab -side left
 824
 825     pack $eb.emsg -side top -pady 2 -fill x
 826
 827     frame $eb.text -bd 2 -relief groove
 828     pack $eb.text -side bottom -pady 2 -fill both -expand y
 829
 830     label $eb.text.lab -anchor nw
 831
 832     text $eb.text.text -width 85 \
 833         -xscrollcommand [list $eb.text.xscroll set] \
 834         -yscrollcommand [list $eb.text.yscroll set]
 835     $eb.text.text tag configure error \
 836         -background red -foreground white
 837
 838     scrollbar $eb.text.xscroll -orient horizontal \
 839         -command [list $eb.text.text xview]
 840     scrollbar $eb.text.yscroll -orient vertical \
 841         -command [list $eb.text.text yview]
 842
 843     grid configure $eb.text.lab -row 0 -column 0 -sticky w -columnspan 2
 844     grid configure $eb.text.text -row 1 -column 0 -sticky news
 845     grid configure $eb.text.yscroll -sticky ns -row 1 -column 1
 846     grid configure $eb.text.xscroll -sticky ew -row 2 -column 0
 847     grid rowconfigure $eb.text 0 -weight 0
 848     grid rowconfigure $eb.text 1 -weight 1
 849     grid rowconfigure $eb.text 2 -weight 0
 850     grid columnconfigure $eb.text 0 -weight 1
 851     grid columnconfigure $eb.text 1 -weight 0
 852 }
 853
 854 proc parser-control-ok-core {w base background show} {
 855     debug "parser-control-ok-core $w $base $background $show"
 856     upvar #0 deffont_$base deffont
 857     $w.resframe.res configure \
 858         -background $background -disabledforeground black -font $deffont \
 859         -state disabled -command {} \
 860         -text $show
 861 }
 862 proc parser-control-ok {w base show} {
 863     parser-control-ok-core $w $base green $show
 864 }
 865 proc parser-control-none {w base show} {
 866     parser-control-ok-core $w $base blue $show
 867 }
 868 proc parser-control-failed-core {w base foreground background smallfont
 869                                  tiny summary fulldesc fulldata} {
 870     debug "parser-control-failed-core $w $base $summary $fulldesc"
 871     upvar #0 deffont_$base deffont
 872     set eb .err_$base
 873
 874     $eb.emsg.text delete 0.0 end
 875     $eb.emsg.text insert end $summary
 876
 877     $eb.text.lab configure -text $fulldesc
 878     $eb.text.text delete 0.0 end
 879     $eb.text.text insert end $fulldata
 880
 881     regsub -all {.{18}} $tiny "&\n" ewrap
 882
 883     if {$smallfont} {
 884         set font fixed
 885     } else {
 886         set font $deffont
 887     }
 888
 889     $w.resframe.res configure \
 890         -background $background -foreground $foreground -font $font \
 891         -state normal -command [list wm deiconify $eb] \
 892         -text $ewrap
 893 }
 894
 895 proc parser-control-failed-expected {w base emsg lno ei fulldesc newdata} {
 896     set eb .err_$base
 897
 898     set line [lindex [split $ei "\n"] 0]
 899     debug "parser-control-failed-expected: $w $base: $lno: $emsg\n $line"
 900
 901     parser-control-failed-core $w $base \
 902         white red 1 \
 903         "err: [string trim $emsg]: \"$line\"" \
 904         "at line $lno: $emsg" \
 905         $fulldesc $newdata
 906
 907     $eb.text.text tag add error $lno.0 $lno.end
 908     $eb.text.text see $lno.0
 909 }
 910 proc parser-control-failed-unexpected {w base emsg ei} {
 911     global errorInfo
 912     parser-control-failed-core $w $base \
 913         black yellow 1 \
 914         $emsg $emsg "Details and stack trace:" $ei
 915 }
 916
 917 proc reparse {base varname old fulldesc okshow noneshow parse ok} {
 918     upvar #0 $varname var
 919     manyset [errexpect-catch {
 920         uplevel 1 $parse
 921         if {[string length [string trim $var]]} {
 922             parser-control-ok .cp.ctrl.$base $base $okshow
 923         } else {
 924             parser-control-none .cp.ctrl.$base $base $noneshow
 925         }
 926     }] failed emsg lno ei
 927     if {$failed} {
 928         parser-control-failed-expected .cp.ctrl.$base $base \
 929             $emsg $lno $ei $fulldesc $var
 930         set var $old
 931         uplevel 1 $parse
 932     } else {
 933         uplevel 1 $ok
 934     }
 935 }
 936
 937 #---------- island names selection etc. ----------
 938
 939 proc islandnames-update {} {
 940     global islandnames
 941     .islands.count configure -text [format "ships at %d island(s)" \
 942                                         [llength $islandnames]]
 943 }
 944
 945 proc islandnames-select {} {
 946     .islands.clip configure -relief sunken -state disabled
 947     selection own -command islandnames-deselect .islands.clip
 948 }
 949 proc islandnames-deselect {} {
 950     .islands.clip configure -relief raised -state normal
 951 }
 952
 953 proc islandnames-handler {offset maxchars} {
 954     global islandnames
 955     return [string range [join $islandnames ", "] \
 956                 $offset [expr {$offset+$maxchars-1}]]
 957 }
 958
 959 #---------- main user interface ----------
 960
 961 proc widgets-setup {} {
 962     global canvas debug pirate ocean filterstyle
 963
 964     wm geometry . 1024x600
 965     wm title . "where-vessels - $pirate on the $ocean ocean"
 966
 967     #----- map -----
 968
 969     frame .f -border 1 -relief groove
 970     set canvas .f.c
 971     canvas $canvas
 972     pack $canvas -expand 1 -fill both
 973     pack .f -expand 1 -fill both -side left
 974
 975     #----- control panels and filter -----
 976
 977     frame .cp
 978     frame .filter -relief groove -bd 2 -padx 1
 979     frame .islands -pady 2
 980     pack .cp .filter .islands -side top
 981
 982     set filterstyle 1
 983     trace add variable filterstyle write filterstyle-changed
 984
 985     frame .filter.title
 986     label .filter.title.title -text Show
 987     pack .filter.title.title -side left
 988     for {set fing 0} {$fing < 4} {incr fing} {
 989         radiobutton .filter.title.f$fing \
 990             -variable filterstyle -value $fing \
 991             -text [lindex {All Useable Mine These:} $fing]
 992         pack .filter.title.f$fing -side left
 993     }
 994
 995     grid configure .filter.title -row 0 -column 0 -columnspan 2
 996
 997     #----- control panel -----
 998
 999     frame .cp.ctrl
1000     pack .cp.ctrl -side left -anchor n
1001
1002     debug "BBOX [$canvas bbox all]"
1003
1004     panner::canvas-scroll-bbox .f.c
1005     panner::create .cp.ctrl.pan .f.c 120 120 $debug
1006
1007     pack .cp.ctrl.pan -side top -pady 0 -padx 5
1008     frame .cp.ctrl.zoom
1009     pack .cp.ctrl.zoom -side top
1010
1011     button .cp.ctrl.zoom.out -text - -font {Courier 16} -command {zoom /2} -pady 0
1012     button .cp.ctrl.zoom.in  -text + -font {Courier 16} -command {zoom *2} -pady 0
1013     pack .cp.ctrl.zoom.out .cp.ctrl.zoom.in -side left
1014
1015     parser-control-create .cp.ctrl.acquire \
1016         acquire Acquire \
1017         "Clipboard parsing error" \
1018
1019     pack .cp.ctrl.acquire -side top -pady 2
1020
1021     parser-control-create .cp.ctrl.notes \
1022         notes "Reload notes" \
1023         "Vessel notes loading report" \
1024
1025     pack .cp.ctrl.notes -side top -pady 2
1026
1027     #----- island name count and copy -----
1028
1029     label .islands.count
1030     button .islands.clip -text "copy island names" -pady 2 -padx 2 \
1031          -command islandnames-select
1032     selection handle .islands.clip islandnames-handler
1033     pack .islands.count .islands.clip -side left
1034
1035     #----- decoding etc. report -----
1036
1037     frame .cp.report
1038     pack .cp.report -side left -anchor n
1039
1040     label .cp.report.island -text { }
1041
1042     canvas .cp.report.abbrev -width 1 -height 15
1043
1044     frame .cp.report.code
1045     label .cp.report.code.lab -text Code:
1046     glset report_code { }
1047     entry .cp.report.code.code -state readonly \
1048         -textvariable report_code -width 15
1049     pack .cp.report.code.lab .cp.report.code.code -side left
1050     frame .cp.report.details -bd 2 -relief groove -padx 2 -pady 2
1051
1052     listbox .cp.report.list -height 5
1053
1054     pack .cp.report.island .cp.report.abbrev .cp.report.details \
1055         .cp.report.list -side top
1056     #pack .cp.report.code -side top
1057     pack configure .cp.report.details -fill x
1058
1059     foreach sw {inport class subclass lock own xabbrev} {
1060         label .cp.report.details.$sw -text { }
1061         pack .cp.report.details.$sw -side top -anchor w
1062     }
1063 }
1064
1065 proc report-set {sw val} { .cp.report.details.$sw configure -text $val }
1066
1067 proc show-report {islandname code} {
1068     .cp.report.island configure -text $islandname
1069
1070     .cp.report.abbrev delete all
1071     set y 2
1072     code2canvas $code .cp.report.abbrev 5 y {} 0 {}
1073     manyset [.cp.report.abbrev bbox all] minx dummy maxx dummy
1074     .cp.report.abbrev configure -width [expr {$maxx-$minx+4}]
1075
1076     glset report_code $code
1077     show-report-decode $code
1078
1079     set kk "$islandname $code"
1080     upvar #0 found($kk) k
1081
1082     .cp.report.list delete 0 end
1083
1084     foreach entry $k {
1085         manyset $entry vid name owner
1086         lappend owned($owner) $name
1087     }
1088
1089     foreach owner [lsort [array names owned]] {
1090         if {[string length $owner]} {
1091             set owndesc "$owner's"
1092         } else {
1093             set owndesc "Owner unknown"
1094         }
1095         .cp.report.list insert end "$owndesc:"
1096         foreach name $owned($owner) {
1097             .cp.report.list insert end " $name"
1098         }
1099     }
1100 }
1101
1102 proc zoom {extail} {
1103     global scale canvas
1104     set nscale [expr "\$scale $extail"]
1105     debug "ZOOM $scale $nscale"
1106     if {$nscale < 1 || $nscale > 200} return
1107     set scale $nscale
1108     draw
1109 }
1110
1111 proc invoke_acquire {} {
1112     global clipboard errorInfo
1113     set old $clipboard
1114
1115     if {[catch {
1116         set clipboard [clipboard get]
1117     } emsg]} {
1118         parser-control-failed-unexpected .cp.ctrl.acquire acquire \
1119             $emsg "fetching clipboard:\n\n$errorInfo"
1120         return
1121     }
1122
1123     reparse acquire \
1124         clipboard $old "Clipboard contents:" { acquired ok } { no vessels } {
1125             parse-clipboard
1126         } {
1127             display-note-infos
1128         }
1129     draw
1130 }
1131
1132 proc invoke_notes {} {
1133     global notes_data errorInfo notes_loc
1134     set old $notes_data
1135
1136     if {[catch {
1137         load-notes
1138     } emsg]} {
1139         parser-control-failed-unexpected .cp.ctrl.notes notes \
1140             $emsg "loading $notes_loc:\n\n$errorInfo"
1141         return
1142     }
1143
1144     reparse notes \
1145         notes_data $old "Vessel notes:" "loaded ok" { no notes } {
1146             parse-notes
1147             parse-clipboard
1148         } {
1149             display-note-infos
1150         }
1151     draw
1152 }
1153
1154 #---------- main program ----------
1155
1156 parseargs
1157 vesselclasses-init
1158 argdefaults
1159 httpclientsetup where-vessels
1160 load-chart
1161 widgets-setup
1162 make-filters
1163
1164 set notes_data {}
1165 if {[catch { parse-clipboard } emsg]} {
1166     puts stderr "$emsg\n$errorInfo"
1167     exit 1
1168 }
1169 after idle invoke_notes
1170
1171 draw