/* -*-sod-*-
 *
 * A simple SOD module for testing.
 */

code c : includes {
#include <stdio.h>
#include "chimaera.h"
}

code h : includes {
#include "sod.h"
}

[nick = nml, link = SodObject]
class Animal : SodObject {
  int tickles = 0;

  [combination = progn] void tickle();
  [role = before] void nml.tickle() { me->nml.tickles++; }
}

class Lion : Animal {
  void bite() { puts("Munch!"); }
  void nml.tickle() { Lion_bite(me); }
}

class Goat : Animal {
  void butt() { puts("Bonk!"); }
  void nml.tickle() { Goat_butt(me); }
}

class Serpent : Animal {
  int limit = 2;

  void hiss() { puts("Sssss!"); }
  void bite() { puts("Nom!"); }
  void nml.tickle() {
    if (SERPENT__CONV_NML(me)->nml.tickles <= me->serpent.limit)
      Serpent_hiss(me);
    else
      Serpent_bite(me);
  }
}

[nick = sir, link = Animal]
class Chimaera : Lion, Goat, Serpent {
  serpent.limit = 1;
}

code c : user {
/*----- Main driver code --------------------------------------------------*/

static void tickle_animal(Animal *a)
{
  int i;

  for (i = 0; i < 3; i++) {
    printf("tickle %s #%d...\n", a->_vt->_class->cls.name, i);
    Animal_tickle(a);
  }
}

static void provoke_lion(Lion *l)
{
  printf("provoking %s as a lion\n", l->_vt->_class->cls.name);
  Lion_bite(l);
}

static void provoke_goat(Goat *g)
{
  printf("provoking %s as a goat\n", g->_vt->_class->cls.name);
  Goat_butt(g);
}

static void provoke_serpent(Serpent *s)
{
  printf("provoking %s as a serpent\n", s->_vt->_class->cls.name);
  Serpent_bite(s);
}

int main(void)
{
  {
    SOD_DECL(Lion, l, NO_KWARGS);
    provoke_lion(l);
    tickle_animal(LION__CONV_NML(l));
  }

  {
    SOD_DECL(Goat, g, NO_KWARGS);
    provoke_goat(g);
    tickle_animal(GOAT__CONV_NML(g));
  }

  {
    SOD_DECL(Serpent, s, NO_KWARGS);
    provoke_serpent(s);
    tickle_animal(SERPENT__CONV_NML(s));
  }

  {
    SOD_DECL(Chimaera, c, NO_KWARGS);
    provoke_lion(CHIMAERA__CONV_LION(c));
    provoke_goat(CHIMAERA__CONV_GOAT(c));
    provoke_serpent(CHIMAERA__CONV_SERPENT(c));
    tickle_animal(CHIMAERA__CONV_NML(c));
  }

  return (0);
}

}