chiark / gitweb /
server/tests.at (server retry): Use the new `WITH_STRACE' macro.
[tripe] / configure.ac
1 dnl -*-autoconf-*-
2 dnl
3 dnl Configuration script for TrIPE
4 dnl
5 dnl (c) 2001 Straylight/Edgeware
6 dnl
7
8 dnl----- Licensing notice ---------------------------------------------------
9 dnl
10 dnl This file is part of Trivial IP Encryption (TrIPE).
11 dnl
12 dnl TrIPE is free software; you can redistribute it and/or modify
13 dnl it under the terms of the GNU General Public License as published by
14 dnl the Free Software Foundation; either version 2 of the License, or
15 dnl (at your option) any later version.
16 dnl
17 dnl TrIPE is distributed in the hope that it will be useful,
18 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
19 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
20 dnl GNU General Public License for more details.
21 dnl
22 dnl You should have received a copy of the GNU General Public License
23 dnl along with TrIPE; if not, write to the Free Software Foundation,
24 dnl Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
25
26 dnl--------------------------------------------------------------------------
27 dnl Initialization.
28
29 mdw_AUTO_VERSION
30 AC_INIT([tripe], AUTO_VERSION, [mdw@distorted.org.uk])
31 AC_CONFIG_SRCDIR([server/tripe.h])
32 AC_CONFIG_AUX_DIR([config])
33 AM_INIT_AUTOMAKE([foreign])
34 mdw_SILENT_RULES
35
36 AC_PROG_CC
37 AM_PROG_CC_C_O
38 AX_CFLAGS_WARN_ALL
39 AC_CANONICAL_HOST
40 AM_PROG_LIBTOOL
41
42 AC_CHECK_PROGS([AUTOM4TE], [autom4te])
43
44 mdw_ORIG_CFLAGS=$CFLAGS
45 mdw_ORIG_CPPFLAGS=$CPPFLAGS
46 AC_SUBST(AM_CFLAGS)
47 AC_SUBST(AM_CPPFLAGS)
48
49 dnl--------------------------------------------------------------------------
50 dnl C programming environment.
51
52 AC_CHECK_HEADERS([stdarg.h])
53
54 AC_SEARCH_LIBS([socket], [socket])
55
56 case "$host_os" in
57   linux)
58     AC_ARG_WITH([linux-includes],
59                 AS_HELP_STRING(
60                   [--with-linux-includes=DIR],
61                   [Linux kernel includes]),
62                 [AM_CPPFLAGS="AM_CPPFLAGS -I$withval"], [:])
63     ;;
64 esac
65
66 PKG_CHECK_MODULES([mLib], [mLib >= 2.2.1])
67 PKG_CHECK_MODULES([catacomb], [catacomb >= 2.1.4])
68
69 AM_CFLAGS="$AM_CFLAGS $mLib_CFLAGS $catacomb_CFLAGS"
70
71 dnl--------------------------------------------------------------------------
72 dnl Directories to install things into.
73
74 dnl TRIPE_DEFINE_PATH(VAR, ARG, HELP, DEFAULT, [DEFINE, DEFINEHELP])
75 AC_DEFUN([TRIPE_DEFINE_PATH], [
76   AC_ARG_WITH([$1], AS_HELP_STRING([--with-$1=$2], [$3]),
77               [$1=$withval], [$1=$4])
78   AC_SUBST([$1])
79   m4_if([$5], [], [], [
80     mdw_DEFINE_PATHS([mdw_DEFINE_PATH([$5], [$][$1], [$6])])
81   ])
82 ])
83
84 dnl Actual options.
85 TRIPE_DEFINE_PATH(
86   [configdir], [DIR], [keys and other configuration [[LOCALSTATE/tripe]]],
87   ['${localstatedir}/tripe'],
88   [CONFIGDIR], [Look for keys and other configuration here.])
89
90 TRIPE_DEFINE_PATH(
91   [socketdir], [DIR], [admin socket [[.]]], [.],
92   [SOCKETDIR], [Create or look for administration socket here.])
93
94 TRIPE_DEFINE_PATH(
95   [pidfile], [FILE], [process-id [[./tripectl.pid]]], [tripectl.pid])
96
97 TRIPE_DEFINE_PATH(
98   [initconfig], [FILE],
99   [configuration for init script [[SYSCONFDIR/tripe.conf]]],
100   ['${sysconfdir}/tripe.conf'])
101
102 TRIPE_DEFINE_PATH(
103   [logfile], [FILE], [logging output [[./tripe.log]]], [tripe.log])
104
105 dnl--------------------------------------------------------------------------
106 dnl Privilege-separation helper.
107
108 mdw_DEFINE_PATHS([
109   AC_DEFINE_UNQUOTED([PRIVSEP_HELPER],
110     ["mdw_PATH([$libexecdir])/mdw_PROG([tripe-privhelper])"],
111     [Pathname of privilege-separation helper.])
112 ])
113
114 dnl--------------------------------------------------------------------------
115 dnl Other options.
116
117 AC_ARG_WITH([tracing],
118             AS_HELP_STRING(
119               [--without-tracing],
120               [compile out tracing support (not recommended)]),
121             [test "$withval" = no &&
122               AC_DEFINE([NTRACE], [1], [Disable all tracing.])],
123             [:])
124
125 dnl--------------------------------------------------------------------------
126 dnl Tunnel devices.
127
128 dnl Provide the user with a choice.
129 AC_ARG_WITH([tunnel],
130             AS_HELP_STRING(
131               [--with-tunnel=KIND],
132               [kinds of tunnel device to use (linux, unet, bsd, slip)]),
133             [tun=$withval], [tun=auto])
134
135 dnl If he doesn't choose, pick something sensible.
136 if test "$tun" = auto; then
137   AC_CACHE_CHECK([tunnel drivers to use], [mdw_cv_tunnel], [
138     mdw_cv_tunnel=""
139     case $host_os in
140       linux*)
141         case `uname -r` in
142           [2.[4-9].*] | [2.[1-9][0-9]*.*] | [[3-9].*] | [[1-9][0-9]*.*])
143             mdw_cv_tunnel=linux
144             ;;
145           *)
146             mdw_cv_tunnel=unet
147             ;;
148         esac
149         ;;
150       *bsd*)
151         mdw_cv_tunnel=bsd
152         ;;
153     esac
154     mdw_cv_tunnel=$mdw_cv_tunnel${mdw_cv_tunnel:+ }slip
155   ])
156   tun=$mdw_cv_tunnel
157 fi
158
159 tunnels=""
160 for i in $tun; do
161   case $i in
162     linux) AC_DEFINE([TUN_LINUX], [1],
163                      [Install the Linux TUN/TAP driver.]) ;;
164     bsd) AC_DEFINE([TUN_BSD], [1],
165                    [Install the BSD tunnel driver.]) ;;
166     unet) AC_DEFINE([TUN_UNET], [1],
167                     [Install the obsolete Linux Usernet driver.]) ;;
168     slip) ;;
169     *) AC_MSG_ERROR([Unknown tunnel type]) ;;
170   esac
171   tunnels="$tunnels&tun_$i, "
172 done
173 AC_DEFINE_UNQUOTED([TUN_LIST], [$tunnels 0],
174   [List of tunnel drivers to install.])
175
176 dnl--------------------------------------------------------------------------
177 dnl Python.
178
179 dnl Find out whether Python exists at all.
180 AM_PATH_PYTHON([2.4], [python=yes], [python=no])
181 AM_CONDITIONAL([HAVE_PYTHON], [test $python = yes])
182
183 dnl Find out whether we can use Catacomb and GTK.
184 if test $python = yes; then
185   AC_PYTHON_MODULE([pygtk])
186   AC_PYTHON_MODULE([catacomb])
187 fi
188 AM_CONDITIONAL([HAVE_PYGTK], [test ${HAVE_PYMOD_PYGTK-no} = yes])
189 AM_CONDITIONAL([HAVE_PYCATACOMB], [test ${HAVE_PYMOD_CATACOMB-no} = yes])
190
191 dnl--------------------------------------------------------------------------
192 dnl Wireshark.
193 dnl
194 dnl This is all distressingly ugly and complicated.  Why they can't just
195 dnl provide a pkg-config dropping containing all the useful information about
196 dnl the installation I don't know.
197
198 WIRESHARK_CFLAGS=""
199 : ${wireshark_plugindir=unknown}
200
201 dnl Get the user to help.
202 AC_ARG_WITH([wireshark],
203             AS_HELP_STRING(
204               [--with-wireshark[=DIR]],
205               [build and install Wireshark plugin]),
206             [case "$withval" in
207                no)  haveshark=no needshark=no ;;
208                yes) haveshark=yes needshark=yes ;;
209                *)   haveshark=yes needshark=yes
210                     wireshark_plugindir=$withval ;;
211             esac],
212             [haveshark=yes needshark=no])
213
214 dnl Try to find the Wireshark installation directory the hard way.  This is
215 dnl remarkably annoying.  This is, unfortunately, very likely to guess wrong,
216 dnl but there doesn't seem to be a better way.
217 case "$haveshark,$wireshark_plugindir" in
218   yes,unknown)
219     AC_CACHE_CHECK([where to put Wireshark plugins],
220       [mdw_cv_wireshark_plugin_dir], [
221       mdw_cv_wireshark_plugin_dir=$(
222         for i in \
223           $libexecdir $libdir $exec_prefix/lib $prefix/lib \
224           /usr/local/lib /usr/lib
225         do
226           for j in \
227             wireshark/plugins/* wireshark/*/plugins \
228             */wireshark/plugins/* */wireshark/*/plugins
229           do
230             for k in $i/$j/*.so; do
231               if test -f "$k"; then
232                 echo $(AS_DIRNAME(["$k"]))
233                 exit
234               fi
235             done
236           done
237         done
238         echo "failed"
239       )
240     ])
241     case $mdw_cv_wireshark_plugin_dir in
242       failed) haveshark=no ;;
243       *) wireshark_plugindir=$mdw_cv_wireshark_plugin_dir ;;
244     esac
245 esac
246
247 dnl If we're still interested, find Glib.
248 case "$haveshark" in
249   yes) AM_PATH_GLIB_2_0([2.4.0], [], [haveshark=false], [gmodule]) ;;
250 esac
251
252 dnl Find the include directory.  This would be much easier if they just
253 dnl provided a pkg-config file.
254 case "$haveshark" in
255   yes)
256     bad=yes
257     mdw_CFLAGS=$CFLAGS
258     wsprefix=`echo $wireshark_plugindir | sed 's:/lib/.*$::'`
259     AC_CACHE_CHECK([how to find the Wireshark headers],
260                    [mdw_cv_wireshark_includes], [
261       mdw_cv_wireshark_includes=failed
262       for i in \
263           "" \
264           "-I${wsprefix}/include/wireshark" \
265           "-I${wsprefix}/include" \
266           "-I${prefix}/include/wireshark" \
267           "-I${prefix}/include" \
268           "-I/usr/include/wireshark" \
269           "-I/usr/local/include/wireshark" \
270           "-I/usr/local/include"; do
271         CFLAGS="$GLIB_CFLAGS $i"
272         AC_TRY_COMPILE([
273 #include <netinet/in.h>
274 #include <glib.h>
275 #include <wireshark/config.h>
276 #include <wireshark/epan/packet.h>],
277         [dissector_handle_t dh; dh = create_dissector_handle(0, 0);],
278         [bad=no; break])
279       done
280       case "$bad" in
281         no) mdw_cv_wireshark_includes=$i ;;
282       esac
283       CFLAGS=$mdw_CFLAGS
284     ])
285     case "$mdw_cv_wireshark_includes" in
286       failed) haveshark=no ;;
287     esac
288 esac
289
290 case "$haveshark,$needshark" in
291   no,yes)
292     AC_MSG_ERROR([failed to configure Wireshark plugin])
293     ;;
294   yes,*)
295     WIRESHARK_CFLAGS="$GLIB_CFLAGS $mdw_cv_wireshark_includes"
296     AC_SUBST(WIRESHARK_CFLAGS)
297     AC_SUBST(wireshark_plugindir)
298     ;;
299 esac
300
301 AM_CONDITIONAL([HAVE_WIRESHARK], [test "$haveshark" = yes])
302
303 dnl--------------------------------------------------------------------------
304 dnl Produce output.
305
306 CFLAGS=$mdw_ORIG_CFLAGS
307 CPPFLAGS=$mdw_ORIG_CPPFLAGS
308
309 AC_CONFIG_HEADER([config/config.h])
310 AC_CONFIG_TESTDIR([t])
311
312 AC_CONFIG_FILES(
313   [Makefile]
314   [common/Makefile]
315   [uslip/Makefile]
316   [pathmtu/Makefile]
317   [client/Makefile]
318   [priv/Makefile]
319   [server/Makefile]
320   [proxy/Makefile]
321   [pkstream/Makefile]
322   [wireshark/Makefile]
323   [init/Makefile]
324   [py/Makefile]
325   [peerdb/Makefile]
326   [keys/Makefile]
327   [svc/Makefile]
328   [mon/Makefile]
329   [contrib/Makefile]
330   [t/Makefile t/atlocal])
331 AC_OUTPUT
332
333 dnl----- That's all, folks --------------------------------------------------