yarrg/where-vessels

   1 #!/usr/bin/wish
   2 # show your vessels on a map
   3
   4 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   5 # players of Yohoho Puzzle Pirates.
   6 #
   7 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   8 #
   9 # This program is free software: you can redistribute it and/or modify
  10 # it under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation, either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  23 # are used without permission.  This program is not endorsed or
  24 # sponsored by Three Rings.
  25
  26
  27
  28 source yarrglib.tcl
  29 source panner.tcl
  30 package require http
  31
  32 #---------- general utilities ----------
  33
  34 set debug 0
  35 proc debug {m} {
  36     global debug
  37     if {$debug} { puts "DEBUG $m" }
  38 }
  39
  40 proc badusage {m} {
  41     puts stderr "where-vessels: bad usage: $m"
  42     exit 1
  43 }
  44
  45 proc glset {n val} {
  46     upvar #0 $n var
  47     set var $val
  48 }
  49
  50 #---------- expecting certain errors ----------
  51
  52 proc errexpect-setline {lno line} {
  53     glset errexpect_lno $lno
  54     glset errexpect_line $line
  55 }
  56
  57 proc errexpect-error {m} {
  58     global errexpect_line errexpect_lno
  59     error $m "$errexpect_line\n" [list YARRG-ERREXPECT $errexpect_lno]
  60 }
  61
  62 proc errexpect-arrayget {arrayvar key} {
  63     upvar 1 $arrayvar av
  64     upvar 1 ${arrayvar}($key) v
  65     if {[info exists v]} { return $v }
  66     errexpect-error "undefined $key"
  67 }
  68
  69 proc errexpect-arrayget-boolean {arrayvar key} {
  70     switch -exact [uplevel 1 [list errexpect-arrayget $arrayvar $key]] {
  71         true    { return 1 }
  72         false   { return 0 }
  73         default { errexpect-error "unexpected $key" }
  74     }
  75 }
  76
  77 proc errexpect-catch {code} {
  78     global errorInfo errorCode
  79     set rc [catch {
  80         uplevel 1 $code
  81     } rv]
  82     debug "ERREXPECT CATCH |$rc|$rv|$errorCode|$errorInfo|"
  83     if {$rc==1 && ![string compare YARRG-ERREXPECT [lindex $errorCode 0]]} {
  84         return [list 1 $rv [lindex $errorCode 1] $errorInfo]
  85     } elseif {$rc==0} {
  86         return [list 0 $rv]
  87     } else {
  88         return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rv
  89     }
  90 }
  91
  92 #---------- argument parsing ----------
  93
  94 proc nextarg {} {
  95     global ai argv
  96     if {$ai >= [llength $argv]} {
  97         badusage "option [lindex $argv [expr {$ai-1}]] needs a value"
  98     }
  99     set v [lindex $argv $ai]
 100     incr ai
 101     return $v
 102 }
 103
 104 set notes_loc vessel-notes
 105 set scraper {./yppedia-ocean-scraper --chart}
 106 set info_cache _vessel-info-cache
 107 set info_source rsync.yarrg.chiark.net::yarrg/vessel-info
 108
 109 proc parseargs {} {
 110     global ai argv
 111     global debug scraper
 112     set ai 0
 113
 114     while {[regexp {^\-} [set arg [lindex $argv $ai]]]} {
 115         incr ai
 116         switch -exact -- $arg {
 117             -- { break }
 118             --pirate { glset pirate [string totitle [nextarg]] }
 119             --ocean { glset ocean [string totitle [nextarg]] }
 120             --clipboard-file { load-clipboard-file [nextarg] }
 121             --local-html-dir { lappend scraper --local-html-dir=[nextarg] }
 122             --notes { glset notes_loc [nextarg] }
 123             --vessel-info-source { glset info_source [nextarg] }
 124             --debug { incr debug }
 125             default { badusage "unknown option $arg" }
 126         }
 127     }
 128     set argv [lrange $argv $ai end]
 129     if {[llength $argv]} { badusage "non-option args not allowed" }
 130 }
 131
 132 proc argdefaults {} {
 133     global ocean notes_loc pirate scraper
 134     if {![info exists ocean] || ![info exists pirate]} {
 135         set cmd {./yarrg --find-window-only --quiet}
 136         if {[info exists ocean]} { lappend cmd --ocean $ocean }
 137         if {[info exists pirate]} { lappend cmd --pirate $pirate }
 138         manyset [split [eval exec $cmd] " "] ocean pirate
 139         if {![llength $ocean] || ![llength $pirate]} {
 140             error "$ocean $pirate ?"
 141         }
 142     }
 143     lappend scraper $ocean
 144 }
 145
 146
 147 #---------- loading and parsing the vessel notes ----------
 148
 149 proc load-notes {} {
 150     global notes_loc notes_data
 151     if {[regexp {^\w+\:} $notes_loc]} {
 152         update
 153         debug "FETCHING NOTES $notes_loc"
 154         set req [::http::geturl $notes_loc]
 155         switch -glob [::http::status $req].[::http::ncode $req] {
 156             ok.200 { }
 157             ok.* { error "retrieving vessel-notes: [::http::code $req]" }
 158             * { error "Retrieving vessel-notes: [::http::error $req]" }
 159         }
 160         set newdata [::http::data $req]
 161         ::http::cleanup $req
 162     } else {
 163         debug "READING NOTES $notes_loc"
 164         set vn [open $notes_loc]
 165         set newdata [read $vn]
 166         close $vn
 167     }
 168     set notes_data $newdata
 169 }
 170
 171 proc parse-notes {} {
 172     global notes_data notes
 173     catch { unset notes }
 174
 175     set lno 0
 176     foreach l [split $notes_data "\n"] {
 177         incr lno
 178         errexpect-setline $lno $l
 179         set l [string trim $l]
 180         if {![string length $l]} continue
 181         if {[regexp {^\#} $l]} continue
 182         if {![regexp -expanded \
 183                   {^ (\d+) (?: \s+([^=]*?) )? \s* =
 184                       (?: \s* (\S+)
 185                        (?: \s+ (\S+) )?)? $} \
 186                   $l dummy vid vname owner note]} {
 187               errexpect-error "badly formatted"
 188         }
 189         set vname [string trim $vname]
 190         if {[info exists notes($vid)]} {
 191             errexpect-error "duplicate vesselid $vid"
 192         }
 193         set notes($vid) [list $lno $vname $owner $note]
 194     }
 195 }
 196
 197 proc note-info {lno vid name island description} {
 198     global note_infos
 199     lappend note_infos [list $lno $vid $name $island $description]
 200 }
 201
 202 proc display-note-infos {} {
 203     global note_infos note_missings notes
 204
 205     set nmissing [llength $note_missings]
 206     debug "display-note-infos $nmissing [array size notes]"
 207
 208     if {[llength $note_infos]} {
 209         set tiny "[llength $note_infos] warning(s)"
 210     } elseif {$nmissing && [array size notes]} {
 211         set tiny "$nmissing missing"
 212     } else {
 213         return
 214     }
 215
 216     set infodata {}
 217
 218     foreach info $note_infos {
 219         manyset $info lno vid name island description
 220         append infodata "vessel"
 221         append infodata " $vid"
 222         if {[string length $name]} { append infodata " $name" }
 223         if {[string length $island]} { append infodata " ($island)" }
 224         append infodata ": " $description "\n"
 225     }
 226
 227     if {$nmissing} {
 228         if {[string length $infodata]} { append infodata "\n" }
 229         append infodata "$nmissing vessel(s) not mentioned in notes:\n"
 230         set last_island {}
 231         foreach info [lsort $note_missings] {
 232             manyset $info island name vid
 233             if {[string compare $island $last_island]} {
 234                 append infodata "# $island:\n"
 235                 set last_island $island
 236             }
 237             append infodata [format "%-9d %-29s =\n" $vid $name]
 238         }
 239     }
 240
 241     parser-control-failed-core .cp.ctrl.notes notes \
 242         white blue 0 \
 243         $tiny \
 244         "[llength $note_infos] warning(s);\
 245          $nmissing vessel(s) missing" \
 246         "Full description of warnings and missing vessels:" \
 247         $infodata
 248 }
 249
 250 #---------- vessel properties ----------
 251
 252 proc info-cache-update {} {
 253     global info_source info_cache
 254     file mkdir $info_cache
 255     exec sh -c "cp -u icons/* $info_cache/."
 256
 257     if {[string length $info_source]} {
 258         set cmdl [list \
 259                   rsync -udLKtOzm \
 260                   --exclude=*~ --exclude=*.bak --exclude=.* --exclude=*.tmp \
 261                   $info_source/ $info_cache 2>@ stderr]
 262         debug "INFO-CACHE $cmdl"
 263         eval exec $cmdl
 264     }
 265
 266     set f [open $info_cache/vessel-info]
 267     glset vessel_class_data [read $f]
 268     close $f
 269 }
 270
 271 proc vesselclasses-init {} {
 272     global vc_game2code vc_code2abbrev vc_code2full vc_codes
 273
 274     global vessel_class_data
 275     manyset $vessel_class_data classinfos subclassinfos
 276
 277     set vc_codes {}
 278     foreach {game code abbrev full} $classinfos {
 279         if {![regexp {^[a-z][a-z]$} $code code]} { error "bad code" }
 280         if {![regexp {^[a-z][a-z]$} $abbrev abbrev]} { error "bad abbrev" }
 281         lappend vc_codes $code
 282         set vc_game2code($game) $code
 283         set vc_code2abbrev($code) $abbrev
 284         set vc_code2full($code) $full
 285         load-icon $abbrev
 286     }
 287
 288     global vsc_code2report
 289     global vsc_game2code
 290     set vsc_game2code(null) {}
 291     set vsc_code2report() Ordinary
 292     set vsc_code2report(!) "Special/L.E."
 293     foreach {game code full} $subclassinfos {
 294         if {![regexp {^[A-Z]$} $code code]} { error "bad code" }
 295         set vsc_game2code($game) $code
 296         set vsc_code2report($code) $full
 297     }
 298
 299     load-icon atsea
 300     foreach a {battle borrow dot} {
 301         foreach b {ours dot query} {
 302             load-icon-combine $a $b
 303         }
 304     }
 305 }
 306
 307 proc load-icon {icon} {
 308     global info_cache
 309     image create bitmap icon/$icon -file $info_cache/$icon.xbm
 310 }
 311
 312 proc load-icon-combine {args} {
 313     global info_cache
 314     set cmd {}
 315     set delim "pnmcat -lr "
 316     foreach icon $args {
 317         append cmd $delim " <(xbmtopbm $info_cache/$icon.xbm)"
 318         set delim " <(pbmmake -white 1 1)"
 319     }
 320     append cmd " | pbmtoxbm"
 321     debug "load-icon-combine $cmd"
 322     image create bitmap icon/[join $args +] -data [exec bash -c $cmd]
 323 }
 324
 325 proc code-lockown2icon {lockown} {
 326     manyset [split $lockown ""] lock notown
 327     return icon/[
 328                  lindex {battle borrow dot} $lock
 329                 ]+[
 330                    lindex {ours dot query} $notown
 331                   ]
 332 }
 333
 334 proc canvas-horiz-stack {xvar xoff y bind type args} {
 335     upvar 1 $xvar x
 336     upvar 1 canvas canvas
 337     set id [eval $canvas create $type [expr {$x+$xoff}] $y $args]
 338     set bbox [$canvas bbox $id]
 339     set x [lindex $bbox 2]
 340     $canvas bind $id <ButtonPress> $bind
 341     return $id
 342 }
 343
 344 proc code2canvas {code canvas x yvar qty qtylen bind} {
 345     global vc_code2abbrev
 346     upvar 1 $yvar y
 347
 348     manyset [split $code _] inport class subclass lockown xabbrev
 349
 350     set stackx $x
 351     incr stackx 2
 352     set imy [expr {$y+2}]
 353
 354     if {!$inport} { incr qtylen -1 }
 355     if {$qtylen<=0} { set qtylen {} }
 356     set qty [format "%${qtylen}s" $qty]
 357
 358     set qtyid [canvas-horiz-stack stackx 0 $y $bind \
 359                    text -anchor nw -font fixed -text $qty]
 360
 361     if {!$inport} {
 362         canvas-horiz-stack stackx 0 $imy $bind \
 363             image -anchor nw -image icon/atsea
 364         incr stackx
 365     }
 366
 367     upvar #0 vc_code2abbrev($class) vcabb
 368     if {![info exists vcabb]} {
 369         set vcabb vc-$class
 370         image create bitmap icon/$vcabb -data \
 371             [exec pbmtext -builtin fixed $class | pnminvert | pnmcrop >t.pnm]
 372     }
 373     canvas-horiz-stack stackx -1 $imy $bind \
 374             image -anchor nw -image icon/$vcabb
 375
 376     if {[string length $subclass]} {
 377         canvas-horiz-stack stackx 0 $y $bind \
 378             text -anchor nw -font fixed -text \
 379             $subclass
 380     }
 381
 382     incr stackx
 383     canvas-horiz-stack stackx 0 $imy $bind \
 384         image -anchor nw -image [code-lockown2icon $lockown]
 385     incr stackx
 386
 387     if {[string length $xabbrev]} {
 388         canvas-horiz-stack stackx 0 $y $bind \
 389             text -anchor nw -font fixed -text \
 390             $xabbrev
 391     }
 392
 393     set bbox [$canvas bbox $qtyid]
 394     set ny [lindex $bbox 3]
 395     set bid [$canvas create rectangle \
 396                  $x $y $stackx $ny \
 397                  -fill white]
 398
 399     set y $ny
 400     $canvas lower $bid $qtyid
 401
 402     $canvas bind $bid <ButtonPress> $bind
 403 }
 404
 405 proc show-report-decode {code} {
 406     global vc_code2full
 407
 408     manyset [split $code _] inport classcode subclass lockown xabbrev
 409     manyset [split $lockown ""] lock notown
 410
 411     report-set inport [lindex {{At Sea} {In port}} $inport]
 412     report-set class $vc_code2full($classcode)
 413
 414     upvar #0 vsc_code2report($subclass) subclass_report
 415     if {[info exists subclass_report]} {
 416         report-set subclass $subclass_report
 417     } else {
 418         report-set subclass "Subclass \"$subclass\""
 419     }
 420
 421     report-set lock [lindex {
 422         {Battle ready} {Unlocked} {Locked}
 423     } $lock]
 424
 425     switch -exact $notown {
 426         0 { report-set own "Yours" }
 427         1 { report-set own "Other pirate's" }
 428         2 { report-set own "Owner unknown" }
 429         default { report-set own "?? $notown" }
 430     }
 431
 432     if {[string length $xabbrev]} {
 433         report-set xabbrev "Notes flags: $xabbrev"
 434     } else {
 435         report-set xabbrev "No flags in notes"
 436     }
 437 }
 438
 439 #---------- smashing ----------
 440
 441 set smash_subclass 0
 442
 443 proc smash-code {code} {
 444     manyset [split $code _] inport class subclass lockown xabbrev
 445
 446     global smash_subclass
 447     if {$smash_subclass > 1} {
 448         set subclass {}
 449     } elseif {$smash_subclass && [string length $subclass]} {
 450         set subclass !
 451     }
 452
 453     return [join [list $inport $class $subclass $lockown $xabbrev] _]
 454 }
 455
 456 proc make-radio-smasher {w label variable descs} {
 457     frame $w
 458     label $w.label -text $label
 459     pack $w.label -side left
 460     for {set i 0} {$i < [llength $descs]} {incr i} {
 461         radiobutton $w.v$i \
 462             -variable $variable -value $i -command redraw-needed \
 463             -text [lindex $descs $i]
 464         pack $w.v$i -side left
 465     }
 466 }
 467
 468 #---------- filtering ----------
 469
 470 set filters {}
 471
 472 proc filter-values/size {} { global vc_codes; return $vc_codes }
 473 proc filter-icon/size {code} {
 474     upvar #0 vc_code2abbrev($code) abb
 475     return icon/$abb
 476 }
 477 proc filter-default/size {code} { return 1 }
 478 proc filter-says-yes/size {codel} {
 479     set sizecode [lindex $codel 1]
 480     upvar #0 filter_size($sizecode) yes
 481     return $yes
 482 }
 483
 484 proc filter-values/lockown {} {
 485     foreach lv {0 1 2} {
 486         foreach ov {0 1 2} {
 487             lappend vals "$lv$ov"
 488         }
 489     }
 490     return $vals
 491 }
 492 proc filter-icon/lockown {lockown} { return [code-lockown2icon $lockown] }
 493 proc filter-default/lockown {lockown} {
 494     return [regexp {^[01]|^2[^1]} $lockown]
 495 }
 496 proc filter-says-yes/lockown {codel} {
 497     set lockown [lindex $codel 3]
 498     upvar #0 filter_lockown($lockown) yes
 499     return $yes
 500 }
 501
 502 proc filter-validate/xabbre {re} {
 503     if {[catch {
 504         regexp -- $re {}
 505     } emsg]} {
 506         regsub {^.*:\s*} $emsg {} emsg
 507         regsub {^.*(.{30})$} $emsg {\1} emsg
 508         return $emsg
 509     }
 510     return {}
 511 }
 512 proc filter-says-yes/xabbre {codel} {
 513     global filter_xabbre
 514     set xabbrev [lindex $codel 4]
 515     return [regexp -- $filter_xabbre $xabbrev]
 516 }
 517
 518 proc filter-tickbox-flip {fil} {
 519     upvar #0 filter_$fil vars
 520     set values [filter-values/$fil]
 521     foreach val $values {
 522         set vars($val) [expr {!$vars($val)}]
 523     }
 524     redraw-needed
 525 }
 526
 527 proc make-tickbox-filter {fil label rows inrow} {
 528     upvar #0 filter_$fil vars
 529     set fw [make-filter tickbox $fil $label frame]
 530     set values [filter-values/$fil]
 531     set nvalues [llength $values]
 532     if {!$inrow} {
 533         set inrow [expr {($nvalues + $rows) / $rows}]
 534     }
 535     set noicons [catch { info args filter-icon/$fil }]
 536     for {set ix 0} {$ix < $nvalues} {incr ix} {
 537         set val [lindex $values $ix]
 538         set vars($val) [filter-default/$fil $val]
 539         checkbutton $fw.$ix -variable filter_${fil}($val) \
 540             -font fixed -command redraw-needed
 541         if {!$noicons} {
 542             $fw.$ix configure -image [filter-icon/$fil $val] -height 16
 543         } else {
 544             $fw.$ix configure -text [filter-map/$fil $val]
 545         }
 546         grid configure $fw.$ix -sticky sw \
 547             -row [expr {$ix / $inrow}] \
 548             -column [expr {$ix % $inrow}]
 549     }
 550     button $fw.invert -text flip -command [list filter-tickbox-flip $fil] \
 551         -padx 0 -pady 0
 552     grid configure $fw.invert -sticky se \
 553         -row [expr {$rows-1}] \
 554         -column [expr {$inrow-1}]
 555 }
 556
 557 proc entry-filter-changed {fw fil n1 n2 op} {
 558     global errorInfo
 559     upvar #0 filter_$fil realvar
 560     upvar #0 filterentered_$fil entryvar
 561     global def_background
 562     debug "entry-filter-changed $fw $fil $entryvar"
 563     if {[catch {
 564         set error [filter-validate/$fil $entryvar]
 565         if {[string length $error]} {
 566             $fw.error configure -text $error -foreground white -background red
 567         } else {
 568             $fw.error configure -text { } -background $def_background
 569             set realvar $entryvar
 570             redraw-needed
 571         }
 572     } emsg]} {
 573         puts stderr "FILTER CHECK ERROR $emsg $errorInfo"
 574     }
 575 }
 576
 577 proc make-entry-filter {fil label def} {
 578     global filterentered_$fil
 579     upvar #0 filter_$fil realvar
 580     set realvar $def
 581     set fw [make-filter entry $fil $label frame]
 582     entry $fw.entry -textvariable filterentered_$fil
 583     label $fw.error
 584     glset def_background [$fw.error cget -background]
 585     trace add variable filterentered_$fil write \
 586         [list entry-filter-changed $fw $fil]
 587     pack $fw.entry $fw.error -side top -anchor w
 588 }
 589
 590 proc make-filter {kind fil label ekind} {
 591     global filters
 592     label .filter.lab_$fil -text $label -justify left
 593     $ekind .filter.$fil
 594     lappend filters $fil
 595     set nfilters [llength $filters]
 596     grid configure .filter.lab_$fil -row $nfilters -column 0 -sticky nw -pady 4
 597     grid configure .filter.$fil -row $nfilters -column 1 -sticky w -pady 3
 598     return .filter.$fil
 599 }
 600
 601 proc make-filters {} {
 602     make-tickbox-filter size Size 2 0
 603     make-tickbox-filter lockown "Lock/\nowner" 2 6
 604     make-entry-filter xabbre "Flags\n regexp" {}
 605 }
 606
 607 proc filterstyle-changed {n1 n2 op} {
 608     global filterstyle
 609     debug "filterstyle-changed $filterstyle"
 610     redraw-needed
 611 }
 612
 613 proc filters-say-yes {code} {
 614     global filters filterstyle
 615     debug "filters-say-yes $code"
 616     set codel [split $code _]
 617     set lockown [lindex $codel 3]
 618     switch -exact $filterstyle {
 619         0 { return 1 }
 620         1 { return [filter-default/lockown $lockown] }
 621         2 { return [regexp {^.0} $lockown] }
 622         3 { }
 623         default { error $filterstyle }
 624     }
 625
 626     foreach fil $filters {
 627         if {![filter-says-yes/$fil $codel]} { return 0 }
 628     }
 629     return 1
 630 }
 631
 632 #---------- loading and parsing the clipboard (vessel locations) ----------
 633
 634 proc vessel {vin} {
 635     global pirate notes_used note_missings newnotes
 636     upvar 1 $vin vi
 637
 638     set codel {}
 639     lappend codel [errexpect-arrayget-boolean vi inPort]
 640
 641     set gameclass [errexpect-arrayget vi vesselClass]
 642     upvar #0 vc_game2code($gameclass) class
 643     if {![info exists class]} {
 644         set class "($gameclass)"
 645         upvar #0 vc_code2abbrev($class) vcabb
 646         set vcabb vc-$class
 647         set data [exec pbmtext -builtin fixed " $gameclass " \
 648                  | pnminvert | pnmcrop | pbmtoxbm]
 649         debug "INVENTED ICON $vcabb $data"
 650         image create bitmap icon/$vcabb -data $data
 651
 652         global vc_code2full
 653         set vc_code2full($class) "Type \"$gameclass\""
 654     }
 655     lappend codel $class
 656
 657     set gamesubclass [errexpect-arrayget vi vesselSubclass]
 658     upvar #0 vsc_game2code($gamesubclass) subclass
 659     if {[info exists subclass]} {
 660         lappend codel $subclass
 661     } else {
 662         lappend codel ($gamesubclass)
 663     }
 664
 665     switch -exact [errexpect-arrayget vi isLocked]/[ \
 666                    errexpect-arrayget vi isBattleReady] {
 667         true/false      { set lock 2 }
 668         false/false     { set lock 1 }
 669         false/true      { set lock 0 }
 670         default         { errexpect-error "unexpected isLocked/isBattleReady" }
 671     }
 672
 673     set vid [errexpect-arrayget vi vesselId]
 674     upvar #0 notes($vid) note
 675     set realname [errexpect-arrayget vi vesselName]
 676     set island [errexpect-arrayget vi islandName]
 677
 678     set owner {}
 679     set xabbrev {}
 680     if {[info exists note]} {
 681         manyset $note lno notename owner xabbrev
 682         if {[string compare -nocase $realname $notename]} {
 683             note-info $lno $vid $realname $island \
 684                 "notes say name is $notename"
 685         }
 686         if {[string length $owner]} {
 687             if {![string compare $owner $pirate]} {
 688                 set notown 0
 689             } else {
 690                 set notown 1
 691             }
 692         } else {
 693             set notown 2
 694         }
 695         append abbrev $xabbrev
 696         set notes_used($vid) 1
 697
 698     } else {
 699         set notown 2
 700         lappend note_missings [list $island $realname $vid]
 701     }
 702
 703     lappend codel "$lock$notown" $xabbrev
 704     lappend newnotes [list $vid $realname $owner $xabbrev]
 705     set kk "$island [join $codel _]"
 706     upvar #0 found($kk) k
 707     lappend k [list $vid $realname $owner]
 708
 709     debug "CODED $kk $vid $realname"
 710 }
 711
 712 set clipboard {}
 713 proc parse-clipboard {} {
 714     global clipboard found notes notes_used newnotes
 715
 716     catch { unset found }
 717     catch { unset notes_used }
 718     glset note_infos {}
 719     glset note_missings {}
 720
 721     set newnotes {}
 722
 723     set itemre { (\w+) = ([^=]*) }
 724     set manyitemre "^\\\[ $itemre ( (?: ,\\ $itemre)* ) \\]\$"
 725     debug $manyitemre
 726
 727     set lno 0
 728     foreach l [split $clipboard "\n"] {
 729         incr lno
 730         errexpect-setline $lno $l
 731         if {![string length $l]} continue
 732         catch { unset vi }
 733         while 1 {
 734                 if {![regexp -expanded $manyitemre $l dummy \
 735                         thiskey thisval rhs]} {
 736                     errexpect-error "badly formatted"
 737                 }
 738                 set vi($thiskey) $thisval
 739                 if {![string length $rhs]} break
 740                 regsub {^, } $rhs {} rhs
 741                 set l "\[$rhs\]"
 742         }
 743         vessel vi
 744     }
 745
 746     if {[llength $newnotes]} {
 747         foreach vid [lsort [array names notes]] {
 748             if {![info exists notes_used($vid)]} {
 749                 manyset $notes($vid) lno notename
 750                 note-info $lno $vid $notename {} \
 751                     "vessel in notes no longer found"
 752             }
 753         }
 754     }
 755 }
 756
 757 proc load-clipboard-file {fn} {
 758     set f [open $fn]
 759     glset clipboard [read $f]
 760     close $f
 761 }
 762
 763
 764 #---------- loading and parsing the chart ----------
 765
 766 proc load-chart {} {
 767     global chart scraper
 768     debug "FETCHING CHART"
 769     set chart [eval exec $scraper [list | perl -we {
 770         use strict;
 771         use CommodsScrape;
 772         use IO::File;
 773         use IO::Handle;
 774         yppedia_chart_parse(\*STDIN, (new IO::File ">/dev/null"),
 775                 sub { sprintf "%d %d", @_; },
 776                 sub { printf "archlabel %d %d %s\n", @_; },
 777                 sub { printf "island %s {%s} %s\n", @_; },
 778                 sub { printf "league %s %s %s.\n", @_; },
 779                 sub { printf STDERR "warning: %s: incomprehensible: %s", @_; }
 780                         );
 781         STDOUT->error and die $!;
 782     }]]
 783 }
 784
 785
 786 set scale 16
 787
 788 proc coord {c} {
 789         global scale
 790         return [expr {$c * $scale}]
 791 }
 792
 793 proc chart-got/archlabel {args} { }
 794 proc chart-got/island {x y isle sizecol} {
 795         debug "ISLE $x $y $isle $sizecol"
 796         global canvas isleloc
 797         set isleloc($isle) [list $x $y]
 798         set sz 5
 799 #       $canvas create oval \
 800 #               [expr {[coord $x] - $sz}] [expr {[coord $y] - $sz}] \
 801 #               [expr {[coord $x] + $sz}] [expr {[coord $y] + $sz}] \
 802 #               -fill blue
 803         set colour "#888"
 804         if {[string match *_col $sizecol]} { set colour black }
 805         $canvas create text [coord $x] [coord $y] \
 806                 -text $isle -anchor s -fill $colour
 807 }
 808 proc chart-got/league {x1 y1 x2 y2 kind} {
 809 #       debug "LEAGUE $x1 $y1 $x2 $y2 $kind"
 810         global canvas
 811         set l [$canvas create line \
 812                 [coord $x1] [coord $y1] \
 813                 [coord $x2] [coord $y2]]
 814         if {![string compare $kind .]} {
 815                 $canvas itemconfigure $l -dash .
 816         }
 817 }
 818
 819 proc redraw-needed {} {
 820     global redraw_after
 821     debug "REDRAW NEEDED"
 822     if {[info exists redraw_after]} return
 823     set redraw_after [after 250 draw]
 824 }
 825
 826 proc draw {} {
 827     global chart found isleloc canvas redraw_after islandnames smfound
 828
 829     catch { after cancel $redraw_after }
 830     catch { unset redraw_after }
 831
 832     $canvas delete all
 833
 834     foreach l [split $chart "\n"] {
 835 #       debug "CHART-GOT $l"
 836         set proc [lindex $l 0]
 837         eval chart-got/$proc [lrange $l 1 end]
 838     }
 839
 840     catch { unset smfound }
 841     foreach key [lsort [array names found]] {
 842         regexp {^(.*) (\S+)$} $key dummy islandname code
 843         set smcode [smash-code $code]
 844         debug "smashed $code => $smcode"
 845         set smkey "$islandname $smcode"
 846         foreach vessel $found($key) { lappend smfound($smkey) $vessel }
 847     }
 848
 849     set islandnames {}
 850     set lastislandname {}
 851     foreach smkey [lsort [array names smfound]] {
 852         set c [llength $smfound($smkey)]
 853 #       debug "SHOWING $smkey $c"
 854         regexp {^(.*) (\S+)$} $smkey dummy islandname code
 855
 856         if {![filters-say-yes $code]} continue
 857
 858         if {[string compare $lastislandname $islandname]} {
 859                 manyset $isleloc($islandname) x y
 860                 set x [coord $x]
 861                 set y [coord $y]
 862                 set lastislandname $islandname
 863                 lappend islandnames $islandname
 864 #               debug "START Y $y"
 865         }
 866
 867         if {$c > 1} { set qty [format %d $c] } else { set qty {} }
 868         code2canvas $code $canvas $x y $qty 2 \
 869             [list show-report $islandname $code]
 870 #       debug "NEW Y $y"
 871     }
 872
 873     panner::updatecanvas-bbox .cp.ctrl.pan
 874
 875     islandnames-update
 876 }
 877
 878
 879 #---------- parser error reporting ----------
 880
 881 proc parser-control-create {w base invokebuttontext etl_title} {
 882     frame $w
 883     button $w.do -text $invokebuttontext -command invoke_$base -pady 3
 884
 885     frame $w.resframe -width 120 -height 32
 886     button $w.resframe.res -text {} -anchor nw \
 887         -padx 1 -pady 1 -borderwidth 0 -justify left
 888     glset deffont_$base [$w.resframe.res cget -font]
 889     place $w.resframe.res -relx 0.5 -y 0 -anchor n
 890
 891     pack $w.do -side top
 892     pack $w.resframe -side top -expand y -fill both
 893
 894     set eb .err_$base
 895     toplevel $eb
 896     wm withdraw $eb
 897     wm title $eb "where-vessels - $etl_title"
 898     wm protocol $eb WM_DELETE_WINDOW [list wm withdraw $eb]
 899
 900     label $eb.title -text $etl_title
 901     pack $eb.title -side top
 902
 903     button $eb.close -text Close -command [list wm withdraw $eb]
 904     pack $eb.close -side bottom
 905
 906     frame $eb.emsg -bd 2 -relief groove
 907     label $eb.emsg.lab -anchor nw -text "Error:"
 908     text $eb.emsg.text -height 1
 909     pack $eb.emsg.text -side bottom -fill x
 910     pack $eb.emsg.lab -side left
 911
 912     pack $eb.emsg -side top -pady 2 -fill x
 913
 914     frame $eb.text -bd 2 -relief groove
 915     pack $eb.text -side bottom -pady 2 -fill both -expand y
 916
 917     label $eb.text.lab -anchor nw
 918
 919     text $eb.text.text -width 85 \
 920         -xscrollcommand [list $eb.text.xscroll set] \
 921         -yscrollcommand [list $eb.text.yscroll set]
 922     $eb.text.text tag configure error \
 923         -background red -foreground white
 924
 925     scrollbar $eb.text.xscroll -orient horizontal \
 926         -command [list $eb.text.text xview]
 927     scrollbar $eb.text.yscroll -orient vertical \
 928         -command [list $eb.text.text yview]
 929
 930     grid configure $eb.text.lab -row 0 -column 0 -sticky w -columnspan 2
 931     grid configure $eb.text.text -row 1 -column 0 -sticky news
 932     grid configure $eb.text.yscroll -sticky ns -row 1 -column 1
 933     grid configure $eb.text.xscroll -sticky ew -row 2 -column 0
 934     grid rowconfigure $eb.text 0 -weight 0
 935     grid rowconfigure $eb.text 1 -weight 1
 936     grid rowconfigure $eb.text 2 -weight 0
 937     grid columnconfigure $eb.text 0 -weight 1
 938     grid columnconfigure $eb.text 1 -weight 0
 939 }
 940
 941 proc parser-control-ok-core {w base background show} {
 942     debug "parser-control-ok-core $w $base $background $show"
 943     upvar #0 deffont_$base deffont
 944     $w.resframe.res configure \
 945         -background $background -disabledforeground black -font $deffont \
 946         -state disabled -command {} \
 947         -text $show
 948 }
 949 proc parser-control-ok {w base show} {
 950     parser-control-ok-core $w $base green $show
 951 }
 952 proc parser-control-none {w base show} {
 953     parser-control-ok-core $w $base blue $show
 954 }
 955 proc parser-control-failed-core {w base foreground background smallfont
 956                                  tiny summary fulldesc fulldata} {
 957     debug "parser-control-failed-core $w $base $summary $fulldesc"
 958     upvar #0 deffont_$base deffont
 959     set eb .err_$base
 960
 961     $eb.emsg.text delete 0.0 end
 962     $eb.emsg.text insert end $summary
 963
 964     $eb.text.lab configure -text $fulldesc
 965     $eb.text.text delete 0.0 end
 966     $eb.text.text insert end $fulldata
 967
 968     regsub -all {.{18}} $tiny "&\n" ewrap
 969
 970     if {$smallfont} {
 971         set font fixed
 972     } else {
 973         set font $deffont
 974     }
 975
 976     $w.resframe.res configure \
 977         -background $background -foreground $foreground -font $font \
 978         -state normal -command [list wm deiconify $eb] \
 979         -text $ewrap
 980 }
 981
 982 proc parser-control-failed-expected {w base emsg lno ei fulldesc newdata} {
 983     set eb .err_$base
 984
 985     set line [lindex [split $ei "\n"] 0]
 986     debug "parser-control-failed-expected: $w $base: $lno: $emsg\n $line"
 987
 988     parser-control-failed-core $w $base \
 989         white red 1 \
 990         "err: [string trim $emsg]: \"$line\"" \
 991         "at line $lno: $emsg" \
 992         $fulldesc $newdata
 993
 994     $eb.text.text tag add error $lno.0 $lno.end
 995     $eb.text.text see $lno.0
 996 }
 997 proc parser-control-failed-unexpected {w base emsg ei} {
 998     global errorInfo
 999     parser-control-failed-core $w $base \
1000         black yellow 1 \
1001         $emsg $emsg "Details and stack trace:" $ei
1002 }
1003
1004 proc reparse {base varname old fulldesc okshow noneshow parse ok} {
1005     upvar #0 $varname var
1006     manyset [errexpect-catch {
1007         uplevel 1 $parse
1008         if {[string length [string trim $var]]} {
1009             parser-control-ok .cp.ctrl.$base $base $okshow
1010         } else {
1011             parser-control-none .cp.ctrl.$base $base $noneshow
1012         }
1013     }] failed emsg lno ei
1014     if {$failed} {
1015         parser-control-failed-expected .cp.ctrl.$base $base \
1016             $emsg $lno $ei $fulldesc $var
1017         set var $old
1018         uplevel 1 $parse
1019     } else {
1020         uplevel 1 $ok
1021     }
1022 }
1023
1024 #---------- island names selection etc. ----------
1025
1026 proc islandnames-update {} {
1027     global islandnames
1028     .islands.count configure -text [format "ships at %d island(s)" \
1029                                         [llength $islandnames]]
1030 }
1031
1032 proc islandnames-select {} {
1033     .islands.clip configure -relief sunken -state disabled
1034     selection own -command islandnames-deselect .islands.clip
1035 }
1036 proc islandnames-deselect {} {
1037     .islands.clip configure -relief raised -state normal
1038 }
1039
1040 proc islandnames-handler {offset maxchars} {
1041     global islandnames
1042     return [string range [join $islandnames ", "] \
1043                 $offset [expr {$offset+$maxchars-1}]]
1044 }
1045
1046 #---------- main user interface ----------
1047
1048 proc widgets-setup {} {
1049     global canvas debug pirate ocean filterstyle
1050
1051     wm geometry . 1024x600
1052     wm title . "where-vessels - $pirate on the $ocean ocean"
1053
1054     #----- map -----
1055
1056     frame .f -border 1 -relief groove
1057     set canvas .f.c
1058     canvas $canvas
1059     pack $canvas -expand 1 -fill both
1060     pack .f -expand 1 -fill both -side left
1061
1062     #----- control panels and filter -----
1063
1064     frame .cp
1065     frame .smash -relief groove -bd 2 -padx 1
1066     frame .filter -relief groove -bd 2 -padx 1
1067     frame .islands -pady 2
1068     pack .cp .filter .islands .smash -side top
1069
1070     label .smash.title -text Smash
1071     pack .smash.title -side top
1072
1073     make-radio-smasher .smash.subclass Subclass smash_subclass \
1074         {Show Normal/LE Hide}
1075     pack .smash.subclass -side top
1076
1077     set filterstyle 1
1078     trace add variable filterstyle write filterstyle-changed
1079
1080     frame .filter.title
1081     label .filter.title.title -text Show
1082     pack .filter.title.title -side left
1083     for {set fing 0} {$fing < 4} {incr fing} {
1084         radiobutton .filter.title.f$fing \
1085             -variable filterstyle -value $fing \
1086             -text [lindex {All Useable Mine These:} $fing]
1087         pack .filter.title.f$fing -side left
1088     }
1089
1090     grid configure .filter.title -row 0 -column 0 -columnspan 2
1091
1092     #----- control panel -----
1093
1094     frame .cp.ctrl
1095     pack .cp.ctrl -side left -anchor n
1096
1097     debug "BBOX [$canvas bbox all]"
1098
1099     panner::canvas-scroll-bbox .f.c
1100     panner::create .cp.ctrl.pan .f.c 120 120 $debug
1101
1102     pack .cp.ctrl.pan -side top -pady 0 -padx 5
1103     frame .cp.ctrl.zoom
1104     pack .cp.ctrl.zoom -side top
1105
1106     button .cp.ctrl.zoom.out -text - -font {Courier 16} -command {zoom /2} -pady 0
1107     button .cp.ctrl.zoom.in  -text + -font {Courier 16} -command {zoom *2} -pady 0
1108     pack .cp.ctrl.zoom.out .cp.ctrl.zoom.in -side left
1109
1110     parser-control-create .cp.ctrl.acquire \
1111         acquire Acquire \
1112         "Clipboard parsing error" \
1113
1114     pack .cp.ctrl.acquire -side top -pady 2
1115
1116     parser-control-create .cp.ctrl.notes \
1117         notes "Reload notes" \
1118         "Vessel notes loading report" \
1119
1120     pack .cp.ctrl.notes -side top -pady 2
1121
1122     #----- island name count and copy -----
1123
1124     label .islands.count
1125     button .islands.clip -text "copy island names" -pady 2 -padx 2 \
1126          -command islandnames-select
1127     selection handle .islands.clip islandnames-handler
1128     pack .islands.count .islands.clip -side left
1129
1130     #----- decoding etc. report -----
1131
1132     frame .cp.report
1133     pack .cp.report -side left -anchor n
1134
1135     label .cp.report.island -text { }
1136
1137     canvas .cp.report.abbrev -width 1 -height 15
1138
1139     frame .cp.report.code
1140     label .cp.report.code.lab -text Code:
1141     glset report_code { }
1142     entry .cp.report.code.code -state readonly \
1143         -textvariable report_code -width 15
1144     pack .cp.report.code.lab .cp.report.code.code -side left
1145     frame .cp.report.details -bd 2 -relief groove -padx 2 -pady 2
1146
1147     listbox .cp.report.list -height 5
1148
1149     pack .cp.report.island .cp.report.abbrev .cp.report.details \
1150         .cp.report.list -side top
1151     #pack .cp.report.code -side top
1152     pack configure .cp.report.details -fill x
1153
1154     foreach sw {inport class subclass lock own xabbrev} {
1155         label .cp.report.details.$sw -text { }
1156         pack .cp.report.details.$sw -side top -anchor w
1157     }
1158 }
1159
1160 proc report-set {sw val} { .cp.report.details.$sw configure -text $val }
1161
1162 proc show-report {islandname code} {
1163     .cp.report.island configure -text $islandname
1164
1165     .cp.report.abbrev delete all
1166     set y 2
1167     code2canvas $code .cp.report.abbrev 5 y {} 0 {}
1168     manyset [.cp.report.abbrev bbox all] minx dummy maxx dummy
1169     .cp.report.abbrev configure -width [expr {$maxx-$minx+4}]
1170
1171     glset report_code $code
1172     show-report-decode $code
1173
1174     set kk "$islandname $code"
1175     upvar #0 smfound($kk) k
1176
1177     .cp.report.list delete 0 end
1178
1179     foreach entry $k {
1180         manyset $entry vid name owner
1181         lappend owned($owner) $name
1182     }
1183
1184     foreach owner [lsort [array names owned]] {
1185         if {[string length $owner]} {
1186             set owndesc "$owner's"
1187         } else {
1188             set owndesc "Owner unknown"
1189         }
1190         .cp.report.list insert end "$owndesc:"
1191         foreach name $owned($owner) {
1192             .cp.report.list insert end " $name"
1193         }
1194     }
1195 }
1196
1197 proc zoom {extail} {
1198     global scale canvas
1199     set nscale [expr "\$scale $extail"]
1200     debug "ZOOM $scale $nscale"
1201     if {$nscale < 1 || $nscale > 200} return
1202     set scale $nscale
1203     draw
1204 }
1205
1206 proc invoke_acquire {} {
1207     global clipboard errorInfo
1208     set old $clipboard
1209
1210     if {[catch {
1211         set clipboard [clipboard get]
1212     } emsg]} {
1213         parser-control-failed-unexpected .cp.ctrl.acquire acquire \
1214             $emsg "fetching clipboard:\n\n$errorInfo"
1215         return
1216     }
1217
1218     reparse acquire \
1219         clipboard $old "Clipboard contents:" { acquired ok } { no vessels } {
1220             parse-clipboard
1221         } {
1222             display-note-infos
1223         }
1224     draw
1225 }
1226
1227 proc invoke_notes {} {
1228     global notes_data errorInfo notes_loc
1229     set old $notes_data
1230
1231     if {[catch {
1232         load-notes
1233     } emsg]} {
1234         parser-control-failed-unexpected .cp.ctrl.notes notes \
1235             $emsg "loading $notes_loc:\n\n$errorInfo"
1236         return
1237     }
1238
1239     reparse notes \
1240         notes_data $old "Vessel notes:" "loaded ok" { no notes } {
1241             parse-notes
1242             parse-clipboard
1243         } {
1244             display-note-infos
1245         }
1246     draw
1247 }
1248
1249 #---------- main program ----------
1250
1251 parseargs
1252 argdefaults
1253 httpclientsetup where-vessels
1254 info-cache-update
1255 vesselclasses-init
1256 load-chart
1257 widgets-setup
1258 make-filters
1259
1260 set notes_data {}
1261 if {[catch { parse-clipboard } emsg]} {
1262     puts stderr "$emsg\n$errorInfo"
1263     exit 1
1264 }
1265 after idle invoke_notes
1266
1267 draw
1268
1269 # rsync -r --exclude=\*~ yarrg/icons/. ijackson@chiark.greenend.org.uk:/home/ftp/users/ijackson/yarrg/vessel-info/.