chiark / gitweb /
Disobedience memory/widget debugging stuff has thoroughly rotted, so
[disorder] / configure.ac
index a9331b2..44ca4b2 100644 (file)
@@ -1,7 +1,8 @@
 # Process this file with autoconf to produce a configure script.
 #
 # This file is part of DisOrder.
-# Copyright (C) 2004, 2005, 2006, 2007 Richard Kettlewell
+# Copyright (C) 2004-2008 Richard Kettlewell
+# Portions copyright (C) 2007 Ross Younger
 #
 # This program is free software; you can redistribute it and/or modify
 # it under the terms of the GNU General Public License as published by
@@ -19,9 +20,9 @@
 # USA
 #
 
-AC_INIT([disorder], [1.5.99+], [richard+disorder@sfere.greenend.org.uk])
+AC_INIT([disorder], [3.0+], [richard+disorder@sfere.greenend.org.uk])
 AC_CONFIG_AUX_DIR([config.aux])
-AM_INIT_AUTOMAKE(disorder, [1.5.99+])
+AM_INIT_AUTOMAKE(disorder, [3.0+])
 AC_CONFIG_SRCDIR([server/disorderd.c])
 AM_CONFIG_HEADER([config.h])
 
@@ -31,6 +32,9 @@ AC_CANONICAL_HOST
 # What we want to build
 want_gtk=yes
 want_python=yes
+want_tests=yes
+want_server=yes
+want_cgi=yes
 
 # APIs we want
 want_alsa=yes
@@ -42,7 +46,15 @@ AC_PROG_CC
 AC_SET_MAKE
 if test "x$GCC" = xyes; then
   gcc_werror=-Werror
+  case "$CC" in
+  *-std=* )
+    ;;
+  * )
+    CC="${CC} -std=gnu99"
+    ;;
+  esac
 else
+  AC_MSG_ERROR([GNU C is required to build this program])
   gcc_werror=""
 fi
 
@@ -58,6 +70,10 @@ AC_ARG_WITH([coreaudio],
            [AS_HELP_STRING([--without-coreaudio],
                            [do not build with Core Audio support])],
            [want_coreaudio=$withval])
+AC_ARG_WITH([tests],
+           [AS_HELP_STRING([--without-tests],
+                           [do not build test suit])],
+           [want_tests=$withval])
 
 AC_MSG_CHECKING([for a known target platform])
 case "$host" in
@@ -68,29 +84,94 @@ case "$host" in
   AC_CHECK_LIB([gpg-error], [gpg_strerror])
   AC_CHECK_LIB([pthread], [pthread_create])
   want_server=no
+  want_cgi=no
  ;;
 *linux* | *Linux* )
   AC_MSG_RESULT([Linux])
-  want_server=yes
   ;;
 *-apple-darwin* )
   AC_MSG_RESULT([Mac OS X])
-  want_server=yes
   if test $want_coreaudio = yes; then
     COREAUDIO="-framework CoreAudio"
   fi
+  browser=open
+  AC_MSG_CHECKING([Mac OS X target version])
+  # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
+  # behaviour.  But we provide a command line option to override it and
+  # we default to wide support instead of supporting only the build platform.
+  #
+  # Currently if you ask for 10.5 you will get a deprecation warning
+  # when building the CoreAudio support code.  For the time being the
+  # answer to this is "don't do that then".  If a good reason to ask
+  # for a 10.5 deployment target emerges then this will be fixed.
+  if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
+    MACOSX_DEPLOYMENT_TARGET=10.0
+  fi
+  AC_ARG_WITH([deployment-target],
+              [AS_HELP_STRING([--with-deployment-target=TARGET],
+                              [set target OS X version])],
+              [MACOSX_DEPLOYMENT_TARGET=$withval])
+  # Convert to desired format
+  underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
+  minver="MAC_OS_X_VERSION_$underscored"
+  AC_MSG_RESULT([$minver])
+  AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
+                     [define to minimum version of Mac OS X to support])
+  ;;
+*-freebsd* )
+  AC_MSG_RESULT([FreeBSD])
+  # Ports install to /usr/local but the compiler stupidly doesn't look
+  # there by default
+  LDFLAGS="${LDFLAGS} -L/usr/local/lib"
+  CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
+  # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
+  AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
+    rjk_cv_libdb="none"
+    for db in db43 db44 db45 db46; do
+      if test -e /usr/local/lib/$db; then
+        rjk_cv_libdb=$db
+        break
+      fi
+    done
+  ])
+  if test $rjk_cv_libdb != none; then
+    LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
+    CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
+  fi
   ;;
 * )
   AC_MSG_RESULT([unknown, winging it])
-  want_server=no
   ;;
 esac
 AC_SUBST([COREAUDIO])
 
