### -*-pyrex-*-
###
### In-band signals
###
### (c) 2005 Straylight/Edgeware
###

###----- Licensing notice ---------------------------------------------------
###
### This file is part of the Python interface to mLib.
###
### mLib/Python is free software; you can redistribute it and/or modify
### it under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2 of the License, or
### (at your option) any later version.
###
### mLib/Python is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with mLib/Python; if not, write to the Free Software Foundation,
### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

import signal

cdef class SelSignal:
  cdef sig s
  cdef int _activep
  cdef readonly int signal
  cdef _signalled
  def __cinit__(me, int sig, signalledproc = None, *hunoz, **hukairz):
    if sig < 0 or sig >= signal.NSIG:
      raise ValueError, 'signal number out of range'
    me.signal = sig
    me._signalled = _checkcallable(signalledproc, 'signalled proc')
    me._activep = 0
  def __dealloc__(me):
    if me._activep:
      sig_remove(&me.s)
  property activep:
    def __get__(me):
      return _tobool(me._activep)
  property signalledproc:
    def __get__(me):
      return me._signalled
    def __set__(me, proc):
      me._signalled = _checkcallable(proc, 'signalled proc')
    def __del__(me):
      me._signalled = None
  def enable(me):
    if me._activep:
      raise ValueError, 'already enabled'
    sig_add(&me.s, me.signal, _sigfunc, <void *>me)
    me._enabled()
    return me
  def disable(me):
    if not me._activep:
      raise ValueError, 'already disabled'
    sig_remove(&me.s)
    me._disabled()
    return me
  cdef _enabled(me):
    me._activep = 1
    me.enabled()
  cdef _disabled(me):
    me._activep = 0
    me.disabled()
  def enabled(me):
    pass
  def disabled(me):
    pass
  def signalled(me):
    return _maybecall(me._signalled, ())

cdef void _sigfunc(int sig, void *arg):
  cdef SelSignal s
  s = <SelSignal>arg
  s.signalled()

sig_init(&_sel)

###----- That's all, folks --------------------------------------------------