#! /usr/bin/perl

use lib "lib";
use Odin;

my $db = Odin::open_db;
my %newlang, %oldlang;

open my $fh, "-|", "highlight", "-p" or die "highlight: $!";
while (<$fh>) {
  my ($descr, $lang) = /^(.*\S)\s*:\s*(\S+)(?:\s.*|)$/;
  next if !defined $lang or $lang eq "txt";
  $newlang{"hl:$lang"} = $descr;
}
close $fh or die "close highlight: $! $?";
$newlang{"txt"} = "Plain text";

Odin::xact {
  my $h = $db->selectall_hashref
    ("SELECT lang, descr FROM odin_pastebin_lang", "lang");
  for my $k (keys %$h) { $oldlang{$k} = $h->{$k}{descr}; }
  for my $lang (keys %oldlang) {
    if (!exists $newlang{$lang}) {
      print ";; delete stale language `$lang' (`$oldlang{$lang}')\n";
      $db->do("DELETE FROM odin_pastebin_lang WHERE lang = ?", undef, $lang);
    }
  }
  for my $lang (keys %newlang) {
    if (!exists $oldlang{$lang}) {
      print ";; insert new language `$lang' (`$newlang{$lang}')\n";
      $db->do("INSERT INTO odin_pastebin_lang (lang, descr) VALUES (?, ?)",
	      undef, $lang, $newlang{$lang});
    } elsif ($oldlang{$lang} ne $newlang{$lang}) {
      print ";; change description for `$lang' ",
	"(`$oldlang{$lang}' -> `$newlang{$lang}')\n";
      $db->do("UPDATE odin_pastebin_lang SET descr = ? WHERE lang = ?",
	      undef, $newlang{$lang}, $lang);
    }
  }
} $db;