Major network reorganization.

[zones] / Makefile.m4

### Makefile for mdw's zones
###
### Preprocessed with m4, for the sake of madness

m4_divert(-1)
###--------------------------------------------------------------------------
### M4 trickery.

m4_changequote([, ])
m4_define([_dolist], [m4_pushdef([$1])__loop($@)m4_popdef([$1])])
m4_define([__loop], [m4_ifelse([$2], [()], ,m4_dnl
[m4_define([$1], __first$2)$3[]__loop([$1],(m4_shift$2),[$3])])])
m4_define([__first], [$1])

m4_define([DOMAIN], [m4_dnl
m4_pushdef([_undivert], [m4_divert(]m4_divnum[)m4_popdef([_undivert])])m4_dnl
m4_divert(10)m4_dnl
$1_SUBNETS = _dolist([_subnet], [($2)], [ _subnet])
$1_ZONES = _dolist([_zone], [($3)], [ _zone])
$1_ZONE_FILES = _dolist([_subnet], [($2)],
	[_dolist([_zone], [($3)], [ _subnet/_zone.zone])])
ALL_SUBNETS += $($1_SUBNETS)
ALL_ZONES += $($1_ZONES)
ALL_ZONE_FILES += $($1_ZONE_FILES)
ALL_CLEAN_FILES += _dolist([_subnet], [($2)], [ _subnet/*])
m4_divert(30)m4_dnl
$($1_ZONE_FILES): $1.lisp $(ZONEDEPS)
	mkdir -p $($1_SUBNETS)m4_dnl
_dolist([_subnet], [($2)], [
	$(ZONE) -d _subnet/ -f subnet/_subnet -s _subnet $1.lisp])
_undivert[]m4_dnl
])

m4_divert(-1)
###--------------------------------------------------------------------------
### Domains.

DOMAIN([distorted], [inet, fretwank],
	[distorted.org.uk, io.distorted.org.uk, dhcp.distorted.org.uk,
	 204.49.62.in-addr.arpa, 198.29.172.in-addr.arpa,
	 199.29.172.in-addr.arpa, dhcp.199.29.172.in-addr.arpa])
DOMAIN([harlequin], [inet, fretwank], [harlequin.org.uk])

m4_divert(0)
###--------------------------------------------------------------------------
### Make configuration.

ZONE = zone

ALL_ZONES =
ALL_ZONE_FILES =
ALL_CLEAN_FILES =
ALL_SUBNETS =

PUBLISH = publish

ZONEDEPS = hosts.lisp

DOCS = distorted.tex
DOC_OUTPUTS = $(foreach suffix,dvi ps,\
		$(patsubst %.tex,%.$(suffix),$(DOCS)))

m4_divert(20)
###--------------------------------------------------------------------------
### Rules

all: $(ALL_ZONE_FILES)
doc: $(DOC_OUTPUTS)

install: all
	##
	## Make directories
	rm -rf $(PUBLISH).new
	mkdir $(PUBLISH).new
	cd $(PUBLISH).new && mkdir $(sort $(ALL_SUBNETS))
	##
	## Copy zone files to output
	for i in $(ALL_ZONE_FILES); do \
	  cp $$i $(PUBLISH).new/$$i; \
	done
	##
	## Make links as necessary
	cd $(PUBLISH).new; \
	for i in $(sort $(ALL_SUBNETS)); do \
	  test $$i = inet && continue; \
	  for z in $(sort $(ALL_ZONES)); do \
	    test -f $$i/$$z.zone || ln -s ../inet/$$z.zone $$i/$$z.zone; \
	  done; \
	done
	##
	## Switch over
	rm -rf $(PUBLISH).old
	mv $(PUBLISH) $(PUBLISH).old
	mv $(PUBLISH).new $(PUBLISH)
	##
	## Get nameserver to reload changed zones
	for i in $(sort $(ALL_SUBNETS)); do \
	  for z in $(sort $(ALL_ZONES)); do \
	    cmp $(PUBLISH)/$$i/$$z.zone $(PUBLISH).old/$$i/$$z.zone \
		>/dev/null 2>&1 && continue; \
	    echo -n "$$z ($$i): "; \
	    userv root named-reload $$z $$i; \
	  done; \
	done
	##
	## Clear up mess
	rm -rf $(PUBLISH).old

%.dvi: %.tex
	latex $<
	latex $<

%.ps: %.dvi
	dvips -o $@ $<

m4_divert(40)
Makefile: Makefile.m4
	m4 -P $< >$@.new
	mv $@.new $@

clean:
	rm -f $(ALL_ZONE_FILES) $(ALL_CLEAN_FILES) \
		*.toc *.lof *.lot *.log *.dvi *.ps *.aux
	rmdir $(sort $(ALL_SUBNETS))

###----- That's all, folks --------------------------------------------------