;;; nsis installer script

Name "Dep-UI"
OutFile "setup-dep-ui.exe"
InstallDir $PROGRAMFILES\Straylight-Edgeware\Dep-UI
InstallDirRegKey HKLM Software\Straylight-Edgeware\Dep-UI install-location
RequestExecutionLevel user

Page license
Page directory
Page components
Page instfiles

UninstPage uninstConfirm
UninstPage instfiles

LicenseText "The GNU General Public License" "Whatever"
LicenseData GPL.dostxt

Section "Programs"
  SetOutPath $INSTDIR
  SectionIn RO
  File dep-ui.jar
  File /oname=rolling.dui rolling.lisp
  WriteUninstaller uninstall.exe
  WriteRegStr \
    HKLM Software\Straylight-Edgeware\Dep-UI \
    install-location $INSTDIR
  WriteRegStr \
    HKLM Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2 \
    DisplayName Dep-UI
  WriteRegStr \
    HKLM Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2 \
    UninstallString $INSTDIR\uninstall.exe
  WriteRegDWORD \
    HKLM Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2 \
    NoModify 1
  WriteRegDWORD \
    HKLM Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2 \
    NoRepair 1
SectionEnd

Section "Start menu shortcuts"
  CreateDirectory $SMPROGRAMS\Dep-UI
  CreateShortCut $SMPROGRAMS\Dep-UI\Rolling.lnk \
    $SYSDIR\javaw.exe "-cp $\"$INSTDIR\dep-ui.jar$\" Startup $\"$INSTDIR\rolling.dui$\"" \
    $SYSDIR\javaw.exe 0
  CreateShortCut $SMPROGRAMS\Dep-UI\Uninstall.lnk \
    $INSTDIR\uninstall.exe "" $INSTDIR\uninstall.exe 0
SectionEnd

Section "Register file type"
  WriteRegStr HKCR .dui "" dep-ui-file
  WriteRegStr HKCR .dui "Content Type" application/x-dep-ui
  WriteRegStr HKCR dep-ui-file\shell\open\command "" "$SYSDIR\javaw.exe -cp $\"$INSTDIR\dep-ui.jar$\" Startup %1"
SectionEnd

Section "Uninstall"
  Delete $INSTDIR\dep-ui.jar
  Delete $INSTDIR\rolling.dui
  Delete $INSTDIR\uninstall.exe
  Delete $SMPROGRAMS\Dep-UI\*.*
  DeleteRegKey HKLM Software\Straylight-Edgeware\Dep-UI
  DeleteRegKey \
    HKLM Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2
  DeleteRegKey HKCR .dui
  DeleteRegKey HKCR dep-ui-file
  RMDir $SMPROGRAMS\Dep-UI
  RMDir $INSTDIR
SectionEnd