+AC_ARG_WITH([browser],
+            [AS_HELP_STRING([--with-browser=BROWSER],
+                           [use BROWSER to display HTML])],
+            [browser=$withval])
+
+AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
+  rjk_cv_browser=UNKNOWN
+  for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
+    if type $candidate >/dev/null 2>&1; then
+      rjk_cv_browser="$candidate"
+      break
+    fi
+  done
+])
+if test -z "$browser"; then
+  browser="$rjk_cv_browser"
+fi
+AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
+
 AC_ARG_WITH([server],
            [AS_HELP_STRING([--without-server],
                            [do not build server])],
            [want_server=$withval])
+AC_ARG_WITH([cgi],
+           [AS_HELP_STRING([--without-cgi],
+                           [do not build CGI])],
+           [want_cgi=$withval])
 AC_ARG_WITH([gtk],
            [AS_HELP_STRING([--without-gtk],
                            [do not build GTK+ client])],
@@ -100,14 +181,98 @@ AC_ARG_WITH([python],
                            [do not build Python support])],
            [want_python=$withval])
 
-subdirs="scripts lib clients doc examples debian"
+if test $want_server = no; then
+  want_cgi=no
+fi
+
+#
+# OS          Document Root                  CGI directory
+# ==          =============                  =============
+# Debian      /var/www                       /usr/lib/cgi-bin
+# Ubuntu      /var/www                       /usr/lib/cgi-bin
+# Red Hat     /var/www/html                  /var/www/cgi-bin
+#      or:    /home/httpd/html/              /home/httpd/cgi-bin
+# Slackware   /var/www/htdocs                (unknown)
+# SuSE        /srv/www/html                  /srv/www/cgi-bin
+# Gentoo      /var/www/localhost/htdocs      /var/www/localhost/cgi-bin/
+# FreeBSD     /usr/local/www/data            /usr/local/www/cgi-bin
+#      or:    /usr/local/www/???/data        /usr/local/www/???/cgi-bin
+# OS X        /Library/WebServer/Documents   /Library/WebServer/CGI-Executables
+# Apache      /usr/local/apache/htdocs       (none)
+#
+# Sources:
+#   http://wiki.linuxquestions.org/wiki/Apache
+#   http://mapserver.gis.umn.edu/docs/howto/suse-linux
+#   http://www.yolinux.com/TUTORIALS/LinuxTutorialWebSiteConfig.html
+#   http://sources.gentoo.org/viewcvs.py/apache/trunk/dist/2.2/conf/vhosts.d/default_vhost.include?rev=198&view=log
+#   http://httpd.apache.org/docs/
+#
+if test $want_cgi = yes; then
+  if test -z "$httpdir"; then
+    AC_CACHE_CHECK([for httpd document root],[rjk_cv_httpdir],[
+      rjk_cv_httpdir="not found"
+      for dir in /var/www/html \
+                 /var/www/htdocs \
+                 /var/www/localhost/htdocs \
+                 /var/www \
+                 /home/httpd/html \
+                 /srv/www/html \
+                 /usr/local/www/data \
+                 /usr/local/www/*/data \
+                 /Library/WebServer/Documents \
+                 /usr/local/apache/htdocs; do
+        if test -d "$dir"; then
+          rjk_cv_httpdir="$dir"
+        fi
+      done
+    ])
+    if test "$rjk_cv_cgidir" = "not found"; then
+      AC_MSG_ERROR([cannot identify httpd documentroot.  Set httpdir on configure command line])
+    fi
+    httpdir="$rjk_cv_httpdir"
+  fi
+  if test -z "$cgidir"; then
+    AC_CACHE_CHECK([for CGI directory],[rjk_cv_cgidir],[
+      rjk_cv_cgidir="not found"
+      for dir in /usr/lib/cgi-bin \
+                 /Library/WebServer/CGI-Executables \
+                 /srv/www/cgi-bin \
+                 /var/www/cgi-bin \
+                 /home/httpd/cgi-bin \
+                 /var/www/localhost/cgi-bin \
+                 /usr/local/lib/cgi-bin \
+                 /usr/local/www/cgi-bin \
+                 /usr/local/www/*/cgi-bin; do
+        if test -d "$dir"; then
+          rjk_cv_cgidir="$dir"
+          break
+        fi
+      done
+    ])
+    if test "$rjk_cv_cgidir" = "not found"; then
+      AC_MSG_ERROR([cannot identify CGI install directory.  Set cgidir on configure command line])
+    fi
+    cgidir="$rjk_cv_cgidir"
+  fi
+fi
+AC_ARG_VAR([cgidir], [location of cgi-bin directory, e.g. /usr/lib/cgi-bin])
+AC_ARG_VAR([httpdir], [location of http document root, e.g. /var/www/htdocs])
+if test -z "$pkghttpdir"; then
+  pkghttpdir='$(httpdir)/disorder'
+fi
+AC_SUBST([pkghttpdir])
+
+subdirs="scripts lib"
+if test $want_tests = yes; then
+  subdirs="${subdirs} libtests"
+fi
+subdirs="${subdirs} clients doc examples debian"
 
 if test $want_server = yes; then
