chiark - git - mdw - zone/blob - frontend.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Zone generator frontend
   4 ;;;
   5 ;;; (c) 2005 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This program is free software; you can redistribute it and/or modify
  11 ;;; it under the terms of the GNU General Public License as published by
  12 ;;; the Free Software Foundation; either version 2 of the License, or
  13 ;;; (at your option) any later version.
  14 ;;;
  15 ;;; This program is distributed in the hope that it will be useful,
  16 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;;; GNU General Public License for more details.
  19 ;;;
  20 ;;; You should have received a copy of the GNU General Public License
  21 ;;; along with this program; if not, write to the Free Software Foundation,
  22 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  23
  24 (defpackage #:zone.frontend
  25   (:use #:common-lisp #:mdw.sys-base #:optparse #:net #:zone
  26         #+cmu #:mop
  27         #+sbcl #:sb-mop)
  28   (:export #:main))
  29 (in-package #:zone.frontend)
  30
  31 (defvar opt-zones nil
  32   "Which zones to be emitted.")
  33 (defvar opt-format :bind
  34   "Which format to use on output.")
  35
  36 (defun directory-exists-p (name)
  37
  38   ;; Make a pathname for NAME which has the right form for a directory.
  39   (let ((dirpath
  40          (let ((path (pathname name)))
  41            (if (null (pathname-name path))
  42                path
  43                (make-pathname :directory
  44                               (append (or (pathname-directory path)
  45                                           (list :relative))
  46                                       (list (pathname-name path)))
  47                               :name nil
  48                               :type nil
  49                               :defaults path)))))
  50
  51     ;; Now check that it exists.
  52     #+clisp (and (ext:probe-directory dirpath) (truename dirpath))
  53     #-clisp (probe-file dirpath)))
  54
  55 (eval-when (:compile-toplevel :load-toplevel)
  56   (defopthandler dir (var arg) ()
  57     (let ((path (directory-exists-p arg)))
  58       (if (and path
  59                (not (pathname-name path)))
  60           (setf var path)
  61           (option-parse-error "path `~A' doesn't name a directory." arg)))))
  62
  63 (define-program
  64     :version "1.0.0" :usage "ZONEDEF..."
  65     :help "Generates BIND zone files from Lisp descriptions."
  66     :options (options help-options
  67                       "Parsing options"
  68                       (#\f "feature" (:arg "KEYWORD")
  69                            (list *features* 'keyword)
  70                            "Insert KEYWORD in *features* list.")
  71                       (#\s "subnet" (:arg "NET")
  72                            (list zone:*preferred-subnets*)
  73                            "Designate NET as a preferred subnet.")
  74                       "Output options"
  75                       (#\d "directory" (:arg "DIRECTORY")
  76                            (dir *zone-output-path*)
  77                            "Write zone and serial files to DIRECTORY.")
  78                       (#\F "format" (:arg "FORMAT")
  79                            (keyword opt-format
  80                                     (delete-duplicates
  81                                      (loop for method in
  82                                            (generic-function-methods
  83                                             #'zone:zone-write)
  84                                            for specs =
  85                                            (method-specializers method)
  86                                            if (typep (car specs)
  87                                                      'eql-specializer)
  88                                            collect
  89                                            (eql-specializer-object
  90                                             (car specs)))))
  91                            "Format to use for output.")
  92                       (#\z "zone" (:arg "NAME") (list opt-zones)
  93                            "Write information about zone NAME.")))
  94
  95 (defun main ()
  96   (set-command-line-arguments)
  97   (with-unix-error-reporting ()
  98     (let ((files nil))
  99       (unless (option-parse-try
 100                 (do-options ()
 101                   (nil (rest)
 102                     (when (zerop (length rest))
 103                       (option-parse-error "no files to read"))
 104                     (setf files rest))))
 105         (die-usage))
 106       (dolist (f files)
 107         (let ((*package* (make-package "ZONE.SCRATCH"
 108                                        :use '(#:common-lisp #:net #:zone))))
 109           (load f :verbose nil :print nil :if-does-not-exist :error)
 110           (delete-package *package*)))
 111       (zone-save opt-zones :format opt-format))))
 112
 113 ;;;----- That's all, folks --------------------------------------------------