chiark - git - mdw - tripe/blob - server/tests.at

   1 ### -*-autotest-*-
   2 ###
   3 ### Test script for the main server
   4 ###
   5 ### (c) 2008 Straylight/Edgeware
   6 ###
   7
   8 ###----- Licensing notice ---------------------------------------------------
   9 ###
  10 ### This file is part of Trivial IP Encryption (TrIPE).
  11 ###
  12 ### TrIPE is free software; you can redistribute it and/or modify
  13 ### it under the terms of the GNU General Public License as published by
  14 ### the Free Software Foundation; either version 2 of the License, or
  15 ### (at your option) any later version.
  16 ###
  17 ### TrIPE is distributed in the hope that it will be useful,
  18 ### but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ### GNU General Public License for more details.
  21 ###
  22 ### You should have received a copy of the GNU General Public License
  23 ### along with TrIPE; if not, write to the Free Software Foundation,
  24 ### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 m4_define([nl], [
  27 ])
  28
  29 ## Configure a directory ready for use by tripe.
  30 m4_define([SETUPDIR], [
  31   cp $abs_top_srcdir/t/keyring-$1 ./keyring
  32   key extract -f-secret keyring.pub
  33 ])
  34
  35 ## Running standard programs with useful options.
  36 m4_define([TRIPE],
  37   [env TRIPE_PRIVHELPER=$abs_top_builddir/priv/tripe-privhelper \
  38      $abs_top_builddir/server/tripe -F -d. -aadmin -p0 -b127.0.0.1 -talice])
  39 m4_define([TRIPECTL], [$abs_top_builddir/client/tripectl -d. -aadmin])
  40 m4_define([USLIP], [$abs_top_builddir/uslip/tripe-uslip])
  41
  42 ## Sequences.  (These are used for testing the replay protection machinery.)
  43 m4_define([R32], [ 0  1  2  3  4  5  6  7  8  9 10 11 12 13 14 15   dnl
  44                   16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31])
  45 m4_define([P32], [21 26 14 12 25 18  2 27 10 31 24 29  0 20 17 11   dnl
  46                    8  3  7 23 19  1 13 30  6  9  5 22 15 28 16  4])
  47
  48 ###--------------------------------------------------------------------------
  49 ### Scaffolding for running a TrIPE server.
  50
  51 ## WITH_TRIPEX(dir, args, body)
  52 m4_define([WITH_TRIPEX], [
  53
  54 ## If this directory doesn't exist then Bad Things will happen.
  55 if test ! -d $1; then
  56   echo >&2 "server directory \`$1' doesn't exist"
  57   exit 99
  58 fi
  59
  60 ## Remove the status file.  This is how we notice that the server's died.
  61 rm -f $1/server-status
  62 > $1/expected-server-output
  63 > $1/expected-server-errors
  64
  65 ## Autotest writes crap to standard output, which we don't want going to the
  66 ## server.  So keep a copy of the standard output, do the pipe, and recover
  67 ## the old stdout inside the group.
  68 exec 3>&1
  69 { (
  70 exec 1>&3 3>&-
  71
  72 ## Wait for the socket to appear.  Watch for the server crashing during
  73 ## initialization.  Busy waiting is evil, but it's the best I can do and
  74 ## not sleep for ages.  (Yes, a second on each test group is a long time.)
  75 while test ! -r $1/server-status && test ! -S $1/admin; do :; done
  76
  77 ## Make the port number availale.
  78 AT_CHECK([TRIPECTL -d$1 PORT],, [stdout])
  79 mv stdout $1/port
  80
  81 ## Test body...
  82 $3
  83
  84 ## End of the test, now run the server.  There's an awful hack here.  If a
  85 ## process running under strace exits with a signal, then strace will kill
  86 ## itself with the same signal -- and therefore clobber the original
  87 ## process's core file.  So we arrange to run strace in one directory and
  88 ## have the child process run in another.
  89 ) && :; } | {
  90   cd $1
  91   mkdir -p strace-hack/
  92   echo TRIPE $2 >&2
  93   (cd strace-hack/
  94    ulimit -c hard >/dev/null 2>&1
  95    strace -f -o ../tripe.trace \
  96      TRIPE -d.. $2 >../server-output.full 2>../server-errors)
  97   stat=$?
  98   echo $stat >server-status
  99   if test $stat -ne 0; then
 100     echo "exit status: $stat" >>server-errors
 101   fi
 102
 103   ## We interrupt this relatively sensible macro for an especially awful
 104   ## hack.  The tripe server emits warnings which are often caused by lack of
 105   ## synchronization between two peers.  These are harmless and shouldn't
 106   ## cause test failures.  But we shouldn't just trim out all messages that
 107   ## look like the spurious ones: if they appear when we're not expecting
 108   ## them, that's bad and they should properly cause a test failure.
 109   ##
 110   ## So we use the WARN command to insert magic directives into the server's
 111   ## message stream.  The directives begin with `WARN USER test'; remaining
 112   ## tokens may be as follows.
 113   ##
 114   ## PUSH               Introduce a new layer of nesting.  Settings between
 115   ##                    this PUSH and the matching POP will be forgotten
 116   ##                    following the POP.
 117   ##
 118   ## POP                End a layer of nesting.  See PUSH above.
 119   ##
 120   ## IGNORE tokens      Ignore lines which begin with the tokens.
 121   ##
 122   ## Token comparison isn't done very well, but it's good enough for these
 123   ## purposes.
 124   ##
 125   ## We also trim out trace lines here, since it's useful to produce them for
 126   ## debugging purposes and changing or introducing more of them shouldn't
 127   ## cause failures.
 128   awk '
 129         BEGIN {
 130           sp = 0;
 131           npat = 0;
 132         }
 133         $[]1 == "TRACE" { next; }
 134         $[]1 == "WARN" && $[]2 == "USER" && $[]3 == "test" {
 135           if ($[]4 == "PUSH")
 136             npatstk[[sp++]] = npat;
 137           else if ($[]4 == "IGNORE") {
 138             s = "";
 139             p = "";
 140             for (i = 5; i <= NF; i++) {
 141               p = p s $[]i;
 142               s = " ";
 143             }
 144             pat[[npat++]] = p;
 145           } else if ($[]4 == "POP")
 146             npat = npatstk[[--sp]];
 147           next;
 148         }
 149         {
 150           for (i = 0; i < npat; i++) {
 151             n = length(pat[[i]]);
 152             if (substr($[]0, 0, n) == pat[[i]])
 153               next;
 154           }
 155           print $[]0;
 156         }
 157   ' server-output.full >server-output
 158 }
 159 exec 3>&-
 160
 161 ## Now check that the server's output matches our expectations.
 162 mv $1/expected-server-output expout
 163 mv $1/expected-server-errors experr
 164 AT_CHECK([cat $1/server-output; cat >&2 $1/server-errors],,
 165          [expout], [experr])
 166 ])
 167
 168 ## WITH_TRIPE(args, body)
 169 m4_define([WITH_TRIPE], [WITH_TRIPEX([.], [$1], [$2])])
 170
 171 ## WITH_2TRIPES(adir, bdir, bothargs, aargs, bargs, body)
 172 m4_define([WITH_2TRIPES],
 173           [WITH_TRIPEX([$1], [$3 $4], [WITH_TRIPEX([$2], [$3 $5], [$6])])])
 174
 175 ## COMMS_EPING(adir, aname, bdir, bname)
 176 m4_define([COMMS_EPING], [
 177   AT_CHECK([TRIPECTL -d$1 EPING $4],, [ignore])
 178   AT_CHECK([TRIPECTL -d$3 EPING $2],, [ignore])
 179 ])
 180
 181 ## COMMS_SLIP(adir, aname, bdir, bname)
 182 m4_define([COMMS_SLIP], [
 183   AT_CHECK([echo "from $1" | USLIP -p $1/$4])
 184   AT_CHECK([USLIP -g $3/$2],, [from $1[]nl])
 185   AT_CHECK([echo "from $3" | USLIP -p $3/$2])
 186   AT_CHECK([USLIP -g $1/$4],, [from $3[]nl])
 187 ])
 188
 189 ## AWAIT_KXDONE(adir, aname, bdir, bname, body)
 190 m4_define([AWAIT_KXDONE], [
 191
 192   ## Ignore some reports caused by races.
 193   TRIPECTL -d$3 WARN test PUSH
 194   TRIPECTL -d$3 WARN test IGNORE WARN KX $2 incorrect cookie
 195   TRIPECTL -d$3 WARN test IGNORE WARN KX $2 unexpected pre-challenge
 196
 197   ## Watch for the key-exchange completion announcement in the background.
 198   COPROCESSES([wait-$1], [
 199     echo WATCH +n
 200     while read line; do
 201       set x $line; shift
 202       echo >&2 ">>> $line"
 203       case "$[]1:$[]2:$[]3" in
 204         OK::) ;;
 205         NOTE:KXDONE:$4) break ;;
 206         NOTE:*) ;;
 207         *) exit 63 ;;
 208       esac
 209     done
 210   ], [
 211     TRIPECTL -d$1
 212   ]) & waiter_$1=$!
 213
 214   $5
 215
 216   ## Collect the completion announcement.
 217   wait $waiter_$1; waitrc=$?
 218   AT_CHECK([echo $waitrc],, [0[]nl])
 219
 220   ## Be interested in key-exchange warnings again.
 221   TRIPECTL -d$4 WARN test POP
 222 ])
 223
 224 ## ESTABLISH(adir, aname, aopts, bdir, bname, bopts)
 225 m4_define([ESTABLISH], [
 226
 227   ## Set up the establishment.
 228   AWAIT_KXDONE([$1], [$2], [$4], [$5], [
 229     AT_CHECK([TRIPECTL -d$1 ADD -cork $6 $5 INET 127.0.0.1 $(cat $4/port)])
 230     AT_CHECK([TRIPECTL -d$4 ADD $3 $2 INET 127.0.0.1 $(cat $1/port)])
 231   ])
 232
 233   ## Check transport pinging.
 234   AT_CHECK([TRIPECTL -d$1 PING $5],, [ignore])
 235   AT_CHECK([TRIPECTL -d$4 PING $2],, [ignore])
 236
 237   ## Check communication works.
 238   COMMS_EPING([$1], [$2], [$4], [$5])
 239   COMMS_SLIP([$1], [$2], [$4], [$5])
 240 ])
 241
 242 ###--------------------------------------------------------------------------
 243 ### Very unpleasant coprocess handling.
 244
 245 ## COPROCESSES(TAG, PROC-A, PROC-B)
 246 m4_define([COPROCESSES], [dnl
 247 rm -f pipe-$1; mknod pipe-$1 p
 248 { { $2 nl } <pipe-$1 | { $3 nl } >pipe-$1; } dnl
 249 ])
 250
 251 ## TRIPECTL_INTERACT(ARGS, SHELLSTUFF)
 252 m4_define([TRIPECTL_INTERACT], [
 253   exec 3>&1
 254   COPROCESSES([client], [exec 4>&1 1>&3 $1], [TRIPECTL $2])
 255 ])
 256
 257 ## TRIPECTL_COMMAND(CMD, EXPECT)
 258 m4_define([TRIPECTL_COMMAND], [
 259   AT_CHECK([
 260     m4_if([$1], [!], [:], [echo "$1" >&4])
 261     read line
 262     case "$line" in
 263       "$2") ;;
 264       *) echo 2>&1 "submitted $1: expected $2, found $line"; exit 1 ;;
 265     esac
 266   ])
 267   exec 3>&-
 268 ])
 269
 270 ###--------------------------------------------------------------------------
 271 ### Make sure the thing basically works.
 272
 273 AT_SETUP([server basics])
 274 SETUPDIR([ec])
 275 AT_CHECK([echo port | TRIPE -p54321],, [INFO 54321[]nl[]OK[]nl])
 276 AT_CLEANUP
 277
 278 ###--------------------------------------------------------------------------
 279 ### Challenges.
 280
 281 AT_SETUP([server challenges])
 282 AT_KEYWORDS([chal])
 283 SETUPDIR([ec])
 284
 285 WITH_TRIPE(, [
 286   ## A simple test.
 287   AT_CHECK([chal=$(TRIPECTL GETCHAL); TRIPECTL checkchal $chal])
 288
 289   ## A wrong challenge.  (This was valid once, but the probablity that the
 290   ## server chose the same key is negligible.)
 291   AT_CHECK([TRIPECTL checkchal AAAAAHyoOL+HMaE0Y9B3ivuszt0], [1],,
 292            [tripectl: invalid-challenge[]nl])
 293   echo WARN CHAL incorrect-tag >>expected-server-output
 294
 295   ## A duplicated challenge.
 296   AT_CHECK([
 297     chal=$(TRIPECTL GETCHAL)
 298     TRIPECTL CHECKCHAL $chal
 299     TRIPECTL CHECKCHAL $chal
 300   ], [1],, [tripectl: invalid-challenge[]nl])
 301   echo WARN CHAL replay duplicated-sequence >>expected-server-output
 302
 303   ## Out-of-order reception.  There should be a window of 32 challenges; we
 304   ## make 33 and check them in a strange order.
 305   rm -f experr
 306   echo "tripectl: invalid-challenge" >>experr
 307   echo "WARN CHAL replay old-sequence" >>expected-server-output
 308   for i in P32; do
 309     echo "tripectl: invalid-challenge" >>experr
 310     echo "WARN CHAL replay duplicated-sequence" >>expected-server-output
 311   done
 312   AT_CHECK([
 313
 314     ## Make the challenges.
 315     for i in old R32; do TRIPECTL GETCHAL >chal-$i || exit 2; done
 316
 317     ## Now check them back.
 318     for i in P32; do TRIPECTL CHECKCHAL $(cat chal-$i) || exit 3; done
 319
 320     ## Check the one which should have fallen off the front.
 321     TRIPECTL CHECKCHAL $(cat chal-old) && exit 4
 322
 323     ## And make sure that the others are now considered duplicates.
 324     for i in R32; do TRIPECTL CHECKCHAL $(cat chal-$i) && exit 5; done
 325
 326     ## All done: tidy cruft away.
 327     rm -f chal-*
 328     exit 0
 329   ], [0],, [experr])
 330 ])
 331
 332 AT_CLEANUP
 333
 334 ###--------------------------------------------------------------------------
 335 ### Communication.
 336
 337 AT_SETUP([server communication])
 338 AT_KEYWORDS([comm])
 339 export TRIPE_SLIPIF=USLIP
 340
 341 for i in alice bob; do (mkdir $i; cd $i; SETUPDIR([ec])); done
 342
 343 WITH_2TRIPES([alice], [bob], [-nslip], [-talice], [-tbob], [
 344   ESTABLISH([alice], [not-alice], [-key alice],
 345             [bob], [bob], [])
 346 ])
 347
 348 AT_CLEANUP
 349
 350 ###--------------------------------------------------------------------------
 351 ### Services.
 352
 353 AT_SETUP([server services])
 354 AT_KEYWORDS([svc])
 355 SETUPDIR([ec])
 356
 357 WITH_TRIPE(, [
 358
 359   ## Make sure it's not running yet.
 360   AT_CHECK([TRIPECTL SVCENSURE test], [1],,
 361            [tripectl: unknown-service test[]nl])
 362
 363   ## Run a simple service.
 364   rm -f svc-test-running tripectl-status
 365   COPROCESSES([svc], [
 366     echo SVCCLAIM test 1.0.0
 367     read line
 368     case "$line" in
 369       OK)
 370         ;;
 371       *)
 372         echo >&2 "SVCCLAIM failed: $line"
 373         exit 1
 374         ;;
 375     esac
 376     echo ok >svc-test-running
 377     while read line; do
 378       set -- $line
 379       case "$[]1,$[]3,$[]4" in
 380         SVCJOB,test,HELP)
 381           echo SVCINFO try not to use this service for anything useful
 382           echo SVCOK $[]2
 383           ;;
 384         SVCJOB,test,GOOD)
 385           echo SVCOK $[]2
 386           ;;
 387         SVCJOB,test,BAD)
 388           echo SVCFAIL $[]2 this-command-always-fails
 389           ;;
 390         SVCJOB,test,UGLY)
 391           tag=$2
 392           while read line; do
 393             set -- $line
 394             case "$[]1,$[]2,$[]3,$[]4" in
 395               SVCCANCEL,$tag,,) break ;;
 396               SVCJOB,*,test,ESCAPE)
 397                 echo >&2 "attempt to escape from alkatraz"
 398                 exit 1
 399                 ;;
 400             esac
 401           done
 402           ;;
 403         SVCJOB,test,FIRST)
 404           firsttag=$[]2
 405           ;;
 406         SVCJOB,test,SECOND)
 407           echo SVCOK $firsttag
 408           echo SVCOK $[]2
 409           ;;
 410         SVCJOB,*)
 411           echo SVCFAIL $[]2 unknown-svc-command $[]4
 412           ;;
 413         SVCCLAIM,*)
 414           break
 415           ;;
 416         OK,* | INFO,*)
 417           ;;
 418         FAIL,*)
 419           echo "failure in service: $line" >&2
 420           ;;
 421       esac
 422     done
 423   ], [
 424     TRIPECTL; echo $? >tripectl-status
 425   ]) 2>tripectl-errors &
 426
 427   ## Wait until it starts up.
 428   while test ! -r svc-test-running && test ! -r tripectl-status; do :; done
 429
 430   ## Make sure it's running.
 431   AT_CHECK([TRIPECTL SVCQUERY test],, [name=test version=1.0.0[]nl])
 432
 433   ## Try some simple commands.
 434   AT_CHECK([TRIPECTL SVCSUBMIT test GOOD])
 435   AT_CHECK([TRIPECTL SVCSUBMIT test BAD], [1],,
 436            [tripectl: this-command-always-fails[]nl])
 437
 438   ## And now with commands in the background.
 439   TRIPECTL_INTERACT([
 440     TRIPECTL_COMMAND([SVCSUBMIT test GOOD], [OK])
 441     TRIPECTL_COMMAND([SVCSUBMIT -background foo test UGLY], [BGDETACH foo])
 442     TRIPECTL_COMMAND([BGCANCEL foo], [OK])
 443     TRIPECTL_COMMAND([SVCSUBMIT test ESCAPE],
 444                      [FAIL unknown-svc-command ESCAPE])
 445   ])
 446
 447   ## Out-of-order completion.
 448   TRIPECTL_INTERACT([
 449     TRIPECTL_COMMAND([SVCSUBMIT -background one test FIRST], [BGDETACH one])
 450     TRIPECTL_COMMAND([SVCSUBMIT -background two test SECOND], [BGDETACH two])
 451     TRIPECTL_COMMAND([!], [BGOK one])
 452     TRIPECTL_COMMAND([!], [BGOK two])
 453   ])
 454
 455   ## All done.
 456   exit 0
 457 ])
 458
 459 AT_CLEANUP
 460
 461 ###----- That's all, folks --------------------------------------------------