yarrg/where-vessels

   1 #!/usr/bin/wish
   2 # show your vessels on a map
   3
   4 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   5 # players of Yohoho Puzzle Pirates.
   6 #
   7 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   8 #
   9 # This program is free software: you can redistribute it and/or modify
  10 # it under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation, either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  21 #
  22 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  23 # are used without permission.  This program is not endorsed or
  24 # sponsored by Three Rings.
  25
  26
  27
  28 source yarrglib.tcl
  29 source panner.tcl
  30 package require http
  31
  32 #---------- general utilities ----------
  33
  34 set debug 0
  35 proc debug {m} {
  36     global debug
  37     if {$debug} { puts "DEBUG $m" }
  38 }
  39
  40 proc badusage {m} {
  41     puts stderr "where-vessels: bad usage: $m"
  42     exit 1
  43 }
  44
  45 proc glset {n val} {
  46     upvar #0 $n var
  47     set var $val
  48 }
  49
  50 #---------- expecting certain errors ----------
  51
  52 proc errexpect-setline {lno line} {
  53     glset errexpect_lno $lno
  54     glset errexpect_line $line
  55 }
  56
  57 proc errexpect-error {m} {
  58     global errexpect_line errexpect_lno
  59     error $m "$errexpect_line\n" [list YARRG-ERREXPECT $errexpect_lno]
  60 }
  61
  62 proc errexpect-arrayget {arrayvar key} {
  63     upvar 1 $arrayvar av
  64     upvar 1 ${arrayvar}($key) v
  65     if {[info exists v]} { return $v }
  66     errexpect-error "undefined $key"
  67 }
  68
  69 proc errexpect-arrayget-boolean {arrayvar key} {
  70     switch -exact [uplevel 1 [list errexpect-arrayget $arrayvar $key]] {
  71         true    { return 1 }
  72         false   { return 0 }
  73         default { errexpect-error "unexpected $key" }
  74     }
  75 }
  76
  77 proc errexpect-catch {code} {
  78     global errorInfo errorCode
  79     set rc [catch {
  80         uplevel 1 $code
  81     } rv]
  82     debug "ERREXPECT CATCH |$rc|$rv|$errorCode|$errorInfo|"
  83     if {$rc==1 && ![string compare YARRG-ERREXPECT [lindex $errorCode 0]]} {
  84         return [list 1 $rv [lindex $errorCode 1] $errorInfo]
  85     } elseif {$rc==0} {
  86         return [list 0 $rv]
  87     } else {
  88         return -code $rc -errorinfo $errorInfo -errorcode $errorCode $rv
  89     }
  90 }
  91
  92 #---------- argument parsing ----------
  93
  94 proc nextarg {} {
  95     global ai argv
  96     if {$ai >= [llength $argv]} {
  97         badusage "option [lindex $argv [expr {$ai-1}]] needs a value"
  98     }
  99     set v [lindex $argv $ai]
 100     incr ai
 101     return $v
 102 }
 103
 104 set notes_loc vessel-notes
 105 set scraper {./yppedia-ocean-scraper --chart}
 106 set info_cache _vessel-info-cache
 107 set info_source rsync.yarrg.chiark.net::yarrg/vessel-info
 108
 109 proc parseargs {} {
 110     global ai argv
 111     global debug scraper
 112     set ai 0
 113
 114     while {[regexp {^\-} [set arg [lindex $argv $ai]]]} {
 115         incr ai
 116         switch -exact -- $arg {
 117             -- { break }
 118             --pirate { glset pirate [string totitle [nextarg]] }
 119             --ocean { glset ocean [string totitle [nextarg]] }
 120             --clipboard-file { load-clipboard-file [nextarg] }
 121             --local-html-dir { lappend scraper --local-html-dir=[nextarg] }
 122             --notes { glset notes_loc [nextarg] }
 123             --vessel-info-source { glset info_source [nextarg] }
 124             --debug { incr debug }
 125             default { badusage "unknown option $arg" }
 126         }
 127     }
 128     set argv [lrange $argv $ai end]
 129     if {[llength $argv]} { badusage "non-option args not allowed" }
 130 }
 131
 132 proc argdefaults {} {
 133     global ocean notes_loc pirate scraper
 134     if {![info exists ocean] || ![info exists pirate]} {
 135         set cmd {./yarrg --find-window-only --quiet}
 136         if {[info exists ocean]} { lappend cmd --ocean $ocean }
 137         if {[info exists pirate]} { lappend cmd --pirate $pirate }
 138         manyset [split [eval exec $cmd] " "] ocean pirate
 139         if {![llength $ocean] || ![llength $pirate]} {
 140             error "$ocean $pirate ?"
 141         }
 142     }
 143     lappend scraper $ocean
 144 }
 145
 146
 147 #---------- loading and parsing the vessel notes ----------
 148
 149 proc load-notes {} {
 150     global notes_loc notes_data
 151     if {[regexp {^\w+\:} $notes_loc]} {
 152         update
 153         debug "FETCHING NOTES $notes_loc"
 154         set req [::http::geturl $notes_loc]
 155         switch -glob [::http::status $req].[::http::ncode $req] {
 156             ok.200 { }
 157             ok.* { error "retrieving vessel-notes: [::http::code $req]" }
 158             * { error "Retrieving vessel-notes: [::http::error $req]" }
 159         }
 160         set newdata [::http::data $req]
 161         ::http::cleanup $req
 162     } else {
 163         debug "READING NOTES $notes_loc"
 164         set vn [open $notes_loc]
 165         set newdata [read $vn]
 166         close $vn
 167     }
 168     set notes_data $newdata
 169 }
 170
 171 proc parse-notes {} {
 172     global notes_data notes
 173     catch { unset notes }
 174
 175     set lno 0
 176     foreach l [split $notes_data "\n"] {
 177         incr lno
 178         errexpect-setline $lno $l
 179         set l [string trim $l]
 180         if {![string length $l]} continue
 181         if {[regexp {^\#} $l]} continue
 182         if {![regexp -expanded \
 183                   {^ (\d+) (?: \s+([^=]*?) )? \s* =
 184                       (?: \s* (\S+)
 185                        (?: \s+ (\S+) )?)? $} \
 186                   $l dummy vid vname owner note]} {
 187               errexpect-error "badly formatted"
 188         }
 189         set vname [string trim $vname]
 190         if {[info exists notes($vid)]} {
 191             errexpect-error "duplicate vesselid $vid"
 192         }
 193         set notes($vid) [list $lno $vname $owner $note]
 194     }
 195 }
 196
 197 proc note-info {lno vid name island description} {
 198     global note_infos
 199     lappend note_infos [list $lno $vid $name $island $description]
 200 }
 201
 202 proc display-note-infos {} {
 203     global note_infos note_missings notes
 204
 205     set nmissing [llength $note_missings]
 206     debug "display-note-infos $nmissing [array size notes]"
 207
 208     if {[llength $note_infos]} {
 209         set tiny "[llength $note_infos] warning(s)"
 210     } elseif {$nmissing && [array size notes]} {
 211         set tiny "$nmissing missing"
 212     } else {
 213         return
 214     }
 215
 216     set infodata {}
 217
 218     foreach info $note_infos {
 219         manyset $info lno vid name island description
 220         append infodata "vessel"
 221         append infodata " $vid"
 222         if {[string length $name]} { append infodata " $name" }
 223         if {[string length $island]} { append infodata " ($island)" }
 224         append infodata ": " $description "\n"
 225     }
 226
 227     if {$nmissing} {
 228         if {[string length $infodata]} { append infodata "\n" }
 229         append infodata "$nmissing vessel(s) not mentioned in notes:\n"
 230         set last_island {}
 231         foreach info [lsort $note_missings] {
 232             manyset $info island name vid
 233             if {[string compare $island $last_island]} {
 234                 append infodata "# $island:\n"
 235                 set last_island $island
 236             }
 237             append infodata [format "%-9d %-29s =\n" $vid $name]
 238         }
 239     }
 240
 241     parser-control-failed-core .cp.ctrl.notes notes \
 242         white blue 0 \
 243         $tiny \
 244         "[llength $note_infos] warning(s);\
 245          $nmissing vessel(s) missing" \
 246         "Full description of warnings and missing vessels:" \
 247         $infodata
 248 }
 249
 250 #---------- vessel properties ----------
 251
 252 proc info-cache-update {} {
 253     global info_source info_cache
 254     file mkdir $info_cache
 255     exec sh -c "cp -u icons/* $info_cache/."
 256
 257     if {[string length $info_source]} {
 258         set cmdl [list \
 259                   rsync -udLKtOzm \
 260                   --exclude=*~ --exclude=*.bak --exclude=.* --exclude=*.tmp \
 261                   $info_source/ $info_cache 2>@ stderr]
 262         debug "INFO-CACHE $cmdl"
 263         eval exec $cmdl
 264     }
 265
 266     set f [open $info_cache/vessel-info]
 267     glset vessel_class_data [read $f]
 268     close $f
 269 }
 270
 271 proc vesselclasses-init {} {
 272     global vc_game2code vc_code2abbrev vc_code2full vc_codes
 273
 274     global vessel_class_data
 275     manyset $vessel_class_data classinfos subclassinfos
 276
 277     set vc_codes {}
 278     foreach {game code abbrev full} $classinfos {
 279         if {![regexp {^[a-z][a-z]$} $code code]} { error "bad code" }
 280         if {![regexp {^[a-z][a-z]$} $abbrev abbrev]} { error "bad abbrev" }
 281         lappend vc_codes $code
 282         set vc_game2code($game) $code
 283         set vc_code2abbrev($code) $abbrev
 284         set vc_code2full($code) $full
 285         load-icon $abbrev
 286     }
 287
 288     global vsc_code2report
 289     global vsc_game2code
 290     set vsc_game2code(null) {}
 291     set vsc_code2report() Ordinary
 292     set vsc_code2report(!) "(Special/L.E.)"
 293     foreach {game code full} $subclassinfos {
 294         if {![regexp {^[A-Z]$} $code code]} { error "bad code" }
 295         set vsc_game2code($game) $code
 296         set vsc_code2report($code) $full
 297     }
 298
 299     load-icon atsea
 300     set owners {ours dot query}
 301     foreach b $owners { load-icon $b }
 302     foreach a {battle borrow dot} {
 303         load-icon $a
 304         foreach b $owners { load-icon-combine $a $b }
 305     }
 306 }
 307
 308 proc load-icon {icon} {
 309     global info_cache
 310     image create bitmap icon/$icon -file $info_cache/$icon.xbm
 311 }
 312
 313 proc load-icon-combine {args} {
 314     global info_cache
 315     set cmd {}
 316     set delim "pnmcat -lr "
 317     foreach icon $args {
 318         append cmd $delim " <(xbmtopbm $info_cache/$icon.xbm)"
 319         set delim " <(pbmmake -white 1 1)"
 320     }
 321     append cmd " | pbmtoxbm"
 322     debug "load-icon-combine $cmd"
 323     image create bitmap icon/[join $args +] -data [exec bash -c $cmd]
 324 }
 325
 326 proc code-lockown2icon {lockown} {
 327     manyset [split $lockown ""] lock notown
 328     set l "
 329          [lindex {battle borrow dot} $lock]
 330          [lindex {ours dot query {} {} dot} $notown]
 331     "
 332     if {[llength $l]} { return icon/[join $l +] } { return {} }
 333 }
 334
 335 proc canvas-horiz-stack {xvar xoff y bind type args} {
 336     upvar 1 $xvar x
 337     upvar 1 canvas canvas
 338     set id [eval $canvas create $type [expr {$x+$xoff}] $y $args]
 339     set bbox [$canvas bbox $id]
 340 #   debug "CANVAS-HORIZ-STACK $type $x $xoff $id $bbox [list $args]"
 341     set x [lindex $bbox 2]
 342     $canvas bind $id <ButtonPress> $bind
 343     return $id
 344 }
 345
 346 proc code2canvas {code canvas x yvar qty qtylen bind} {
 347     global vc_code2abbrev
 348     upvar 1 $yvar y
 349
 350     manyset [split $code _] inport class subclass lockown xabbrev
 351
 352     set stackx $x
 353     incr stackx 2
 354     set imy [expr {$y+2}]
 355
 356     if {!$inport} { incr qtylen -1 }
 357     if {$qtylen<=0} { set qtylen {} }
 358     set qty [format "%${qtylen}s" $qty]
 359
 360     set qtyid [canvas-horiz-stack stackx 0 $y $bind \
 361                    text -anchor nw -font fixed -text $qty]
 362
 363     if {!$inport} {
 364         canvas-horiz-stack stackx 0 $imy $bind \
 365             image -anchor nw -image icon/atsea
 366         incr stackx
 367     }
 368
 369     upvar #0 vc_code2abbrev($class) vcabb
 370     if {![info exists vcabb]} {
 371         set vcabb vc-$class
 372         image create bitmap icon/$vcabb -data \
 373             [exec pbmtext -builtin fixed $class | pnminvert | pnmcrop >t.pnm]
 374     }
 375     canvas-horiz-stack stackx -1 $imy $bind \
 376             image -anchor nw -image icon/$vcabb
 377
 378     if {[string length $subclass]} {
 379         canvas-horiz-stack stackx 0 $y $bind \
 380             text -anchor nw -font fixed -text \
 381             $subclass
 382     }
 383
 384     incr stackx
 385     set lockownicon [code-lockown2icon $lockown]
 386     if {[string length $lockownicon]} {
 387         canvas-horiz-stack stackx 0 $imy $bind \
 388             image -anchor nw -image $lockownicon
 389         incr stackx
 390     }
 391
 392     if {[string length $xabbrev]} {
 393         canvas-horiz-stack stackx 0 $y $bind \
 394             text -anchor nw -font fixed -text \
 395             $xabbrev
 396     }
 397
 398     set bbox [$canvas bbox $qtyid]
 399     set ny [lindex $bbox 3]
 400     set bid [$canvas create rectangle \
 401                  $x $y $stackx $ny \
 402                  -fill white]
 403
 404     set y $ny
 405     $canvas lower $bid $qtyid
 406
 407     $canvas bind $bid <ButtonPress> $bind
 408 }
 409
 410 proc show-report-decode {code} {
 411     global vc_code2full
 412
 413     manyset [split $code _] inport classcode subclass lockown xabbrev
 414     manyset [split $lockown ""] lock notown
 415
 416     report-set inport [lindex {{At Sea} {In port}} $inport]
 417     report-set class $vc_code2full($classcode)
 418
 419     global smash_subclass
 420     if {$smash_subclass >= 2} {
 421         report-set subclass "(Any subclass)"
 422     } elseif {[
 423                upvar #0 vsc_code2report($subclass) subclass_report
 424                info exists subclass_report
 425               ]} {
 426         report-set subclass $subclass_report
 427     } else {
 428         report-set subclass "Subclass \"$subclass\""
 429     }
 430
 431     report-set lock [lindex {
 432         {Battle ready} {Unlocked} {Locked}
 433         {(All lock states)} {(Not battle ready)}
 434     } $lock]
 435
 436     switch -exact $notown {
 437         0 { report-set own "Yours" }
 438         1 { report-set own "Other pirate's" }
 439         2 { report-set own "Owner unknown" }
 440         3 { report-set own "(All ownerships)" }
 441         4 - 5 { report-set own "(Yours/unknown)" }
 442         default { report-set own "?? $notown" }
 443     }
 444
 445     if {[string length $xabbrev]} {
 446         report-set xabbrev "Notes flags: $xabbrev"
 447     } else {
 448         report-set xabbrev "No flags in notes"
 449     }
 450 }
 451
 452 #---------- common to smashing and filtering ----------
 453
 454 proc make-control {parent ctrl label ekind} {
 455     debug "MAKE-CONTROL [list $parent $ctrl $label $ekind]"
 456     label $parent.lab_$ctrl -text $label -justify left
 457     $ekind $parent.$ctrl
 458     manyset [grid size $parent] dummy row
 459     incr row
 460     grid configure $parent.lab_$ctrl -row $row -column 0 -sticky nw -pady 4
 461     grid configure $parent.$ctrl -row $row -column 1 -sticky w -pady 3
 462     return $parent.$ctrl
 463 }
 464
 465 proc begin-control-grid {cw count rows inrow} {
 466     if {!$inrow} { set inrow [expr {($count + $rows) / $rows}] }
 467     upvar #0 control_grid_properties($cw) props
 468     set props [list $rows $inrow]
 469     return $cw
 470 }
 471
 472 proc make-control-grid-entry {cw kind ix ekind args} {
 473     upvar #0 control_grid_properties($cw) props
 474     manyset $props rows inrow
 475
 476     set ew $cw.$ix
 477     eval [list $ekind $ew] $args
 478
 479     switch -exact $kind {
 480         ix {
 481             grid configure $ew -sticky sw \
 482                 -row [expr {$ix / $inrow}] \
 483                 -column [expr {$ix % $inrow}]
 484         }
 485         final {
 486             grid configure $ew -sticky se \
 487                 -row [expr {$rows-1}] \
 488                 -column [expr {$inrow-1}]
 489         }
 490         default {
 491             error "$kind ?"
 492         }
 493     }
 494     return $ew
 495 }
 496
 497 #---------- smashing ----------
 498
 499 set smash_subclass 0
 500 set smash_owner 0
 501
 502 proc smash-code {code} {
 503     manyset [split $code _] inport class subclass lockown xabbrev
 504
 505     global smash_subclass
 506     if {$smash_subclass > 1} {
 507         set subclass {}
 508     } elseif {$smash_subclass && [string length $subclass]} {
 509         set subclass !
 510     }
 511
 512     global smash_owner
 513     switch $smash_owner {
 514         0 { }
 515         1 { regsub {[12]$} $lockown 5 lockown }
 516         2 {
 517             if {[regexp {^0.} $lockown]} {
 518                 # battle ready / all lock states
 519                 set lockown 03
 520             } elseif {[regexp {^.0} $lockown]} {
 521                 # not battle ready / yours
 522                 set lockown 40
 523             } else {
 524                 # state (not battle ready) / not known to be yours
 525                 regsub {.$} $lockown 4 lockown
 526             }
 527         }
 528         3 { regsub {.$} $lockown {3} lockown }
 529         4 { set lockown 33 }
 530     }
 531
 532     return [join [list $inport $class $subclass $lockown $xabbrev] _]
 533 }
 534
 535 proc make-smasher {sma label ekind} {
 536     return [make-control .smash $sma $label $ekind]
 537 }
 538
 539 proc make-radio-smasher {sma label variable descs} {
 540     set w [make-smasher $sma $label frame]
 541     for {set i 0} {$i < [llength $descs]} {incr i} {
 542         radiobutton $w.v$i \
 543             -variable $variable -value $i -command redraw-needed \
 544             -text [lindex $descs $i]
 545         pack $w.v$i -side left
 546     }
 547 }
 548
 549 #---------- filtering ----------
 550
 551 set filters {}
 552
 553 proc filter-values/size {} { global vc_codes; return $vc_codes }
 554 proc filter-icon/size {code} {
 555     upvar #0 vc_code2abbrev($code) abb
 556     return icon/$abb
 557 }
 558 proc filter-default/size {code} { return 1 }
 559 proc filter-says-yes/size {codel} {
 560     set sizecode [lindex $codel 1]
 561     upvar #0 filter_size($sizecode) yes
 562     return $yes
 563 }
 564
 565 proc filter-values/lockown {} {
 566     foreach lv {0 1 2} {
 567         foreach ov {0 1 2} {
 568             lappend vals "$lv$ov"
 569         }
 570     }
 571     return $vals
 572 }
 573 proc filter-icon/lockown {lockown} { return [code-lockown2icon $lockown] }
 574 proc filter-default/lockown {lockown} {
 575     return [regexp {^[01]|^2[^1]} $lockown]
 576 }
 577 proc filter-says-yes/lockown {codel} {
 578     set lockown [lindex $codel 3]
 579     upvar #0 filter_lockown($lockown) yes
 580     debug "FILTER-SAYS-YES/LOCKOWN $codel $lockown $yes"
 581     return $yes
 582 }
 583
 584 proc filter-validate/xabbre {re} {
 585     if {[catch {
 586         regexp -- $re {}
 587     } emsg]} {
 588         regsub {^.*:\s*} $emsg {} emsg
 589         regsub {^.*(.{30})$} $emsg {\1} emsg
 590         return $emsg
 591     }
 592     return {}
 593 }
 594 proc filter-says-yes/xabbre {codel} {
 595     global filter_xabbre
 596     set xabbrev [lindex $codel 4]
 597     return [regexp -- $filter_xabbre $xabbrev]
 598 }
 599
 600 proc filter-tickbox-flip {fil} {
 601     upvar #0 filter_$fil vars
 602     set values [filter-values/$fil]
 603     foreach val $values {
 604         set vars($val) [expr {!$vars($val)}]
 605     }
 606     redraw-needed
 607 }
 608
 609 proc make-tickbox-filter {fil label rows inrow} {
 610     upvar #0 filter_$fil vars
 611     set values [filter-values/$fil]
 612     set count [llength $values]
 613     set noicons [catch { info args filter-icon/$fil }]
 614
 615     set fw [make-filter $fil $label frame]
 616     begin-control-grid $fw $count $rows $inrow
 617
 618     for {set ix 0} {$ix < $count} {incr ix} {
 619         set val [lindex $values $ix]
 620         set vars($val) [filter-default/$fil $val]
 621         set ew [make-control-grid-entry $fw ix $ix checkbutton \
 622                     -variable filter_${fil}($val) \
 623                     -font fixed \
 624                     -command [list redraw-needed tickbox-filter $fil $val]]
 625         if {!$noicons} {
 626             $fw.$ix configure -image [filter-icon/$fil $val] -height 16
 627         } else {
 628             $fw.$ix configure -text [filter-map/$fil $val]
 629         }
 630     }
 631     [make-control-grid-entry $fw final invert button] \
 632         configure \
 633         -text flip -command [list filter-tickbox-flip $fil] \
 634         -padx 0 -pady 0
 635 }
 636
 637 proc entry-filter-changed {fw fil n1 n2 op} {
 638     global errorInfo
 639     upvar #0 filter_$fil realvar
 640     upvar #0 filterentered_$fil entryvar
 641     global def_background
 642     debug "entry-filter-changed $fw $fil $entryvar"
 643     if {[catch {
 644         set error [filter-validate/$fil $entryvar]
 645         if {[string length $error]} {
 646             $fw.error configure -text $error -foreground white -background red
 647         } else {
 648             $fw.error configure -text { } -background $def_background
 649             set realvar $entryvar
 650             redraw-needed
 651         }
 652     } emsg]} {
 653         puts stderr "FILTER CHECK ERROR $emsg $errorInfo"
 654     }
 655 }
 656
 657 proc make-entry-filter {fil label def} {
 658     global filterentered_$fil
 659     upvar #0 filter_$fil realvar
 660     set realvar $def
 661     set fw [make-filter $fil $label frame]
 662     entry $fw.entry -textvariable filterentered_$fil
 663     label $fw.error
 664     glset def_background [$fw.error cget -background]
 665     trace add variable filterentered_$fil write \
 666         [list entry-filter-changed $fw $fil]
 667     pack $fw.entry $fw.error -side top -anchor w
 668 }
 669
 670 proc make-filter {fil label ekind} {
 671     global filters
 672     lappend filters $fil
 673     return [make-control .filter $fil $label $ekind]
 674 }
 675
 676 proc make-filters {} {
 677     make-tickbox-filter size Size 2 0
 678     make-tickbox-filter lockown "Lock/\nowner" 2 6
 679     make-entry-filter xabbre "Flags\n regexp" {}
 680 }
 681
 682 proc filterstyle-changed {n1 n2 op} {
 683     global filterstyle
 684     debug "filterstyle-changed $filterstyle"
 685     redraw-needed
 686 }
 687
 688 proc filters-say-yes {code} {
 689     global filters filterstyle
 690     set codel [split $code _]
 691     set lockown [lindex $codel 3]
 692     switch -exact $filterstyle {
 693         0 { return 1 }
 694         1 { return [filter-default/lockown $lockown] }
 695         2 { return [regexp {^.0} $lockown] }
 696         3 { }
 697         default { error $filterstyle }
 698     }
 699
 700     foreach fil $filters {
 701         if {![filter-says-yes/$fil $codel]} {
 702             debug "FILTERS-SAY-YES $code NO $fil"
 703             return 0
 704         }
 705     }
 706     debug "FILTERS-SAY-YES $code YES $filters"
 707     return 1
 708 }
 709
 710 #---------- loading and parsing the clipboard (vessel locations) ----------
 711
 712 proc vessel {vin} {
 713     global pirate notes_used note_missings newnotes
 714     upvar 1 $vin vi
 715
 716     set codel {}
 717     lappend codel [errexpect-arrayget-boolean vi inPort]
 718
 719     set gameclass [errexpect-arrayget vi vesselClass]
 720     upvar #0 vc_game2code($gameclass) class
 721     if {![info exists class]} {
 722         set class "($gameclass)"
 723         upvar #0 vc_code2abbrev($class) vcabb
 724         set vcabb vc-$class
 725         set data [exec pbmtext -builtin fixed " $gameclass " \
 726                  | pnminvert | pnmcrop | pbmtoxbm]
 727         debug "INVENTED ICON $vcabb $data"
 728         image create bitmap icon/$vcabb -data $data
 729
 730         global vc_code2full
 731         set vc_code2full($class) "Type \"$gameclass\""
 732     }
 733     lappend codel $class
 734
 735     set gamesubclass [errexpect-arrayget vi vesselSubclass]
 736     upvar #0 vsc_game2code($gamesubclass) subclass
 737     if {[info exists subclass]} {
 738         lappend codel $subclass
 739     } else {
 740         lappend codel ($gamesubclass)
 741     }
 742
 743     switch -exact [errexpect-arrayget vi isLocked]/[ \
 744                    errexpect-arrayget vi isBattleReady] {
 745         true/false      { set lock 2 }
 746         false/false     { set lock 1 }
 747         false/true      { set lock 0 }
 748         default         { errexpect-error "unexpected isLocked/isBattleReady" }
 749     }
 750
 751     set vid [errexpect-arrayget vi vesselId]
 752     upvar #0 notes($vid) note
 753     set realname [errexpect-arrayget vi vesselName]
 754     set island [errexpect-arrayget vi islandName]
 755
 756     set owner {}
 757     set xabbrev {}
 758     if {[info exists note]} {
 759         manyset $note lno notename owner xabbrev
 760         if {[string compare -nocase $realname $notename]} {
 761             note-info $lno $vid $realname $island \
 762                 "notes say name is $notename"
 763         }
 764         if {[string length $owner]} {
 765             if {![string compare $owner $pirate]} {
 766                 set notown 0
 767             } else {
 768                 set notown 1
 769             }
 770         } else {
 771             set notown 2
 772         }
 773         append abbrev $xabbrev
 774         set notes_used($vid) 1
 775
 776     } else {
 777         set notown 2
 778         lappend note_missings [list $island $realname $vid]
 779     }
 780
 781     lappend codel "$lock$notown" $xabbrev
 782     lappend newnotes [list $vid $realname $owner $xabbrev]
 783     set kk "$island [join $codel _]"
 784     upvar #0 found($kk) k
 785     lappend k [list $vid $realname $owner]
 786
 787     debug "CODED $kk $vid $realname"
 788 }
 789
 790 set clipboard {}
 791 proc parse-clipboard {} {
 792     global clipboard found notes notes_used newnotes
 793
 794     catch { unset found }
 795     catch { unset notes_used }
 796     glset note_infos {}
 797     glset note_missings {}
 798
 799     set newnotes {}
 800
 801     set itemre { (\w+) = ([^=]*) }
 802     set manyitemre "^\\\[ $itemre ( (?: ,\\ $itemre)* ) \\]\$"
 803     debug $manyitemre
 804
 805     set lno 0
 806     foreach l [split $clipboard "\n"] {
 807         incr lno
 808         errexpect-setline $lno $l
 809         if {![string length $l]} continue
 810         catch { unset vi }
 811         while 1 {
 812                 if {![regexp -expanded $manyitemre $l dummy \
 813                         thiskey thisval rhs]} {
 814                     errexpect-error "badly formatted"
 815                 }
 816                 set vi($thiskey) $thisval
 817                 if {![string length $rhs]} break
 818                 regsub {^, } $rhs {} rhs
 819                 set l "\[$rhs\]"
 820         }
 821         vessel vi
 822     }
 823
 824     if {[llength $newnotes]} {
 825         foreach vid [lsort [array names notes]] {
 826             if {![info exists notes_used($vid)]} {
 827                 manyset $notes($vid) lno notename
 828                 note-info $lno $vid $notename {} \
 829                     "vessel in notes no longer found"
 830             }
 831         }
 832     }
 833 }
 834
 835 proc load-clipboard-file {fn} {
 836     set f [open $fn]
 837     glset clipboard [read $f]
 838     close $f
 839 }
 840
 841
 842 #---------- loading and parsing the chart ----------
 843
 844 proc load-chart {} {
 845     global chart scraper
 846     debug "FETCHING CHART"
 847     set chart [eval exec $scraper [list | perl -we {
 848         use strict;
 849         use CommodsScrape;
 850         use IO::File;
 851         use IO::Handle;
 852         yppedia_chart_parse(\*STDIN, (new IO::File ">/dev/null"),
 853                 sub { sprintf "%d %d", @_; },
 854                 sub { printf "archlabel %d %d %s\n", @_; },
 855                 sub { printf "island %s {%s} %s\n", @_; },
 856                 sub { printf "league %s %s %s.\n", @_; },
 857                 sub { printf STDERR "warning: %s: incomprehensible: %s", @_; }
 858                         );
 859         STDOUT->error and die $!;
 860     }]]
 861 }
 862
 863
 864 set scale 16
 865
 866 proc coord {c} {
 867         global scale
 868         return [expr {$c * $scale}]
 869 }
 870
 871 proc chart-got/archlabel {args} { }
 872 proc chart-got/island {x y isle sizecol} {
 873         debug "ISLE $x $y $isle $sizecol"
 874         global canvas isleloc
 875         set isleloc($isle) [list $x $y]
 876         set sz 5
 877 #       $canvas create oval \
 878 #               [expr {[coord $x] - $sz}] [expr {[coord $y] - $sz}] \
 879 #               [expr {[coord $x] + $sz}] [expr {[coord $y] + $sz}] \
 880 #               -fill blue
 881         set colour "#888"
 882         if {[string match *_col $sizecol]} { set colour black }
 883         $canvas create text [coord $x] [coord $y] \
 884                 -text $isle -anchor s -fill $colour
 885 }
 886 proc chart-got/league {x1 y1 x2 y2 kind} {
 887 #       debug "LEAGUE $x1 $y1 $x2 $y2 $kind"
 888         global canvas
 889         set l [$canvas create line \
 890                 [coord $x1] [coord $y1] \
 891                 [coord $x2] [coord $y2]]
 892         if {![string compare $kind .]} {
 893                 $canvas itemconfigure $l -dash .
 894         }
 895 }
 896
 897 proc debug-filter-array {array} {
 898     upvar #0 $array a
 899     set m " FILTER $array"
 900     foreach k [lsort [array names a]] {
 901         append m " $k=$a($k)"
 902     }
 903     debug $m
 904 }
 905
 906 proc redraw-needed {args} {
 907     global redraw_after
 908     debug "REDRAW NEEDED $args"
 909     if {[info exists redraw_after]} return
 910
 911     global filterstyle
 912     debug " FILTER style $filterstyle"
 913     debug-filter-array filter_size
 914     debug-filter-array filter_lockown
 915     global filter_xabbre
 916     debug " FILTER xabbre $filter_xabbre"
 917
 918     set redraw_after [after 250 draw]
 919 }
 920
 921 proc draw {} {
 922     global chart found isleloc canvas redraw_after islandnames smfound
 923
 924     catch { after cancel $redraw_after }
 925     catch { unset redraw_after }
 926
 927     $canvas delete all
 928
 929     foreach l [split $chart "\n"] {
 930 #       debug "CHART-GOT $l"
 931         set proc [lindex $l 0]
 932         eval chart-got/$proc [lrange $l 1 end]
 933     }
 934
 935     catch { unset smfound }
 936     foreach key [lsort [array names found]] {
 937         regexp {^(.*) (\S+)$} $key dummy islandname code
 938
 939         if {![filters-say-yes $code]} continue
 940
 941         set smcode [smash-code $code]
 942         debug "smashed $code => $smcode"
 943         set smkey "$islandname $smcode"
 944         foreach vessel $found($key) { lappend smfound($smkey) $vessel }
 945     }
 946
 947     set islandnames {}
 948     set lastislandname {}
 949     foreach smkey [lsort [array names smfound]] {
 950         set c [llength $smfound($smkey)]
 951         regexp {^(.*) (\S+)$} $smkey dummy islandname code
 952         debug "SHOWING [list $smkey $c $islandname $code l=$lastislandname]"
 953
 954         if {[string compare $lastislandname $islandname]} {
 955                 manyset $isleloc($islandname) x y
 956                 set x [coord $x]
 957                 set y [coord $y]
 958                 set lastislandname $islandname
 959                 lappend islandnames $islandname
 960 #               debug "START Y $y"
 961         }
 962
 963         if {$c > 1} { set qty [format %d $c] } else { set qty {} }
 964         code2canvas $code $canvas $x y $qty 2 \
 965             [list show-report $islandname $code]
 966 #       debug "NEW Y $y"
 967     }
 968
 969     panner::updatecanvas-bbox .cp.ctrl.pan
 970
 971     islandnames-update
 972 }
 973
 974
 975 #---------- parser error reporting ----------
 976
 977 proc parser-control-create {w base invokebuttontext etl_title} {
 978     frame $w
 979     button $w.do -text $invokebuttontext -command invoke_$base -pady 3
 980
 981     frame $w.resframe -width 120 -height 32
 982     button $w.resframe.res -text {} -anchor nw \
 983         -padx 1 -pady 1 -borderwidth 0 -justify left
 984     glset deffont_$base [$w.resframe.res cget -font]
 985     place $w.resframe.res -relx 0.5 -y 0 -anchor n
 986
 987     pack $w.do -side top
 988     pack $w.resframe -side top -expand y -fill both
 989
 990     set eb .err_$base
 991     toplevel $eb
 992     wm withdraw $eb
 993     wm title $eb "where-vessels - $etl_title"
 994     wm protocol $eb WM_DELETE_WINDOW [list wm withdraw $eb]
 995
 996     label $eb.title -text $etl_title
 997     pack $eb.title -side top
 998
 999     button $eb.close -text Close -command [list wm withdraw $eb]
1000     pack $eb.close -side bottom
1001
1002     frame $eb.emsg -bd 2 -relief groove
1003     label $eb.emsg.lab -anchor nw -text "Error:"
1004     text $eb.emsg.text -height 1
1005     pack $eb.emsg.text -side bottom -fill x
1006     pack $eb.emsg.lab -side left
1007
1008     pack $eb.emsg -side top -pady 2 -fill x
1009
1010     frame $eb.text -bd 2 -relief groove
1011     pack $eb.text -side bottom -pady 2 -fill both -expand y
1012
1013     label $eb.text.lab -anchor nw
1014
1015     text $eb.text.text -width 85 \
1016         -xscrollcommand [list $eb.text.xscroll set] \
1017         -yscrollcommand [list $eb.text.yscroll set]
1018     $eb.text.text tag configure error \
1019         -background red -foreground white
1020
1021     scrollbar $eb.text.xscroll -orient horizontal \
1022         -command [list $eb.text.text xview]
1023     scrollbar $eb.text.yscroll -orient vertical \
1024         -command [list $eb.text.text yview]
1025
1026     grid configure $eb.text.lab -row 0 -column 0 -sticky w -columnspan 2
1027     grid configure $eb.text.text -row 1 -column 0 -sticky news
1028     grid configure $eb.text.yscroll -sticky ns -row 1 -column 1
1029     grid configure $eb.text.xscroll -sticky ew -row 2 -column 0
1030     grid rowconfigure $eb.text 0 -weight 0
1031     grid rowconfigure $eb.text 1 -weight 1
1032     grid rowconfigure $eb.text 2 -weight 0
1033     grid columnconfigure $eb.text 0 -weight 1
1034     grid columnconfigure $eb.text 1 -weight 0
1035 }
1036
1037 proc parser-control-ok-core {w base background show} {
1038     debug "parser-control-ok-core $w $base $background $show"
1039     upvar #0 deffont_$base deffont
1040     $w.resframe.res configure \
1041         -background $background -disabledforeground black -font $deffont \
1042         -state disabled -command {} \
1043         -text $show
1044 }
1045 proc parser-control-ok {w base show} {
1046     parser-control-ok-core $w $base green $show
1047 }
1048 proc parser-control-none {w base show} {
1049     parser-control-ok-core $w $base blue $show
1050 }
1051 proc parser-control-failed-core {w base foreground background smallfont
1052                                  tiny summary fulldesc fulldata} {
1053     debug "parser-control-failed-core $w $base $summary $fulldesc"
1054     upvar #0 deffont_$base deffont
1055     set eb .err_$base
1056
1057     $eb.emsg.text delete 0.0 end
1058     $eb.emsg.text insert end $summary
1059
1060     $eb.text.lab configure -text $fulldesc
1061     $eb.text.text delete 0.0 end
1062     $eb.text.text insert end $fulldata
1063
1064     regsub -all {.{18}} $tiny "&\n" ewrap
1065
1066     if {$smallfont} {
1067         set font fixed
1068     } else {
1069         set font $deffont
1070     }
1071
1072     $w.resframe.res configure \
1073         -background $background -foreground $foreground -font $font \
1074         -state normal -command [list wm deiconify $eb] \
1075         -text $ewrap
1076 }
1077
1078 proc parser-control-failed-expected {w base emsg lno ei fulldesc newdata} {
1079     set eb .err_$base
1080
1081     set line [lindex [split $ei "\n"] 0]
1082     debug "parser-control-failed-expected: $w $base: $lno: $emsg\n $line"
1083
1084     parser-control-failed-core $w $base \
1085         white red 1 \
1086         "err: [string trim $emsg]: \"$line\"" \
1087         "at line $lno: $emsg" \
1088         $fulldesc $newdata
1089
1090     $eb.text.text tag add error $lno.0 $lno.end
1091     $eb.text.text see $lno.0
1092 }
1093 proc parser-control-failed-unexpected {w base emsg ei} {
1094     global errorInfo
1095     parser-control-failed-core $w $base \
1096         black yellow 1 \
1097         $emsg $emsg "Details and stack trace:" $ei
1098 }
1099
1100 proc reparse {base varname old fulldesc okshow noneshow parse ok} {
1101     upvar #0 $varname var
1102     manyset [errexpect-catch {
1103         uplevel 1 $parse
1104         if {[string length [string trim $var]]} {
1105             parser-control-ok .cp.ctrl.$base $base $okshow
1106         } else {
1107             parser-control-none .cp.ctrl.$base $base $noneshow
1108         }
1109     }] failed emsg lno ei
1110     if {$failed} {
1111         parser-control-failed-expected .cp.ctrl.$base $base \
1112             $emsg $lno $ei $fulldesc $var
1113         set var $old
1114         uplevel 1 $parse
1115     } else {
1116         uplevel 1 $ok
1117     }
1118 }
1119
1120 #---------- island names selection etc. ----------
1121
1122 proc islandnames-update {} {
1123     global islandnames
1124     .islands.count configure -text [format "ships at %d island(s)" \
1125                                         [llength $islandnames]]
1126 }
1127
1128 proc islandnames-select {} {
1129     .islands.clip configure -relief sunken -state disabled
1130     selection own -command islandnames-deselect .islands.clip
1131 }
1132 proc islandnames-deselect {} {
1133     .islands.clip configure -relief raised -state normal
1134 }
1135
1136 proc islandnames-handler {offset maxchars} {
1137     global islandnames
1138     return [string range [join $islandnames ", "] \
1139                 $offset [expr {$offset+$maxchars-1}]]
1140 }
1141
1142 #---------- main user interface ----------
1143
1144 proc widgets-setup {} {
1145     global canvas debug pirate ocean filterstyle
1146
1147     wm geometry . 1024x600
1148     wm title . "where-vessels - $pirate on the $ocean ocean"
1149
1150     #----- map -----
1151
1152     frame .f -border 1 -relief groove
1153     set canvas .f.c
1154     canvas $canvas
1155     pack $canvas -expand 1 -fill both
1156     pack .f -expand 1 -fill both -side left
1157
1158     #----- control panels and filter -----
1159
1160     frame .cp
1161     frame .smash -relief groove -bd 2 -padx 1
1162     frame .filter -relief groove -bd 2 -padx 1
1163     frame .islands -pady 2
1164     pack .cp .filter .islands .smash -side top
1165
1166     label .smash.title -text Smash
1167     grid .smash.title -row 0 -column 0 -columnspan 2
1168
1169     make-radio-smasher subclass Subclass smash_subclass \
1170         {Show Normal/LE Hide}
1171
1172     make-radio-smasher owner Owner smash_owner \
1173         {Show Yours? You Lock Hide}
1174
1175     set filterstyle 1
1176     trace add variable filterstyle write filterstyle-changed
1177
1178     frame .filter.title
1179     label .filter.title.title -text Show
1180     pack .filter.title.title -side left
1181     for {set fing 0} {$fing < 4} {incr fing} {
1182         radiobutton .filter.title.f$fing \
1183             -variable filterstyle -value $fing \
1184             -text [lindex {All Useable Mine These:} $fing]
1185         pack .filter.title.f$fing -side left
1186     }
1187
1188     grid configure .filter.title -row 0 -column 0 -columnspan 2
1189
1190     #----- control panel -----
1191
1192     frame .cp.ctrl
1193     pack .cp.ctrl -side left -anchor n
1194
1195     debug "BBOX [$canvas bbox all]"
1196
1197     panner::canvas-scroll-bbox .f.c
1198     panner::create .cp.ctrl.pan .f.c 120 120 $debug
1199
1200     pack .cp.ctrl.pan -side top -pady 0 -padx 5
1201     frame .cp.ctrl.zoom
1202     pack .cp.ctrl.zoom -side top
1203
1204     button .cp.ctrl.zoom.out -text - -font {Courier 16} -command {zoom /2} -pady 0
1205     button .cp.ctrl.zoom.in  -text + -font {Courier 16} -command {zoom *2} -pady 0
1206     pack .cp.ctrl.zoom.out .cp.ctrl.zoom.in -side left
1207
1208     parser-control-create .cp.ctrl.acquire \
1209         acquire Acquire \
1210         "Clipboard parsing error" \
1211
1212     pack .cp.ctrl.acquire -side top -pady 2
1213
1214     parser-control-create .cp.ctrl.notes \
1215         notes "Reload notes" \
1216         "Vessel notes loading report" \
1217
1218     pack .cp.ctrl.notes -side top -pady 2
1219
1220     #----- island name count and copy -----
1221
1222     label .islands.count
1223     button .islands.clip -text "copy island names" -pady 2 -padx 2 \
1224          -command islandnames-select
1225     selection handle .islands.clip islandnames-handler
1226     pack .islands.count .islands.clip -side left
1227
1228     #----- decoding etc. report -----
1229
1230     frame .cp.report
1231     pack .cp.report -side left -anchor n
1232
1233     label .cp.report.island -text { }
1234
1235     canvas .cp.report.abbrev -width 1 -height 15
1236
1237     frame .cp.report.code
1238     label .cp.report.code.lab -text Code:
1239     glset report_code { }
1240     entry .cp.report.code.code -state readonly \
1241         -textvariable report_code -width 15
1242     pack .cp.report.code.lab .cp.report.code.code -side left
1243     frame .cp.report.details -bd 2 -relief groove -padx 2 -pady 2
1244
1245     listbox .cp.report.list -height 5
1246
1247     pack .cp.report.island .cp.report.abbrev .cp.report.details \
1248         .cp.report.list -side top
1249     #pack .cp.report.code -side top
1250     pack configure .cp.report.details -fill x
1251
1252     foreach sw {inport class subclass lock own xabbrev} {
1253         label .cp.report.details.$sw -text { }
1254         pack .cp.report.details.$sw -side top -anchor w
1255     }
1256 }
1257
1258 proc report-set {sw val} { .cp.report.details.$sw configure -text $val }
1259
1260 proc show-report {islandname code} {
1261     .cp.report.island configure -text $islandname
1262
1263     .cp.report.abbrev delete all
1264     set y 2
1265     code2canvas $code .cp.report.abbrev 5 y {} 0 {}
1266     manyset [.cp.report.abbrev bbox all] minx dummy maxx dummy
1267     .cp.report.abbrev configure -width [expr {$maxx-$minx+4}]
1268
1269     glset report_code $code
1270     show-report-decode $code
1271
1272     set kk "$islandname $code"
1273     upvar #0 smfound($kk) k
1274
1275     .cp.report.list delete 0 end
1276
1277     foreach entry $k {
1278         manyset $entry vid name owner
1279         lappend owned($owner) $name
1280     }
1281
1282     foreach owner [lsort [array names owned]] {
1283         if {[string length $owner]} {
1284             set owndesc "$owner's"
1285         } else {
1286             set owndesc "Owner unknown"
1287         }
1288         .cp.report.list insert end "$owndesc:"
1289         foreach name $owned($owner) {
1290             .cp.report.list insert end " $name"
1291         }
1292     }
1293 }
1294
1295 proc zoom {extail} {
1296     global scale canvas
1297     set nscale [expr "\$scale $extail"]
1298     debug "ZOOM $scale $nscale"
1299     if {$nscale < 1 || $nscale > 200} return
1300     set scale $nscale
1301     draw
1302 }
1303
1304 proc invoke_acquire {} {
1305     global clipboard errorInfo
1306     set old $clipboard
1307
1308     if {[catch {
1309         set clipboard [clipboard get]
1310     } emsg]} {
1311         parser-control-failed-unexpected .cp.ctrl.acquire acquire \
1312             $emsg "fetching clipboard:\n\n$errorInfo"
1313         return
1314     }
1315
1316     reparse acquire \
1317         clipboard $old "Clipboard contents:" { acquired ok } { no vessels } {
1318             parse-clipboard
1319         } {
1320             display-note-infos
1321         }
1322     draw
1323 }
1324
1325 proc invoke_notes {} {
1326     global notes_data errorInfo notes_loc
1327     set old $notes_data
1328
1329     if {[catch {
1330         load-notes
1331     } emsg]} {
1332         parser-control-failed-unexpected .cp.ctrl.notes notes \
1333             $emsg "loading $notes_loc:\n\n$errorInfo"
1334         return
1335     }
1336
1337     reparse notes \
1338         notes_data $old "Vessel notes:" "loaded ok" { no notes } {
1339             parse-notes
1340             parse-clipboard
1341         } {
1342             display-note-infos
1343         }
1344     draw
1345 }
1346
1347 #---------- main program ----------
1348
1349 parseargs
1350 argdefaults
1351 httpclientsetup where-vessels
1352 info-cache-update
1353 vesselclasses-init
1354 load-chart
1355 widgets-setup
1356 make-filters
1357
1358 set notes_data {}
1359 if {[catch { parse-clipboard } emsg]} {
1360     puts stderr "$emsg\n$errorInfo"
1361     exit 1
1362 }
1363 after idle invoke_notes
1364
1365 draw
1366
1367 # rsync -r --exclude=\*~ yarrg/icons/. ijackson@chiark.greenend.org.uk:/home/ftp/users/ijackson/yarrg/vessel-info/.