+AC_ARG_WITH([alsa],
+ [AS_HELP_STRING([--without-alsa],
+ [do not build with ALSA support])],
+ [want_alsa=$withval])
+AC_ARG_WITH([oss],
+ [AS_HELP_STRING([--without-oss],
+ [do not build with OSS support])],
+ [want_oss=$withval])
+AC_ARG_WITH([coreaudio],
+ [AS_HELP_STRING([--without-coreaudio],
+ [do not build with Core Audio support])],
+ [want_coreaudio=$withval])
+AC_ARG_WITH([tests],
+ [AS_HELP_STRING([--without-tests],
+ [do not build test suit])],
+ [want_tests=$withval])
+AC_ARG_WITH([gtk-osx],
+ [AS_HELP_STRING([--with-gtk-osx],
+ [use native GTK+])],
+ [want_gtkosx=$withval])
+
+AC_MSG_CHECKING([for a known target platform])
+case "$host" in
+*empeg* )
+ AC_MSG_RESULT([empeg car stereo])
+ AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
+ # work around broken toolchain
+ AC_CHECK_LIB([gpg-error], [gpg_strerror])
+ AC_CHECK_LIB([pthread], [pthread_create])
+ want_server=no
+ want_cgi=no
+ ;;
+*linux* | *Linux* )
+ AC_MSG_RESULT([Linux])
+ ;;
+*-apple-darwin* )
+ AC_MSG_RESULT([Mac OS X])
+ if test $want_coreaudio = yes; then
+ COREAUDIO="-framework CoreFoundation -framework CoreServices -framework CoreAudio"
+ fi
+ browser=open
+ AC_MSG_CHECKING([Mac OS X target version])
+ # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
+ # behaviour. But we provide a command line option to override it and
+ # we default to wide support instead of supporting only the build platform.
+ #
+ # Currently if you ask for 10.5 you will get a deprecation warning
+ # when building the CoreAudio support code. For the time being the
+ # answer to this is "don't do that then". If a good reason to ask
+ # for a 10.5 deployment target emerges then this will be fixed.
+ if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
+ MACOSX_DEPLOYMENT_TARGET=10.0
+ fi
+ AC_ARG_WITH([deployment-target],
+ [AS_HELP_STRING([--with-deployment-target=TARGET],
+ [set target OS X version])],
+ [MACOSX_DEPLOYMENT_TARGET=$withval])
+ # Convert to desired format
+ underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
+ minver="MAC_OS_X_VERSION_$underscored"
+ AC_MSG_RESULT([$minver])
+ AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
+ [define to minimum version of Mac OS X to support])
+
+ if test $want_gtkosx = no; then
+ # Fink's GTK+ is hopelessly broken
+ PKG_CONFIG_PATH=${PKG_CONFIG_PATH:-/sw/lib/pango-ft219/lib/pkgconfig}
+ export PKG_CONFIG_PATH
+ fi
+
+ ;;
+*-freebsd* )
+ AC_MSG_RESULT([FreeBSD])
+ # Ports install to /usr/local but the compiler stupidly doesn't look
+ # there by default
+ LDFLAGS="${LDFLAGS} -L/usr/local/lib"
+ CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
+ # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
+ AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
+ rjk_cv_libdb="none"
+ for db in db43 db44 db45 db46; do
+ if test -e /usr/local/lib/$db; then
+ rjk_cv_libdb=$db
+ break
+ fi
+ done
+ ])
+ if test $rjk_cv_libdb != none; then
+ LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
+ CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
+ fi
+ ;;
+* )
+ AC_MSG_RESULT([unknown, winging it])
+ ;;
+esac
+AC_SUBST([COREAUDIO])
+
+AC_ARG_WITH([browser],
+ [AS_HELP_STRING([--with-browser=BROWSER],
+ [use BROWSER to display HTML])],
+ [browser=$withval])
+
+AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
+ rjk_cv_browser=UNKNOWN
+ for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
+ if type $candidate >/dev/null 2>&1; then
+ rjk_cv_browser="$candidate"
+ break
+ fi
+ done
+])
+if test -z "$browser"; then
+ browser="$rjk_cv_browser"
+fi
+AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
+
+# Figure out what version of sox is installed
+AC_CACHE_CHECK([sox version],[rjk_cv_soxver],[
+ rjk_cv_soxver=UNKNOWN
+ if sox --version > /dev/null 2>&1; then
+ rjk_cv_soxver=`sox --version|$AWK '{ if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
+ else
+ rjk_cv_soxver=`sox -h 2>&1|$AWK '/Version/ { if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
+ fi
+])
+
+# Decide what command line options to use
+#
+# sox version endian bits deployed
+# 12.17.9 -x -[bwld] debian etch, ubuntu dapper
+# 14.0.0 -x/-[BL] -[bwld] ubuntu hardy
+# 14.0.1 -x/-[BL] -[1248] debian lenny
+# 14.2.0 -x/-[BL] -[1248] debian sid (at 2008-12)
+
+AC_CACHE_CHECK([default sox generation],[rjk_cv_soxgen],[
+ case $rjk_cv_soxver in
+ [[0-9]].* | 1[[0123]].* )
+ rjk_cv_soxgen=0
+ ;;
+ * )
+ rjk_cv_soxgen=1
+ ;;
+ esac
+])
+AC_DEFINE_UNQUOTED([DEFAULT_SOX_GENERATION],[$rjk_cv_soxgen],
+ [default sox generation])
+