codec.pyx: Interface to new codec machinery.

[mLib-python] / pkbuf.pyx

### -*-pyrex-*-
###
### Packet buffering
###
### (c) 2005 Straylight/Edgeware
###

###----- Licensing notice ---------------------------------------------------
###
### This file is part of the Python interface to mLib.
###
### mLib/Python is free software; you can redistribute it and/or modify
### it under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2 of the License, or
### (at your option) any later version.
###
### mLib/Python is distributed in the hope that it will be useful,
### but WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
### GNU General Public License for more details.
###
### You should have received a copy of the GNU General Public License
### along with mLib/Python; if not, write to the Free Software Foundation,
### Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.

cdef class PacketBuffer:
  cdef pkbuf pk
  cdef _packet
  cdef _eof
  def __cinit__(me, packetproc = None, eofproc = None, *hunoz, **hukairz):
    pkbuf_init(&me.pk, _pkfunc, <void *>me)
    me._packet = _checkcallable(packetproc, 'packet proc')
    me._eof = _checkcallable(eofproc, 'eof proc')
  def __dealloc__(me):
    pkbuf_destroy(&me.pk)
  property activep:
    def __get__(me):
      return _tobool(me.pk.f & PKBUF_ENABLE)
  property want:
    def __get__(me):
      return me.pk.want
    def __set__(me, want):
      if want <= 0:
        raise TypeError, 'want must be positive'
      pkbuf_want(&me.pk, pk)
  property packetproc:
    def __get__(me):
      return me._packet
    def __set__(me, proc):
      me._line = _checkcallable(proc, 'packet proc')
    def __del__(me):
      me._line = None
  property eofproc:
    def __get__(me):
      return me._eof
    def __set__(me, proc):
      me._eof = _checkcallable(proc, 'eof proc')
    def __del__(me):
      me._eof = None
  def enable(me):
    if me.pk.f & PKBUF_ENABLE:
      raise ValueError, 'already enabled'
    me.pk.f = me.pk.f | PKBUF_ENABLE
    me.enabled()
    return me
  def disable(me):
    if not (me.pk.f & PKBUF_ENABLE):
      raise ValueError, 'already disabled'
    me.pk.f = me.pk.f & ~PKBUF_ENABLE
    me.disabled()
    return me
  def close(me):
    if not (me.pk.f & PKBUF_ENABLE):
      raise ValueError, 'buffer disabled'
    pkbuf_close(&me.pk)
    return me
  property free:
    def __get__(me):
      cdef unsigned char *p
      return pkbuf_free(&me.pk, &p)
  def flush(me, str):
    cdef int len
    cdef unsigned char *p
    cdef unsigned char *q
    cdef size_t n
    PyObject_AsReadBuffer(str, <void **>&p, &len)
    while len > 0:
      n = pkbuf_free(&me.pk, &q)
      if n > len:
        n = len
      memcpy(q, p, n)
      p = p + n
      len = len - n
      if not (me.pk.f & PKBUF_ENABLE):
        break
      pkbuf_flush(&me.pk, q, n)
    return PyString_FromStringAndSize(<char *>p, len)
  def enabled(me):
    pass
  def disabled(me):
    pass
  def packet(me, pk):
    return _maybecall(me._packet, (pk,))
  def eof(me):
    return _maybecall(me._eof, ())

cdef void _pkfunc(unsigned char *p, size_t n, pkbuf *pk,
                  size_t *keep, void *arg):
  cdef PacketBuffer pb
  cdef void *rp
  cdef int rn
  pb = <PacketBuffer>arg
  if p is NULL:
    pb.eof()
  else:
    r = pb.packet(PyString_FromStringAndSize(<char *>p, n))
    if r is not None:
      PyObject_AsReadBuffer(r, &rp, &rn)
      if rn > n:
        raise ValueError, 'remaining buffer too large'
      if rn:
        memcpy(p + n - rn, rp, rn)
        keep[0] = rn

###----- That's all, folks --------------------------------------------------