chiark / gitweb /
Commit as 2.1.0.
[mLib] / configure.ac
1 dnl -*-autoconf-*-
2 dnl
3 dnl Configuration script for mLib
4 dnl
5 dnl (c) 2008 Straylight/Edgeware
6 dnl
7
8 dnl ----- Licensing notice --------------------------------------------------
9 dnl
10 dnl This file is part of the mLib utilities library.
11 dnl
12 dnl mLib is free software; you can redistribute it and/or modify
13 dnl it under the terms of the GNU Library General Public License as
14 dnl published by the Free Software Foundation; either version 2 of the
15 dnl License, or (at your option) any later version.
16 dnl
17 dnl mLib is distributed in the hope that it will be useful,
18 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
19 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
20 dnl GNU Library General Public License for more details.
21 dnl
22 dnl You should have received a copy of the GNU Library General Public
23 dnl License along with mLib; if not, write to the Free
24 dnl Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
25 dnl MA 02111-1307, USA.
26
27 dnl--------------------------------------------------------------------------
28 dnl Initialization.
29
30 mdw_AUTO_VERSION
31 AC_INIT([mLib], AUTO_VERSION, [mdw@distorted.org.uk], [mLib])
32 AC_CONFIG_SRCDIR([mLib.pc.in])
33 AC_CONFIG_AUX_DIR([config])
34 AM_INIT_AUTOMAKE([foreign])
35
36 AC_PROG_CC
37 AM_PROG_CC_C_O
38 AM_PROG_LIBTOOL
39 AX_CFLAGS_WARN_ALL
40 mdw_LIBTOOL_VERSION_INFO
41
42 mdw_MANEXT
43
44 AC_DEFINE_UNQUOTED([SRCDIR], ["$(cd $srcdir && pwd)"],
45                    [absolute pathname for the source directory.])
46
47 dnl--------------------------------------------------------------------------
48 dnl C programming environment.
49
50 dnl Headers.
51 AC_CHECK_HEADERS([float.h])
52
53 dnl Libraries.
54 AC_SEARCH_LIBS([socket], [socket])
55 AC_SEARCH_LIBS([gethostbyname], [nsl resolv])
56
57 dnl Which version of struct msghdr do we have?
58 AC_CHECK_MEMBERS([struct msgdr.msg_control],,, [
59 #include <sys/types.h>
60 #include <sys/socket.h>
61 ])
62
63 dnl--------------------------------------------------------------------------
64 dnl Name resolution.
65
66 AC_ARG_WITH([adns],
67   AS_HELP_STRING([--with-adns],
68                  [use ADNS library for background name resolution]),
69   [want_adns=$withval],
70   [want_adns=auto])
71
72 case $want_adns in
73   no) ;;
74   *) AC_SEARCH_LIBS([adns_init], [adns], [have_adns=yes], [have_adns=no]) ;;
75 esac
76 case $want_adns,$have_adns in
77   yes,no)
78     AC_MSG_ERROR([ADNS library not found but explicitly requested])
79     ;;
80   yes,yes | auto,yes)
81     use_adns=yes
82     AC_DEFINE([HAVE_ADNS], [1],
83               [define if you have (and want to use) the ADNS library.])
84     ;;
85   no,* | auto,no)
86     use_adns=no
87     mdw_DEFINE_PATHS([
88       AC_DEFINE_UNQUOTED([BRES_SERVER],
89                          ["mdw_PATH($libexecdir)/$PACKAGE/mdw_PROG(bres)"],
90                          [pathname to the standalone `bres' binary.'])
91     ])
92     ;;
93 esac
94 AM_CONDITIONAL([WITH_ADNS], [test "$use_adns" = yes])
95
96 dnl--------------------------------------------------------------------------
97 dnl Output.
98
99 AC_CONFIG_HEADER([config/config.h])
100
101 AC_CONFIG_FILES(
102   [Makefile])
103 AC_OUTPUT
104
105 dnl ----- That's all, folks -------------------------------------------------