-  subdirs="${subdirs} server plugins driver templates sounds images"
+  subdirs="${subdirs} server plugins driver sounds"
 fi
-if test $want_python = yes; then
-  AM_PATH_PYTHON
-  subdirs="${subdirs} python"
+if test $want_cgi = yes; then
+  subdirs="${subdirs} cgi templates images"
 fi
 if test $want_gtk = yes; then
   subdirs="${subdirs} disobedience"
@@ -115,7 +280,10 @@ if test $want_gtk = yes; then
     subdirs="${subdirs} images"
   fi
 fi
-subdirs="${subdirs} tests"
+if test $want_tests = yes && test $want_python = yes; then
+  AM_PATH_PYTHON([2.4])
+  subdirs="${subdirs} python tests"
+fi
 AC_SUBST([subdirs])
 
 # libtool config
@@ -124,12 +292,31 @@ AC_DISABLE_STATIC
 
 AC_PROG_LIBTOOL
 
+AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
+  rjk_cv_gnused="not found"
+  for candidate in sed gsed; do
+    if $candidate --version >/dev/null 2>&1; then
+      rjk_cv_gnused=$candidate 
+    fi
+  done
+])
+GNUSED="${GNUSED:-$rjk_cv_gnused}"
+if test "$GNUSED" = "not found"; then
+  AC_MSG_ERROR([GNU sed is required to build this program])
+fi
+AC_SUBST([GNUSED])
+
+AC_CHECK_PROGS([GROG],[grog])
+AM_CONDITIONAL([GROG],[test "x$GROG" != xnone])
+
 missing_libraries=""
 missing_headers=""
 missing_functions=""
 
 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
 
+AC_PATH_PROG([SENDMAIL],[sendmail],[none],[$PATH:/usr/sbin:/usr/lib])
+
 # Macs might have libraries under fink's root
 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
 if test "x$FINK" != xnone; then
@@ -185,6 +372,9 @@ if test $want_server = yes; then
               [AC_SUBST(LIBFLAC,[-lFLAC])],
               [missing_libraries="$missing_libraries libFLAC"])
 fi
+AC_CHECK_LIB([pthread], [pthread_create],
+             [AC_SUBST(LIBPTHREAD,[-lpthread])],
+            [missing_libraries="$missing_libraries libpthread"])
 
 if test $want_gtk = yes; then
   AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
@@ -213,9 +403,6 @@ if test ! -z "$missing_libraries"; then
   AC_MSG_ERROR([missing libraries:$missing_libraries])
 fi
 
-# We require that libpcre support UTF-8
-RJK_REQUIRE_PCRE_UTF8([-lpcre])
-
 # Checks for header files.
 RJK_FIND_GC_H
 if test $want_oss = yes; then
@@ -235,6 +422,7 @@ if test $want_server = yes; then
   AC_CHECK_HEADERS([db.h],[:],[
     missing_headers="$missing_headers $ac_header"
   ])
+  AC_CHECK_HEADERS([FLAC/file_decoder.h])
 fi
 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
                 getopt.h iconv.h langinfo.h \
@@ -247,6 +435,9 @@ if test ! -z "$missing_headers"; then
   AC_MSG_ERROR([missing headers:$missing_headers])
 fi
 
+# We require that libpcre support UTF-8
+RJK_REQUIRE_PCRE_UTF8([-lpcre])
+
 # Checks for typedefs, structures, and compiler characteristics.
 AC_C_CONST
 AC_TYPE_SIZE_T
@@ -334,7 +525,7 @@ if test $ac_cv_type_long_long = yes; then
     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
   fi
 fi
