chiark / gitweb /
24f2e81ae9eedb49353a925f4a2a06d2aeb1b200
[ypp-sc-tools.db-live.git] / yarrg / Commods.pm
1 # This is part of ypp-sc-tools, a set of third-party tools for assisting
2 # players of Yohoho Puzzle Pirates.
3 #
4 # Copyright (C) 2009 Ian Jackson <ijackson@chiark.greenend.org.uk>
5 #
6 # This program is free software: you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation, either version 3 of the License, or
9 # (at your option) any later version.
10 #
11 # This program is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15 #
16 # You should have received a copy of the GNU General Public License
17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
18 #
19 # Yohoho and Puzzle Pirates are probably trademarks of Three Rings and
20 # are used without permission.  This program is not endorsed or
21 # sponsored by Three Rings.
22
23 package Commods;
24 use IO::File;
25 use IO::Pipe;
26 use HTTP::Request::Common ();
27 use POSIX;
28 use LWP::UserAgent;
29
30 use strict;
31 use warnings;
32
33 BEGIN {
34     use Exporter ();
35     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
36     $VERSION     = 1.00;
37     @ISA         = qw(Exporter);
38     @EXPORT      = qw(&parse_info_clientside &fetch_with_rsync
39                       &parse_info_serverside &parse_info_serverside_ocean
40                       %oceans %commods %clients
41                       %vessels %shotname2damage
42                       &parse_pctb_commodmap %pctb_commodmap @pctb_commodmap
43                       &get_our_version &check_tsv_line
44                       &pipethrough_prep &pipethrough_run
45                       &pipethrough_run_along &pipethrough_run_finish
46                       &pipethrough_run_gzip &http_useragent &version_core
47                       &http_useragent_string_map
48                       &cgipostform &yarrgpostform &cgi_get_caller
49                       &set_ctype_utf8 $masterinfoversion
50                       &source_tarball);
51     %EXPORT_TAGS = ( );
52
53     @EXPORT_OK   = qw();
54 }
55
56 our $masterinfoversion= 2; # version we understand.
57 #
58 # To extend the source-info.txt format:
59 #
60 #    * Commods.pm:parse_info1
61 #       add code to parse new version
62 #
63 #    * source-info.txt
64 #       add new information
65 #
66 # If new data should NOT be in master-info.txt too:
67 #
68 #    * update-master-info:process_some_info
69 #       check that code for converting source-info to master-info
70 #       removes the extra info; add code to remove it if necessary
71 #
72 #    * db-idempotent-populate
73 #       if database schema is extended, add code to copy data
74 #
75 # If new data DOES need to be in master-info.txt too:
76 #
77 #    * Commods.pm:$masterinfoversion
78 #       increment
79 #
80 #    * update-master-info:process_some_info
81 #       add code to convert new version to old, by removing
82 #       extra info conditionally depending on version
83
84 our %oceans; # eg $oceans{'Midnight'}{'Ruby'}{'Eta Island'}= $sources;
85 our %clients; # eg $clients{'ypp-sc-tools'}= [ qw(last-page) ];
86 our %vessels; # eg $vessels{'War Brig'}{Shot}='medium'
87               #    $vessels{'War Brig'}{Volume}= 81000
88               #    $vessels{'War Brig'}{Mass}= 54000
89 our %shotname2damage; # eg $shotname2damage{'medium'}= 3;
90 # $sources = 's[l]b';
91 #       's' = Special Circumstances; 'l' = local ; B = with Bleach
92
93 our %commods;
94 # eg $commods{'Fine black cloth'}{Srcs}= $sources;
95 # eg $commods{'Fine black cloth'}{Mass}= 700 [g]
96 # eg $commods{'Fine black cloth'}{Volume}= 1000 [ml]
97
98 our (%pctb_commodmap,@pctb_commodmap);
99
100 my %colours; # eg $colours{'c'}{'black'}= $sources
101 my (@rawcm, @nocm); # eg $rawcm[0]='fine rum'; $rawcm[1]='fine %c cloth'
102
103 # IMPORTANT
104 #  when extending the format of source-info in a non-backward
105 #  compatible way, be sure to update update-master-info too.
106
107 sub parse_info1 ($$$) {
108     my ($mmfn,$src,$enoentok)= @_;
109     my $mm= new IO::File $mmfn, 'r';
110     if (!$mm) {
111         return if $enoentok && $!==&ENOENT;
112         die "$mmfn $!";
113     }
114     my @ctx= ();
115     while (<$mm>) {
116         next if m/^\s*\#/;
117         next unless m/\S/;
118         s/\s+$//;
119         if (m/^\%(\w+)$/) {
120             my $colourkind= $1;
121             @ctx= (sub { $colours{$colourkind}{lc $_} .= $src; });
122         } elsif (m/^commods$/) {
123             @ctx= (sub { push @rawcm, lc $_; });
124         } elsif (m/^nocommods$/) {
125             @ctx= (sub { push @nocm, lc $_; });
126         } elsif (m/^ocean (\w+)$/) {
127             my $ocean= $1;
128             keys %{ $oceans{$ocean} };
129             @ctx= (sub {
130                 $ocean or die; # ref to $ocean needed to work
131                                # around a perl bug
132                 my $arch= $_;
133                 keys %{ $oceans{$ocean}{$arch} };
134                 $ctx[1]= sub {
135                     $oceans{$ocean}{$arch}{$_} .= $src;
136                 };
137             });
138         } elsif (m/^vessels$/) {
139             @ctx= (sub {
140                 return if m/^[-+|]+$/;
141                 m/^ \| \s* ([A-Z][a-z\ ]+[a-z]) \s*
142                     \| \s* (small|medium|large) \s*
143                     \| \s* ([1-9][0-9,]+) \s*
144                     \| \s* ([1-9][0-9,]+) \s*
145                     \| $/x
146                     or die;
147                 my $name= $1;
148                 my $v= { Shot => $2, Volume => $3, Mass => $4 };
149                 foreach my $vm (qw(Volume Mass)) { $v->{$vm} =~ s/,//g; }
150                 $vessels{$name}= $v;
151             });
152         } elsif (m/^shot$/) {
153             @ctx= (sub {
154                 m/^ ([a-z]+) \s+ (\d+) $/x or die;
155                 $shotname2damage{$1}= $2;
156             });
157         } elsif (m/^client (\S+.*\S)$/) {
158             my $client= $1;
159             $clients{$client}= [ ];
160             @ctx= (sub {
161                 my $bug= $_;
162                 push @{ $clients{$client} }, $bug;
163             });
164         } elsif (s/^ +//) {
165             my $indent= length $&;
166             die "wrong indent $indent" unless defined $ctx[$indent-1];
167             &{ $ctx[$indent-1] }();
168         } else {
169             die "bad syntax";
170         }
171     }
172     $mm->error and die $!;
173     close $mm or die $!;
174
175 #print Dumper(\%oceans);
176 #print Dumper(\@rawcm);
177         
178     %commods= ();
179     my $ca;
180     $ca= sub {
181         my ($s,$ss) = @_;
182 #print "ca($s)\n";
183         if ($s !~ m/\%(\w+)/) {
184             my ($name, $props) = $s =~
185                 /^(\S[^\t]*\S)(?:\t+(\S[^\t]*\S))?$/
186                 or die "bad commodspec $s";
187             return if grep { $name eq $_ } @nocm;
188             my $ucname= ucfirst $name;
189             $commods{$ucname}{Srcs} .= $ss;
190             my $c= $commods{$ucname};
191             $c->{Volume}= 1000;
192             foreach my $prop (defined $props ? split /\s+/, $props : ()) {
193                 if ($prop =~ m/^([1-9]\d*)(k?)g$/) {
194                     $c->{Mass}= $1 * ($2 ? 1000 : 1);
195                 } elsif ($prop =~m/^([1-9]\d*)l$/) {
196                     $c->{Volume}= $1 * 1000;
197                 } else {
198                     die "unknown property $prop for $ucname";
199                 }
200             }
201             return;
202         }
203         die "unknown $&" unless defined $colours{$1};
204         my ($lhs,$pctlet,$rhs)= ($`,$1,$');
205         foreach my $c (keys %{ $colours{$pctlet} }) {
206             &$ca($lhs.$c.$rhs, $ss .'%'. $colours{$pctlet}{$c});
207         }
208     };
209     foreach (@rawcm) { &$ca($_,$src); }
210 }
211
212 sub parse_info_clientside () {
213     my $master= fetch_with_rsync("info-v$masterinfoversion");
214     parse_info1($master,'s',1);
215     parse_info1('_local-info.txt','s',1);
216 }
217
218 sub fetch_with_rsync ($) {
219     my ($stem) = @_;
220
221     my $rsync= $ENV{'YPPSC_YARRG_RSYNC'};
222     $rsync= 'rsync' if !defined $rsync;
223
224     my $local= "_master-$stem.txt";
225     my $src= $ENV{'YPPSC_YARRG_DICT_UPDATE'};
226     if ($src) {
227         my $remote= "$src/master-$stem.txt";
228         $!=0; system 'rsync','-Lt','--',$remote,$local;
229         die "$? $!" if $! or $?;
230     }
231     return $local;
232 }
233
234 sub parse_info_serverside () {
235     parse_info1('source-info.txt','s',0);
236 }
237 sub parse_info_serverside_ocean ($) {
238     my ($oceanname) = @_;
239     die "unknown ocean $oceanname ?" unless exists $oceans{$oceanname};
240     parse_info1("_ocean-".(lc $oceanname).".txt", 's',0);
241 }
242
243 sub parse_pctb_commodmap () {
244     undef %pctb_commodmap;
245     foreach my $commod (keys %commods) { $commods{$commod}{Srcs} =~ s/b//; }
246
247     my $c= new IO::File '_commodmap.tsv';
248     if (!$c) { $!==&ENOENT or die $!; return 0; }
249
250     while (<$c>) {
251         m/^(\S.*\S)\t(\d+)\n$/ or die "$_";
252         die if defined $pctb_commodmap{$1};  $pctb_commodmap{$1}= $2;
253         die if defined $pctb_commodmap[$2];  $pctb_commodmap[$2]= $1;
254         $commods{$1}{Srcs} .= 'b';
255     }
256     $c->error and die $!;
257     close $c or die $!;
258     return 1;
259 }
260
261 sub get_our_version ($$) {
262     my ($aref,$prefix) = @_;
263     $aref->{"${prefix}name"}= 'ypp-sc-tools yarrg';
264     $aref->{"${prefix}fixes"}= 'lastpage checkpager';
265     $aref->{"${prefix}version"}= version_core();
266     return $aref;
267     # clientname        "ypp-sc-tools"
268     # clientversion     2.1-g2e06a26  [from git-describe --tags HEAD]
269     # clientfixes       "lastpage"  [space separated list]
270 }
271
272 sub version_core () {
273     my $version= `
274         if type -p git-describe >/dev/null 2>&1; then
275                 gd=git-describe
276         else
277                 gd="git describe"
278         fi
279         \$gd --tags HEAD || echo 0unknown
280     `; $? and die $?;
281     chomp($version);
282     return $version;
283 }
284
285 sub pipethrough_prep () {
286     my $tf= IO::File::new_tmpfile() or die $!;
287     return $tf;
288 }
289
290 sub pipethrough_run_along ($$$@) {
291     my ($tf, $childprep, $cmd, @a) = @_;
292     $tf->error and die $!;
293     $tf->flush or die $!;
294     $tf->seek(0,0) or die $!;
295     my $fh= new IO::File;
296     my $child= $fh->open("-|"); defined $child or die $!;
297     if (!$child) {
298         open STDIN, "<&", $tf;
299         &$childprep() if defined $childprep;
300         exec $cmd @a; die "@a $!";
301     }
302     return $fh;
303 }
304 sub pipethrough_run_finish ($$) {
305     my ($fh, $what)= @_;
306     $fh->error and die $!;
307     close $fh or die "$what $! $?";  die $? if $?;
308 }
309
310 sub pipethrough_run ($$$@) {
311     my ($tf, $childprep, $cmd, @a) = @_;
312     my $pt= pipethrough_run_along($tf,$childprep,$cmd,@a);
313     my $r;
314     { undef $/; $!=0; $r= <$pt>; }
315     defined $r or die $!;
316     pipethrough_run_finish($pt, "@a");
317     return $r;
318 }
319 sub pipethrough_run_gzip ($) {
320     pipethrough_run($_[0],undef,'gzip','gzip');
321 }
322
323 sub yarrgpostform ($$) {
324     my ($ua, $form) = @_;
325     my $dest= $ENV{'YPPSC_YARRG_YARRG'};
326     get_our_version($form, 'client');
327     die unless $dest =~ m,/$,;
328     return cgipostform($ua, "${dest}commod-update-receiver", $form);
329 }    
330
331 sub cgipostform ($$$) {
332     my ($ua, $url, $form) = @_;
333     my $req= HTTP::Request::Common::POST($url,
334                                          Content => $form,
335                                          Content_Type => 'form-data');
336     if ($url =~ m,^\.?/,) {
337         my $tf= pipethrough_prep();
338         print $tf $req->content() or die $!;
339 #print STDERR "[[[",$req->content(),"]]]";
340         my $out= pipethrough_run($tf, sub {
341             $ENV{'REQUEST_METHOD'}= 'POST';
342             $ENV{'QUERY_STRING'}= '';
343             $ENV{'PATH_TRANSLATED'}= $url;
344             $ENV{'PATH_INFO'}= '';
345             $ENV{'HTTP_HOST'}= 'localhost';
346             $ENV{'REMOTE_ADDR'}= '127.0.0.1';
347             $ENV{'GATEWAY_INTERFACE'}= 'CGI/1.1';
348             $ENV{'DOCUMENT_ROOT'}= '.';
349             $ENV{'SCRIPT_FILENAME'}= $url;
350             $ENV{'SCRIPT_NAME'}= $url;
351             $ENV{'HTTP_USER_AGENT'}= 'Commods.pm local test';
352
353             foreach my $f (qw(Content_Length Content_Type)) {
354                 $ENV{uc $f}= $req->header($f);
355             }
356 #system 'printenv >&2';
357         }, "$url", "$url");
358         $out =~ s/\r\n/\n/g;
359         $out =~ m,^Content-Type: text/plain.*\n\n, or die "$out ?";
360         return $';
361     } else {
362         my $resp= $ua->request($req);
363         die $resp->status_line."\n".$resp->content."\n "
364             unless $resp->is_success;
365         return $resp->content();
366     }
367 }
368
369 our %check_tsv_done;
370
371 sub check_tsv_line ($$) {
372     my ($l, $bad_data_callback) = @_;
373     my $bad_data= sub { &$bad_data_callback("bad data: line $.: $_[0]"); };
374     
375     chomp($l) or &$bad_data('missing end-of-line');
376
377     $l !~ m/\P{IsPrint}/ or &$bad_data('nonprinting char(s)');
378     my @v= split /\t/, $l, -1;
379     @v==6 or &$bad_data('wrong number of fields');
380     my ($commod,$stall) = @v;
381
382     !keys %commods or
383         defined $commods{$commod} or
384         &$bad_data("unknown commodity \`$commod'");
385     
386     $stall =~ m/^\p{IsUpper}|^[0-9]/ or &$bad_data("stall not capitalised");
387     !exists $check_tsv_done{$commod,$stall} or &$bad_data("repeated data");
388     $check_tsv_done{$commod,$stall}= 1;
389     foreach my $i (2..5) {
390         my $f= $v[$i];
391         $f =~ m/^(|0|[1-9][0-9]{0,5}|\>1000)$/ or &$bad_data("bad field $i");
392         ($i % 2) or ($f !~ m/\>/) or &$bad_data("> in field $i price");
393     }
394
395     foreach my $i (2,4) {
396         &$bad_data("price with no qty or vice versa (field $i)")
397             if length($v[$i]) xor length($v[$i+1]);
398     }
399     length($v[2]) or length($v[4]) or
400         &$bad_data("commodity entry with no buy or sell offer");
401     
402     return @v;
403 }
404
405 sub cgi_get_caller () {
406     my $caller= $ENV{'REMOTE_ADDR'};
407     $caller= 'LOCAL' unless defined $caller;
408
409     my $fwdf= $ENV{'HTTP_X_FORWARDED_FOR'};
410     if (defined $fwdf) {
411         $fwdf =~ s/\s//g;
412         $fwdf =~ s/[^0-9.,]/?/g;
413         $caller= "$fwdf";
414     }
415     return $caller;
416 }
417
418 sub set_ctype_utf8 () {
419     setlocale(LC_CTYPE, "en.UTF-8");
420 }
421
422 sub http_useragent_string_map ($$) {
423     my ($caller_lib_agent, $reason_style_or_caller) = @_;
424     $caller_lib_agent =~ y/A-Za-z/N-ZA-Mn-za-m/;
425     $caller_lib_agent =~ s/\s/_/g;
426     my $version= version_core();
427     return "yarrg/$version ($reason_style_or_caller)".
428            " $caller_lib_agent".
429            " (http://yarrg.chiark.net/intro)";
430 }
431
432 sub http_useragent ($) {
433     my ($who) = @_;
434     my $ua= LWP::UserAgent->new;
435     my $base= $ua->_agent();
436     $ua->agent(http_useragent_string_map($base, $who));
437     return $ua;
438 }
439
440 sub source_tarball ($$) {
441     my ($sourcebasedir,$spitoutfn) = @_;
442
443     my $pipe= new IO::Pipe or die $!;
444     my $pid= fork();  defined $pid or die $!;
445     if (!$pid) {
446         $ENV{'YPPSC_YARRG_SRCBASE'}= $sourcebasedir;
447         $pipe->writer();
448         exec '/bin/sh','-c','
449                 cd -P "$YPPSC_YARRG_SRCBASE"
450                 (
451                  git-ls-files -z;
452                  git-ls-files -z --others --exclude-from=.gitignore;
453                  if test -d .git; then find .git -print0; fi
454                 ) | (
455                  cpio -Hustar -o --quiet -0 -R 1000:1000 || \
456                  cpio -Hustar -o --quiet -0
457                 ) | gzip
458         ';
459         die $!;
460     }
461     $pipe->reader();
462
463     my ($d, $l);
464     while ($l= read $pipe, $d, 65536) {
465         $spitoutfn->($d);
466     }
467     waitpid $pid,0;
468     defined $l or die "read pipe $!";
469     $pipe->error and die "pipe error $!";
470     close $pipe;
471     # deliberately ignore errors
472 }
473
474 1;