dot/zshrc: Sink completion setup.

[profile] / dot / zshrc

### -*-sh-*-
###
### Zsh session things.

__mdw_shell=zsh
case ${INSIDE_EMACS+t},$TERM in t,dumb) unsetopt zle ;; esac

. "$HOME/.shell-rc"

###--------------------------------------------------------------------------
### Prompt hacking.

__mdw_set_prompt_hacks () {
  case $TERM in
    linux*|screen*|xterm*|vt100*|eterm*)
      bold=%B unbold=%b
      gitcolour=%F{cyan} rccolour=%F{red} uncolour=%f
      ;;
  esac
  host=%m dir=" %(6~!%-1~/.../%5~!%~)"
}

if [ -t 0 ]; then
  __mdw_source_if_exists /usr/lib/git-core/git-sh-prompt
  __mdw_set_prompt_pieces
  precmd_functions+=(__mdw_precmd)
  preexec_functions+=(__mdw_preexec)
fi

###--------------------------------------------------------------------------
### Line editing.

bindkey -e

for w in \
  forward-word backward-word kill-word backward-kill-word \
  transpose-words capitalize-word up-case-word down-case-word \
  delete-whole-word select-word
do
  autoload -U $w-match
  zle -N $w-bash $w-match
  zle -N $w-shell $w-match
  zstyle ':zle:*-bash' word-style standard
  zstyle ':zle:*-bash' skip-whitespace-first true
  zstyle ':zle:*-bash' word-chars ""
  zstyle ':zle:*-shell' word-style shell
  zstyle ':zle:*-shell' skip-whitespace-first false
done

bindkey "\eb" backward-word-bash
bindkey "\e^b" backward-word-shell
bindkey "\ef" forward-word-bash
bindkey "\e^f" forward-word-shell
bindkey "\e^?" backward-kill-word-bash
bindkey "^w" backward-kill-word-shell
bindkey "\ed" kill-word-bash
bindkey "\e^d" kill-word-shell
bindkey "\et" transpose-words-bash
bindkey "\e^t" transpose-words-shell
bindkey "\eu" up-case-word-bash
bindkey "\e^u" up-case-word-shell
bindkey "\el" up-case-word-bash
bindkey "\e^l" up-case-word-shell
bindkey "\ec" capitalize-word-bash
bindkey "\e^c" capitalize-word-shell

bindkey "\ep" history-beginning-search-backward
bindkey "\en" history-beginning-search-forward

setopt interactive_comments
bindkey "\e#" pound-insert

__mdw_delete_horizontal_space () {
  LBUFFER=${LBUFFER%%[[:space:]]##}
  RBUFFER=${RBUFFER##[[:space:]]##}
}
zle -N delete-horizontal-space __mdw_delete_horizontal_space
bindkey "\e\\" delete-horizontal-space

__mdw_just_one_space () {
  LBUFFER="${LBUFFER%%[[:space:]]##} "
  RBUFFER=${RBUFFER##[[:space:]]##}
}
zle -N just-one-space __mdw_just_one_space
bindkey "\e " just-one-space

###--------------------------------------------------------------------------
### Completion.

## Contexts: :completion:FUNCTION:COMPLETER:COMMAND:ARGUMENT:TAG
zstyle ':completion:*' completer _expand _complete _ignored _approximate
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt %SAt %p: Hit TAB for more, or the character to insert%s
zstyle ':completion:*' matcher-list '' '+m:{[:lower:]}={[:upper:]} r:|[._-]=** r:|=**' '+l:|=* r:|=*'
zstyle ':completion:*' max-errors 0 numeric
zstyle ':completion:*' original true
zstyle ':completion:*' verbose false
zstyle ':completion:*:*:git*:*' verbose true

## Initialize the fancy completion machinery.
autoload -Uz compinit
compinit

_r () { words[1]=sudo; _normal; }
compdef _r rootly
compdef _ssh @

###--------------------------------------------------------------------------
### Other shell tweaking.

HISTFILE=~/.zsh-history
HISTSIZE=1000
SAVEHIST=1000

unsetopt auto_cd
unsetopt auto_menu
unsetopt bash_auto_list
unsetopt beep
setopt extendedglob
unsetopt flow_control
setopt hist_ignore_all_dups
setopt ksh_glob
setopt list_ambiguous
setopt list_packed
unsetopt nomatch
unsetopt menu_complete
setopt notify
setopt share_history

zshaddhistory () {
  case "$1" in
    " "*) return 2 ;;
    *) return 0 ;;
  esac
}

###--------------------------------------------------------------------------
### Finishing touches.

__mdw_source_if_exists "$HOME/.zshrc-local"

###----- That's all, folks --------------------------------------------------