Variable fuel range for connectivity map and pathfinder.

[rocl] / elite-pairs

#! /usr/bin/tclsh
#
# $Id: elite-pairs,v 1.2 2003/02/25 00:25:38 mdw Exp $

package require "elite" "1.0.0"

proc ok {s vv expr} {
  global argv0
  set ip [interp create]
  foreach v $vv {
    upvar 1 $v var
    if {[array exists var]} {
      foreach {k d} [array get var] {
	$ip eval [list set ${v}($k) $d]
      }
    } else {
      $ip eval [list set $v $var]
    }
  }
  elite-worldinfo p $s
  foreach {k v} [array get p] {
    $ip eval [list set $k $v]
  }
  if {[catch { $ip eval [list expr $expr] } rc]} {
    puts stderr "$argv0: error in expression: $rc"
    exit 1
  }
  interp delete $ip
  return $rc
}

set g $galaxy1
set d 70
for {set i 0} {$i < [llength $argv]} {incr i} {
  set a [lindex $argv $i]
  switch -glob -- $a {
    "-g" {
      incr i
      set a [lindex $argv $i]
      set g [parse-galaxy-spec $a]
      if {[string equal $g ""]} {
	puts stderr "$argv0: bad galaxy string `$a'"
	exit 1
      }
      destructure {. g} $g
    }
    "-d" {
      incr i
      set d [expr {[lindex $argv $i] * 10}]
    }
    "--" {
      incr i
      break
    }
    "-*" {
      puts stderr "usage: $argv0 \[-g GALAXY\] \[-d DIST\] AEXPR BEXPR"
      exit 1
    }
    default {
      break
    }    
  }
}
if {$i != [llength $argv] - 2} {
  puts stderr "usage: $argv0 \[-g GALAXY\] \[-d DIST\] AEXPR BEXPR"
  exit 1
}
destructure {aexpr bexpr} [lrange $argv $i end]
puts -nonewline stderr "\[computing adjacency table..."
flush stderr
set ww [worldinfo $g]
adjacency $ww adj $d
puts stderr " done\]"
unset a
foreach {s x y} $ww {
  if {![ok $s {} $aexpr]} { continue }
  elite-worldinfo a $s
  set l {}
  foreach {ss xx yy} $adj($s) {
    set d [world-distance $x $y $xx $yy]
    if {[ok $ss {a d} $bexpr]} {
      puts [format "%-11s %-11s (%.1f LY)" $a(name) [worldname $ss] \
	  [expr {[world-distance $x $y $xx $yy]/10.0}]]
    }
  }
}