chiark / gitweb /
00c6f24b8cc5ce0ce9713592de4897428ffcdcd6
[ypp-sc-tools.db-live.git] / yarrg / CommodsWeb.pm
1 # This is part of the YARRG website.  YARRG is a tool and website
2 # for assisting players of Yohoho Puzzle Pirates.
3 #
4 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
5 # Copyright (C) 2009 Clare Boothby
6 #
7 #  YARRG's client code etc. is covered by the ordinary GNU GPL (v3 or later).
8 #  The YARRG website is covered by the GNU Affero GPL v3 or later, which
9 #   basically means that every installation of the website will let you
10 #   download the source.
11 #
12 # This program is free software: you can redistribute it and/or modify
13 # it under the terms of the GNU Affero General Public License as
14 # published by the Free Software Foundation, either version 3 of the
15 # License, or (at your option) any later version.
16 #
17 # This program is distributed in the hope that it will be useful,
18 # but WITHOUT ANY WARRANTY; without even the implied warranty of
19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
20 # GNU Affero General Public License for more details.
21 #
22 # You should have received a copy of the GNU Affero General Public License
23 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
24 #
25 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
26 # are used without permission.  This program is not endorsed or
27 # sponsored by Three Rings.
28
29
30 # This Perl module is used by the Mason scripts in yarrg/web/.
31 # We look for a symlink DATA to the actual data to use, so that
32 # the data uploader and website displayer can use different code.
33
34 package CommodsWeb;
35
36 use strict;
37 use warnings;
38
39 use DBI;
40 use POSIX;
41 use JSON;
42
43 use Commods;
44 use CommodsDatabase;
45
46 BEGIN {
47     use Exporter ();
48     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
49     $VERSION     = 1.00;
50     @ISA         = qw(Exporter);
51     @EXPORT      = qw(&dbw_connect &dbw_filename &ocean_list &sourcebasedir
52                       &to_json_shim &to_json_protecttags
53                       &set_ctype_utf8
54                       &expected_error &dbw_lookup_string
55                       &prettyprint_age &meta_prettyprint_age);
56     %EXPORT_TAGS = ( );
57
58     @EXPORT_OK   = qw();
59 }
60
61 sub dotperllibdir () {
62     my $dir;
63     
64     for my $dir (@INC) {
65         if ($dir =~ m/\.perl-lib$/) {
66             return $dir;
67         }
68     }
69     die "no appropriate dotperllib dir in @INC";
70 }
71
72 sub sourcebasedir () {
73     return dotperllibdir().'/..';
74 }
75
76 sub datadir () {
77     my $edir= $ENV{'YARRG_DATA_DIR'};
78     return $edir if defined $edir;
79     my $dir= dotperllibdir();
80     if (stat "$dir/DATA") {
81         return "$dir/DATA";
82     } elsif ($!==&ENOENT) {
83         return "$dir";
84     } else {
85         die "stat $dir/DATA $!";
86     }
87     return '.';
88 }
89
90 my @ocean_list;
91
92 sub ocean_list () {
93     my $datadir= datadir();
94     if (!@ocean_list) {
95         my $fn= "$datadir/source-info.txt";
96         my $f= new IO::File $fn or die "$fn $!";
97         my @r;
98         while (<$f>) {
99             next unless m/^ocean\s+(\S.*\S)\s*$/;
100             push @r, $1;
101         }
102         $f->error and die $!;
103         close $fn;
104         @ocean_list= @r;
105     }
106     return @ocean_list;
107 }
108
109 sub dbw_filename ($) {
110     my ($ocean) = @_;
111     die "unknown ocean $ocean ?"
112         unless grep { $_ eq $ocean } ocean_list();
113     return dbr_filename(datadir(), $ocean);
114 }
115
116 sub dbw_connect ($) {
117     my ($ocean) = @_;
118     my $fn= dbw_filename($ocean);
119     return db_connect_core($fn);
120 }
121
122 sub to_json_shim ($) {
123     my ($obj) = @_;
124     # In JSON.pm 2.x, jsonToObj prints a warning to stderr which
125     # our callers don't like at all.
126     if ($JSON::VERSION >= 2.0) {
127         return to_json($obj);
128     } else {
129         return objToJson($obj);
130     }
131 }
132
133 sub to_json_protecttags ($) {
134     my ($v) = @_;
135     my $j= to_json_shim($v);
136     $j =~ s,/,\\/,g;
137     return $j;
138 }
139
140 sub meta_prettyprint_age ($$$) {
141     my ($age,$floor,$plus) = @_;
142     return <<END;
143         $age < 60 ?             'less than a minute'                    :
144         $age < 60*2 ?           '1 minute'                              :
145         $age < 3600*2 ?         $floor ($age/60) $plus' minutes'        :
146         $age < 86400*2 ?        $floor ($age/3600) $plus ' hours'       :
147                                 $floor ($age/86400) $plus ' days';
148 END
149 };
150
151 BEGIN { eval '
152   sub prettyprint_age ($) {
153                 my ($age) = @_;
154                 '.meta_prettyprint_age('$age','floor','.').'
155   };
156   1;
157 ' or die "$@";
158 }
159
160
161 sub dbw_lookup_string ($$$$$$$$) { # => ( $emsg, @dbresults )
162     my ($each,
163         $sth, $stmt_nqs, $abbrev_initials, $maxambig,
164         $em_nomatch, $em_manyambig, $emf_ambiguous) = @_;
165     
166     $each =~ s/^\s*//;  $each =~ s/\s*$//;  $each =~ s/\s+/ /g;
167     my %m;
168     my $results;
169     my @pats= ("$each", "$each \%", "$each\%", "\%$each\%");
170     if ($abbrev_initials) {
171         push @pats, join ' ', map { "$_%" } split //, $each;
172     }
173     foreach my $pat (@pats) {
174         $sth->execute(($pat) x $stmt_nqs);
175         $results= $sth->fetchall_arrayref();
176         last if @$results==1;
177         $m{ $_->[0] }=1 for @$results;
178         $results= undef;
179     }
180     if (!$results) {
181         if (!%m) {
182             return $em_nomatch;
183         } elsif (keys(%m) > $maxambig) {
184             return $em_manyambig;
185         } else {
186             return $emf_ambiguous->($each, join(', ', sort keys %m));
187         }
188     }
189     return (undef, @{ $results->[0] });
190 }
191
192 sub expected_error ($) {
193     my $r= { Emsg => $_[0] };
194     bless $r, 'CommodsWeb::ExpectedError';
195     die $r;
196 }
197
198 package CommodsWeb::ExpectedError;
199
200 sub emsg ($) {
201     my ($self) = @_;
202     return $self->{Emsg};
203 }
204
205 1;