yarrg/Commods.pm

   1 # This is part of ypp-sc-tools, a set of third-party tools for assisting
   2 # players of Yohoho Puzzle Pirates.
   3 #
   4 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 #
  19 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
  20 # are used without permission.  This program is not endorsed or
  21 # sponsored by Three Rings.
  22
  23 package Commods;
  24 use IO::File;
  25 use IO::Pipe;
  26 use HTTP::Request::Common ();
  27 use POSIX;
  28 use LWP::UserAgent;
  29
  30 use strict;
  31 use warnings;
  32
  33 BEGIN {
  34     use Exporter ();
  35     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  36     $VERSION     = 1.00;
  37     @ISA         = qw(Exporter);
  38     @EXPORT      = qw(&parse_info_clientside &fetch_with_rsync
  39                       &parse_info_serverside &parse_info_serverside_ocean
  40                       %oceans %commods %clients %commodclasses
  41                       %vessels %shotname2damage
  42                       &parse_pctb_commodmap %pctb_commodmap @pctb_commodmap
  43                       &get_our_version &check_tsv_line &errsan
  44                       &pipethrough_prep &pipethrough_run
  45                       &pipethrough_run_along &pipethrough_run_finish
  46                       &pipethrough_run_gzip &http_useragent &version_core
  47                       &http_useragent_string_map
  48                       &cgipostform &yarrgpostform &cgi_get_caller
  49                       &set_ctype_utf8 $masterinfoversion
  50                       &source_tarball);
  51     %EXPORT_TAGS = ( );
  52
  53     @EXPORT_OK   = qw();
  54 }
  55
  56 our $masterinfoversion= 2; # version we understand.
  57 #
  58 # To extend the source-info.txt format:
  59 #
  60 #    * Commods.pm:parse_info1
  61 #       add code to parse new version
  62 #
  63 #    * source-info.txt
  64 #       add new information
  65 #
  66 # If new data should NOT be in master-info.txt too:
  67 #
  68 #    * update-master-info:process_some_info
  69 #       check that code for converting source-info to master-info
  70 #       removes the extra info; add code to remove it if necessary
  71 #
  72 #    * db-idempotent-populate
  73 #       if database schema is extended, add code to copy data
  74 #
  75 # If new data DOES need to be in master-info.txt too:
  76 #
  77 #    * Commods.pm:$masterinfoversion
  78 #       increment
  79 #
  80 #    * update-master-info:process_some_info
  81 #       add code to convert new version to old, by removing
  82 #       extra info conditionally depending on version
  83
  84 our %oceans; # eg $oceans{'Midnight'}{'Ruby'}{'Eta Island'}= $sources;
  85 our %clients; # eg $clients{'ypp-sc-tools'}= [ qw(last-page) ];
  86 our %vessels; # eg $vessels{'War Brig'}{Shot}='medium'
  87               #    $vessels{'War Brig'}{Volume}= 81000
  88               #    $vessels{'War Brig'}{Mass}= 54000
  89 our %shotname2damage; # eg $shotname2damage{'medium'}= 3;
  90 # $sources = 's[l]b';
  91 #       's' = Special Circumstances; 'l' = local ; B = with Bleach
  92
  93 our %commods;
  94 # eg $commods{'Fine black cloth'}{Srcs}= $sources;
  95 # eg $commods{'Fine black cloth'}{Mass}= 700 [g]
  96 # eg $commods{'Fine black cloth'}{Volume}= 1000 [ml]
  97 # eg $commods{'Fine black cloth'}{Ordval}= 203921
  98
  99 our (%pctb_commodmap,@pctb_commodmap);
 100
 101 my %colours; # eg $colours{'c'}{'black'}= $sources
 102 my (@rawcm, @nocm); # eg $rawcm[0]='fine rum'; $rawcm[1]='fine %c cloth'
 103
 104 my %colour_ordvals; # $colour_ordvals{'c'}{'green'}= '30';
 105 our %commodclasses; # $commodclasses{'dye'}= '3';
 106
 107 # IMPORTANT
 108 #  when extending the format of source-info in a non-backward
 109 #  compatible way, be sure to update update-master-info too.
 110
 111 sub parse_info1 ($$$) {
 112     my ($mmfn,$src,$enoentok)= @_;
 113     my $mm= new IO::File $mmfn, 'r';
 114     if (!$mm) {
 115         return if $enoentok && $!==&ENOENT;
 116         die "$mmfn $!";
 117     }
 118     my @ctx= ();
 119     while (<$mm>) {
 120         next if m/^\s*\#/;
 121         next unless m/\S/;
 122         s/\s+$//;
 123         if (m/^\%(\w+)$/) {
 124             my $colourkind= $1;
 125             @ctx= (sub {
 126                 m/^(\S[^\t@]*\S)(?:\t+\@(\d+\+?))?$/ or die "$_ ?";
 127                 my ($colour,$order)=($1,$2);
 128                 $colours{$colourkind}{$colour} .= $src;
 129                 if (defined $order) {
 130                     $order =~ s/^(\d+)\+$/ $1  + $. * 10 /e;
 131                     $colour_ordvals{$colourkind}{$colour}= $order;
 132                 }
 133             });
 134         } elsif (m/^commods$/) {
 135             @ctx= (sub { push @rawcm, lc $_; });
 136         } elsif (m/^nocommods$/) {
 137             @ctx= (sub { push @nocm, lc $_; });
 138         } elsif (m/^commodclasses$/) {
 139             @ctx= (sub {
 140                 die unless m/^\*([_a-z]+)$/;
 141                 $commodclasses{$1}= scalar keys %commodclasses;
 142             });
 143         } elsif (m/^ocean (\w+)$/) {
 144             my $ocean= $1;
 145             keys %{ $oceans{$ocean} };
 146             @ctx= (sub {
 147                 $ocean or die; # ref to $ocean needed to work
 148                                # around a perl bug
 149                 my $arch= $_;
 150                 keys %{ $oceans{$ocean}{$arch} };
 151                 $ctx[1]= sub {
 152                     $oceans{$ocean}{$arch}{$_} .= $src;
 153                 };
 154             });
 155         } elsif (m/^vessels$/) {
 156             @ctx= (sub {
 157                 return if m/^[-+|]+$/;
 158                 m/^ \| \s* ([A-Z][a-z\ ]+[a-z]) \s*
 159                     \| \s* (small|medium|large) \s*
 160                     \| \s* ([1-9][0-9,]+) \s*
 161                     \| \s* ([1-9][0-9,]+) \s*
 162                     \| $/x
 163                     or die;
 164                 my $name= $1;
 165                 my $v= { Shot => $2, Volume => $3, Mass => $4 };
 166                 foreach my $vm (qw(Volume Mass)) { $v->{$vm} =~ s/,//g; }
 167                 $vessels{$name}= $v;
 168             });
 169         } elsif (m/^shot$/) {
 170             @ctx= (sub {
 171                 m/^ ([a-z]+) \s+ (\d+) $/x or die;
 172                 $shotname2damage{$1}= $2;
 173             });
 174         } elsif (m/^client (\S+.*\S)$/) {
 175             my $client= $1;
 176             $clients{$client}= [ ];
 177             @ctx= (sub {
 178                 my $bug= $_;
 179                 push @{ $clients{$client} }, $bug;
 180             });
 181         } elsif (s/^ +//) {
 182             my $indent= length $&;
 183             die "wrong indent $indent" unless defined $ctx[$indent-1];
 184             &{ $ctx[$indent-1] }();
 185         } else {
 186             die "bad syntax";
 187         }
 188     }
 189     $mm->error and die $!;
 190     close $mm or die $!;
 191
 192 #print Dumper(\%oceans);
 193 #print Dumper(\@rawcm);
 194
 195     %commods= ();
 196     my $ca;
 197     my $lnoix=0;
 198     $ca= sub {
 199         my ($s,$ss,$ordbase) = @_;
 200 #print STDERR "ca($s,,".(defined $ordbase ? $ordbase : '?').")\n";
 201         if ($s !~ m/\%(\w+)/) {
 202             my ($name, $props) = $s =~
 203                 /^(\S[^\t]*\S)(?:\t+(\S.*\S))?$/
 204                 or die "bad commodspec $s";
 205             return if grep { $name eq $_ } @nocm;
 206             my $ucname= ucfirst $name;
 207             $commods{$ucname}{Srcs} .= $ss;
 208             my $c= $commods{$ucname};
 209             $c->{Volume}= 1000;
 210             $c->{Flags}= '';
 211             my ($ordval, $ordclassval);
 212             foreach my $prop (defined $props ? split /\s+/, $props : ()) {
 213                 if ($prop =~ m/^([1-9]\d*)(k?)g$/) {
 214                     $c->{Mass}= $1 * ($2 ? 1000 : 1);
 215                 } elsif ($prop =~ m/^([1-9]\d*)l$/) {
 216                     $c->{Volume}= $1 * 1000;
 217                 } elsif ($prop =~ m/^\*([_a-z]+)$/) {
 218                     $c->{Class}= $1;
 219                     die "$1" unless exists $commodclasses{$1};
 220                     $ordclassval= 1e7 + $commodclasses{$1} * 1e7;
 221                 } elsif ($prop =~ m/^\@(\d+\+?)$/) {
 222                     $ordval= $1;
 223                     $ordval =~ s/^(\d+)\+$/ $1 + $lnoix * 10 /e;
 224                 } elsif ($prop =~ m/^\!([a-z]+)$/) {
 225                     $c->{Flags} .= $1;
 226                 } else {
 227                     die "unknown property $prop for $ucname";
 228                 }
 229             }
 230             $c->{ClassOrdval}= $ordclassval;
 231             if (defined $ordbase && defined $ordval && defined $ordclassval) {
 232                 my $ordvalout= $ordbase + $ordval + $ordclassval;
 233                 $c->{Ordval}= $ordvalout;
 234 #print STDERR "ordval $ordvalout $name OV=$ordval OB=$ordbase OCV=$ordclassval\n";
 235             } else {
 236 #print STDERR "ordval NONE $name\n";
 237             }
 238             return;
 239         }
 240         die "unknown $&" unless defined $colours{$1};
 241         my ($lhs,$pctlet,$rhs)= ($`,$1,$');
 242         foreach my $c (keys %{ $colours{$pctlet} }) {
 243             my $ordcolour= $colour_ordvals{$pctlet}{$c};
 244             &$ca($lhs.$c.$rhs,
 245                  $ss .'%'. $colours{$pctlet}{$c},
 246                  defined($ordbase) && defined($ordcolour)
 247                      ? $ordbase+$ordcolour : undef);
 248         }
 249     };
 250     foreach (@rawcm) { $lnoix++; &$ca($_,$src,0); }
 251 }
 252
 253 sub parse_info_clientside () {
 254     my $master= fetch_with_rsync("info-v$masterinfoversion");
 255     parse_info1($master,'s',1);
 256     parse_info1('_local-info.txt','s',1);
 257 }
 258
 259 sub fetch_with_rsync ($) {
 260     my ($stem) = @_;
 261
 262     my $rsync= $ENV{'YPPSC_YARRG_RSYNC'};
 263     $rsync= 'rsync' if !defined $rsync;
 264
 265     my $local= "_master-$stem.txt";
 266     my $src= $ENV{'YPPSC_YARRG_DICT_UPDATE'};
 267     if ($src) {
 268         my $remote= "$src/master-$stem.txt";
 269         $!=0; system 'rsync','-Lt','--',$remote,$local;
 270         die "$? $!" if $! or $?;
 271     }
 272     return $local;
 273 }
 274
 275 sub parse_info_serverside () {
 276     parse_info1('source-info.txt','s',0);
 277     parse_info1('tree-info.txt','t',1);
 278 }
 279 sub parse_info_serverside_ocean ($) {
 280     my ($oceanname) = @_;
 281     die "unknown ocean $oceanname ?" unless exists $oceans{$oceanname};
 282     parse_info1("_ocean-".(lc $oceanname).".txt", 's',0);
 283 }
 284
 285 sub parse_pctb_commodmap () {
 286     undef %pctb_commodmap;
 287     foreach my $commod (keys %commods) { $commods{$commod}{Srcs} =~ s/b//; }
 288
 289     my $c= new IO::File '_commodmap.tsv';
 290     if (!$c) { $!==&ENOENT or die $!; return 0; }
 291
 292     while (<$c>) {
 293         m/^(\S.*\S)\t(\d+)\n$/ or die "$_";
 294         die if defined $pctb_commodmap{$1};  $pctb_commodmap{$1}= $2;
 295         die if defined $pctb_commodmap[$2];  $pctb_commodmap[$2]= $1;
 296         $commods{$1}{Srcs} .= 'b';
 297     }
 298     $c->error and die $!;
 299     close $c or die $!;
 300     return 1;
 301 }
 302
 303 sub get_our_version ($$) {
 304     my ($aref,$prefix) = @_;
 305     $aref->{"${prefix}name"}= 'ypp-sc-tools yarrg';
 306     $aref->{"${prefix}fixes"}= 'lastpage checkpager';
 307     $aref->{"${prefix}version"}= version_core();
 308     return $aref;
 309     # clientname        "ypp-sc-tools"
 310     # clientversion     2.1-g2e06a26  [from git-describe --tags HEAD]
 311     # clientfixes       "lastpage"  [space separated list]
 312 }
 313
 314 sub version_core () {
 315     my $version= `
 316         if type -p git-describe >/dev/null 2>&1; then
 317                 gd=git-describe
 318         else
 319                 gd="git describe"
 320         fi
 321         \$gd --tags HEAD || echo 0unknown
 322     `; $? and die $?;
 323     chomp($version);
 324     return $version;
 325 }
 326
 327 sub pipethrough_prep () {
 328     my $tf= IO::File::new_tmpfile() or die $!;
 329     return $tf;
 330 }
 331
 332 sub pipethrough_run_along ($$$@) {
 333     my ($tf, $childprep, $cmd, @a) = @_;
 334     $tf->error and die $!;
 335     $tf->flush or die $!;
 336     $tf->seek(0,0) or die $!;
 337     my $fh= new IO::File;
 338     my $child= $fh->open("-|"); defined $child or die $!;
 339     if (!$child) {
 340         open STDIN, "<&", $tf;
 341         &$childprep() if defined $childprep;
 342         exec $cmd @a; die "@a $!";
 343     }
 344     return $fh;
 345 }
 346 sub pipethrough_run_finish ($$) {
 347     my ($fh, $what)= @_;
 348     $fh->error and die $!;
 349     close $fh or die "$what $! $?";  die $? if $?;
 350 }
 351
 352 sub pipethrough_run ($$$@) {
 353     my ($tf, $childprep, $cmd, @a) = @_;
 354     my $pt= pipethrough_run_along($tf,$childprep,$cmd,@a);
 355     my $r;
 356     { undef $/; $!=0; $r= <$pt>; }
 357     defined $r or die $!;
 358     pipethrough_run_finish($pt, "@a");
 359     return $r;
 360 }
 361 sub pipethrough_run_gzip ($) {
 362     pipethrough_run($_[0],undef,'gzip','gzip');
 363 }
 364
 365 sub yarrgpostform ($$) {
 366     my ($ua, $form) = @_;
 367     my $dest= $ENV{'YPPSC_YARRG_YARRG'};
 368     get_our_version($form, 'client');
 369     die unless $dest =~ m,/$,;
 370     return cgipostform($ua, "${dest}commod-update-receiver", $form);
 371 }
 372
 373 sub cgipostform ($$$) {
 374     my ($ua, $url, $form) = @_;
 375     my $req= HTTP::Request::Common::POST($url,
 376                                          Content => $form,
 377                                          Content_Type => 'form-data');
 378     if ($url =~ m,^\.?/,) {
 379         my $tf= pipethrough_prep();
 380         print $tf $req->content() or die $!;
 381 #print STDERR "[[[",$req->content(),"]]]";
 382         my $out= pipethrough_run($tf, sub {
 383             $ENV{'REQUEST_METHOD'}= 'POST';
 384             $ENV{'QUERY_STRING'}= '';
 385             $ENV{'PATH_TRANSLATED'}= $url;
 386             $ENV{'PATH_INFO'}= '';
 387             $ENV{'HTTP_HOST'}= 'localhost';
 388             $ENV{'REMOTE_ADDR'}= '127.0.0.1';
 389             $ENV{'GATEWAY_INTERFACE'}= 'CGI/1.1';
 390             $ENV{'DOCUMENT_ROOT'}= '.';
 391             $ENV{'SCRIPT_FILENAME'}= $url;
 392             $ENV{'SCRIPT_NAME'}= $url;
 393             $ENV{'HTTP_USER_AGENT'}= 'Commods.pm local test';
 394
 395             foreach my $f (qw(Content_Length Content_Type)) {
 396                 $ENV{uc $f}= $req->header($f);
 397             }
 398 #system 'printenv >&2';
 399         }, "$url", "$url");
 400         $out =~ s/\r\n/\n/g;
 401         $out =~ m,^Content-Type: text/plain.*\n\n, or die "$out ?";
 402         return $';
 403     } else {
 404         my $resp= $ua->request($req);
 405         die $resp->status_line."\n".$resp->content."\n "
 406             unless $resp->is_success;
 407         return $resp->content();
 408     }
 409 }
 410
 411 our %check_tsv_done;
 412
 413 sub errsan ($) {
 414     my ($value) = @_;
 415     $value =~ s/[^-+\'. A-Za-z0-9]/ sprintf "\\x%02x",ord $& /ge;
 416     return "\"$value\"";
 417 }
 418
 419 sub check_tsv_line ($$) {
 420     my ($l, $bad_data_callback) = @_;
 421     my $bad_data= sub { &$bad_data_callback("bad data: line $.: $_[0]"); };
 422
 423     chomp($l) or &$bad_data('missing end-of-line');
 424
 425     $l !~ m/\P{IsPrint}/ or &$bad_data('nonprinting char(s)');
 426     my @v= split /\t/, $l, -1;
 427     @v==6 or &$bad_data('wrong number of fields');
 428     my ($commod,$stall) = @v;
 429
 430     !keys %commods or
 431         defined $commods{$commod} or
 432         &$bad_data("unknown commodity ".errsan($commod));
 433
 434     $stall =~ m/^\p{IsUpper}|^[0-9]/ or
 435         &$bad_data("stall not capitalised ".errsan($stall));
 436     !exists $check_tsv_done{$commod,$stall} or
 437         &$bad_data("repeated data ".errsan($commod).",".errsan($stall));
 438     $check_tsv_done{$commod,$stall}= 1;
 439     foreach my $i (2..5) {
 440         my $f= $v[$i];
 441         $f =~ m/^(|0|[1-9][0-9]{0,5}|\>1000)$/ or
 442             &$bad_data("bad field $i ".errsan($f));
 443         ($i % 2) or ($f !~ m/\>/) or
 444             &$bad_data("> in field $i price ".errsan($f));
 445     }
 446
 447     foreach my $i (2,4) {
 448         &$bad_data("price with no qty or vice versa (field $i)")
 449             if length($v[$i]) xor length($v[$i+1]);
 450     }
 451     length($v[2]) or length($v[4]) or
 452         &$bad_data("commodity entry with no buy or sell offer");
 453
 454     return @v;
 455 }
 456
 457 sub cgi_get_caller () {
 458     my $caller= $ENV{'REMOTE_ADDR'};
 459     $caller= 'LOCAL' unless defined $caller;
 460
 461     my $fwdf= $ENV{'HTTP_X_FORWARDED_FOR'};
 462     if (defined $fwdf) {
 463         $fwdf =~ s/\s//g;
 464         $fwdf =~ s/[^0-9.,]/?/g;
 465         $caller= "$fwdf";
 466     }
 467     return $caller;
 468 }
 469
 470 sub set_ctype_utf8 () {
 471     setlocale(LC_CTYPE, "en.UTF-8");
 472 }
 473
 474 sub http_useragent_string_map ($$) {
 475     my ($caller_lib_agent, $reason_style_or_caller) = @_;
 476     $caller_lib_agent =~ y/A-Za-z/N-ZA-Mn-za-m/;
 477     $caller_lib_agent =~ s/\s/_/g;
 478     my $version= version_core();
 479     return "yarrg/$version ($reason_style_or_caller)".
 480            " $caller_lib_agent".
 481            " (http://yarrg.chiark.net/intro)";
 482 }
 483
 484 sub http_useragent ($) {
 485     my ($who) = @_;
 486     my $ua= LWP::UserAgent->new;
 487     my $base= $ua->_agent();
 488     $ua->agent(http_useragent_string_map($base, $who));
 489     return $ua;
 490 }
 491
 492 sub source_tarball ($$) {
 493     my ($sourcebasedir,$spitoutfn) = @_;
 494
 495     my $pipe= new IO::Pipe or die $!;
 496     my $pid= fork();  defined $pid or die $!;
 497     if (!$pid) {
 498         $ENV{'YPPSC_YARRG_SRCBASE'}= $sourcebasedir;
 499         $pipe->writer();
 500         exec '/bin/sh','-c','
 501                 cd -P "$YPPSC_YARRG_SRCBASE"
 502                 (
 503                  git-ls-files -z;
 504                  git-ls-files -z --others --exclude-from=.gitignore;
 505                  if test -d .git; then find .git -print0; fi
 506                 ) | (
 507                  cpio -Hustar -o --quiet -0 -R 1000:1000 || \
 508                  cpio -Hustar -o --quiet -0
 509                 ) | gzip
 510         ';
 511         die $!;
 512     }
 513     $pipe->reader();
 514
 515     my ($d, $l);
 516     while ($l= read $pipe, $d, 65536) {
 517         $spitoutfn->($d);
 518     }
 519     waitpid $pid,0;
 520     defined $l or die "read pipe $!";
 521     $pipe->error and die "pipe error $!";
 522     close $pipe;
 523     # deliberately ignore errors
 524 }
 525
 526 1;