chiark - git - mdw - sod/blob - src/final.lisp

   1 ;;; -*-lisp-*-
   2 ;;;
   3 ;;; Finishing touches for Sod
   4 ;;;
   5 ;;; (c) 2015 Straylight/Edgeware
   6 ;;;
   7
   8 ;;;----- Licensing notice ---------------------------------------------------
   9 ;;;
  10 ;;; This file is part of the Sensible Object Design, an object system for C.
  11 ;;;
  12 ;;; SOD is free software; you can redistribute it and/or modify
  13 ;;; it under the terms of the GNU General Public License as published by
  14 ;;; the Free Software Foundation; either version 2 of the License, or
  15 ;;; (at your option) any later version.
  16 ;;;
  17 ;;; SOD is distributed in the hope that it will be useful,
  18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;;; GNU General Public License for more details.
  21 ;;;
  22 ;;; You should have received a copy of the GNU General Public License
  23 ;;; along with SOD; if not, write to the Free Software Foundation,
  24 ;;; Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 (cl:in-package #:sod)
  27
  28 ;;;--------------------------------------------------------------------------
  29 ;;; Miscellaneous details.
  30
  31 (export '*sod-version*)
  32 (defparameter *sod-version* sod-sysdef:*version*
  33   "The version of the SOD translator system, as a string.")
  34
  35 ;;;--------------------------------------------------------------------------
  36 ;;; Debugging utilities.
  37
  38 (export '*debugout-pathname*)
  39 (defvar *debugout-pathname* #p"debugout.c")
  40
  41 (export 'test-module)
  42 (defun test-module (path reason)
  43   "Reset the translator's state, read a module from PATH and output it with
  44    REASON, returning the result as a string."
  45   (with-open-file (out *debugout-pathname*
  46                    :direction :output
  47                    :if-exists :supersede
  48                    :if-does-not-exist :create)
  49     (output-module (read-module path) reason out)))
  50
  51 (export 'test-parse-c-type)
  52 (defun test-parse-c-type (string)
  53   "Parse STRING as a C type, with optional kernel, and show the results."
  54   (with-input-from-string (in string)
  55     (let* ((*module-type-map* (make-hash-table))
  56            (charscan (make-instance 'charbuf-scanner
  57                                     :stream in
  58                                     :filename "<string>"))
  59            (tokscan (make-instance 'sod-token-scanner
  60                                    :char-scanner charscan
  61                                    :filename "<string>")))
  62       (with-parser-context (token-scanner-context :scanner tokscan)
  63         (multiple-value-bind (value winp consumedp)
  64             (parse (seq ((decls (parse-c-type tokscan))
  65                          (type (parse-declarator tokscan decls :abstractp t))
  66                          :eof)
  67                      type))
  68           (declare (ignore consumedp))
  69           (if winp
  70               (values t (car value) (cdr value)
  71                       (princ-to-string (car value)))
  72               (values nil value)))))))
  73
  74 (export 'test-parser)
  75 (defmacro test-parser ((scanner &key backtrace) parser input)
  76   "Convenient macro for testing parsers at the REPL.
  77
  78    This is a macro so that the parser can use the fancy syntax.  The name
  79    SCANNER is bound to a `sod-token-scanner' reading tokens from the INPUT
  80    string.  Then the PARSER is invoked and three values are returned: the
  81    result of the parse, or `nil' if the main parse failed; a list containing
  82    the number of errors and warnings (respectively) reported during the
  83    parse; and a list consisting of the lookahead token type and value, and a
  84    string containing the untokenized remaining input.
  85
  86    If BACKTRACE is nil (the default) then leave errors to the calling
  87    environment to sort out (e.g., by entering the Lisp debugger); otherwise,
  88    catch and report them as they happen so that you can test error recovery
  89    strategies."
  90   (once-only (input)
  91     (with-gensyms (char-scanner value winp body consumedp where nerror nwarn)
  92       `(let ((,char-scanner nil) (,scanner nil))
  93          (with-parser-context (token-scanner-context :scanner ,scanner)
  94            (multiple-value-bind (,value ,nerror ,nwarn)
  95                (flet ((,body ()
  96                         (setf ,char-scanner (make-string-scanner ,input)
  97                               ,scanner (make-instance
  98                                         'sod-token-scanner
  99                                         :char-scanner ,char-scanner))
 100                         (multiple-value-bind (,value ,winp ,consumedp)
 101                             (parse ,parser)
 102                           (declare (ignore ,consumedp))
 103                           (cond (,winp ,value)
 104                                 (t (syntax-error ,scanner ,value)
 105                                    nil)))))
 106                  (if ,backtrace (,body)
 107                      (count-and-report-errors ()
 108                        (with-default-error-location (,scanner)
 109                          (,body)))))
 110              (let ((,where (scanner-capture-place ,char-scanner)))
 111                (values ,value
 112                        (list ,nerror ,nwarn)
 113                        (and ,scanner (list (token-type ,scanner)
 114                                            (token-value ,scanner)
 115                                            (subseq ,input ,where)))))))))))
 116
 117 ;;;--------------------------------------------------------------------------
 118 ;;; Calisthenics.
 119
 120 (export 'exercise)
 121 (defun exercise ()
 122   "Exercise the pieces of the metaobject protocol.
 123
 124    In some Lisps, the compiler is run the first time methods are called, to
 125    do fancy just-in-time optimization things.  This is great, only the
 126    program doesn't actually run for very long and a lot of that work is
 127    wasted because we're going to have to do it again next time the program
 128    starts.  Only, if we exercise the various methods, or at least a large
 129    fraction of them, before we dump an image, then everything will be fast.
 130
 131    That's the theory anyway.  Call this function before you dump an image and
 132    see what happens."
 133
 134   (dolist (reason '(:h :c))
 135     (with-output-to-string (bitbucket)
 136       (output-module *builtin-module* reason bitbucket)))
 137
 138   (clear-the-decks))
 139
 140 ;;;--------------------------------------------------------------------------
 141 ;;; Make sure things work after loading the system.
 142
 143 (clear-the-decks)
 144
 145 ;;;----- That's all, folks --------------------------------------------------