dnl -*-m4-*-
dnl
dnl $Id$
dnl
dnl Configuration script for mLib
dnl
dnl (c) 1998 Straylight/Edgeware
dnl

dnl ----- Licensing notice --------------------------------------------------
dnl
dnl This file is part of the mLib utilities library.
dnl
dnl mLib is free software; you can redistribute it and/or modify
dnl it under the terms of the GNU Library General Public License as
dnl published by the Free Software Foundation; either version 2 of the
dnl License, or (at your option) any later version.
dnl 
dnl mLib is distributed in the hope that it will be useful,
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl GNU Library General Public License for more details.
dnl 
dnl You should have received a copy of the GNU Library General Public
dnl License along with mLib; if not, write to the Free
dnl Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
dnl MA 02111-1307, USA.

AC_INIT(exc.c)
mdw_INIT_LIB(mLib, mLib, 2.0.3)

AC_PROG_CC
AM_PROG_LIBTOOL
mdw_GCC_FLAGS
mdw_MANEXT

AC_CHECK_HEADERS(float.h)

mdw_CHECK_MANYLIBS(socket, socket)
mdw_CHECK_MANYLIBS(gethostbyname, nsl resolv)

DEPLIBS=$LIBS AC_SUBST(DEPLIBS)
BRES_LIBEXEC="bres\$(EXEEXT)" BRES_SOURCE="bres"
AC_SUBST(BRES_LIBEXEC) AC_SUBST(BRES_SOURCE)
AC_ARG_WITH(adns,
[  --with-adns             use ADNS library for background name resolution],
[want_adns=$withval], [want_adns=auto])
if test $want_adns != no; then
  save_LIBS=$LIBS
  LIBS=$DEPLIBS
  mdw_CHECK_MANYLIBS(adns_init, adns, [have_adns=yes], [have_adns=no])
  DEPLIBS=$LIBS
  LIBS=$save_LIBS
  if test $have_adns = yes; then
    AC_DEFINE(HAVE_ADNS)
    BRES_LIBEXEC=""
    BRES_SOURCE="bres-adns"
  elif test $want_adns = yes; then
    AC_MSG_ERROR([ADNS library not found, but explicitly requested])
  fi
fi

AC_CACHE_CHECK([for msg_control], [mdw_cv_msg_control],
[AC_TRY_COMPILE(
[#include <sys/types.h>
#include <sys/socket.h>],
[struct msghdr msg;
msg.msg_control = 0;],
[mdw_cv_msg_control=yes],
[mdw_cv_msg_control=no])])
if test $mdw_cv_msg_control = no; then
  AC_DEFINE([HAVE_MSG_ACCRIGHTS])
fi

AC_DEFINE(BUILDING_MLIB)
mdw_OPT_mLib_DEBUG(mLib)

AC_OUTPUT(Makefile man/Makefile mLib-config:lib-config.in)