chiark / gitweb /
server/tests.at (AWAIT_KXDONE): Ignore the correct server messages.
[tripe] / server / tests.at
CommitLineData
5d85da1c
MW
1### -*-autotest-*-
2###
3### Test script for the main server
4###
5### (c) 2008 Straylight/Edgeware
6###
7
8###----- Licensing notice ---------------------------------------------------
9###
10### This file is part of Trivial IP Encryption (TrIPE).
11###
12### TrIPE is free software; you can redistribute it and/or modify
13### it under the terms of the GNU General Public License as published by
14### the Free Software Foundation; either version 2 of the License, or
15### (at your option) any later version.
16###
17### TrIPE is distributed in the hope that it will be useful,
18### but WITHOUT ANY WARRANTY; without even the implied warranty of
19### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
20### GNU General Public License for more details.
21###
22### You should have received a copy of the GNU General Public License
23### along with TrIPE; if not, write to the Free Software Foundation,
24### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
25
26m4_define([nl], [
27])
28
29## Configure a directory ready for use by tripe.
30m4_define([SETUPDIR], [
31 cp $abs_top_srcdir/t/keyring-$1 ./keyring
32 key extract -f-secret keyring.pub
33])
34
35## Running standard programs with useful options.
36m4_define([TRIPE],
388e0319 37 [env TRIPE_PRIVHELPER=$abs_top_builddir/priv/tripe-privhelper \
4606744f
MW
38 $abs_top_builddir/server/tripe -F -d. -aadmin -p0 -b127.0.0.1 -talice \
39 ${TRIPE_TEST_TRACEOPTS+-T$TRIPE_TEST_TRACEOPTS}])
5d85da1c
MW
40m4_define([TRIPECTL], [$abs_top_builddir/client/tripectl -d. -aadmin])
41m4_define([USLIP], [$abs_top_builddir/uslip/tripe-uslip])
01c21903
MW
42m4_define([PKSTREAM],
43 [$abs_top_builddir/pkstream/pkstream -b127.0.0.1 -p127.0.0.1])
f884ef9d 44m4_define([MITM], [$abs_top_builddir/proxy/tripe-mitm])
5d85da1c 45
9867bea0
MW
46## WITH_STRACE(tag, cmd)
47##
48## There's an awful hack here. If a process running under strace exits with
49## a signal, then strace will kill itself with the same signal -- and
50## therefore clobber the original process's core file. So we arrange to run
51## strace in one directory and have the child process run in another.
52m4_define([WITH_STRACE],
53[case "${TRIPE_TEST_STRACE-nil}" in
54 nil)
55 $2
56 ;;
57 *)
58 mkdir -p strace-hack.$1/
59 (ulimit -c hard >/dev/null 2>&1
60 sh -c 'cd strace-hack.$1; exec "$[]@"' - \
5e55d10b 61 strace -ff -tt -v -s1024 -o../$1.trace \
9867bea0
MW
62 sh -c 'cd ..; exec "$[]@"' - \
63 $2)
64 ;;
65 esac])
66
5d85da1c
MW
67## Sequences. (These are used for testing the replay protection machinery.)
68m4_define([R32], [ 0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 dnl
69 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31])
70m4_define([P32], [21 26 14 12 25 18 2 27 10 31 24 29 0 20 17 11 dnl
71 8 3 7 23 19 1 13 30 6 9 5 22 15 28 16 4])
72
73###--------------------------------------------------------------------------
74### Scaffolding for running a TrIPE server.
75
05d4b7da 76## WITH_TRIPEX(dir, args, body)
5d85da1c
MW
77m4_define([WITH_TRIPEX], [
78
05d4b7da
MW
79## If this directory doesn't exist then Bad Things will happen.
80if test ! -d $1; then
81 echo >&2 "server directory \`$1' doesn't exist"
82 exit 99
83fi
84
5d85da1c
MW
85## Remove the status file. This is how we notice that the server's died.
86rm -f $1/server-status
87> $1/expected-server-output
88> $1/expected-server-errors
89
768a2316
MW
90## Autotest writes crap to standard output, which we don't want going to the
91## server. So keep a copy of the standard output, do the pipe, and recover
92## the old stdout inside the group.
5d85da1c
MW
93exec 3>&1
94{ (
95exec 1>&3 3>&-
96
97## Wait for the socket to appear. Watch for the server crashing during
98## initialization. Busy waiting is evil, but it's the best I can do and
99## not sleep for ages. (Yes, a second on each test group is a long time.)
768a2316 100while test ! -r $1/server-status && test ! -S $1/admin; do :; done
5d85da1c 101
05d4b7da
MW
102## Make the port number availale.
103AT_CHECK([TRIPECTL -d$1 PORT],, [stdout])
104mv stdout $1/port
105
5d85da1c
MW
106## Test body...
107$3
108
9867bea0 109## End of the test, now run the server.
5d85da1c
MW
110) && :; } | {
111 cd $1
112 echo TRIPE $2 >&2
377824e5 113 WITH_STRACE([tripe], [TRIPE $2 >server-output.full 2>server-errors.full])
5d85da1c
MW
114 stat=$?
115 echo $stat >server-status
116 if test $stat -ne 0; then
377824e5 117 echo "exit status: $stat" >>server-errors.full
5d85da1c 118 fi
377824e5 119 grep -v '^+ tripe: ' server-errors.full >server-errors
05d4b7da
MW
120
121 ## We interrupt this relatively sensible macro for an especially awful
122 ## hack. The tripe server emits warnings which are often caused by lack of
123 ## synchronization between two peers. These are harmless and shouldn't
124 ## cause test failures. But we shouldn't just trim out all messages that
125 ## look like the spurious ones: if they appear when we're not expecting
126 ## them, that's bad and they should properly cause a test failure.
127 ##
128 ## So we use the WARN command to insert magic directives into the server's
129 ## message stream. The directives begin with `WARN USER test'; remaining
130 ## tokens may be as follows.
131 ##
132 ## PUSH Introduce a new layer of nesting. Settings between
133 ## this PUSH and the matching POP will be forgotten
134 ## following the POP.
135 ##
136 ## POP End a layer of nesting. See PUSH above.
137 ##
138 ## IGNORE tokens Ignore lines which begin with the tokens.
139 ##
140 ## Token comparison isn't done very well, but it's good enough for these
141 ## purposes.
142 ##
143 ## We also trim out trace lines here, since it's useful to produce them for
144 ## debugging purposes and changing or introducing more of them shouldn't
145 ## cause failures.
146 awk '
147 BEGIN {
148 sp = 0;
149 npat = 0;
150 }
151 $[]1 == "TRACE" { next; }
152 $[]1 == "WARN" && $[]2 == "USER" && $[]3 == "test" {
153 if ($[]4 == "PUSH")
154 npatstk[[sp++]] = npat;
155 else if ($[]4 == "IGNORE") {
156 s = "";
157 p = "";
158 for (i = 5; i <= NF; i++) {
159 p = p s $[]i;
160 s = " ";
161 }
162 pat[[npat++]] = p;
163 } else if ($[]4 == "POP")
164 npat = npatstk[[--sp]];
165 next;
166 }
167 {
168 for (i = 0; i < npat; i++) {
169 n = length(pat[[i]]);
ee7a2a10 170 if (substr($[]0, 1, n) == pat[[i]])
05d4b7da
MW
171 next;
172 }
173 print $[]0;
174 }
175 ' server-output.full >server-output
5d85da1c
MW
176}
177exec 3>&-
178
179## Now check that the server's output matches our expectations.
180mv $1/expected-server-output expout
181mv $1/expected-server-errors experr
182AT_CHECK([cat $1/server-output; cat >&2 $1/server-errors],,
183 [expout], [experr])
184])
185
05d4b7da 186## WITH_TRIPE(args, body)
5d85da1c
MW
187m4_define([WITH_TRIPE], [WITH_TRIPEX([.], [$1], [$2])])
188
05d4b7da 189## WITH_2TRIPES(adir, bdir, bothargs, aargs, bargs, body)
5d85da1c
MW
190m4_define([WITH_2TRIPES],
191 [WITH_TRIPEX([$1], [$3 $4], [WITH_TRIPEX([$2], [$3 $5], [$6])])])
192
203e1b1f
MW
193## WITH_3TRIPES(adir, bdir, cdir, allargs, aargs, bargs, cargs, body)
194m4_define([WITH_3TRIPES],
195 [WITH_TRIPEX([$1], [$4 $5],
196 [WITH_TRIPEX([$2], [$4 $6],
197 [WITH_TRIPEX([$3], [$4 $7],
198 [$8])])])])
199
9e930d39
MW
200## RETRY(n, body)
201m4_define([RETRY], [
202 n=0 rc=1
203 while test $n -lt $1; do
204 if $2
205 then rc=0; break
206 fi
207 n=$(( $n + 1 ))
208 done
209 exit $rc
210])
211
212## COMMS_EPING(adir, aname, bdir, bname, [n])
05d4b7da 213m4_define([COMMS_EPING], [
9e930d39
MW
214 AT_CHECK([RETRY([m4_default([$5], [1])],
215 [TRIPECTL -d$1 EPING $4])],, [ignore])
216 AT_CHECK([RETRY([m4_default([$5], [1])],
217 [TRIPECTL -d$3 EPING $2])],, [ignore])
05d4b7da
MW
218])
219
220## COMMS_SLIP(adir, aname, bdir, bname)
221m4_define([COMMS_SLIP], [
222 AT_CHECK([echo "from $1" | USLIP -p $1/$4])
223 AT_CHECK([USLIP -g $3/$2],, [from $1[]nl])
224 AT_CHECK([echo "from $3" | USLIP -p $3/$2])
225 AT_CHECK([USLIP -g $1/$4],, [from $3[]nl])
226])
227
228## AWAIT_KXDONE(adir, aname, bdir, bname, body)
229m4_define([AWAIT_KXDONE], [
230
231 ## Ignore some reports caused by races.
add23883
MW
232 for i in $1!$4 $3!$2; do
233 d=${i%!*} o=${i#*!}
91a97a96 234 TRIPECTL -d$d WARN test PUSH
add23883
MW
235 TRIPECTL -d$d WARN test IGNORE WARN KX $o incorrect cookie
236 TRIPECTL -d$d WARN test IGNORE WARN KX $o unexpected pre-challenge
237 TRIPECTL -d$d WARN test IGNORE WARN KX $o unexpected challenge
91a97a96 238 done
05d4b7da
MW
239
240 ## Watch for the key-exchange completion announcement in the background.
241 COPROCESSES([wait-$1], [
242 echo WATCH +n
243 while read line; do
244 set x $line; shift
245 echo >&2 ">>> $line"
246 case "$[]1:$[]2:$[]3" in
247 OK::) ;;
248 NOTE:KXDONE:$4) break ;;
249 NOTE:*) ;;
250 *) exit 63 ;;
251 esac
252 done
253 ], [
254 TRIPECTL -d$1
255 ]) & waiter_$1=$!
256
257 $5
258
259 ## Collect the completion announcement.
260 wait $waiter_$1; waitrc=$?
261 AT_CHECK([echo $waitrc],, [0[]nl])
262
263 ## Be interested in key-exchange warnings again.
91a97a96 264 for d in $1 $3; do TRIPECTL -d$d WARN test POP; done
05d4b7da
MW
265])
266
01c21903 267## ESTABLISH(adir, aname, aopts, bdir, bname, bopts, [aport], [bport])
05d4b7da
MW
268m4_define([ESTABLISH], [
269
270 ## Set up the establishment.
271 AWAIT_KXDONE([$1], [$2], [$4], [$5], [
01c21903
MW
272 AT_CHECK([TRIPECTL -d$1 ADD -cork $6 $5 INET 127.0.0.1 \
273 m4_if([$8], [], [$(cat $4/port)], [$8])])
274 AT_CHECK([TRIPECTL -d$4 ADD $3 $2 INET 127.0.0.1 \
275 m4_if([$7], [], [$(cat $1/port)], [$7])])
05d4b7da
MW
276 ])
277
278 ## Check transport pinging.
279 AT_CHECK([TRIPECTL -d$1 PING $5],, [ignore])
280 AT_CHECK([TRIPECTL -d$4 PING $2],, [ignore])
281
282 ## Check communication works.
283 COMMS_EPING([$1], [$2], [$4], [$5])
284 COMMS_SLIP([$1], [$2], [$4], [$5])
285])
286
5d85da1c
MW
287###--------------------------------------------------------------------------
288### Very unpleasant coprocess handling.
289
290## COPROCESSES(TAG, PROC-A, PROC-B)
291m4_define([COPROCESSES], [dnl
292rm -f pipe-$1; mknod pipe-$1 p
293{ { $2 nl } <pipe-$1 | { $3 nl } >pipe-$1; } dnl
294])
295
296## TRIPECTL_INTERACT(ARGS, SHELLSTUFF)
297m4_define([TRIPECTL_INTERACT], [
768a2316 298 exec 3>&1
11715242 299 COPROCESSES([client], [exec 4>&1 1>&3 $1], [TRIPECTL $2])
5d85da1c
MW
300])
301
302## TRIPECTL_COMMAND(CMD, EXPECT)
303m4_define([TRIPECTL_COMMAND], [
304 AT_CHECK([
305 m4_if([$1], [!], [:], [echo "$1" >&4])
306 read line
307 case "$line" in
308 "$2") ;;
309 *) echo 2>&1 "submitted $1: expected $2, found $line"; exit 1 ;;
310 esac
311 ])
312 exec 3>&-
313])
314
315###--------------------------------------------------------------------------
316### Make sure the thing basically works.
317
318AT_SETUP([server basics])
59d05259 319SETUPDIR([alpha])
5d85da1c
MW
320AT_CHECK([echo port | TRIPE -p54321],, [INFO 54321[]nl[]OK[]nl])
321AT_CLEANUP
322
323###--------------------------------------------------------------------------
324### Challenges.
325
326AT_SETUP([server challenges])
327AT_KEYWORDS([chal])
59d05259 328SETUPDIR([alpha])
5d85da1c
MW
329
330WITH_TRIPE(, [
331 ## A simple test.
332 AT_CHECK([chal=$(TRIPECTL GETCHAL); TRIPECTL checkchal $chal])
333
334 ## A wrong challenge. (This was valid once, but the probablity that the
335 ## server chose the same key is negligible.)
336 AT_CHECK([TRIPECTL checkchal AAAAAHyoOL+HMaE0Y9B3ivuszt0], [1],,
337 [tripectl: invalid-challenge[]nl])
338 echo WARN CHAL incorrect-tag >>expected-server-output
339
340 ## A duplicated challenge.
341 AT_CHECK([
342 chal=$(TRIPECTL GETCHAL)
343 TRIPECTL CHECKCHAL $chal
344 TRIPECTL CHECKCHAL $chal
345 ], [1],, [tripectl: invalid-challenge[]nl])
346 echo WARN CHAL replay duplicated-sequence >>expected-server-output
347
348 ## Out-of-order reception. There should be a window of 32 challenges; we
349 ## make 33 and check them in a strange order.
350 rm -f experr
351 echo "tripectl: invalid-challenge" >>experr
352 echo "WARN CHAL replay old-sequence" >>expected-server-output
353 for i in P32; do
354 echo "tripectl: invalid-challenge" >>experr
355 echo "WARN CHAL replay duplicated-sequence" >>expected-server-output
356 done
357 AT_CHECK([
358
359 ## Make the challenges.
360 for i in old R32; do TRIPECTL GETCHAL >chal-$i || exit 2; done
361
362 ## Now check them back.
363 for i in P32; do TRIPECTL CHECKCHAL $(cat chal-$i) || exit 3; done
364
365 ## Check the one which should have fallen off the front.
366 TRIPECTL CHECKCHAL $(cat chal-old) && exit 4
367
368 ## And make sure that the others are now considered duplicates.
369 for i in R32; do TRIPECTL CHECKCHAL $(cat chal-$i) && exit 5; done
370
371 ## All done: tidy cruft away.
372 rm -f chal-*
373 exit 0
374 ], [0],, [experr])
375])
376
377AT_CLEANUP
378
379###--------------------------------------------------------------------------
380### Communication.
381
382AT_SETUP([server communication])
383AT_KEYWORDS([comm])
384export TRIPE_SLIPIF=USLIP
385
b87bffcb
MW
386for k in alpha beta-new; do
387 for p in alice bob; do (
388 rm -rf $p; mkdir $p; cd $p; SETUPDIR([$k])
389 ); done
390 WITH_2TRIPES([alice], [bob], [-nslip], [-talice], [-tbob], [
391 ESTABLISH([alice], [not-alice], [-key alice],
392 [bob], [bob], [])
393 ])
394done
5d85da1c
MW
395
396AT_CLEANUP
397
398###--------------------------------------------------------------------------
01c21903
MW
399### Mobile peer tracking.
400
401AT_SETUP([peer tracking])
402AT_KEYWORDS([mobile])
403export TRIPE_SLIPIF=USLIP
404
405for p in alice bob carol; do (mkdir $p; cd $p; SETUPDIR([alpha])); done
406
407## WITH_PKSTREAM(adir, aport, bdir, bport, body)
408m4_define([WITH_PKSTREAM], [
409 echo >&2 "pkstream: $1 <--> :$2 <-pkstream-> :$4 <--> $3"
410 PKSTREAM -l$4 127.0.0.1:$4 127.0.0.1:$(cat $3/port)& pkstream_$3_$1=$!
411 sleep 1
412 PKSTREAM -c127.0.0.1:$4 127.0.0.1:$2 127.0.0.1:$(cat $1/port)&
413 pkstream_$1_$3=$!
414 set +x
415 $5
416 kill $pkstream_$3_$1 $pkstream_$1_$3
417])
418
419WITH_3TRIPES([alice], [bob], [carol], [-nslip],
420 [-talice], [-tbob], [-tcarol], [
421
422 ## We need an indirection layer between the two peers so that we can
423 ## simulate the effects of NAT remapping. The nearest thing we have to
424 ## this is pkstream, so we may as well use that.
425 ##
426 ## alice <--> :5311 <-pkstream-> :5312 <--> bob
427 ## alice <--> :5321 <-pkstream-> :5322 <--> carol
428
429 WITH_PKSTREAM([alice], [5311], [bob], [5312], [
430 ESTABLISH([alice], [alice], [], [bob], [bob], [-mobile], [5312], [5311])
431 ])
432
433 WITH_PKSTREAM([alice], [5319], [bob], [5312], [
434 COMMS_EPING([bob], [bob], [alice], [alice])
435 COMMS_SLIP([bob], [bob], [alice], [alice])
436 ])
437
438 WITH_PKSTREAM([alice], [5321], [carol], [5322], [
439 ESTABLISH([alice], [alice], [], [carol], [carol], [-mobile],
440 [5322], [5321])
441 ])
442
443 WITH_PKSTREAM([alice], [5311], [bob], [5312], [
444 WITH_PKSTREAM([alice], [5321], [carol], [5322], [
445 COMMS_EPING([bob], [bob], [alice], [alice])
446 COMMS_EPING([carol], [carol], [alice], [alice])
447 COMMS_SLIP([bob], [bob], [alice], [alice])
448 COMMS_SLIP([carol], [carol], [alice], [alice])
449 ])])
450
451 WITH_PKSTREAM([alice], [5321], [bob], [5312], [
452 WITH_PKSTREAM([alice], [5311], [carol], [5322], [
453 COMMS_EPING([bob], [bob], [alice], [alice])
454 COMMS_EPING([carol], [carol], [alice], [alice])
455 COMMS_SLIP([bob], [bob], [alice], [alice])
456 COMMS_SLIP([carol], [carol], [alice], [alice])
457 ])])
458 wait
459])
460
461AT_CLEANUP
462
463###--------------------------------------------------------------------------
f884ef9d
MW
464### Adverse communication.
465
466AT_SETUP([server retry])
467AT_KEYWORDS([backoff])
468export TRIPE_SLIPIF=USLIP
469
9cda68ab 470for i in alice bob; do (mkdir $i; cd $i; SETUPDIR([beta])); done
f884ef9d
MW
471
472WITH_2TRIPES([alice], [bob], [-nslip], [-talice], [-tbob], [
473
474 ## Set up the evil proxy.
475 alicemitm=24516 bobmitm=14016
ee07712c
MW
476 mknod pipe-mitmpid p
477 WITH_STRACE([mitm],
478 [sh -c 'echo $$ >pipe-mitmpid; exec "$@"' - \
479 MITM -kalice/keyring.pub >mitm.out 2>mitm.err \
480 peer:alice:$alicemitm:127.0.0.1:$(cat alice/port) \
481 peer:bob:$bobmitm:127.0.0.1:$(cat bob/port) \
482 filt:drop:5 filt:send])&
483 read mitmpid <pipe-mitmpid
484 trap 'kill $mitmpid; exit 127' EXIT INT QUIT TERM HUP
485 exec 3>&-
f884ef9d
MW
486
487 ## Try to establish keys anyway.
488 AWAIT_KXDONE([alice], [alice], [bob], [bob], [
489 AT_CHECK([TRIPECTL -dalice ADD -cork bob INET 127.0.0.1 $alicemitm])
490 AT_CHECK([TRIPECTL -dbob ADD alice INET 127.0.0.1 $bobmitm])
491 ])
492
493 ## Check pinging.
494 COMMS_EPING([alice], [alice], [bob], [bob], [10])
495 COMMS_EPING([bob], [bob], [alice], [alice], [10])
496
497 ## Tear down the MITM proxy.
498 kill $mitmpid
f884ef9d
MW
499])
500
501AT_CLEANUP
502
503###--------------------------------------------------------------------------
31b8e627
MW
504### Key management.
505
506AT_SETUP([server key-management])
507AT_KEYWORDS([keymgmt])
508export TRIPE_SLIPIF=USLIP
509
510## Determine all of the nets and the principals.
511princs=""
512nets=" "
513while read princ pnets; do
514 princs="$princs $princ"
515 for n in $pnets; do
516 case " $nets " in *" $n "*) ;; *) nets="$nets$n " ;; esac
517 done
518done <<PRINC
519alice alpha beta
520bob alpha beta
521carol beta
522PRINC
523
524## Build the master keyring. All key tags here are of the form PRINC/NET.
525for n in $nets; do
526 key -k$abs_top_srcdir/t/keyring-$n extract keyring-$n $princs
527 for p in $princs; do key -kkeyring-$n tag $p $p/$n; done
528 key merge keyring-$n
529 rm keyring-$n
530done
531key extract -f-secret keyring.pub
532
533## Set up the principals' directories.
534for p in $princs; do
535 mkdir $p
536 cp keyring keyring.pub $p/
537done
538
539WITH_3TRIPES([alice], [bob], [carol], [-nslip -Tmx],
540 [-talice/alpha], [-tbob/alpha], [-tcarol/beta], [
541
542 ## Establish this little merry-go-round.
543 ESTABLISH([alice], [alice], [-key alice/alpha],
544 [bob], [bob], [-key bob/alpha])
545 ESTABLISH([alice], [alice], [-key alice/beta],
546 [carol], [carol], [-priv alice/beta -key carol/beta])
547 ESTABLISH([bob], [bob], [-key bob/beta],
548 [carol], [carol], [-priv bob/beta -key carol/beta])
549
550 ## Tweak Bob's alpha key.
551 for p in $princs; do
552 TRIPECTL -d$p WARN test COMMENT tweak bob/alpha
553 done
554
555 key -k$abs_top_srcdir/t/keyring-alpha extract keyring-bob-new bob-new
556 key merge keyring-bob-new
557 key tag -r bob-new bob/alpha
558 key extract -f-secret keyring.pub
559 for p in alice bob; do cp keyring keyring.pub $p/; done
560
561 ## Kick the peers to see whether they update.
562 AWAIT_KXDONE([alice], [alice], [bob], [bob], [
563 TRIPECTL -dalice RELOAD
564 TRIPECTL -dbob RELOAD
565 TRIPECTL -dalice FORCEKX bob
566 TRIPECTL -dbob FORCEKX alice
567 ])
568
569 COMMS_EPING([alice], [alice], [bob], [bob])
570 COMMS_EPING([bob], [bob], [alice], [alice])
571
572 ## Update the beta ring.
573 key merge $abs_top_srcdir/t/keyring-beta-new
574 for p in $princs; do key tag -r $p $p/beta; done
575 key extract -f-secret keyring.pub
576
577 ## Update alice's and carol's private keys, bob's public. This should be
578 ## insufficient for them to switch, but the results could be interesting.
579 for p in $princs; do
580 TRIPECTL -d$p WARN test COMMENT tweak beta step 1
581 done
582
583 for p in alice carol; do cp keyring $p/; done
584 cp keyring.pub bob/
585 for p in $princs; do TRIPECTL -d$p RELOAD; done
586
587 AT_DATA([algs-alpha], [dnl
588kx-group=ec kx-group-order-bits=256 kx-group-elt-bits=512
589hash=rmd160 mgf=rmd160-mgf hash-sz=20
a93aacce 590bulk-transform=v0 bulk-overhead=22
31b8e627
MW
591cipher=blowfish-cbc cipher-keysz=20 cipher-blksz=8
592cipher-data-limit=67108864
593mac=rmd160-hmac mac-keysz=20 mac-tagsz=10
594])
595
596 AT_DATA([algs-beta-old], [dnl
597kx-group=prime kx-group-order-bits=160 kx-group-elt-bits=1023
598hash=rmd160 mgf=rmd160-mgf hash-sz=20
a93aacce 599bulk-transform=v0 bulk-overhead=22
31b8e627
MW
600cipher=blowfish-cbc cipher-keysz=20 cipher-blksz=8
601cipher-data-limit=67108864
602mac=rmd160-hmac mac-keysz=20 mac-tagsz=10
603])
604
605 AT_DATA([algs-beta-new], [dnl
606kx-group=ec kx-group-order-bits=161 kx-group-elt-bits=320
607hash=rmd160 mgf=rmd160-mgf hash-sz=20
b87bffcb 608bulk-transform=iiv bulk-overhead=14
31b8e627
MW
609cipher=blowfish-cbc cipher-keysz=20 cipher-blksz=8
610cipher-data-limit=67108864
611mac=rmd160-hmac mac-keysz=20 mac-tagsz=10
b87bffcb 612blkc=blowfish blkc-keysz=20 blkc-blksz=8
31b8e627
MW
613])
614
615 cp algs-alpha expout; AT_CHECK([TRIPECTL -dalice ALGS],, [expout])
616 cp algs-beta-old expout; AT_CHECK([TRIPECTL -dalice ALGS carol],, [expout])
617 cp algs-beta-old expout; AT_CHECK([TRIPECTL -dbob ALGS carol],, [expout])
618 cp algs-beta-new expout; AT_CHECK([TRIPECTL -dcarol ALGS],, [expout])
619 cp algs-beta-old expout; AT_CHECK([TRIPECTL -dcarol ALGS alice],, [expout])
620
621 ## Now copy the full keys. We expect this to provoke key exchange.
622 for p in $princs; do
623 TRIPECTL -d$p WARN test COMMENT tweak beta step 2
624 done
625
626 for p in $princs; do cp keyring keyring.pub $p/; done
627
628 AWAIT_KXDONE([alice], [alice], [carol], [carol], [
629 TRIPECTL -dalice RELOAD
630 AWAIT_KXDONE([bob], [bob], [carol], [carol], [
631 TRIPECTL -dbob RELOAD
632 TRIPECTL -dcarol RELOAD
633 ])
634 ])
635
636 cp algs-alpha expout; AT_CHECK([TRIPECTL -dalice ALGS],, [expout])
637 cp algs-beta-new expout; AT_CHECK([TRIPECTL -dalice ALGS carol],, [expout])
638 cp algs-beta-new expout; AT_CHECK([TRIPECTL -dbob ALGS carol],, [expout])
639 cp algs-beta-new expout; AT_CHECK([TRIPECTL -dcarol ALGS],, [expout])
640])
641
642AT_CLEANUP
643
644###--------------------------------------------------------------------------
5d85da1c
MW
645### Services.
646
647AT_SETUP([server services])
648AT_KEYWORDS([svc])
59d05259 649SETUPDIR([alpha])
5d85da1c
MW
650
651WITH_TRIPE(, [
652
653 ## Make sure it's not running yet.
654 AT_CHECK([TRIPECTL SVCENSURE test], [1],,
655 [tripectl: unknown-service test[]nl])
656
657 ## Run a simple service.
658 rm -f svc-test-running tripectl-status
659 COPROCESSES([svc], [
660 echo SVCCLAIM test 1.0.0
661 read line
662 case "$line" in
663 OK)
2f20abf2 664 ;;
5d85da1c 665 *)
2f20abf2 666 echo >&2 "SVCCLAIM failed: $line"
5d85da1c
MW
667 exit 1
668 ;;
669 esac
670 echo ok >svc-test-running
671 while read line; do
672 set -- $line
673 case "$[]1,$[]3,$[]4" in
674 SVCJOB,test,HELP)
675 echo SVCINFO try not to use this service for anything useful
676 echo SVCOK $[]2
677 ;;
678 SVCJOB,test,GOOD)
679 echo SVCOK $[]2
680 ;;
681 SVCJOB,test,BAD)
682 echo SVCFAIL $[]2 this-command-always-fails
683 ;;
684 SVCJOB,test,UGLY)
685 tag=$2
686 while read line; do
687 set -- $line
688 case "$[]1,$[]2,$[]3,$[]4" in
689 SVCCANCEL,$tag,,) break ;;
690 SVCJOB,*,test,ESCAPE)
2f20abf2 691 echo >&2 "attempt to escape from alkatraz"
5d85da1c
MW
692 exit 1
693 ;;
694 esac
695 done
696 ;;
697 SVCJOB,test,FIRST)
698 firsttag=$[]2
699 ;;
700 SVCJOB,test,SECOND)
701 echo SVCOK $firsttag
702 echo SVCOK $[]2
703 ;;
704 SVCJOB,*)
705 echo SVCFAIL $[]2 unknown-svc-command $[]4
706 ;;
707 SVCCLAIM,*)
708 break
709 ;;
710 OK,* | INFO,*)
711 ;;
712 FAIL,*)
713 echo "failure in service: $line" >&2
714 ;;
715 esac
716 done
717 ], [
718 TRIPECTL; echo $? >tripectl-status
719 ]) 2>tripectl-errors &
720
721 ## Wait until it starts up.
722 while test ! -r svc-test-running && test ! -r tripectl-status; do :; done
723
724 ## Make sure it's running.
725 AT_CHECK([TRIPECTL SVCQUERY test],, [name=test version=1.0.0[]nl])
726
727 ## Try some simple commands.
728 AT_CHECK([TRIPECTL SVCSUBMIT test GOOD])
729 AT_CHECK([TRIPECTL SVCSUBMIT test BAD], [1],,
730 [tripectl: this-command-always-fails[]nl])
731
732 ## And now with commands in the background.
733 TRIPECTL_INTERACT([
734 TRIPECTL_COMMAND([SVCSUBMIT test GOOD], [OK])
735 TRIPECTL_COMMAND([SVCSUBMIT -background foo test UGLY], [BGDETACH foo])
736 TRIPECTL_COMMAND([BGCANCEL foo], [OK])
737 TRIPECTL_COMMAND([SVCSUBMIT test ESCAPE],
738 [FAIL unknown-svc-command ESCAPE])
739 ])
740
741 ## Out-of-order completion.
742 TRIPECTL_INTERACT([
743 TRIPECTL_COMMAND([SVCSUBMIT -background one test FIRST], [BGDETACH one])
744 TRIPECTL_COMMAND([SVCSUBMIT -background two test SECOND], [BGDETACH two])
745 TRIPECTL_COMMAND([!], [BGOK one])
746 TRIPECTL_COMMAND([!], [BGOK two])
747 ])
748
749 ## All done.
750 exit 0
751])
752
753AT_CLEANUP
754
755###----- That's all, folks --------------------------------------------------