Can do "seen" now.

[ircbot] / bot.tcl

#!/usr/bin/tclsh8.2

set host chiark
set port 6667
set nick Blight

proc sendout {command args} {
    global sock
    if {[llength $args]} {
	set la [lindex $args end]
	set args [lreplace $args end end]
	foreach i $args {
	    if {[regexp {[: ]} $i]} {
		error "bad argument in output $i ($command $args)"
	    }
	}
	lappend args :$la
    }
    set args [lreplace $args 0 -1 $command]
    set string [join $args { }]
    puts "-> $string"
    puts $sock $string
}

proc log {data} {
    puts $data
}

proc logerror {data} {
    log $data
}

proc saveeic {} {
    global saveei saveec errorInfo errorCode

    set saveei $errorInfo
    set saveec $errorCode

    puts ">$saveec|$saveei<"
}

proc bgerror {msg} {
    global save
    logerror $msg
    saveeic
}

proc onread {args} {
    global sock
    
    if {[gets $sock line] == -1} { set terminate 1; return }
    regsub -all "\[^ -\176\240-\376\]" $line ? line
    set org $line
    if {[regexp -nocase {^:([^ ]+) (.*)} $line dummy prefix remain]} {
	set line $remain
    } else {
	set prefix {}
    }
    if {![string length $line]} { return }
    if {![regexp -nocase {^([0-9a-z]+) *(.*)} $line dummy command line]} {
	log "bad command: $org"
	return
    }
    set command [string toupper $command]
    set params {}
    while {[regexp {^([^ :]+) *(.*)} $line dummy thisword line]} {
	lappend params $thisword
    }
    if {[regexp {^:(.*)} $line dummy thisword]} {
	lappend params $thisword
    } elseif {[string length $line]} {
	log "junk at end: $org"
	return
    }
    if {"$command" == "PRIVMSG" &&
        [regexp {^[&#+!]} [lindex $params 0]] &&
        ![regexp {^!} [lindex $params 1]]} {
	# on-channel message, ignore
	catch {
	    recordlastseen_p $prefix "talking on [lindex $params 0]"
	}
	return
    }
    log "<- $org"
    set procname msg_$command
    if {[catch { info body $procname }]} { return }
    if {[catch {
	eval [list $procname $prefix $command] $params
    } emsg]} {
	logerror "error: $emsg ($prefix $command $params)"
	saveeic
    }
}

proc prefix_none {} {
    upvar 1 p p
    if {[string length $p]} { error "prefix specified" }
}

proc msg_PING {p c s1} {
    prefix_none
    sendout PONG $s1
}

proc check_nick {n} {
    if {[regexp -nocase {[^][\\`_^{|}a-z0-9-]} $n]} { error "bad char in nick" }
    if {[regexp {^[-0-9]} $n]} { error "bad nick start" }
}

proc ischan {dest} {
    return [regexp {^[&#+!]} $dest]
}

proc irctolower {v} {
    foreach {from to} [list "\\\[" "{" \
			  "\\\]" "}" \
	                  "\\\\" "|" \
			  "~"    "^"] {
	regsub -all $from $v $to v
    }
    return [string tolower $v]
}

proc prefix_nick {} {
    global nick
    upvar 1 p p
    upvar 1 n n
    if {![regexp {^([^!]+)!} $p dummy n]} { error "not from nick" }
    check_nick $n
    if {"[irctolower $n]" == "[irctolower $nick]"} { error "from myself" }
}

proc recordlastseen_n {n how} {
    global lastseen
    set lastseen([irctolower $n]) [list $n [clock seconds] $how]
}
		
proc recordlastseen_p {p how} {
    prefix_nick
    recordlastseen_n $n $how
}

proc chanmode_arg {} {
    upvar 2 args cm_args
    set rv [lindex $cm_args 0]
    set cm_args [lreplace cm_args 0 0]
    return $rv
}

proc chanmode_o0 {m g p chan} {
    global nick chandeop
    prefix_nick
    set who [chanmode_arg]
    recordlastseen_p $p "being mean to $who"
    if {"[irctolower $who]" == "[irctolower $nick]"} {
	set chandeop($chan) [list [clock seconds] $p]
    }
}

proc msg_MODE {p c dest modelist args} {
    if {![ischan $dest]} return
    if {[regexp {^\-(.+)$} $modelist dummy modelist]} {
	set give 0
    } elseif {[regexp {^\+(.+)$} $modelist dummy modelist]} {
	set give 1
    } else {
	error "invalid modelist"
    }
    foreach m [split $modelist] {
	set procname chanmode_$m$give
	if {[catch { info body $procname }]} {
	    recordlastseen_p $p "fiddling with $dest"
	} else {
	    $procname $m $give  $p $dest
	}
    }
}

proc msg_JOIN {p c chan} { recordlastseen_p $p "joining $chan" }
proc msg_PART {p c chan} { recordlastseen_p $p "leaving $chan" }
proc msg_QUIT {p c why} { recordlastseen_p $p "leaving ($why)" }

proc msg_PRIVMSG {p c dest text} {
    prefix_nick
    if {[ischan $dest]} {
	recordlastseen_n $n "invoking me in $dest"
	set output $dest
    } else {
	recordlastseen_n $n "talking to me"
	set output $n
    }

    if {[catch {
	regsub {^! *} $text {} text
	set ucmd [ta_word]
	set procname ucmd_[string tolower $ucmd]
	if {[catch { info body $procname }]} {
	    error "unknown command; try help for help"
	}
	$procname
    } rv]} {
	sendout PRIVMSG $n "error: $rv"
    } else {
	foreach {td val} [list $n [lindex $rv 0] $output [lindex $rv 1]] {
	    foreach l [split $val "\n"] {
		sendout PRIVMSG $td $l
	    }
	}
    }
}

proc ta_nomore {} {
    upvar 1 text text
    if {[string length $text]} { error "too many parameters" }
}

proc ta_word {} {
    upvar 1 text text
    if {![regexp {^([^ 	]+) *(.*)} $text dummy firstword text]} {
	error "too few parameters"
    }
    return $firstword
}

proc ta_nick {} {
    upvar 1 text text
    set v [ta_word]
    check_nick $v
    return $v
}

proc ucmdr {priv pub} {
    return -code return [list $priv $pub]
}
    
proc ucmd_help {} {
    upvar 1 text text
    ta_nomore
    ucmdr \
{Commands currently understood:
help
seen <nick>} {}
}

proc manyset {list args} {
    foreach val $list var $args {
	upvar 1 $var my
	set my $val
    }
}

proc ucmd_seen {} {
    global lastseen nick
    upvar 1 text text
    set n [irctolower [ta_nick]]
    ta_nomore
    if {"$n" == "[irctolower $nick]"} {
	error "I am not self-aware."
    } elseif {![info exists lastseen($n)]} {
	ucmdr {} "I've never seen $n."
    } else {
	manyset $lastseen($n) realnick time what
	set howlong [expr {[clock seconds] - $time}]
	if {$howlong <= 0} {
	    set string now
	} elseif {$howlong < 1000} {
	    set string "${howlong}s ago"
	} else {
	    if {$howlong < 1000000} {
		set pfx k
		set scale 1000
	    } else {
		set pfx M
		set scale 1000000
	    }
	    set value [expr "$howlong.0 / $scale"]
	    foreach {min format} {100 %.0f 10 %.1f 1 %.2f} {
		if {$value < $min} continue
		set string [format "$format${pfx}s ago" $value]
		break
	    }
	}
	if {![info exists string]} { set string now }
	ucmdr {} "I last saw $realnick $string, $what."
    }
}

if {![info exists sock]} {
    set sock [socket $host $port]
    fconfigure $sock -buffering line
    #fconfigure $sock -translation binary
    fconfigure $sock -translation crlf

    sendout USER guest 0 * "chiark testing bot"
    sendout NICK $nick
    fileevent $sock readable onread
}

#if {![regexp {tclsh} $argv0]} {
#    vwait terminate
#}