chiark - git - mdw - zones/blob - Makefile.m4

   1 ### Makefile for mdw's zones
   2 ###
   3 ### Preprocessed with m4, for the sake of madness
   4
   5 m4_divert(-1)
   6 ###--------------------------------------------------------------------------
   7 ### M4 trickery.
   8
   9 m4_changequote([, ])
  10 m4_define([_dolist], [m4_pushdef([$1])__loop($@)m4_popdef([$1])])
  11 m4_define([__loop], [m4_ifelse([$2], [()], ,m4_dnl
  12 [m4_define([$1], __first$2)$3[]__loop([$1],(m4_shift$2),[$3])])])
  13 m4_define([__first], [$1])
  14
  15 m4_define([DOMAIN], [m4_dnl
  16 m4_pushdef([_undivert], [m4_divert(]m4_divnum[)m4_popdef([_undivert])])m4_dnl
  17 m4_divert(10)m4_dnl
  18 $1_SUBNETS = _dolist([_subnet], [($2)], [ _subnet])
  19 $1_ZONES = _dolist([_zone], [($3)], [ _zone])
  20 $1_ZONE_FILES = _dolist([_subnet], [($2)],
  21         [_dolist([_zone], [($3)], [ _subnet/_zone.zone])])
  22 ALL_SUBNETS += $($1_SUBNETS)
  23 ALL_ZONES += $($1_ZONES)
  24 ALL_ZONE_FILES += $($1_ZONE_FILES)
  25 ALL_CLEAN_FILES += _dolist([_subnet], [($2)], [ _subnet/*])
  26 m4_divert(30)m4_dnl
  27 $($1_ZONE_FILES): $1.lisp $(ZONEDEPS)
  28         mkdir -p $($1_SUBNETS)m4_dnl
  29 _dolist([_subnet], [($2)], [
  30         $(ZONE) -d _subnet/ -f subnet/_subnet -s _subnet $1.lisp])
  31 _undivert[]m4_dnl
  32 ])
  33
  34 m4_divert(-1)
  35 ###--------------------------------------------------------------------------
  36 ### Domains.
  37
  38 DOMAIN([distorted], [inet, fretwank],
  39         [distorted.org.uk, io.distorted.org.uk, dhcp.distorted.org.uk,
  40          204.49.62.in-addr.arpa, 198.29.172.in-addr.arpa,
  41          199.29.172.in-addr.arpa, dhcp.199.29.172.in-addr.arpa])
  42 DOMAIN([harlequin], [inet, fretwank], [harlequin.org.uk])
  43
  44 m4_divert(0)
  45 ###--------------------------------------------------------------------------
  46 ### Make configuration.
  47
  48 ZONE = zone
  49
  50 ALL_ZONES =
  51 ALL_ZONE_FILES =
  52 ALL_CLEAN_FILES =
  53 ALL_SUBNETS =
  54
  55 PUBLISH = publish
  56
  57 ZONEDEPS = hosts.lisp
  58
  59 DOCS = distorted.tex
  60 DOC_OUTPUTS = $(foreach suffix,dvi ps,\
  61                 $(patsubst %.tex,%.$(suffix),$(DOCS)))
  62
  63 m4_divert(20)
  64 ###--------------------------------------------------------------------------
  65 ### Rules
  66
  67 all: $(ALL_ZONE_FILES)
  68 doc: $(DOC_OUTPUTS)
  69
  70 install: all
  71         ##
  72         ## Make directories
  73         rm -rf $(PUBLISH).new
  74         mkdir $(PUBLISH).new
  75         cd $(PUBLISH).new && mkdir $(sort $(ALL_SUBNETS))
  76         ##
  77         ## Copy zone files to output
  78         for i in $(ALL_ZONE_FILES); do \
  79           cp $$i $(PUBLISH).new/$$i; \
  80         done
  81         ##
  82         ## Make links as necessary
  83         cd $(PUBLISH).new; \
  84         for i in $(sort $(ALL_SUBNETS)); do \
  85           test $$i = inet && continue; \
  86           for z in $(sort $(ALL_ZONES)); do \
  87             test -f $$i/$$z.zone || ln -s ../inet/$$z.zone $$i/$$z.zone; \
  88           done; \
  89         done
  90         ##
  91         ## Switch over
  92         rm -rf $(PUBLISH).old
  93         mv $(PUBLISH) $(PUBLISH).old
  94         mv $(PUBLISH).new $(PUBLISH)
  95         ##
  96         ## Get nameserver to reload changed zones
  97         for i in $(sort $(ALL_SUBNETS)); do \
  98           for z in $(sort $(ALL_ZONES)); do \
  99             cmp $(PUBLISH)/$$i/$$z.zone $(PUBLISH).old/$$i/$$z.zone \
 100                 >/dev/null 2>&1 && continue; \
 101             echo -n "$$z ($$i): "; \
 102             userv root named-reload $$z $$i; \
 103           done; \
 104         done
 105         ##
 106         ## Clear up mess
 107         rm -rf $(PUBLISH).old
 108
 109 %.dvi: %.tex
 110         latex $<
 111         latex $<
 112
 113 %.ps: %.dvi
 114         dvips -o $@ $<
 115
 116 m4_divert(40)
 117 Makefile: Makefile.m4
 118         m4 -P $< >$@.new
 119         mv $@.new $@
 120
 121 clean:
 122         rm -f $(ALL_ZONE_FILES) $(ALL_CLEAN_FILES) \
 123                 *.toc *.lof *.lot *.log *.dvi *.ps *.aux
 124         rmdir $(sort $(ALL_SUBNETS))
 125
 126 ###----- That's all, folks --------------------------------------------------