yarrg/where-vessels

   1 #!/usr/bin/wish
   2 # show your vessels on a map
   3
   4 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   5 # players of Yohoho Puzzle Pirates.
   6 #
   7 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   8 #
   9 # This program is free software: you can redistribute it and/or modify
  10 # it under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation, either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  23 # are used without permission.  This program is not endorsed or
  24 # sponsored by Three Rings.
  25
  26
  27
  28 source yarrglib.tcl
  29 source panner.tcl
  30 package require http
  31
  32 #---------- general utilities ----------
  33
  34 set debug 0
  35 proc debug {m} {
  36     global debug
  37     if {$debug} { puts "DEBUG $m" }
  38 }
  39
  40 proc badusage {m} {
  41     puts stderr "where-vessels: bad usage: $m"
  42     exit 1
  43 }
  44
  45 proc glset {n val} {
  46     upvar #0 $n var
  47     set var $val
  48 }
  49
  50 #---------- expecting certain errors ----------
  51
  52 proc errexpect-setline {lno line} {
  53     glset errexpect_lno $lno
  54     glset errexpect_line $line
  55 }
  56
  57 proc errexpect-error {m} {
  58     global errexpect_line errexpect_lno
  59     error $m "$errexpect_line\n" [list YARRG-ERREXPECT $errexpect_lno]
  60 }
  61
  62 proc errexpect-arrayget {arrayvar key} {
  63     upvar 1 $arrayvar av
  64     upvar 1 ${arrayvar}($key) v
  65     if {[info exists v]} { return $v }
  66     errexpect-error "undefined $key"
  67 }
  68
  69 proc errexpect-arrayget-boolean {arrayvar key} {
  70     switch -exact [uplevel 1 [list errexpect-arrayget $arrayvar $key]] {
  71         true    { return 1 }
  72         false   { return 0 }
  73         default { errexpect-error "unexpected $key" }
  74     }
  75 }
  76
  77 proc errexpect-catch {code} {
  78     global errorInfo errorCode
  79     set rc [catch {
  80         uplevel 1 $code
  81     } rv]
  82     debug "ERREXPECT CATCH |$rc|$rv|$errorCode|$errorInfo|"
  83     if {$rc==1 && ![string compare YARRG-ERREXPECT [lindex $errorCode 0]]} {
  84         return [list 1 $rv [lindex $errorCode 1] $errorInfo]
  85     } elseif {$rc==0} {
  86         return [list 0 $rv]
  87     } else {
  88         return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rv
  89     }
  90 }
  91
  92 #---------- argument parsing ----------
  93
  94 proc nextarg {} {
  95     global ai argv
  96     if {$ai >= [llength $argv]} {
  97         badusage "option [lindex $argv [expr {$ai-1}]] needs a value"
  98     }
  99     set v [lindex $argv $ai]
 100     incr ai
 101     return $v
 102 }
 103
 104 set notes_loc vessel-notes
 105 set scraper {./yppedia-ocean-scraper --chart}
 106 set info_cache _vessel-info-cache
 107 set info_source rsync.yarrg.chiark.net::yarrg/vessel-info
 108
 109 proc parseargs {} {
 110     global ai argv
 111     global debug scraper
 112     set ai 0
 113
 114     while {[regexp {^\-} [set arg [lindex $argv $ai]]]} {
 115         incr ai
 116         switch -exact -- $arg {
 117             -- { break }
 118             --pirate { glset pirate [string totitle [nextarg]] }
 119             --ocean { glset ocean [string totitle [nextarg]] }
 120             --clipboard-file { load-clipboard-file [nextarg] }
 121             --local-html-dir { lappend scraper --local-html-dir=[nextarg] }
 122             --notes { glset notes_loc [nextarg] }
 123             --vessel-info-source { glset info_source [nextarg] }
 124             --debug { incr debug }
 125             default { badusage "unknown option $arg" }
 126         }
 127     }
 128     set argv [lrange $argv $ai end]
 129     if {[llength $argv]} { badusage "non-option args not allowed" }
 130 }
 131
 132 proc argdefaults {} {
 133     global ocean notes_loc pirate scraper
 134     if {![info exists ocean] || ![info exists pirate]} {
 135         set cmd {./yarrg --find-window-only --quiet}
 136         if {[info exists ocean]} { lappend cmd --ocean $ocean }
 137         if {[info exists pirate]} { lappend cmd --pirate $pirate }
 138         manyset [split [eval exec $cmd] " "] ocean pirate
 139         if {![llength $ocean] || ![llength $pirate]} {
 140             error "$ocean $pirate ?"
 141         }
 142     }
 143     lappend scraper $ocean
 144 }
 145
 146
 147 #---------- loading and parsing the vessel notes ----------
 148
 149 proc load-notes {} {
 150     global notes_loc notes_data
 151     if {[regexp {^\w+\:} $notes_loc]} {
 152         update
 153         debug "FETCHING NOTES $notes_loc"
 154         set req [::http::geturl $notes_loc]
 155         switch -glob [::http::status $req].[::http::ncode $req] {
 156             ok.200 { }
 157             ok.* { error "retrieving vessel-notes: [::http::code $req]" }
 158             * { error "Retrieving vessel-notes: [::http::error $req]" }
 159         }
 160         set newdata [::http::data $req]
 161         ::http::cleanup $req
 162     } else {
 163         debug "READING NOTES $notes_loc"
 164         set vn [open $notes_loc]
 165         set newdata [read $vn]
 166         close $vn
 167     }
 168     set notes_data $newdata
 169 }
 170
 171 proc parse-notes {} {
 172     global notes_data notes
 173     catch { unset notes }
 174
 175     set lno 0
 176     foreach l [split $notes_data "\n"] {
 177         incr lno
 178         errexpect-setline $lno $l
 179         set l [string trim $l]
 180         if {![string length $l]} continue
 181         if {[regexp {^\#} $l]} continue
 182         if {![regexp -expanded \
 183                   {^ (\d+) (?: \s+([^=]*?) )? \s* =
 184                       (?: \s* (\S+)
 185                        (?: \s+ (\S+) )?)? $} \
 186                   $l dummy vid vname owner note]} {
 187               errexpect-error "badly formatted"
 188         }
 189         set vname [string trim $vname]
 190         if {[info exists notes($vid)]} {
 191             errexpect-error "duplicate vesselid $vid"
 192         }
 193         set notes($vid) [list $lno $vname $owner $note]
 194     }
 195 }
 196
 197 proc note-info {lno vid name island description} {
 198     global note_infos
 199     lappend note_infos [list $lno $vid $name $island $description]
 200 }
 201
 202 proc display-note-infos {} {
 203     global note_infos note_missings notes
 204
 205     set nmissing [llength $note_missings]
 206     debug "display-note-infos $nmissing [array size notes]"
 207
 208     if {[llength $note_infos]} {
 209         set tiny "[llength $note_infos] warning(s)"
 210     } elseif {$nmissing && [array size notes]} {
 211         set tiny "$nmissing missing"
 212     } else {
 213         return
 214     }
 215
 216     set infodata {}
 217
 218     foreach info $note_infos {
 219         manyset $info lno vid name island description
 220         append infodata "vessel"
 221         append infodata " $vid"
 222         if {[string length $name]} { append infodata " $name" }
 223         if {[string length $island]} { append infodata " ($island)" }
 224         append infodata ": " $description "\n"
 225     }
 226
 227     if {$nmissing} {
 228         if {[string length $infodata]} { append infodata "\n" }
 229         append infodata "$nmissing vessel(s) not mentioned in notes:\n"
 230         set last_island {}
 231         foreach info [lsort $note_missings] {
 232             manyset $info island name vid
 233             if {[string compare $island $last_island]} {
 234                 append infodata "# $island:\n"
 235                 set last_island $island
 236             }
 237             append infodata [format "%-9d %-29s =\n" $vid $name]
 238         }
 239     }
 240
 241     parser-control-failed-core .cp.ctrl.notes notes \
 242         white blue 0 \
 243         $tiny \
 244         "[llength $note_infos] warning(s);\
 245          $nmissing vessel(s) missing" \
 246         "Full description of warnings and missing vessels:" \
 247         $infodata
 248 }
 249
 250 #---------- vessel properties ----------
 251
 252 proc info-cache-update {} {
 253     global info_source info_cache
 254     file mkdir $info_cache
 255     exec sh -c "cp -u icons/* $info_cache/."
 256
 257     if {[string length $info_source]} {
 258         set cmdl [list \
 259                   rsync -udLKtOzm \
 260                   --exclude=*~ --exclude=*.bak --exclude=.* --exclude=*.tmp \
 261                   $info_source/ $info_cache 2>@ stderr]
 262         debug "INFO-CACHE $cmdl"
 263         eval exec $cmdl
 264     }
 265
 266     set f [open $info_cache/vessel-info]
 267     glset vessel_size_data [read $f]
 268     close $f
 269 }
 270
 271 proc vesselinfo-init {} {
 272     global vc_game2code vc_code2abbrev vc_code2full vc_codes
 273
 274     global vessel_size_data
 275     manyset $vessel_size_data sizeinfos subclassinfos
 276
 277     set vc_codes {}
 278     foreach {game code abbrev full} $sizeinfos {
 279         if {![regexp {^[a-z][a-z]$} $code code]} { error "bad code" }
 280         if {![regexp {^[a-z][a-z]$} $abbrev abbrev]} { error "bad abbrev" }
 281         lappend vc_codes $code
 282         set vc_game2code($game) $code
 283         set vc_code2abbrev($code) $abbrev
 284         set vc_code2full($code) $full
 285         load-icon $abbrev
 286     }
 287
 288     global vsc_code2report
 289     global vsc_game2code
 290     set vsc_game2code(null) {}
 291     set vsc_code2report() Ordinary
 292     set vsc_code2report(!) "(Special/L.E.)"
 293     foreach {game code full} $subclassinfos {
 294         if {![regexp {^[A-Z]$} $code code]} { error "bad code" }
 295         set vsc_game2code($game) $code
 296         set vsc_code2report($code) $full
 297     }
 298
 299     load-icon atsea
 300     set owners {ours dot query}
 301     foreach b $owners { load-icon $b }
 302     foreach a {battle borrow dot} {
 303         load-icon $a
 304         foreach b $owners { load-icon-combine $a $b }
 305     }
 306 }
 307
 308 proc load-icon {icon} {
 309     global info_cache
 310     image create bitmap icon/$icon -file $info_cache/$icon.xbm
 311 }
 312
 313 proc load-icon-combine {args} {
 314     global info_cache
 315     set cmd {}
 316     set delim "pnmcat -lr "
 317     foreach icon $args {
 318         append cmd $delim " <(xbmtopbm $info_cache/$icon.xbm)"
 319         set delim " <(pbmmake -white 1 1)"
 320     }
 321     append cmd " | pbmtoxbm"
 322     debug "load-icon-combine $cmd"
 323     image create bitmap icon/[join $args +] -data [exec bash -c $cmd]
 324 }
 325
 326 proc code-lockown2icon {lockown} {
 327     manyset [split $lockown ""] lock notown
 328     set l "
 329          [lindex {battle borrow dot} $lock]
 330          [lindex {ours dot query {} {} dot} $notown]
 331     "
 332     if {[llength $l]} { return icon/[join $l +] } { return {} }
 333 }
 334
 335 proc canvas-horiz-stack {xvar xoff y bind type args} {
 336     upvar 1 $xvar x
 337     upvar 1 canvas canvas
 338     set id [eval $canvas create $type [expr {$x+$xoff}] $y $args]
 339     set bbox [$canvas bbox $id]
 340 #   debug "CANVAS-HORIZ-STACK $type $x $xoff $id $bbox [list $args]"
 341     set x [lindex $bbox 2]
 342     $canvas bind $id <ButtonPress> $bind
 343     return $id
 344 }
 345
 346 proc code2canvas {code canvas x yvar qty qtylen bind} {
 347     global vc_code2abbrev
 348     upvar 1 $yvar y
 349
 350     manyset [split $code _] inport size subclass lockown xabbrev
 351
 352     set stackx $x
 353     incr stackx 2
 354     set imy [expr {$y+2}]
 355
 356     if {!$inport} { incr qtylen -1 }
 357     if {$qtylen<=0} { set qtylen {} }
 358     set qty [format "%${qtylen}s" $qty]
 359
 360     set qtyid [canvas-horiz-stack stackx 0 $y $bind \
 361                    text -anchor nw -font fixed -text $qty]
 362
 363     if {!$inport} {
 364         canvas-horiz-stack stackx 0 $imy $bind \
 365             image -anchor nw -image icon/atsea
 366         incr stackx
 367     }
 368
 369     upvar #0 vc_code2abbrev($size) vcabb
 370     if {![info exists vcabb]} {
 371         set vcabb vc-$size
 372         image create bitmap icon/$vcabb -data \
 373             [exec pbmtext -builtin fixed $size | pnminvert | pnmcrop >t.pnm]
 374     }
 375     canvas-horiz-stack stackx -1 $imy $bind \
 376             image -anchor nw -image icon/$vcabb
 377
 378     if {[string length $subclass]} {
 379         canvas-horiz-stack stackx 0 $y $bind \
 380             text -anchor nw -font fixed -text \
 381             $subclass
 382     }
 383
 384     incr stackx
 385     set lockownicon [code-lockown2icon $lockown]
 386     if {[string length $lockownicon]} {
 387         canvas-horiz-stack stackx 0 $imy $bind \
 388             image -anchor nw -image $lockownicon
 389         incr stackx
 390     }
 391
 392     if {[string length $xabbrev]} {
 393         canvas-horiz-stack stackx 0 $y $bind \
 394             text -anchor nw -font fixed -text \
 395             $xabbrev
 396     }
 397
 398     set bbox [$canvas bbox $qtyid]
 399     set ny [lindex $bbox 3]
 400     set bid [$canvas create rectangle \
 401                  $x $y $stackx $ny \
 402                  -fill white]
 403
 404     set y $ny
 405     $canvas lower $bid $qtyid
 406
 407     $canvas bind $bid <ButtonPress> $bind
 408 }
 409
 410 proc show-report-decode {code} {
 411     global vc_code2full
 412
 413     smash-prepare
 414
 415     manyset [split $code _] inport sizecode subclass lockown xabbrev
 416     manyset [split $lockown ""] lock notown
 417
 418     report-set inport [lindex {{At Sea} {In port}} $inport]
 419
 420     upvar #0 vc_code2full($sizecode) sizefull
 421     upvar #0 smash_sizeinexact($sizecode) sizeinexact
 422     set size_report $sizefull
 423     if {[info exists sizeinexact]} { set size_report "($sizefull+)" }
 424     report-set size $size_report
 425
 426     global smash_subclass
 427     if {$smash_subclass >= 2} {
 428         report-set subclass "(Any class)"
 429     } elseif {[
 430                upvar #0 vsc_code2report($subclass) subclass_report
 431                info exists subclass_report
 432               ]} {
 433         report-set subclass $subclass_report
 434     } else {
 435         report-set subclass "Class \"$subclass\""
 436     }
 437
 438     report-set lock [lindex {
 439         {Battle ready} {Unlocked} {Locked}
 440         {(All lock states)} {(Not battle ready)}
 441     } $lock]
 442
 443     switch -exact $notown {
 444         0 { report-set own "Yours" }
 445         1 { report-set own "Other pirate's" }
 446         2 { report-set own "Owner unknown" }
 447         3 { report-set own "(All ownerships)" }
 448         4 - 5 { report-set own "(Yours/unknown)" }
 449         default { report-set own "?? $notown" }
 450     }
 451
 452     if {[string length $xabbrev]} {
 453         report-set xabbrev "Notes flags: $xabbrev"
 454     } else {
 455         report-set xabbrev "No flags in notes"
 456     }
 457 }
 458
 459 #---------- common to smashing and filtering ----------
 460
 461 proc make-control {parent ctrl label ekind} {
 462     debug "MAKE-CONTROL [list $parent $ctrl $label $ekind]"
 463     label $parent.lab_$ctrl -text $label -justify left
 464     $ekind $parent.$ctrl
 465     manyset [grid size $parent] dummy row
 466     incr row
 467     grid configure $parent.lab_$ctrl -row $row -column 0 -sticky nw -pady 4
 468     grid configure $parent.$ctrl -row $row -column 1 -sticky w -pady 3
 469     return $parent.$ctrl
 470 }
 471
 472 proc begin-control-grid {cw count rows inrow} {
 473     if {!$inrow} { set inrow [expr {($count + $rows) / $rows}] }
 474     upvar #0 control_grid_properties($cw) props
 475     set props [list $rows $inrow]
 476     return $cw
 477 }
 478
 479 proc make-control-grid-elem {cw kind ix ekind args} {
 480     upvar #0 control_grid_properties($cw) props
 481     manyset $props rows inrow
 482
 483     set ew $cw.$ix
 484
 485     debug "MAKE-CONTROL-GRID-ELEM $cw $kind $ix $ekind $rows $inrow $ew"
 486
 487     eval [list $ekind $ew] $args
 488
 489     switch -exact $kind {
 490         ix {
 491             grid configure $ew -sticky sw \
 492                 -row [expr {$ix / $inrow}] \
 493                 -column [expr {$ix % $inrow}]
 494         }
 495         final {
 496             grid configure $ew -sticky se \
 497                 -row [expr {$rows-1}] \
 498                 -column [expr {$inrow-1}]
 499         }
 500         default {
 501             error "$kind ?"
 502         }
 503     }
 504     return $ew
 505 }
 506
 507 proc control-tickbox-flip {varsvn values} {
 508     upvar #0 $varsvn vars
 509     foreach val $values {
 510         set vars($val) [expr {!$vars($val)}]
 511     }
 512     redraw-needed c.-tickbox-flip $varsvn $values
 513 }
 514
 515 proc populate-control-grid-tickboxes {cw rows inrow varsvn values flipvalues
 516                                     label_kind valvn default_get label_get} {
 517     debug "POPULATE-CONTROL-GRID-TICKBOXES $cw $rows $inrow $varsvn\
 518              [list $values] $label_kind $valvn"
 519
 520     upvar #0 $varsvn vars
 521     upvar 1 $valvn val
 522     set count [llength $values]
 523
 524     begin-control-grid $cw $count $rows $inrow
 525
 526     for {set ix 0} {$ix < $count} {incr ix} {
 527         set val [lindex $values $ix]
 528         set vars($val) [uplevel 1 $default_get]
 529         set ew [make-control-grid-elem $cw ix $ix checkbutton \
 530                     -variable ${varsvn}($val) \
 531                     -font fixed \
 532                     -command [list redraw-needed c.-g.-tickbox $cw $val]]
 533         $ew configure -$label_kind [uplevel 1 $label_get]
 534         switch -exact $label_kind {
 535             image { $ew configure -height 16 }
 536         }
 537     }
 538     [make-control-grid-elem $cw final invert button] \
 539         configure \
 540         -text flip -command [list control-tickbox-flip $varsvn $flipvalues] \
 541         -padx 0 -pady 0
 542 }
 543
 544 #---------- smashing ----------
 545
 546 set smash_subclass 0
 547 set smash_owner 0
 548
 549 proc smash-code {code} {
 550     manyset [split $code _] inport size subclass lockown xabbrev
 551
 552     upvar #0 smash_sizemap($size) smsize
 553
 554     global smash_subclass
 555     if {$smash_subclass > 1} {
 556         set subclass {}
 557     } elseif {$smash_subclass && [string length $subclass]} {
 558         set subclass !
 559     }
 560
 561     global smash_owner
 562     switch $smash_owner {
 563         0 { }
 564         1 { regsub {[12]$} $lockown 5 lockown }
 565         2 {
 566             if {[regexp {^0.} $lockown]} {
 567                 # battle ready / all lock states
 568                 set lockown 03
 569             } elseif {[regexp {^.0} $lockown]} {
 570                 # not battle ready / yours
 571                 set lockown 40
 572             } else {
 573                 # state (not battle ready) / not known to be yours
 574                 regsub {.$} $lockown 4 lockown
 575             }
 576         }
 577         3 { regsub {.$} $lockown {3} lockown }
 578         4 { set lockown 33 }
 579     }
 580
 581     return [join [list $inport $smsize $subclass $lockown $xabbrev] _]
 582 }
 583
 584 proc smash-prepare {} {
 585     global vc_codes smash_sizemap smash_size smash_sizeinexact
 586     set mapto {}
 587     catch { unset smash_sizeplus }
 588     foreach size $vc_codes {
 589         if {!$smash_size($size)} {
 590             set mapto $size
 591         } else {
 592             set smash_sizeinexact($mapto) 1
 593         }
 594         set smash_sizemap($size) $mapto
 595     }
 596 }
 597
 598 proc make-smasher {sma label ekind} {
 599     return [make-control .smash $sma $label $ekind]
 600 }
 601
 602 proc make-radio-smasher {sma label variable descs rows inrow} {
 603     set w [make-smasher $sma $label frame]
 604     begin-control-grid $w [llength $descs] $rows $inrow
 605     for {set i 0} {$i < [llength $descs]} {incr i} {
 606         make-control-grid-elem $w ix $i \
 607             radiobutton \
 608             -variable $variable -value $i -command redraw-needed \
 609             -text [lindex $descs $i]
 610     }
 611 }
 612
 613 proc make-smashers {} {
 614     global vc_codes vc_code2abbrev
 615     set cw [make-smasher size "Size\n round\n down" frame]
 616     populate-control-grid-tickboxes $cw 2 0 smash_size \
 617         $vc_codes [lrange $vc_codes 1 end] \
 618         image val { expr 0 } { expr {"icon/$vc_code2abbrev($val)"} }
 619     $cw.0 configure -state disabled
 620
 621     make-radio-smasher subclass Class smash_subclass \
 622         {Show Normal/LE Hide} 1 0
 623
 624     make-radio-smasher owner Owner smash_owner \
 625         {Show Yours? {For you} Lock Hide} 2 3
 626 }
 627
 628 #---------- filtering ----------
 629
 630 set filters {}
 631
 632 proc filter-values/size {} { global vc_codes; return $vc_codes }
 633 proc filter-icon/size {code} {
 634     upvar #0 vc_code2abbrev($code) abb
 635     return icon/$abb
 636 }
 637 proc filter-default/size {code} { return 1 }
 638 proc filter-says-yes/size {codel} {
 639     set sizecode [lindex $codel 1]
 640     upvar #0 filter_size($sizecode) yes
 641     return $yes
 642 }
 643
 644 proc filter-values/lockown {} {
 645     foreach lv {0 1 2} {
 646         foreach ov {0 1 2} {
 647             lappend vals "$lv$ov"
 648         }
 649     }
 650     return $vals
 651 }
 652 proc filter-icon/lockown {lockown} { return [code-lockown2icon $lockown] }
 653 proc filter-default/lockown {lockown} {
 654     return [regexp {^[01]|^2[^1]} $lockown]
 655 }
 656 proc filter-says-yes/lockown {codel} {
 657     set lockown [lindex $codel 3]
 658     upvar #0 filter_lockown($lockown) yes
 659     debug "FILTER-SAYS-YES/LOCKOWN $codel $lockown $yes"
 660     return $yes
 661 }
 662
 663 proc filter-validate/xabbre {re} {
 664     if {[catch {
 665         regexp -- $re {}
 666     } emsg]} {
 667         regsub {^.*:\s*} $emsg {} emsg
 668         regsub {^.*(.{30})$} $emsg {\1} emsg
 669         return $emsg
 670     }
 671     return {}
 672 }
 673 proc filter-says-yes/xabbre {codel} {
 674     global filter_xabbre
 675     set xabbrev [lindex $codel 4]
 676     return [regexp -- $filter_xabbre $xabbrev]
 677 }
 678
 679 proc make-tickbox-filter {fil label rows inrow} {
 680     set values [filter-values/$fil]
 681
 682     if {![catch { info args filter-icon/$fil }]} {
 683         set label_get { filter-icon/$fil $val }
 684         set label_kind image
 685     } else {
 686         set label_get { filter-map/$fil $val }
 687         set label_kind text
 688     }
 689
 690     set fw [make-filter $fil $label frame]
 691
 692     populate-control-grid-tickboxes $fw $rows $inrow filter_$fil \
 693         $values $values \
 694         $label_kind val { filter-default/$fil $val } $label_get
 695 }
 696
 697 proc entry-filter-changed {fw fil n1 n2 op} {
 698     global errorInfo
 699     upvar #0 filter_$fil realvar
 700     upvar #0 filterentered_$fil entryvar
 701     global def_background
 702     debug "entry-filter-changed $fw $fil $entryvar"
 703     if {[catch {
 704         set error [filter-validate/$fil $entryvar]
 705         if {[string length $error]} {
 706             $fw.error configure -text $error -foreground white -background red
 707         } else {
 708             $fw.error configure -text { } -background $def_background
 709             set realvar $entryvar
 710             redraw-needed
 711         }
 712     } emsg]} {
 713         puts stderr "FILTER CHECK ERROR $emsg $errorInfo"
 714     }
 715 }
 716
 717 proc make-entry-filter {fil label def} {
 718     global filterentered_$fil
 719     upvar #0 filter_$fil realvar
 720     set realvar $def
 721     set fw [make-filter $fil $label frame]
 722     entry $fw.entry -textvariable filterentered_$fil
 723     label $fw.error
 724     glset def_background [$fw.error cget -background]
 725     trace add variable filterentered_$fil write \
 726         [list entry-filter-changed $fw $fil]
 727     pack $fw.entry $fw.error -side top -anchor w
 728 }
 729
 730 proc make-filter {fil label ekind} {
 731     global filters
 732     lappend filters $fil
 733     return [make-control .filter $fil $label $ekind]
 734 }
 735
 736 proc make-filters {} {
 737     make-tickbox-filter size Size 2 0
 738     make-tickbox-filter lockown "Lock/\nowner" 2 6
 739     make-entry-filter xabbre "Flags\n regexp" {}
 740 }
 741
 742 proc filterstyle-changed {n1 n2 op} {
 743     global filterstyle
 744     debug "filterstyle-changed $filterstyle"
 745     redraw-needed
 746 }
 747
 748 proc filters-say-yes {code} {
 749     global filters filterstyle
 750     set codel [split $code _]
 751     set lockown [lindex $codel 3]
 752     switch -exact $filterstyle {
 753         0 { return 1 }
 754         1 { return [filter-default/lockown $lockown] }
 755         2 { return [regexp {^.0} $lockown] }
 756         3 { }
 757         default { error $filterstyle }
 758     }
 759
 760     foreach fil $filters {
 761         if {![filter-says-yes/$fil $codel]} {
 762             debug "FILTERS-SAY-YES $code NO $fil"
 763             return 0
 764         }
 765     }
 766     debug "FILTERS-SAY-YES $code YES $filters"
 767     return 1
 768 }
 769
 770 #---------- loading and parsing the clipboard (vessel locations) ----------
 771
 772 proc vessel {vin} {
 773     global pirate notes_used note_missings newnotes
 774     upvar 1 $vin vi
 775
 776     set codel {}
 777     lappend codel [errexpect-arrayget-boolean vi inPort]
 778
 779     set gamesize [errexpect-arrayget vi vesselClass]
 780     upvar #0 vc_game2code($gamesize) size
 781     if {![info exists size]} {
 782         set size "($gamesize)"
 783         upvar #0 vc_code2abbrev($size) vcabb
 784         set vcabb vc-$size
 785         set data [exec pbmtext -builtin fixed " $gamesize " \
 786                  | pnminvert | pnmcrop | pbmtoxbm]
 787         debug "INVENTED ICON $vcabb $data"
 788         image create bitmap icon/$vcabb -data $data
 789
 790         global vc_code2full
 791         set vc_code2full($size) "Type \"$gamesize\""
 792     }
 793     lappend codel $size
 794
 795     set gamesubclass [errexpect-arrayget vi vesselSubclass]
 796     upvar #0 vsc_game2code($gamesubclass) subclass
 797     if {[info exists subclass]} {
 798         lappend codel $subclass
 799     } else {
 800         lappend codel ($gamesubclass)
 801     }
 802
 803     switch -exact [errexpect-arrayget vi isLocked]/[ \
 804                    errexpect-arrayget vi isBattleReady] {
 805         true/false      { set lock 2 }
 806         false/false     { set lock 1 }
 807         false/true      { set lock 0 }
 808         default         { errexpect-error "unexpected isLocked/isBattleReady" }
 809     }
 810
 811     set vid [errexpect-arrayget vi vesselId]
 812     upvar #0 notes($vid) note
 813     set realname [errexpect-arrayget vi vesselName]
 814     set island [errexpect-arrayget vi islandName]
 815
 816     set owner {}
 817     set xabbrev {}
 818     if {[info exists note]} {
 819         manyset $note lno notename owner xabbrev
 820         if {[string compare -nocase $realname $notename]} {
 821             note-info $lno $vid $realname $island \
 822                 "notes say name is $notename"
 823         }
 824         if {[string length $owner]} {
 825             if {![string compare $owner $pirate]} {
 826                 set notown 0
 827             } else {
 828                 set notown 1
 829             }
 830         } else {
 831             set notown 2
 832         }
 833         append abbrev $xabbrev
 834         set notes_used($vid) 1
 835
 836     } else {
 837         set notown 2
 838         lappend note_missings [list $island $realname $vid]
 839     }
 840
 841     lappend codel "$lock$notown" $xabbrev
 842     lappend newnotes [list $vid $realname $owner $xabbrev]
 843     set kk "$island [join $codel _]"
 844     upvar #0 found($kk) k
 845     lappend k [list $vid $realname $owner]
 846
 847     debug "CODED $kk $vid $realname"
 848 }
 849
 850 set clipboard {}
 851 proc parse-clipboard {} {
 852     global clipboard found notes notes_used newnotes
 853
 854     catch { unset found }
 855     catch { unset notes_used }
 856     glset note_infos {}
 857     glset note_missings {}
 858
 859     set newnotes {}
 860
 861     set itemre { (\w+) = ([^=]*) }
 862     set manyitemre "^\\\[ $itemre ( (?: ,\\ $itemre)* ) \\]\$"
 863     debug $manyitemre
 864
 865     set lno 0
 866     foreach l [split $clipboard "\n"] {
 867         incr lno
 868         errexpect-setline $lno $l
 869         if {![string length $l]} continue
 870         catch { unset vi }
 871         while 1 {
 872                 if {![regexp -expanded $manyitemre $l dummy \
 873                         thiskey thisval rhs]} {
 874                     errexpect-error "badly formatted"
 875                 }
 876                 set vi($thiskey) $thisval
 877                 if {![string length $rhs]} break
 878                 regsub {^, } $rhs {} rhs
 879                 set l "\[$rhs\]"
 880         }
 881         vessel vi
 882     }
 883
 884     if {[llength $newnotes]} {
 885         foreach vid [lsort [array names notes]] {
 886             if {![info exists notes_used($vid)]} {
 887                 manyset $notes($vid) lno notename
 888                 note-info $lno $vid $notename {} \
 889                     "vessel in notes no longer found"
 890             }
 891         }
 892     }
 893 }
 894
 895 proc load-clipboard-file {fn} {
 896     set f [open $fn]
 897     glset clipboard [read $f]
 898     close $f
 899 }
 900
 901
 902 #---------- loading and parsing the chart ----------
 903
 904 proc load-chart {} {
 905     global chart scraper
 906     debug "FETCHING CHART"
 907     set chart [eval exec $scraper [list | perl -we {
 908         use strict;
 909         use CommodsScrape;
 910         use IO::File;
 911         use IO::Handle;
 912         yppedia_chart_parse(\*STDIN, (new IO::File ">/dev/null"),
 913                 sub { sprintf "%d %d", @_; },
 914                 sub { printf "archlabel %d %d %s\n", @_; },
 915                 sub { printf "island %s {%s} %s\n", @_; },
 916                 sub { printf "league %s %s %s.\n", @_; },
 917                 sub { printf STDERR "warning: %s: incomprehensible: %s", @_; }
 918                         );
 919         STDOUT->error and die $!;
 920     }]]
 921 }
 922
 923
 924 set scale 16
 925
 926 proc coord {c} {
 927         global scale
 928         return [expr {$c * $scale}]
 929 }
 930
 931 proc chart-got/archlabel {args} { }
 932 proc chart-got/island {x y isle sizecol} {
 933         debug "ISLE $x $y $isle $sizecol"
 934         global canvas isleloc
 935         set isleloc($isle) [list $x $y]
 936         set sz 5
 937 #       $canvas create oval \
 938 #               [expr {[coord $x] - $sz}] [expr {[coord $y] - $sz}] \
 939 #               [expr {[coord $x] + $sz}] [expr {[coord $y] + $sz}] \
 940 #               -fill blue
 941         set colour "#888"
 942         if {[string match *_col $sizecol]} { set colour black }
 943         $canvas create text [coord $x] [coord $y] \
 944                 -text $isle -anchor s -fill $colour
 945 }
 946 proc chart-got/league {x1 y1 x2 y2 kind} {
 947 #       debug "LEAGUE $x1 $y1 $x2 $y2 $kind"
 948         global canvas
 949         set l [$canvas create line \
 950                 [coord $x1] [coord $y1] \
 951                 [coord $x2] [coord $y2]]
 952         if {![string compare $kind .]} {
 953                 $canvas itemconfigure $l -dash .
 954         }
 955 }
 956
 957 proc debug-filter-array {array} {
 958     upvar #0 $array a
 959     set m " FILTER $array"
 960     foreach k [lsort [array names a]] {
 961         append m " $k=$a($k)"
 962     }
 963     debug $m
 964 }
 965
 966 proc redraw-needed {args} {
 967     global redraw_after
 968     debug "REDRAW NEEDED $args"
 969     if {[info exists redraw_after]} return
 970
 971     global filterstyle
 972     debug " FILTER style $filterstyle"
 973     debug-filter-array filter_size
 974     debug-filter-array filter_lockown
 975     global filter_xabbre
 976     debug " FILTER xabbre $filter_xabbre"
 977
 978     set redraw_after [after 250 draw]
 979 }
 980
 981 proc draw {} {
 982     global chart found isleloc canvas redraw_after islandnames smfound
 983
 984     catch { after cancel $redraw_after }
 985     catch { unset redraw_after }
 986
 987     $canvas delete all
 988
 989     foreach l [split $chart "\n"] {
 990 #       debug "CHART-GOT $l"
 991         set proc [lindex $l 0]
 992         eval chart-got/$proc [lrange $l 1 end]
 993     }
 994
 995     smash-prepare
 996
 997     catch { unset smfound }
 998     foreach key [lsort [array names found]] {
 999         regexp {^(.*) (\S+)$} $key dummy islandname code
1000
1001         if {![filters-say-yes $code]} continue
1002
1003         set smcode [smash-code $code]
1004         debug "smashed $code => $smcode"
1005         set smkey "$islandname $smcode"
1006         foreach vessel $found($key) { lappend smfound($smkey) $vessel }
1007     }
1008
1009     set islandnames {}
1010     set lastislandname {}
1011     foreach smkey [lsort [array names smfound]] {
1012         set c [llength $smfound($smkey)]
1013         regexp {^(.*) (\S+)$} $smkey dummy islandname code
1014         debug "SHOWING [list $smkey $c $islandname $code l=$lastislandname]"
1015
1016         if {[string compare $lastislandname $islandname]} {
1017                 manyset $isleloc($islandname) x y
1018                 set x [coord $x]
1019                 set y [coord $y]
1020                 set lastislandname $islandname
1021                 lappend islandnames $islandname
1022 #               debug "START Y $y"
1023         }
1024
1025         if {$c > 1} { set qty [format %d $c] } else { set qty {} }
1026         code2canvas $code $canvas $x y $qty 2 \
1027             [list show-report $islandname $code]
1028 #       debug "NEW Y $y"
1029     }
1030
1031     panner::updatecanvas-bbox .cp.ctrl.pan
1032
1033     islandnames-update
1034 }
1035
1036
1037 #---------- parser error reporting ----------
1038
1039 proc parser-control-create {w base invokebuttontext etl_title} {
1040     frame $w
1041     button $w.do -text $invokebuttontext -command invoke_$base -pady 3
1042
1043     frame $w.resframe -width 120 -height 32
1044     button $w.resframe.res -text {} -anchor nw \
1045         -padx 1 -pady 1 -borderwidth 0 -justify left
1046     glset deffont_$base [$w.resframe.res cget -font]
1047     place $w.resframe.res -relx 0.5 -y 0 -anchor n
1048
1049     pack $w.do -side top
1050     pack $w.resframe -side top -expand y -fill both
1051
1052     set eb .err_$base
1053     toplevel $eb
1054     wm withdraw $eb
1055     wm title $eb "where-vessels - $etl_title"
1056     wm protocol $eb WM_DELETE_WINDOW [list wm withdraw $eb]
1057
1058     label $eb.title -text $etl_title
1059     pack $eb.title -side top
1060
1061     button $eb.close -text Close -command [list wm withdraw $eb]
1062     pack $eb.close -side bottom
1063
1064     frame $eb.emsg -bd 2 -relief groove
1065     label $eb.emsg.lab -anchor nw -text "Error:"
1066     text $eb.emsg.text -height 1
1067     pack $eb.emsg.text -side bottom -fill x
1068     pack $eb.emsg.lab -side left
1069
1070     pack $eb.emsg -side top -pady 2 -fill x
1071
1072     frame $eb.text -bd 2 -relief groove
1073     pack $eb.text -side bottom -pady 2 -fill both -expand y
1074
1075     label $eb.text.lab -anchor nw
1076
1077     text $eb.text.text -width 85 \
1078         -xscrollcommand [list $eb.text.xscroll set] \
1079         -yscrollcommand [list $eb.text.yscroll set]
1080     $eb.text.text tag configure error \
1081         -background red -foreground white
1082
1083     scrollbar $eb.text.xscroll -orient horizontal \
1084         -command [list $eb.text.text xview]
1085     scrollbar $eb.text.yscroll -orient vertical \
1086         -command [list $eb.text.text yview]
1087
1088     grid configure $eb.text.lab -row 0 -column 0 -sticky w -columnspan 2
1089     grid configure $eb.text.text -row 1 -column 0 -sticky news
1090     grid configure $eb.text.yscroll -sticky ns -row 1 -column 1
1091     grid configure $eb.text.xscroll -sticky ew -row 2 -column 0
1092     grid rowconfigure $eb.text 0 -weight 0
1093     grid rowconfigure $eb.text 1 -weight 1
1094     grid rowconfigure $eb.text 2 -weight 0
1095     grid columnconfigure $eb.text 0 -weight 1
1096     grid columnconfigure $eb.text 1 -weight 0
1097 }
1098
1099 proc parser-control-ok-core {w base background show} {
1100     debug "parser-control-ok-core $w $base $background $show"
1101     upvar #0 deffont_$base deffont
1102     $w.resframe.res configure \
1103         -background $background -disabledforeground black -font $deffont \
1104         -state disabled -command {} \
1105         -text $show
1106 }
1107 proc parser-control-ok {w base show} {
1108     parser-control-ok-core $w $base green $show
1109 }
1110 proc parser-control-none {w base show} {
1111     parser-control-ok-core $w $base blue $show
1112 }
1113 proc parser-control-failed-core {w base foreground background smallfont
1114                                  tiny summary fulldesc fulldata} {
1115     debug "parser-control-failed-core $w $base $summary $fulldesc"
1116     upvar #0 deffont_$base deffont
1117     set eb .err_$base
1118
1119     $eb.emsg.text delete 0.0 end
1120     $eb.emsg.text insert end $summary
1121
1122     $eb.text.lab configure -text $fulldesc
1123     $eb.text.text delete 0.0 end
1124     $eb.text.text insert end $fulldata
1125
1126     regsub -all {.{18}} $tiny "&\n" ewrap
1127
1128     if {$smallfont} {
1129         set font fixed
1130     } else {
1131         set font $deffont
1132     }
1133
1134     $w.resframe.res configure \
1135         -background $background -foreground $foreground -font $font \
1136         -state normal -command [list wm deiconify $eb] \
1137         -text $ewrap
1138 }
1139
1140 proc parser-control-failed-expected {w base emsg lno ei fulldesc newdata} {
1141     set eb .err_$base
1142
1143     set line [lindex [split $ei "\n"] 0]
1144     debug "parser-control-failed-expected: $w $base: $lno: $emsg\n $line"
1145
1146     parser-control-failed-core $w $base \
1147         white red 1 \
1148         "err: [string trim $emsg]: \"$line\"" \
1149         "at line $lno: $emsg" \
1150         $fulldesc $newdata
1151
1152     $eb.text.text tag add error $lno.0 $lno.end
1153     $eb.text.text see $lno.0
1154 }
1155 proc parser-control-failed-unexpected {w base emsg ei} {
1156     global errorInfo
1157     parser-control-failed-core $w $base \
1158         black yellow 1 \
1159         $emsg $emsg "Details and stack trace:" $ei
1160 }
1161
1162 proc reparse {base varname old fulldesc okshow noneshow parse ok} {
1163     upvar #0 $varname var
1164     manyset [errexpect-catch {
1165         uplevel 1 $parse
1166         if {[string length [string trim $var]]} {
1167             parser-control-ok .cp.ctrl.$base $base $okshow
1168         } else {
1169             parser-control-none .cp.ctrl.$base $base $noneshow
1170         }
1171     }] failed emsg lno ei
1172     if {$failed} {
1173         parser-control-failed-expected .cp.ctrl.$base $base \
1174             $emsg $lno $ei $fulldesc $var
1175         set var $old
1176         uplevel 1 $parse
1177     } else {
1178         uplevel 1 $ok
1179     }
1180 }
1181
1182 #---------- island names selection etc. ----------
1183
1184 proc islandnames-update {} {
1185     global islandnames
1186     .islands.count configure -text [format "ships at %d island(s)" \
1187                                         [llength $islandnames]]
1188 }
1189
1190 proc islandnames-select {} {
1191     .islands.clip configure -relief sunken -state disabled
1192     selection own -command islandnames-deselect .islands.clip
1193 }
1194 proc islandnames-deselect {} {
1195     .islands.clip configure -relief raised -state normal
1196 }
1197
1198 proc islandnames-handler {offset maxchars} {
1199     global islandnames
1200     return [string range [join $islandnames ", "] \
1201                 $offset [expr {$offset+$maxchars-1}]]
1202 }
1203
1204 #---------- main user interface ----------
1205
1206 proc widgets-setup {} {
1207     global canvas debug pirate ocean filterstyle
1208
1209     wm geometry . 1200x800
1210     wm title . "where-vessels - $pirate on the $ocean ocean"
1211
1212     #----- map -----
1213
1214     frame .f -border 1 -relief groove
1215     set canvas .f.c
1216     canvas $canvas
1217     pack $canvas -expand 1 -fill both
1218     pack .f -expand 1 -fill both -side left
1219
1220     #----- control panels and filter -----
1221
1222     frame .cp
1223     frame .smash -relief groove -bd 2 -padx 1
1224     frame .filter -relief groove -bd 2 -padx 1
1225     frame .islands -pady 2
1226     pack .cp .filter .islands .smash -side top
1227
1228     label .smash.title -text {Display/combine details}
1229     grid .smash.title -row 0 -column 0 -columnspan 2
1230
1231     set filterstyle 1
1232     trace add variable filterstyle write filterstyle-changed
1233
1234     frame .filter.title
1235     label .filter.title.title -text Show
1236     pack .filter.title.title -side left
1237     for {set fing 0} {$fing < 4} {incr fing} {
1238         radiobutton .filter.title.f$fing \
1239             -variable filterstyle -value $fing \
1240             -text [lindex {All Useable Mine These:} $fing]
1241         pack .filter.title.f$fing -side left
1242     }
1243
1244     grid configure .filter.title -row 0 -column 0 -columnspan 2
1245
1246     #----- control panel -----
1247
1248     frame .cp.ctrl
1249     pack .cp.ctrl -side left -anchor n
1250
1251     debug "BBOX [$canvas bbox all]"
1252
1253     panner::canvas-scroll-bbox .f.c
1254     panner::create .cp.ctrl.pan .f.c 120 120 $debug
1255
1256     pack .cp.ctrl.pan -side top -pady 0 -padx 5
1257     frame .cp.ctrl.zoom
1258     pack .cp.ctrl.zoom -side top
1259
1260     button .cp.ctrl.zoom.out -text - -font {Courier 16} -command {zoom /2} -pady 0
1261     button .cp.ctrl.zoom.in  -text + -font {Courier 16} -command {zoom *2} -pady 0
1262     pack .cp.ctrl.zoom.out .cp.ctrl.zoom.in -side left
1263
1264     parser-control-create .cp.ctrl.acquire \
1265         acquire Acquire \
1266         "Clipboard parsing error" \
1267
1268     pack .cp.ctrl.acquire -side top -pady 2
1269
1270     parser-control-create .cp.ctrl.notes \
1271         notes "Reload notes" \
1272         "Vessel notes loading report" \
1273
1274     pack .cp.ctrl.notes -side top -pady 2
1275
1276     #----- island name count and copy -----
1277
1278     label .islands.count
1279     button .islands.clip -text "copy island names" -pady 2 -padx 2 \
1280          -command islandnames-select
1281     selection handle .islands.clip islandnames-handler
1282     pack .islands.count .islands.clip -side left
1283
1284     #----- decoding etc. report -----
1285
1286     frame .cp.report
1287     pack .cp.report -side left -anchor n
1288
1289     label .cp.report.island -text { }
1290
1291     canvas .cp.report.abbrev -width 1 -height 15
1292
1293     frame .cp.report.code
1294     label .cp.report.code.lab -text Code:
1295     glset report_code { }
1296     entry .cp.report.code.code -state readonly \
1297         -textvariable report_code -width 15
1298     pack .cp.report.code.lab .cp.report.code.code -side left
1299     frame .cp.report.details -bd 2 -relief groove -padx 2 -pady 2
1300
1301     listbox .cp.report.list -height 5
1302
1303     pack .cp.report.island .cp.report.abbrev .cp.report.details \
1304         .cp.report.list -side top
1305     #pack .cp.report.code -side top
1306     pack configure .cp.report.details -fill x
1307
1308     foreach sw {inport size subclass lock own xabbrev} {
1309         label .cp.report.details.$sw -text { }
1310         pack .cp.report.details.$sw -side top -anchor w
1311     }
1312 }
1313
1314 proc report-set {sw val} { .cp.report.details.$sw configure -text $val }
1315
1316 proc show-report {islandname code} {
1317     .cp.report.island configure -text $islandname
1318
1319     .cp.report.abbrev delete all
1320     set y 2
1321     code2canvas $code .cp.report.abbrev 5 y {} 0 {}
1322     manyset [.cp.report.abbrev bbox all] minx dummy maxx dummy
1323     .cp.report.abbrev configure -width [expr {$maxx-$minx+4}]
1324
1325     glset report_code $code
1326     show-report-decode $code
1327
1328     set kk "$islandname $code"
1329     upvar #0 smfound($kk) k
1330
1331     .cp.report.list delete 0 end
1332
1333     foreach elem $k {
1334         manyset $elem vid name owner
1335         lappend owned($owner) $name
1336     }
1337
1338     foreach owner [lsort [array names owned]] {
1339         if {[string length $owner]} {
1340             set owndesc "$owner's"
1341         } else {
1342             set owndesc "Owner unknown"
1343         }
1344         .cp.report.list insert end "$owndesc:"
1345         foreach name $owned($owner) {
1346             .cp.report.list insert end " $name"
1347         }
1348     }
1349 }
1350
1351 proc zoom {extail} {
1352     global scale canvas
1353     set nscale [expr "\$scale $extail"]
1354     debug "ZOOM $scale $nscale"
1355     if {$nscale < 1 || $nscale > 200} return
1356     set scale $nscale
1357     draw
1358 }
1359
1360 proc invoke_acquire {} {
1361     global clipboard errorInfo
1362     set old $clipboard
1363
1364     if {[catch {
1365         set clipboard [clipboard get]
1366     } emsg]} {
1367         parser-control-failed-unexpected .cp.ctrl.acquire acquire \
1368             $emsg "fetching clipboard:\n\n$errorInfo"
1369         return
1370     }
1371
1372     reparse acquire \
1373         clipboard $old "Clipboard contents:" { acquired ok } { no vessels } {
1374             parse-clipboard
1375         } {
1376             display-note-infos
1377         }
1378     draw
1379 }
1380
1381 proc invoke_notes {} {
1382     global notes_data errorInfo notes_loc
1383     set old $notes_data
1384
1385     if {[catch {
1386         load-notes
1387     } emsg]} {
1388         parser-control-failed-unexpected .cp.ctrl.notes notes \
1389             $emsg "loading $notes_loc:\n\n$errorInfo"
1390         return
1391     }
1392
1393     reparse notes \
1394         notes_data $old "Vessel notes:" "loaded ok" { no notes } {
1395             parse-notes
1396             parse-clipboard
1397         } {
1398             display-note-infos
1399         }
1400     draw
1401 }
1402
1403 #---------- main program ----------
1404
1405 parseargs
1406 argdefaults
1407 httpclientsetup where-vessels
1408 info-cache-update
1409 vesselinfo-init
1410 load-chart
1411 widgets-setup
1412 make-filters
1413 make-smashers
1414
1415 set notes_data {}
1416 if {[catch { parse-clipboard } emsg]} {
1417     puts stderr "$emsg\n$errorInfo"
1418     exit 1
1419 }
1420 after idle invoke_notes
1421
1422 draw
1423
1424 if {$debug} {
1425     package require Tclx
1426     commandloop -async \
1427         -prompt1 { return "where-vessels% " } \
1428         -prompt2 { return "> " }
1429 }
1430
1431 # rsync -r --exclude=\*~ yarrg/icons/. ijackson@chiark.greenend.org.uk:/home/ftp/users/ijackson/yarrg/vessel-info/.