chiark - git - mdw - mLib-python/blob - mapping.pyx

   1 ### -*-pyrex-*-
   2 ###
   3 ### Common mapping stuff
   4 ###
   5 ### (c) 2005 Straylight/Edgeware
   6 ###
   7
   8 ###----- Licensing notice ---------------------------------------------------
   9 ###
  10 ### This file is part of the Python interface to mLib.
  11 ###
  12 ### mLib/Python is free software; you can redistribute it and/or modify
  13 ### it under the terms of the GNU General Public License as published by
  14 ### the Free Software Foundation; either version 2 of the License, or
  15 ### (at your option) any later version.
  16 ###
  17 ### mLib/Python is distributed in the hope that it will be useful,
  18 ### but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ### GNU General Public License for more details.
  21 ###
  22 ### You should have received a copy of the GNU General Public License
  23 ### along with mLib/Python; if not, write to the Free Software Foundation,
  24 ### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  25
  26 cdef class Mapping
  27
  28 cdef class _MapIterator:
  29   cdef void *_next(me):
  30     return NULL
  31
  32 cdef class Mapping:
  33
  34   ## Subclasses must implement these
  35   cdef int _init(me) except -1:
  36     raise TypeError, 'abstract class'
  37   cdef void *_find(me, object key, unsigned *f) except NULL:
  38     raise SystemError, 'unimplemented _find'
  39   cdef object _key(me, void *e):
  40     return None
  41   cdef object _value(me, void *e):
  42     return None
  43   cdef void _setval(me, void *e, object val):
  44     pass
  45   cdef void _del(me, void *e):
  46     pass
  47   cdef _MapIterator _iter(me):
  48     raise SystemError, 'unimplemented _iter'
  49
  50   ## Initialization
  51   def __cinit__(me, *hunoz, **hukairz):
  52     me._init()
  53   def __init__(me, stuff = None, **kw):
  54     me.update(stuff, kw)
  55
  56   ## Bulk update
  57   def update(me, stuff = None, **kw):
  58     cdef unsigned f
  59     if stuff is None:
  60       pass
  61     elif hasattr(stuff, 'itemiter'):
  62       for k, v in stuff.itemiter:
  63         me._setval(me._find(k, &f), v)
  64     elif hasattr(stuff, 'keys'):
  65       for k in stuff.keys():
  66         me._setval(me._find( k, &f), stuff[k])
  67     else:
  68       for k, v in stuff:
  69         me._setval(me._find(k, &f), v)
  70     for k, v in kw.iteritems():
  71       me._setval(me._find(k, &f), v)
  72     return me
  73
  74   ## Item access
  75   def __getitem__(me, key):
  76     cdef void *e
  77     e = me._find(key, NULL)
  78     if not e:
  79       raise KeyError, key
  80     return me._value(e)
  81   def __setitem__(me, key, value):
  82     cdef unsigned f
  83     me._setval(me._find(key, &f), value)
  84   def __delitem__(me, key):
  85     cdef void *e
  86     cdef unsigned f
  87     e = me._find(key, &f)
  88     if not e:
  89       raise KeyError, key
  90     me._del(e)
  91   def get(me, key, default = None):
  92     cdef void *e
  93     e = me._find(key, NULL)
  94     if not e:
  95       return default
  96     return me._value(e)
  97   def setdefault(me, key, default = None):
  98     cdef void *e
  99     cdef unsigned f
 100     e = me._find(key, &f)
 101     if f:
 102       return me._value(e)
 103     else:
 104       me._setval(e, default)
 105       return default
 106   def pop(me, key, default = None):
 107     cdef void *e
 108     e = me._find(key, NULL)
 109     if not e:
 110       return default
 111     rc = me._value(e)
 112     me._del(e)
 113     return rc
 114   def popitem(me):
 115     cdef _MapIterator i
 116     cdef void *e
 117     i = me._iter()
 118     e = i._next()
 119     if not e:
 120       raise ValueError, 'popitem(): table is empty'
 121     return me._key(e), me._value(e)
 122
 123   ## Lists of items
 124   cdef object _list(me, object (*func)(Mapping m, void *e)):
 125     cdef _MapIterator i
 126     cdef void *e
 127     i = me._iter()
 128     l = []
 129     while 1:
 130       e = i._next()
 131       if not e:
 132         break
 133       l.append(func(me, e))
 134     return l
 135
 136   def keys(me):
 137     return me._list(_map_key)
 138   def values(me):
 139     return me._list(_map_value)
 140   def items(me):
 141     return me._list(_map_item)
 142
 143   def clear(me):
 144     cdef _MapIterator i
 145     cdef void *e
 146     i = me._iter()
 147     while 1:
 148       e = i._next()
 149       if not e:
 150         break
 151       me._del(e)
 152     return me
 153
 154   ## Iteration
 155   def __iter__(me):
 156     return MapKeyIter(me)
 157   def iterkeys(me):
 158     return MapKeyIter(me)
 159   def itervalues(me):
 160     return MapValueIter(me)
 161   def iteritems(me):
 162     return MapItemIter(me)
 163
 164 cdef class MapIterBase:
 165   cdef Mapping m
 166   cdef object (*func)(Mapping m, void *e)
 167   cdef _MapIterator i
 168   cdef int _init(me) except -1:
 169     raise TypeError, 'abstract class'
 170   def __cinit__(me):
 171     me.i = m._iter()
 172     me._init()
 173   def __iter__(me):
 174     return me
 175   def __next__(me):
 176     cdef void *e
 177     e = me.i._next()
 178     if not e:
 179       raise StopIteration
 180     return me.func(me.m, e)
 181 cdef class MapKeyIter (MapIterBase):
 182   cdef int _init(me) except -1:
 183     me.func = _map_key
 184     return 0
 185 cdef class MapValueIter (MapIterBase):
 186   cdef int _init(me) except -1:
 187     me.func = _map_value
 188     return 0
 189 cdef class MapItemIter (MapIterBase):
 190   cdef int _init(me) except -1:
 191     me.func = _map_item
 192     return 0
 193
 194 cdef object _map_key(Mapping m, void *e):
 195   return m._key(e)
 196 cdef object _map_value(Mapping m, void *e):
 197   return m._value(e)
 198 cdef object _map_item(Mapping m, void *e):
 199   return m._key(e), m._value(e)
 200
 201 ###----- That's all, folks --------------------------------------------------