-AC_CHECK_FUNCS([ioctl nl_langinfo strsignal],[:],[
+AC_CHECK_FUNCS([ioctl nl_langinfo strsignal setenv unsetenv],[:],[
   missing_functions="$missing_functions $ac_func"
 ])
 # fsync will do if fdatasync not available
@@ -345,6 +536,10 @@ AC_CHECK_FUNCS([fdatasync],[:],[
 if test ! -z "$missing_functions"; then
   AC_MSG_ERROR([missing functions:$missing_functions])
 fi
+
+# Functions we can take or leave
+AC_CHECK_FUNCS([fls])
+
 if test $want_server = yes; then
   # <db.h> had better be version 3 or later
   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
@@ -356,7 +551,7 @@ if test $want_server = yes; then
                       #if DB_VERSION_MAJOR < 4
                       # error inadequate db version
                       #endif
-                      #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR < 2
+                      #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
                       # error inadequate db version
                       #endif
                      ],
@@ -368,7 +563,56 @@ if test $want_server = yes; then
   fi
 fi
 
+AM_CONDITIONAL([SERVER], [test x$want_server = xyes])
+if test $want_gtk = yes; then
+  AC_DEFINE([WITH_GTK], [1], [define if using GTK+])
+fi
+
 if test "x$GCC" = xyes; then
+  # We need LLONG_MAX and annoyingly GCC doesn't always give it to us
+  # by default.
+  AC_CACHE_CHECK([what C version to ask for],[rjk_cv_cstd],[
+    AC_TRY_COMPILE([#include <limits.h>],[
+      long long n = LLONG_MAX;
+    ],[rjk_cv_cstd=default],[
+      old_CC="$CC"
+      CC="${CC} -std=gnu99"
+      AC_TRY_COMPILE([#include <limits.h>],[
+        long long n = LLONG_MAX;
+      ],[rjk_cv_cstd=gnu99],[rjk_cv_cstd=unknown])
+      CC="$old_CC"
+    ])
+  ])
+  case $rjk_cv_cstd in
+  default | unknown )
+    ;;
+  * )
+    CC="${CC} -std=${rjk_cv_cstd}"
+    ;;
+  esac
+
+  # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
+  AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
+    old_CC="$CC"
+    if test $GCC = yes; then
+      CC="$CC -Wall -Werror"
+    fi
+    AC_COMPILE_IFELSE([
+      static int x(char *f) {
+       return *f;
+      }
+      int z(const char *g) {
+       return x((char *)g);
+      }],
+      [rjk_cv_pr29478=no],
+      [rjk_cv_pr29478=yes]
+    )
+    CC="$old_CC"
+  ])
+  if test $rjk_cv_pr29478 = yes; then
+    gcc_werror=''
+  fi
+
   # a reasonable default set of warnings
   CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
        -Wwrite-strings -Wmissing-prototypes \
@@ -378,19 +622,26 @@ if test "x$GCC" = xyes; then
   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 
-  # GCC 2.95 doesn't know to ignore warnings from system headers
-  AC_CACHE_CHECK([whether -Werror is usable],
-                  rjk_cv_werror, [
-    save_CFLAGS="${CFLAGS}"
-    CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
-    AC_TRY_COMPILE([#include <gtk/gtk.h>],
-                   [],
-                   [rjk_cv_werror=yes],
-                   [rjk_cv_werror=no])
-    CFLAGS="${save_CFLAGS}"
-  ])
-  if test $rjk_cv_werror = no; then
-    gcc_werror=''
+  if test "$gcc_werror" != ''; then
+    # GCC 2.95 doesn't know to ignore warnings from system headers
+    AC_CACHE_CHECK([whether -Werror is usable],
+                   rjk_cv_werror, [
+      save_CFLAGS="${CFLAGS}"
+      CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
+      AC_TRY_COMPILE([#if WITH_GTK
+ #include <gtk/gtk.h>
+#endif
+
+struct s { int a, b; };
+const struct s sv = { .a = 1 };],
+                    [],
+                    [rjk_cv_werror=yes],
+                    [rjk_cv_werror=no])
+      CFLAGS="${save_CFLAGS}"
+    ])
+    if test $rjk_cv_werror = no; then
+      gcc_werror=''
+    fi
   fi
   CC="${CC} $gcc_werror"
 
@@ -422,10 +673,10 @@ if test "x$GCC" = xyes; then
   if test $rjk_cv_shadow = yes; then
     CC="${CC} -Wshadow"
   fi
-                  
-
 fi
 
+RJK_GCOV
+
 AH_BOTTOM([#ifdef __GNUC__
 # define attribute(x) __attribute__(x)
 #else
@@ -433,19 +684,32 @@ AH_BOTTOM([#ifdef __GNUC__
 #endif])
 
 AC_CONFIG_FILES([Makefile
-                templates/Makefile
                 images/Makefile
                 scripts/Makefile
                 lib/Makefile
                 server/Makefile
+                cgi/Makefile
                 clients/Makefile
                 disobedience/Makefile
                 doc/Makefile
+                templates/Makefile
                 plugins/Makefile
                 driver/Makefile
                 debian/Makefile
                 sounds/Makefile
                 python/Makefile
                 examples/Makefile
+                libtests/Makefile
                 tests/Makefile])
 AC_OUTPUT
+
+if test $GCC = yes && test "$gcc_werror" = ''; then
+  AC_MSG_WARN([building without -Werror])
+fi
+if test $want_python = no; then
+  AC_MSG_WARN([cannot run the test suit without Python])
+fi
+
+# Local Variables:
+# indent-tabs-mode:nil
+# End: