### -*-pyrex-*-
###
### String utilities
###
### (c) 2006 Straylight/Edgeware
###

###----- Licensing notice ---------------------------------------------------
###
### This file is part of the Python interface to mLib.
###
### mLib/Python is free software; you can redistribute it and/or modify
### it under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2 of the License, or
### (at your option) any later version.
###
### mLib/Python is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with mLib/Python; if not, write to the Free Software Foundation,
### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

def word(char *p, quotep = False):
  """word(STR, [quotep = False]) -> WORD, REST"""
  cdef unsigned f
  cdef char *op
  cdef char *pp
  cdef char *q
  cdef object w
  cdef object r

  f = 0
  if quotep:
    f = f | STRF_QUOTE
  pp = op = xstrdup(p)
  q = str_qword(&pp, f)
  if q is NULL:
    w = None
  else:
    w = q
  if pp is NULL:
    r = ''
  else:
    r = pp
  xfree(op)
  return w, r

def split(char *p, int n = -1, quotep = False):
  """split(STR, [n = -1], [quotep = False]) -> WORDS, REST"""
  cdef unsigned f
  cdef char *op
  cdef char *pp
  cdef char *q
  cdef object l
  cdef object r

  f = 0
  if quotep:
    f = f | STRF_QUOTE
  l = []
  op = pp = xstrdup(p)
  while n != 0:
    q = str_qword(&pp, f)
    if q is NULL:
      break
    l.append(q)
    if n > 0:
      n = n - 1
  if pp is NULL:
    r = ''
  else:
    r = pp
  xfree(op)
  return l, r

def match(char *p, char *s, prefixp = False):
  """match(PAT, STR, [prefixp = False]) -> BOOL"""
  cdef unsigned f

  f = 0
  if prefixp:
    f = f | STRF_PREFIX
  return _tobool(str_matchx(p, s, f))

def sanitize(char *p, int n = -1):
  """sanitize(STR, [n = -1]) -> STR"""
  cdef char *buf
  cdef object d

  if n < 0:
    n = strlen(p)
  buf = <char *>xmalloc(n + 1)
  str_sanitize(buf, p, n + 1)
  d = buf
  xfree(buf)
  return d

def versioncmp(char *va, char *vb):
  """versioncmp(V0, V1) -> -1 | 0 | +1"""
  return _versioncmp(va, vb)

###----- That's all, folks --------------------------------------------------