pctb/show-thing.tcl

   1 #!/usr/bin/wish
   2
   3 # usage:
   4 #  run show-thing without args
   5 #  then on stdin write
   6 #     one line which is a Tcl list for unk_{l,r} unk_contexts glyphsdone
   7 #     the xpm in the format expected
   8 #  then expect child to raise SIGSTOP or exit 0 or exit nonzero
   9 #  if child raised SIGSTOP, check database was updated
  10
  11
  12 proc manyset {list args} {
  13     foreach val $list var $args {
  14         upvar 1 $var my
  15         set my $val
  16     }
  17 }
  18
  19
  20 #---------- display core ----------
  21
  22 set mul 6
  23 set inter 1
  24
  25 set gotsh 20
  26 set csrh 20
  27 set ctxh 20
  28
  29 proc init_widgets {} {
  30     # idempotent
  31     global csrh gotsh ctxh
  32
  33     if {[winfo exists .d]} return
  34
  35     frame .d
  36
  37     image create bitmap image/main
  38     label .d.mi -image image/main -borderwidth 0
  39
  40     frame .d.csr -bg black -height $csrh
  41     frame .d.got -bg black -height $gotsh
  42     frame .d.ctx -bg black
  43
  44     image create bitmap image/cursor -data \
  45 {#define csr_width 11
  46 #define csr_height 11
  47 static unsigned char csr_bits[] = {
  48    0x20, 0x00, 0x20, 0x00, 0x20, 0x00, 0x21, 0x04, 0x22, 0x02, 0x25, 0x05,
  49    0xaa, 0x02, 0x74, 0x01, 0xa8, 0x00, 0x70, 0x00, 0x20, 0x00};
  50 }
  51
  52     frame .d.csr.csr
  53     label .d.csr.csr.l -image image/cursor -compound left
  54     entry .d.csr.csr.e -bd 0
  55     pack .d.csr.csr.l -side left
  56
  57     frame .d.mi.csr_0 -bg white -width 1
  58     frame .d.mi.csr_1 -bg white -width 1
  59
  60     pack .d.csr .d.mi .d.got .d.ctx -side top
  61     pack .d
  62
  63     frame .help
  64     pack .help
  65 }
  66
  67 proc show_context {maxhv x ctxs} {
  68     global mul
  69     upvar 1 $maxhv maxh
  70     set w .d.ctx.at$x
  71     if {[llength $ctxs]==1} { set fg blue } { set fg yellow }
  72     label $w -bg black -fg $fg -text [join $ctxs "/\n"] -justify left
  73     place $w -x [expr {($x-1)*$mul}] -y 0
  74     set wh [winfo reqheight $w]
  75     if {$wh > $maxh} { set maxh $wh }
  76 }
  77
  78 proc resize_widgets {} {
  79     global mulcols mulrows csrh gotsh ctxh glyphsdone
  80     global unk_l unk_contexts
  81
  82     foreach w {.d.csr .d.got .d.ctx} {
  83         $w configure -width $mulcols
  84     }
  85     #.d configure -height [expr {$csrh+$mulrows+$gotsh+$ctxh}]
  86     foreach w {0 1} {
  87         .d.mi.csr_$w configure -height $mulrows
  88     }
  89
  90     eval destroy [winfo children .d.ctx]
  91
  92     set maxh 0
  93     foreach {min max contexts got} $glyphsdone {
  94         show_context maxh $min $contexts
  95     }
  96     show_context maxh $unk_l $unk_contexts
  97     .d.ctx configure -height $maxh
  98 }
  99
 100
 101 #---------- xpm input processor ----------
 102
 103 proc read_xpm {f} {
 104     global glyphsdone mul inter rhsmost_max unk_l unk_r mulcols mulrows
 105     global cols rows wordmap
 106
 107     set o {}
 108     set y -3
 109     while 1 {
 110         if {[gets $f l] < 0} { error "huh? "}
 111         if {![regexp {^"(.*)",$} $l dummy l]} {
 112             append o "$l\n"
 113             if {[regexp {^\}\;$} $l]} break
 114             continue
 115         }
 116         if {$y==-3} {
 117             manyset $l cols rows colours cpp
 118             if {$colours!=2 || $cpp!=1} { error "$l ?" }
 119
 120             set chop_l [expr {$unk_l - 80}]
 121             set chop_r [expr {$cols - $unk_l - 100}]
 122             if {$chop_l<0} { set chop_l 0 }
 123
 124             set unk_l [expr {$unk_l - $chop_l}]
 125             set unk_r [expr {$unk_r - $chop_l}]
 126             set ngd {}
 127             foreach {min max contexts got} $glyphsdone {
 128                 lappend ngd \
 129                     [expr {$min-$chop_l}] \
 130                     [expr {$max-$chop_l}] \
 131                     $contexts $got
 132             }
 133             set glyphsdone $ngd
 134
 135             set realcols $cols
 136             set cols [expr {$cols - $chop_l - $chop_r}]
 137             puts stderr "NOW cols=$cols chop_l,r=$chop_l,$chop_r rows=$rows\
 138                 $unk_l $unk_r $ngd"
 139
 140             set mulcols [expr {$cols*$mul+$inter}]
 141             set mulrows [expr {$rows*$mul+$inter}]
 142             append o "\"$mulcols $mulrows 9 1\",\n"
 143             for {set x 0} {$x<$cols} {incr x} { set wordmap($x) 0 }
 144         } elseif {$y==-2} { # first pixel
 145             append o \
 146 "\"+ c #111\",
 147 \"a c #800\",
 148 \"A c #fcc\",
 149 \"b c #00c\",
 150 \"B c #fff\",
 151 \"u c #000\",
 152 \"U c #ff0\",
 153 \"q c #000\",
 154 \"Q c #ff0\",\n"
 155         } elseif {$y==-1} { # 2nd pixel but we've already printed ours
 156         } else {
 157             set ybit [expr {1<<$y}]
 158             set x 0
 159             set ol "\"+"
 160             set olh $ol
 161             if {$chop_r>=0} {
 162                 set l [string range $l $chop_l end-$chop_r]
 163             } else {
 164                 set l [string range $l $chop_l end]
 165                 append l [string repeat " " [expr -$chop_r]]
 166             }
 167             foreach c [split $l ""] {
 168                 set how "u"
 169                 if {$x >= $unk_l && $x <= $unk_r} {
 170                     set how q
 171                 } else {
 172                     set ab 0
 173                     foreach {min max contexts got} $glyphsdone {
 174                         set rhsmost_max $max
 175                         if {$x >= $min && $x <= $max} {
 176                             set how [lindex {a b} $ab]
 177                             break
 178                         }
 179                         set ab [expr {!$ab}]
 180                     }
 181                 }
 182                 switch -exact $c {
 183                     " " { set p $how }
 184                     "o" {
 185                         set p [string toupper $how]
 186                         incr wordmap($x) $ybit
 187                     }
 188                     default { error "$c ?" }
 189                 }
 190                 append ol "[string repeat $p [expr {$mul-$inter}]][
 191                          string repeat + $inter]"
 192                 append olh [string repeat + $mul]
 193                 incr x
 194             }
 195             set ole "\",\n"
 196             append ol $ole
 197             append olh $ole
 198             set olhn [string repeat $olh $inter]
 199             if {!$y} { append o $olhn }
 200             append o [string repeat $ol [expr {$mul-1}]]
 201             append o $olhn
 202         }
 203         incr y
 204     }
 205     set data [exec xpmtoppm << $o]
 206     image create photo image/main -data $data
 207 }
 208
 209
 210 #---------- per-invocation display ----------
 211
 212 proc draw_glyphsdone {} {
 213     global glyphsdone mul inter
 214     eval destroy [winfo children .d.got]
 215     foreach {min max contexts got} $glyphsdone {
 216         frame .d.got.m$min -bd 0 -background \#888
 217         label .d.got.m$min.l -text "$got" -fg white -bg black -bd 0
 218         pack .d.got.m$min.l -padx 1 -pady 1
 219         place .d.got.m$min -x [expr {$min*$mul+$inter}] -y 0
 220     }
 221 }
 222
 223 proc startup_cursor {} {
 224     global cur_already cur_mode cur_0 cur_1 last_ht
 225     global glyphsdone unk_l unk_r
 226
 227     set cur_already [expr {[llength $glyphsdone]/4-1}]
 228     set cur_mode 1 ;# one of:   0 1 already text
 229
 230     set cur_0 $unk_l
 231     set cur_1 [expr {$unk_r+1}]
 232     set last_ht {}
 233
 234     recursor
 235 }
 236
 237
 238 #---------- runtime display and keystroke handling ----------
 239
 240 proc helptext {t} {
 241     global last_ht
 242     if {![string compare $t $last_ht]} return
 243     eval destroy [grid slaves .help]
 244     set y 0; foreach l $t {
 245         set x 0; foreach c $l {
 246             set w .help.at${x}x${y}
 247             label $w -text $c
 248             grid $w -row $y -column $x -padx 5
 249             incr x
 250         }
 251         incr y
 252     }
 253     set last_ht $t
 254 }
 255
 256 proc recursor/0 {} { recursor//01 0 }
 257 proc recursor/1 {} { recursor//01 1 }
 258 proc recursor//01 {z1} {
 259     global mul rhsmost_max cols glyphsdone
 260     upvar #0 cur_$z1 cur
 261     .d.csr.csr.l configure -text {adjust}
 262     place .d.csr.csr -x [expr {$cur*$mul - 7}]
 263     bind_key space { othercursor }
 264     bind_leftright cur_$z1 0 [expr {$cols-1}]
 265     if {[llength $glyphsdone]} {
 266         bind_key Tab { set cur_mode already; recursor }
 267     } else {
 268         bind_key Tab {}
 269     }
 270     bind_key Return {
 271         if {$cur_0 != $cur_1} {
 272             set cur_mode text
 273             recursor
 274         }
 275     }
 276     helptext {
 277         {{<- ->}   {move cursor, adjusting area to define}}
 278         {Space     {switch to moving other cursor}}
 279         {Return    {confirm location, enter letter(s)}}
 280         {Tab       {switch to correcting earlier ocr}}
 281     }
 282 }
 283 proc othercursor {} {
 284     global cur_mode
 285     set cur_mode [expr {!$cur_mode}]
 286     recursor
 287 }
 288
 289 proc recursor/text {} {
 290     helptext {
 291         {Return   {confirm entry of new glyph}}
 292         {Escape   {abandon entry}}
 293     }
 294     unbind_all_keys
 295     .d.csr.csr.l configure -text {define:}
 296     pack .d.csr.csr.e -side left
 297     focus .d.csr.csr.e
 298     bind_key Return {
 299         set strq [.d.csr.csr.e get]
 300         if {[regexp {^(?:[!-[]|[]-~]|\\\\|\\x[0-9a-f]{2})+} $strq]} {
 301             .d.csr.csr.e delete 0 end
 302             RETURN_RESULT DEFINE "$cur_0 $cur_1 $strq"
 303         }
 304     }
 305     bind_key Escape {
 306         bind_key Escape {}
 307         pack forget .d.csr.csr.e
 308         set cur_mode 1
 309         recursor
 310     }
 311 }
 312
 313 proc recursor/already {} {
 314     global mul
 315     global glyphsdone
 316     global cur_already mul
 317     global glyphsdone cur_already mul
 318     .d.csr.csr.l configure -text {correct}
 319     set rmax [lindex $glyphsdone [expr {$cur_already*4}]]
 320     place .d.csr.csr -x [expr {$rmax*$mul-3}]
 321     bind_key Return {}
 322     bind_key space {}
 323     bind_leftright cur_already 0 [expr {[llength $glyphsdone]/4-1}]
 324     bind_key Tab { bind_key Delete {}; set cur_mode 1; recursor }
 325     bind_key Delete {
 326         RETURN_RESULT DELETE [lrange $glyphsdone \
 327                                   [expr $cur_already*4] \
 328                                   [expr $cur_already*4+2]]
 329     }
 330     helptext {
 331         {{<- ->}   {move cursor, selecting glyph to correct}}
 332         {Del       {clear this glyph from the recognition database}}
 333         {Tab       {switch to selecting area to define as new glyph}}
 334     }
 335 }
 336
 337 proc bind_key {k proc} {
 338     global keybindings
 339     bind . <Key-$k> $proc
 340     set keybindings($k) [expr {!![string length $proc]}]
 341 }
 342 proc unbind_all_keys {} {
 343     global keybindings
 344     foreach k [array names keybindings] { bind_key $k {} }
 345 }
 346
 347 proc bind_leftright {var min max} {
 348     bind_key Left  [list leftright $var $min $max -1]
 349     bind_key Right [list leftright $var $min $max +1]
 350 }
 351 proc leftright {var min max inc} {
 352     upvar #0 $var v
 353     set vnew $v
 354     incr vnew $inc
 355     if {$vnew < $min || $vnew > $max} return
 356     set v $vnew
 357     recursor
 358 }
 359
 360 proc recursor {} {
 361     global csrh cur_mode cur_0 cur_1 mul
 362     foreach z1 {0 1} {
 363         place .d.mi.csr_$z1 -y 0 -x [expr {[set cur_$z1] * $mul}]
 364     }
 365     recursor/$cur_mode
 366 }
 367
 368
 369 #---------- database read and write ----------
 370
 371 # database format:
 372 # series of glyphs:
 373 #   <context> <ncharacters> <hex>...
 374 #   width
 375 #   <hex-bitmap>
 376
 377 # $database($context 0x<bits> 0x<bits>...) = $hex
 378
 379 set database_header {# ypp-sc-tools pctb font v1}
 380
 381 proc db_getsl {f} {
 382     if {[gets $f l] < 0} { error "unexpected db eof" }
 383     return $l
 384 }
 385
 386 proc read_database {} {
 387     global database database_header rows database_fn
 388     catch { unset database }
 389     set database_fn ./charset-$rows.txt
 390     set f [open $database_fn r]
 391     if {[string compare [db_getsl $f] $database_header]} { error "$l ?" }
 392     if {([db_getsl $f])+0 != $rows} { error "wrong h ?" }
 393     while 1 {
 394         set context [db_getsl $f]
 395         if {![string length $context]} continue
 396         if {[regexp {^\#} $context]} continue
 397         if {![string compare . $context]} break
 398
 399         set bm $context
 400         set strq [db_getsl $f]
 401         while 1 {
 402             set l [db_getsl $f]
 403             if {![string length $l]} break
 404             lappend bm [format %x 0x$l]
 405         }
 406         set database($bm) $strq
 407     }
 408     close $f
 409 }
 410
 411 proc write_database {} {
 412     global database rows database_fn database_header
 413     set ol {}
 414     foreach bm [array names database] {
 415         set strq $database($bm)
 416         set o "[lindex $bm 0]\n$strq\n"
 417         foreach x [lrange $bm 1 end] { append o "$x\n" }
 418
 419         lappend ol $o
 420     }
 421     set f [open $database_fn.new w]
 422     puts $f "$database_header\n$rows\n"
 423     foreach o [lsort $ol] {
 424         puts $f $o
 425     }
 426     puts $f "."
 427     close $f
 428     file rename -force $database_fn.new $database_fn
 429 }
 430
 431 proc dbkey {ctx l r} {
 432     global wordmap
 433     set bm $ctx
 434     for {set x $l} {$x <= $r} {incr x} {
 435         lappend bm [format %x $wordmap($x)]
 436     }
 437     return $bm
 438 }
 439
 440 proc update_database/DEFINE {c0 c1 strq} {
 441     global glyphsdone unk_l unk_contexts wordmap database
 442     if {$c0 > $c1} { manyset [list $c0 $c1] c1 c0 }
 443     if {$c0 == $unk_l} {
 444         set ncontexts $unk_contexts
 445     } else {
 446         foreach {l r contexts got} $glyphsdone {
 447             if {$l==$c0} { set ncontexts $contexts; break }
 448         }
 449         if {![info exists ncontexts]} {
 450             puts stderr "must start at letter LHS!"
 451             return
 452         }
 453     }
 454     incr c1 -1
 455     foreach c $ncontexts {
 456         set bm [dbkey $c $c0 $c1]
 457         set database($bm) $strq
 458     }
 459     write_database
 460 }
 461
 462 proc update_database/DELETE {l r ctxs} {
 463     global database
 464     foreach ctx $ctxs {
 465         set bm [dbkey $ctx $l $r]
 466         catch { unset database($bm) }
 467     }
 468     write_database
 469 }
 470
 471
 472 proc RETURN_RESULT {how what} {
 473     global mainkind
 474     place forget .d.csr.csr
 475     pack forget .d.csr.csr.e
 476     helptext {{{ Processing }}}
 477     unbind_all_keys
 478     update idletasks
 479     puts stderr "$how $what"
 480     eval update_database/$how $what
 481     done/$mainkind
 482 }
 483
 484 #---------- main progrm ----------
 485
 486 proc main/test {} {
 487     global glyphsdone unk_l unk_r unk_contexts
 488
 489     set glyphsdone {
 490         7 11 1 M
 491         13 17 0 a
 492         19 23 0 n
 493     }
 494     set unk_l 25
 495     set unk_r 29
 496     set unk_contexts Test
 497
 498     set f [open text.xpm]
 499     read_xpm $f
 500     close $f
 501
 502     read_database
 503     resize_widgets
 504     draw_glyphsdone
 505     startup_cursor
 506 }
 507 proc done/test {} {
 508 }
 509
 510 proc required {} {
 511     global glyphsdone unk_l unk_r unk_contexts
 512
 513     if {[gets stdin l]<0} {
 514         if {[eof stdin]} { fconfigure stdin -blocking yes; exit 0 }
 515         return
 516     }
 517     init_widgets
 518     manyset [lrange $l 0 3] unk_l unk_r unk_contexts
 519     set glyphsdone [lrange $l 3 end]
 520     puts stderr "SHOW-THING GOT $l"
 521
 522     fileevent stdin readable {}
 523
 524     read_xpm stdin
 525     resize_widgets
 526     read_database
 527     draw_glyphsdone
 528     startup_cursor
 529 }
 530
 531 proc main/automatic {} {
 532     fconfigure stdin -blocking no
 533     fileevent stdin readable required
 534 }
 535 proc done/automatic {} {
 536     exec sh -c {printf \\0 >&4}
 537     fileevent stdin readable required
 538 }
 539
 540 switch -exact -- $argv {
 541     {}               { set mainkind test }
 542     {--automatic 1}  { set mainkind automatic }
 543     {--automatic*}   { error "incompatible versions - install problem" }
 544     default          { error "huh $argv ?" }
 545 }
 546
 547 main/$mainkind