chiark - git - mdw - disorder/blob - configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #
   3 # This file is part of DisOrder.
   4 # Copyright (C) 2004-2013 Richard Kettlewell
   5 # Portions copyright (C) 2007 Ross Younger
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 AC_INIT([disorder], [5.1.1], [richard+disorder@sfere.greenend.org.uk])
  22 AC_CONFIG_AUX_DIR([config.aux])
  23 AM_INIT_AUTOMAKE([foreign])
  24 AC_CONFIG_SRCDIR([server/disorderd.c])
  25 AM_CONFIG_HEADER([config.h])
  26 AC_CONFIG_MACRO_DIR([m4])
  27
  28 # Find host type
  29 AC_CANONICAL_HOST
  30
  31 # What we want to build
  32 want_gtk=yes
  33 want_python=yes
  34 want_tests=yes
  35 want_server=yes
  36 want_cgi=yes
  37
  38 # APIs we want
  39 want_alsa=yes
  40 want_oss=yes
  41 want_coreaudio=yes
  42 want_pulseaudio=yes
  43
  44 # By default we don't want gtk-osx.  But if you ask for --with-gtk-osx...
  45 #
  46 # Disobedience can be built to a native OS X application.  There are some
  47 # caveats:
  48 #  - you will still need Fink (or something) for other libraries
  49 #  - if you wanted an application bundle you are out of luck
  50 #  - the menu bar is still in the main window (not at the top of the screen)
  51 #  - drag and drop doesn't work
  52 #
  53 # So it's still rather rough and ready.  But it does work...
  54 #
  55 # See:
  56 #   http://www.gtk-osx.org/
  57 #   http://live.gnome.org/GTK%2B/OSX/Framework
  58 want_gtkosx=no
  59
  60 # Checks for programs.
  61 AC_PROG_CC
  62 AM_PROG_CC_C_O
  63 AC_PROG_AWK
  64 AC_SET_MAKE
  65 if test "x$GCC" = xyes; then
  66   gcc_werror=-Werror
  67   case "$CC" in
  68   *-std=* )
  69     ;;
  70   * )
  71     CC="${CC} -std=gnu99"
  72     ;;
  73   esac
  74 else
  75   AC_MSG_ERROR([GNU C is required to build this program])
  76   gcc_werror=""
  77 fi
  78
  79 AC_ARG_WITH([alsa],
  80             [AS_HELP_STRING([--without-alsa],
  81                             [do not build with ALSA support])],
  82             [want_alsa=$withval])
  83 AC_ARG_WITH([pulseaudio],
  84             [AS_HELP_STRING([--without-pulseaudio],
  85                             [do not build with PulseAudio support])],
  86             [want_pulseaudio=$withval])
  87 AC_ARG_WITH([oss],
  88             [AS_HELP_STRING([--without-oss],
  89                             [do not build with OSS support])],
  90             [want_oss=$withval])
  91 AC_ARG_WITH([coreaudio],
  92             [AS_HELP_STRING([--without-coreaudio],
  93                             [do not build with Core Audio support])],
  94             [want_coreaudio=$withval])
  95 AC_ARG_WITH([tests],
  96             [AS_HELP_STRING([--without-tests],
  97                             [do not build test suit])],
  98             [want_tests=$withval])
  99 AC_ARG_WITH([gtk-osx],
 100             [AS_HELP_STRING([--with-gtk-osx],
 101                             [use native GTK+ (OS X only)])],
 102             [want_gtkosx=$withval])
 103
 104 AC_MSG_CHECKING([for a known target platform])
 105 case "$host" in
 106 *empeg* )
 107   AC_MSG_RESULT([empeg car stereo])
 108   AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
 109   # work around broken toolchain
 110   AC_CHECK_LIB([gpg-error], [gpg_strerror])
 111   AC_CHECK_LIB([pthread], [pthread_create])
 112   want_server=no
 113   want_cgi=no
 114  ;;
 115 *linux* | *Linux* )
 116   AC_MSG_RESULT([Linux])
 117   AC_DEFINE_UNQUOTED([PATH_PROC_MOUNTS],["/proc/mounts"],[path to kernel mount list])
 118   ;;
 119 *-apple-darwin* )
 120   AC_MSG_RESULT([Mac OS X])
 121   # AudioHardwareGetProperty is deprecated in 10.6, but it's still _there_,
 122   # so we'll just turn off the warning.
 123   CC="$CC -Wno-deprecated-declarations"
 124   if test $want_coreaudio = yes; then
 125     COREAUDIO="-framework CoreFoundation -framework CoreServices -framework CoreAudio"
 126   fi
 127   browser=open
 128   AC_MSG_CHECKING([Mac OS X target version])
 129   # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
 130   # behaviour.  But we provide a command line option to override it and
 131   # we default to wide support instead of supporting only the build platform.
 132   #
 133   # Currently if you ask for 10.5 you will get a deprecation warning
 134   # when building the CoreAudio support code.  For the time being the
 135   # answer to this is "don't do that then".  If a good reason to ask
 136   # for a 10.5 deployment target emerges then this will be fixed.
 137   if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
 138     MACOSX_DEPLOYMENT_TARGET=10.0
 139   fi
 140   AC_ARG_WITH([deployment-target],
 141               [AS_HELP_STRING([--with-deployment-target=TARGET],
 142                               [set target OS X version])],
 143               [MACOSX_DEPLOYMENT_TARGET=$withval])
 144   # Convert to desired format
 145   underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
 146   minver="MAC_OS_X_VERSION_$underscored"
 147   AC_MSG_RESULT([$minver])
 148   AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
 149                      [define to minimum version of Mac OS X to support])
 150
 151   if test $want_gtkosx = no; then
 152     # Fink's GTK+ is hopelessly broken
 153     PKG_CONFIG_PATH=${PKG_CONFIG_PATH:-/sw/lib/pango-ft219/lib/pkgconfig}
 154     export PKG_CONFIG_PATH
 155   fi
 156
 157   ;;
 158 *-freebsd* )
 159   AC_MSG_RESULT([FreeBSD])
 160   # Ports install to /usr/local but the compiler stupidly doesn't look
 161   # there by default
 162   LDFLAGS="${LDFLAGS} -L/usr/local/lib"
 163   CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
 164   # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
 165   AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
 166     rjk_cv_libdb="none"
 167     for db in db43 db44 db45 db47; do
 168       if test -e /usr/local/lib/$db; then
 169         rjk_cv_libdb=$db
 170         break
 171       fi
 172     done
 173   ])
 174   if test $rjk_cv_libdb != none; then
 175     LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
 176     CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
 177   fi
 178   ;;
 179 * )
 180   AC_MSG_RESULT([unknown, winging it])
 181   ;;
 182 esac
 183 AC_SUBST([COREAUDIO])
 184
 185 AC_ARG_WITH([browser],
 186             [AS_HELP_STRING([--with-browser=BROWSER],
 187                             [use BROWSER to display HTML])],
 188             [browser=$withval])
 189
 190 AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
 191   rjk_cv_browser=UNKNOWN
 192   for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
 193     if type $candidate >/dev/null 2>&1; then
 194       rjk_cv_browser="$candidate"
 195       break
 196     fi
 197   done
 198 ])
 199 if test -z "$browser"; then
 200   browser="$rjk_cv_browser"
 201 fi
 202 AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
 203
 204 # Figure out what version of sox is installed
 205 AC_CACHE_CHECK([sox version],[rjk_cv_soxver],[
 206   rjk_cv_soxver=UNKNOWN
 207   if sox --version > /dev/null 2>&1; then
 208     rjk_cv_soxver=`sox --version|$AWK '{ if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 209   else
 210     rjk_cv_soxver=`sox -h 2>&1|$AWK '/Version/ { if(match($0, /[[0-9\.]]+/)) print substr($0,RSTART,RLENGTH)}'`
 211   fi
 212 ])
 213
 214 # Decide what command line options to use
 215 #
 216 # sox version   endian     bits       deployed
 217 # 12.17.9       -x         -[bwld]    debian etch, ubuntu dapper
 218 # 14.0.0        -x/-[BL]   -[bwld]    ubuntu hardy
 219 # 14.0.1        -x/-[BL]   -[1248]    debian lenny
 220 # 14.2.0        -x/-[BL]   -[1248]    debian sid (at 2008-12)
 221
 222 AC_CACHE_CHECK([default sox generation],[rjk_cv_soxgen],[
 223   case $rjk_cv_soxver in
 224   [[0-9]].* | 1[[0123]].* )
 225     rjk_cv_soxgen=0
 226     ;;
 227   * )
 228     rjk_cv_soxgen=1
 229     ;;
 230   esac
 231 ])
 232 AC_DEFINE_UNQUOTED([DEFAULT_SOX_GENERATION],[$rjk_cv_soxgen],
 233                    [default sox generation])
 234
 235 AC_ARG_WITH([server],
 236             [AS_HELP_STRING([--without-server],
 237                             [do not build server])],
 238             [want_server=$withval])
 239 AC_ARG_WITH([cgi],
 240             [AS_HELP_STRING([--without-cgi],
 241                             [do not build CGI])],
 242             [want_cgi=$withval])
 243 AC_ARG_WITH([gtk],
 244             [AS_HELP_STRING([--without-gtk],
 245                             [do not build GTK+ client])],
 246             [want_gtk=$withval])
 247 AC_ARG_WITH([python],
 248             [AS_HELP_STRING([--without-python],
 249                             [do not build Python support])],
 250             [want_python=$withval])
 251
 252 if test $want_server = no; then
 253   want_cgi=no
 254 fi
 255
 256 #
 257 # OS          Document Root                  CGI directory
 258 # ==          =============                  =============
 259 # Debian      /var/www                       /usr/lib/cgi-bin
 260 # Ubuntu      /var/www                       /usr/lib/cgi-bin
 261 # Red Hat     /var/www/html                  /var/www/cgi-bin
 262 #      or:    /home/httpd/html/              /home/httpd/cgi-bin
 263 # Slackware   /var/www/htdocs                (unknown)
 264 # SuSE        /srv/www/html                  /srv/www/cgi-bin
 265 # Gentoo      /var/www/localhost/htdocs      /var/www/localhost/cgi-bin/
 266 # FreeBSD     /usr/local/www/data            /usr/local/www/cgi-bin
 267 #      or:    /usr/local/www/???/data        /usr/local/www/???/cgi-bin
 268 # OS X        /Library/WebServer/Documents   /Library/WebServer/CGI-Executables
 269 # Apache      /usr/local/apache/htdocs       (none)
 270 #
 271 # Sources:
 272 #   http://wiki.linuxquestions.org/wiki/Apache
 273 #   http://mapserver.gis.umn.edu/docs/howto/suse-linux
 274 #   http://www.yolinux.com/TUTORIALS/LinuxTutorialWebSiteConfig.html
 275 #   http://sources.gentoo.org/viewcvs.py/apache/trunk/dist/2.2/conf/vhosts.d/default_vhost.include?rev=198&view=log
 276 #   http://httpd.apache.org/docs/
 277 #
 278 if test $want_cgi = yes; then
 279   if test -z "$httpdir"; then
 280     AC_CACHE_CHECK([for httpd document root],[rjk_cv_httpdir],[
 281       rjk_cv_httpdir="not found"
 282       for dir in /var/www/html \
 283                  /var/www/htdocs \
 284                  /var/www/localhost/htdocs \
 285                  /var/www \
 286                  /home/httpd/html \
 287                  /srv/www/html \
 288                  /usr/local/www/data \
 289                  /usr/local/www/*/data \
 290                  /Library/WebServer/Documents \
 291                  /usr/local/apache/htdocs; do
 292         if test -d "$dir"; then
 293           rjk_cv_httpdir="$dir"
 294         fi
 295       done
 296     ])
 297     if test "$rjk_cv_httpdir" = "not found"; then
 298       AC_MSG_ERROR([cannot identify httpd documentroot.  Set httpdir on configure command line])
 299     fi
 300     httpdir="$rjk_cv_httpdir"
 301   fi
 302   if test ! -z "$cgidir"; then
 303     # This is a bit harsh but should stop any disasters
 304     AC_MSG_ERROR([cgidir has been renamed to cgiexecdir])
 305   fi
 306   if test -z "$cgiexecdir"; then
 307     AC_CACHE_CHECK([for CGI directory],[rjk_cv_cgiexecdir],[
 308       rjk_cv_cgiexecdir="not found"
 309       for dir in /usr/lib/cgi-bin \
 310                  /Library/WebServer/CGI-Executables \
 311                  /srv/www/cgi-bin \
 312                  /var/www/cgi-bin \
 313                  /home/httpd/cgi-bin \
 314                  /var/www/localhost/cgi-bin \
 315                  /usr/local/lib/cgi-bin \
 316                  /usr/local/www/cgi-bin \
 317                  /usr/local/www/*/cgi-bin; do
 318         if test -d "$dir"; then
 319           rjk_cv_cgiexecdir="$dir"
 320           break
 321         fi
 322       done
 323     ])
 324     if test "$rjk_cv_cgiexecdir" = "not found"; then
 325       AC_MSG_ERROR([cannot identify CGI install directory.  Set cgiexecdir on configure command line])
 326     fi
 327     cgiexecdir="$rjk_cv_cgiexecdir"
 328   fi
 329 fi
 330 AC_ARG_VAR([cgiexecdir], [location of cgi-bin directory, e.g. /usr/lib/cgi-bin])
 331 AC_ARG_VAR([httpdir], [location of http document root, e.g. /var/www/htdocs])
 332 if test -z "$pkghttpdir"; then
 333   pkghttpdir='$(httpdir)/disorder'
 334 fi
 335 AC_SUBST([pkghttpdir])
 336
 337 if test -z "$dochtmldir"; then
 338   dochtmldir='$(docdir)/html'
 339 fi
 340 AC_SUBST([dochtmldir])
 341
 342 subdirs="scripts lib"
 343 if test $want_tests = yes; then
 344   subdirs="${subdirs} libtests"
 345 fi
 346 subdirs="${subdirs} clients doc examples debian"
 347
 348 if test $want_server = yes; then
 349   subdirs="${subdirs} server plugins sounds"
 350 fi
 351 if test $want_cgi = yes; then
 352   subdirs="${subdirs} cgi templates images"
 353 fi
 354 if test $want_gtk = yes; then
 355   subdirs="${subdirs} disobedience"
 356   if test $want_server = no; then
 357     subdirs="${subdirs} images"
 358   fi
 359 fi
 360 if test $want_tests = yes && test $want_python = yes; then
 361   AM_PATH_PYTHON([2.5])
 362   subdirs="${subdirs} python tests"
 363 fi
 364 AC_SUBST([subdirs])
 365
 366 # libtool config
 367 AC_LIBTOOL_DLOPEN
 368 AC_DISABLE_STATIC
 369
 370 AC_PROG_LIBTOOL
 371
 372 AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
 373   rjk_cv_gnused="not found"
 374   for candidate in sed gsed; do
 375     if $candidate --version >/dev/null 2>&1; then
 376       rjk_cv_gnused=$candidate
 377     fi
 378   done
 379 ])
 380 GNUSED="${GNUSED:-$rjk_cv_gnused}"
 381 if test "$GNUSED" = "not found"; then
 382   AC_MSG_ERROR([GNU sed is required to build this program])
 383 fi
 384 AC_SUBST([GNUSED])
 385
 386 AC_CHECK_PROGS([GROG],[grog])
 387 AM_CONDITIONAL([GROG],[test "x$GROG" != xnone])
 388
 389 missing_libraries=""
 390 missing_headers=""
 391 missing_functions=""
 392
 393 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
 394
 395 AC_PATH_PROG([SENDMAIL],[sendmail],[none],[$PATH:/usr/sbin:/usr/lib])
 396
 397 # Macs might have libraries under fink's root
 398 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
 399 if test "x$FINK" != xnone; then
 400   # Find Fink prefix
 401   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
 402     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
 403   ])
 404   # Add include and link paths
 405   finkdir="${rjk_cv_finkprefix}"
 406   finkbindir="${rjk_cv_finkprefix}/bin"
 407   CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/gc -isystem ${rjk_cv_finkprefix}/include"
 408   if test $want_server = yes; then
 409     CPPFLAGS="${CPPFLAGS} -isystem ${rjk_cv_finkprefix}/include/db4"
 410   fi
 411   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
 412   # Distinguish 32- and 64-bit fink
 413   AC_CACHE_CHECK([whether Fink is 32-bit or 64-bit],[rjk_cv_finkbits],[
 414     odata=`otool -v -h $finkbindir/dpkg`
 415     case "$odata" in
 416     *X86_64* )
 417       rjk_cv_finkbits=64
 418       ;;
 419     *I386* )
 420       rjk_cv_finkbits=32
 421       ;;
 422     * )
 423       rjk_cv_finkbits=unknown
 424       ;;
 425     esac
 426   ])
 427   # Match Fink so we can use its libraries
 428   case $rjk_cv_finkbits in
 429   32 | 64 )
 430     CC="$CC -m$rjk_cv_finkbits"
 431     ;;
 432   esac
 433 else
 434   finkbindir=""
 435 fi
 436 AC_SUBST([finkdir])
 437 AC_SUBST([finkbindir])
 438
 439 # Checks for libraries.
 440 # We save up a list of missing libraries that we can't do without
 441 # and report them all at once.
 442 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
 443             [missing_libraries="$missing_libraries libgc"])
 444 AC_CHECK_LIB(gcrypt, gcry_md_open,
 445              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
 446             [missing_libraries="$missing_libraries libgcrypt"])
 447 AC_CHECK_LIB(pcre, pcre_compile,
 448              [AC_SUBST(LIBPCRE,[-lpcre])],
 449              [missing_libraries="$missing_libraries libpcre"])
 450 if test $want_alsa = yes; then
 451   AC_CHECK_LIB([asound], [snd_pcm_open],
 452                [AC_SUBST(LIBASOUND,[-lasound])])
 453 fi
 454 if test $want_pulseaudio = yes; then
 455   PKG_CHECK_MODULES([PULSEAUDIO],[libpulse],
 456                     [AC_DEFINE([HAVE_PULSEAUDIO],[1],[define to 1 for PulseAudio support])],
 457                     [missing_libraries="$missing_libraries libpulse"])
 458   PKG_CHECK_MODULES([PULSEAUDIO_SIMPLE],[libpulse-simple],,
 459                     [missing_libraries="$missing_libraries libpulse-simple"])
 460 fi
 461 AC_CHECK_LIB([samplerate],[src_new],
 462              [AC_SUBST([LIBSAMPLERATE],[-lsamplerate])])
 463 if test $want_server = yes; then
 464   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
 465                [AC_SUBST(LIBDB,[-ldb])],
 466                [missing_libraries="$missing_libraries libdb"])
 467   AC_CHECK_LIB(vorbis, vorbis_info_clear,
 468                [:],
 469                [missing_libraries="$missing_libraries libvorbis"])
 470   AC_CHECK_LIB(vorbisfile, ov_open,
 471                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
 472                [missing_libraries="$missing_libraries libvorbisfile"],
 473                [-lvorbis])
 474   AC_CHECK_LIB(mad, mad_stream_init,
 475                [AC_SUBST(LIBMAD,[-lmad])],
 476                [missing_libraries="$missing_libraries libmad"])
 477   AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
 478                [AC_SUBST(LIBFLAC,[-lFLAC])],
 479                [missing_libraries="$missing_libraries libFLAC"])
 480 fi
 481 AC_CHECK_LIB([pthread], [pthread_create],
 482              [AC_SUBST(LIBPTHREAD,[-lpthread])],
 483              [missing_libraries="$missing_libraries libpthread"])
 484
 485 if test $want_gtk = yes; then
 486   if test $want_gtkosx = yes; then
 487     GTK_CFLAGS="-isystem /Library/Frameworks/Gtk.framework/Headers -isystem /Library/Frameworks/Cairo.framework/Headers"
 488     GLIB_CFLAGS="-isystem /Library/Frameworks/GLib.framework/Headers"
 489     GTK_LIBS="-framework Gtk -framework GLib"
 490   else
 491     AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
 492     AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
 493   fi
 494 fi
 495
 496 # Some platforms have iconv already
 497 AC_CHECK_FUNC(iconv_open, [:],
 498               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
 499                             [AC_SUBST(LIBICONV,[-liconv])],
 500                             [missing_functions="$missing_functions iconv_open"])])
 501 AC_CHECK_FUNC([gethostbyname],[:],[
 502   AC_CHECK_LIB(nsl,gethostbyname,
 503                [AC_SUBST(LIBNSL,[-lnsl])],
 504                [missing_functions="$missing_functions gethostbyname"])])
 505 AC_CHECK_FUNC([socket],[:],[
 506   AC_CHECK_LIB(socket,socket,
 507                [AC_SUBST(LIBSOCKET,[-lsocket])],
 508                [missing_functions="$missing_functions socket"])])
 509 AC_CHECK_FUNC([dlopen],[:],[
 510   AC_CHECK_LIB(dl,dlopen,
 511                [AC_SUBST(LIBDL,[-ldl])],
 512                [missing_functions="$missing_functions dlopen"])])
 513
 514 if test ! -z "$missing_libraries"; then
 515   AC_MSG_ERROR([missing libraries:$missing_libraries])
 516 fi
 517
 518 # Checks for header files.
 519 RJK_FIND_GC_H
 520 if test $want_oss = yes; then
 521   AC_CHECK_HEADERS([sys/soundcard.h])
 522 fi
 523 if test $want_alsa = yes; then
 524   AC_CHECK_HEADERS([alsa/asoundlib.h])
 525 fi
 526 if test $want_coreaudio = yes; then
 527   AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
 528 fi
 529 AC_CHECK_HEADERS([inttypes.h sys/time.h sys/socket.h netinet/in.h \
 530                   arpa/inet.h sys/un.h netdb.h pcre.h pwd.h langinfo.h])
 531 # We don't bother checking very standard stuff
 532 # Compilation will fail if any of these headers are missing, so we
 533 # check for them here and fail early.
 534 if test $want_server = yes; then
 535   AC_CHECK_HEADERS([db.h],[:],[
 536     missing_headers="$missing_headers $ac_header"
 537   ])
 538 fi
 539 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
 540                  getopt.h iconv.h langinfo.h \
 541                  pcre.h sys/ioctl.h \
 542                  syslog.h unistd.h],[:],[
 543   missing_headers="$missing_headers $ac_header"
 544 ])
 545 AC_CHECK_HEADERS([samplerate.h])
 546
 547 if test ! -z "$missing_headers"; then
 548   AC_MSG_ERROR([missing headers:$missing_headers])
 549 fi
 550
 551 # We require that libpcre support UTF-8
 552 RJK_REQUIRE_PCRE_UTF8([-lpcre])
 553
 554 # Checks for typedefs, structures, and compiler characteristics.
 555 AC_C_CONST
 556 AC_TYPE_SIZE_T
 557 AC_C_INLINE
 558 AC_C_BIGENDIAN
 559 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
 560 #include <netinet/in.h>])
 561
 562 # Figure out how we'll check for devices being mounted and unmounted
 563 AC_CACHE_CHECK([for list of mounted filesystems],[rjk_cv_mtab],[
 564   if test -e /etc/mtab; then
 565     rjk_cv_mtab=/etc/mtab
 566   else
 567     rjk_cv_mtab=none
 568   fi
 569 ])
 570 if test $rjk_cv_mtab != none; then
 571   AC_DEFINE_UNQUOTED([PATH_MTAB],["$rjk_cv_mtab"],[path to file containing mount list])
 572 fi
 573
 574 # enable -Werror when we check for certain characteristics:
 575
 576 old_CFLAGS="${CFLAGS}"
 577 CFLAGS="${CFLAGS} $gcc_werror"
 578 AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
 579
 580 # Some GCC invocations warn for converting function pointers to void *.
 581 # This is fair enough, as it's technically forbidden, but we use dlsym()
 582 # which can pretty much only exist if object and function pointers are
 583 # interconvertable.  So we disable -Werror if need be.
 584 if test ! -z "$gcc_werror"; then
 585   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
 586                  [rjk_cv_function_pointer_cast],[
 587     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 588   void somefunction(void);],
 589                       [(void *)somefunction])],
 590                       [rjk_cv_function_pointer_cast=yes],
 591                       [rjk_cv_function_pointer_cast=no])])
 592   if test $rjk_cv_function_pointer_cast = no; then
 593     gcc_werror=""
 594   fi
 595 fi
 596
 597 CFLAGS="${old_CFLAGS}"
 598
 599 # gcrypt maintainers keep changing everything.  Design your interface
 600 # first, then implement it once, rather than getting it wrong three or
 601 # four times and shipping between each attempt.
 602 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
 603                [rjk_cv_gcrypt_hash_handle],[
 604   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 605 #include <gcrypt.h>
 606 ],
 607                [gcry_md_hd_t h;])],
 608                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
 609     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 610 #include <gcrypt.h>
 611 ],
 612                  [GcryMDHd h;])],
 613                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
 614                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
 615 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
 616                    [libgcrypt hash handle type])
 617
 618 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
 619                [rjk_cv_have_gcry_error_t],[
 620   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 621 #include <gcrypt.h>
 622 ],
 623                  [gcry_error_t e;])],
 624                  [rjk_cv_have_gcry_error_t=yes],
 625                  [rjk_cv_have_gcry_error_t=no])])
 626 if test $rjk_cv_have_gcry_error_t = yes; then
 627   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
 628 fi
 629
 630 # Checks for functions
 631 if test $ac_cv_type_long_long = yes; then
 632   AC_CHECK_FUNCS([atoll strtoll],[:],[
 633     missing_functions="$missing_functions $ac_func"
 634   ])
 635   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
 636   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
 637                  [rjk_cv_strtoll_declared],[
 638     AC_EGREP_HEADER([strtoll], [stdlib.h],
 639                     [rjk_cv_strtoll_declared=yes],
 640                     [rjk_cv_strtoll_declared=no])])
 641   if test $rjk_cv_strtoll_declared = yes; then
 642     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
 643   fi
 644   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
 645                  [rjk_cv_atoll_declared],[
 646     AC_EGREP_HEADER([atoll], [stdlib.h],
 647                     [rjk_cv_atoll_declared=yes],
 648                     [rjk_cv_atoll_declared=no])])
 649   if test $rjk_cv_atoll_declared = yes; then
 650     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
 651   fi
 652 fi
 653 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal setenv unsetenv],[:],[
 654   missing_functions="$missing_functions $ac_func"
 655 ])
 656 # fsync will do if fdatasync not available
 657 AC_CHECK_FUNCS([fdatasync],[:],[
 658   AC_CHECK_FUNCS([fsync],
 659                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
 660                  [missing_functions="$missing_functions fdatasync"])])
 661 if test ! -z "$missing_functions"; then
 662   AC_MSG_ERROR([missing functions:$missing_functions])
 663 fi
 664
 665 # Functions we can take or leave
 666 AC_CHECK_FUNCS([fls getfsstat closesocket])
 667
 668 if test $want_server = yes; then
 669   # <db.h> had better be version 3 or later
 670   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
 671     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
 672                        #include <db.h>
 673                        #ifndef DB_VERSION_MAJOR
 674                        # error cannot determine db version
 675                        #endif
 676                        #if DB_VERSION_MAJOR < 4
 677                        # error inadequate db version
 678                        #endif
 679                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
 680                        # error inadequate db version
 681                        #endif
 682                       ],[])],
 683                       [rjk_cv_db_version=ok],
 684                       [rjk_cv_db_version=inadequate])
 685     if test $rjk_cv_db_version = ok; then
 686       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([
 687                          #include <db.h>
 688                          #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR == 6
 689                          # error http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=510270
 690                          #endif
 691                         ],[])],
 692                         [rjk_cv_db_version=ok],
 693                         [rjk_cv_db_version=toxic])
 694     fi
 695   ])
 696   case $rjk_cv_db_version in
 697   ok )
 698     ;;
 699   inadequate )
 700     AC_MSG_ERROR([need db version at least 4.3 (but not 4.6)])
 701     ;;
 702   toxic )
 703     AC_MSG_ERROR([db version 4.6.x does not work - see debian bug 510270])
 704     ;;
 705   esac
 706 fi
 707
 708 AM_CONDITIONAL([SERVER], [test x$want_server = xyes])
 709 if test $want_gtk = yes; then
 710   AC_DEFINE([WITH_GTK], [1], [define if using GTK+])
 711 fi
 712 AM_CONDITIONAL([GTK], [test x$want_gtk = xyes])
 713
 714 if test "x$GCC" = xyes; then
 715   # We need LLONG_MAX and annoyingly GCC doesn't always give it to us
 716   # by default.
 717   AC_CACHE_CHECK([what C version to ask for],[rjk_cv_cstd],[
 718     AC_TRY_COMPILE([#include <limits.h>],[
 719       long long n = LLONG_MAX;
 720     ],[rjk_cv_cstd=default],[
 721       old_CC="$CC"
 722       CC="${CC} -std=gnu99"
 723       AC_TRY_COMPILE([#include <limits.h>],[
 724         long long n = LLONG_MAX;
 725       ],[rjk_cv_cstd=gnu99],[rjk_cv_cstd=unknown])
 726       CC="$old_CC"
 727     ])
 728   ])
 729   case $rjk_cv_cstd in
 730   default | unknown )
 731     ;;
 732   * )
 733     CC="${CC} -std=${rjk_cv_cstd}"
 734     ;;
 735   esac
 736
 737   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
 738   AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
 739     old_CC="$CC"
 740     if test $GCC = yes; then
 741       CC="$CC -Wall -Werror"
 742     fi
 743     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 744       static int x(char *f) {
 745        return *f;
 746       }
 747       int z(const char *g) {
 748         return x((char *)g);
 749       }],[])],
 750       [rjk_cv_pr29478=no],
 751       [rjk_cv_pr29478=yes]
 752     )
 753     CC="$old_CC"
 754   ])
 755   if test $rjk_cv_pr29478 = yes; then
 756     gcc_werror=''
 757   fi
 758
 759   AC_CACHE_CHECK([checking for excessively strict -Wreturn-type],
 760                  [rjk_cv_gcc44_stupidity],[
 761     old_CC="$CC"
 762     if test $GCC = yes; then
 763       CC="$CC -Wreturn-type -Werror"
 764     fi
 765     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],[
 766       static void *threadfn(void) {
 767         for(;;)
 768           ;
 769       }],[])],
 770       [rjk_cv_gcc44_stupidity=no],
 771       [rjk_cv_gcc44_stupidity=yes])
 772     CC="$old_CC"
 773   ])
 774   if test $rjk_cv_gcc44_stupidity = yes; then
 775     AC_DEFINE([HAVE_STUPID_GCC44],[1],[Define if your compiler has excessively strict -Wreturn-type])
 776   fi
 777
 778   # a reasonable default set of warnings
 779   CC="${CC} -Wall -W -Wpointer-arith \
 780         -Wwrite-strings -Wmissing-prototypes \
 781         -Wmissing-declarations -Wnested-externs"
 782
 783   # Fix up GTK+ and GLib compiler flags
 784   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
 785   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
 786
 787   if test "$gcc_werror" != ''; then
 788     # GCC 2.95 doesn't know to ignore warnings from system headers
 789     AC_CACHE_CHECK([whether -Werror is usable],
 790                     rjk_cv_werror, [
 791       save_CFLAGS="${CFLAGS}"
 792       CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
 793       AC_TRY_COMPILE([#if WITH_GTK
 794  #include <gtk/gtk.h>
 795 #endif
 796
 797 struct s { int a, b; };
 798 const struct s sv = { .a = 1 };],
 799                      [],
 800                      [rjk_cv_werror=yes],
 801                      [rjk_cv_werror=no])
 802       CFLAGS="${save_CFLAGS}"
 803     ])
 804     if test $rjk_cv_werror = no; then
 805       gcc_werror=''
 806     fi
 807   fi
 808   CC="${CC} $gcc_werror"
 809
 810   # for older GCCs that don't know %ju (etc)
 811   AC_CACHE_CHECK([whether -Wno-format is required],
 812                  rjk_cv_noformat,
 813                  AC_TRY_COMPILE([#include <stdio.h>
 814 #include <stdint.h>
 815 ],
 816                                 [printf("%ju", (uintmax_t)0);],
 817                                 [rjk_cv_noformat=no],
 818                                 [rjk_cv_noformat=yes]))
 819   if test $rjk_cv_noformat = yes; then
 820     CC="${CC} -Wno-format"
 821   fi
 822
 823   AC_CACHE_CHECK([whether -Wshadow is OK],
 824                  rjk_cv_shadow,
 825                  oldCC="${CC}"
 826                  CC="${CC} -Wshadow"
 827                  [AC_TRY_COMPILE([
 828 #include <unistd.h>
 829 #include <vorbis/vorbisfile.h>
 830 ],
 831                                 [],
 832                                 [rjk_cv_shadow=yes],
 833                                 [rjk_cv_shadow=no])
 834                  CC="${oldCC}"])
 835   if test $rjk_cv_shadow = yes; then
 836     CC="${CC} -Wshadow"
 837   fi
 838 fi
 839
 840 RJK_GCOV
 841
 842 AH_BOTTOM([#ifdef __GNUC__
 843 # define attribute(x) __attribute__(x)
 844 #else
 845 # define attribute(x)
 846 #endif])
 847
 848 AC_CONFIG_FILES([Makefile
 849                  images/Makefile
 850                  scripts/Makefile
 851                  lib/Makefile
 852                  server/Makefile
 853                  cgi/Makefile
 854                  clients/Makefile
 855                  disobedience/Makefile
 856                  disobedience/manual/Makefile
 857                  doc/Makefile
 858                  templates/Makefile
 859                  plugins/Makefile
 860                  debian/Makefile
 861                  sounds/Makefile
 862                  python/Makefile
 863                  examples/Makefile
 864                  libtests/Makefile
 865                  tests/Makefile])
 866 AC_OUTPUT
 867
 868 if test $GCC = yes && test "$gcc_werror" = ''; then
 869   AC_MSG_WARN([building without -Werror])
 870 fi
 871 if test $want_python = no; then
 872   AC_MSG_WARN([cannot run the test suit without Python])
 873 fi
 874 if test $want_server = yes && test "$ac_cv_lib_samplerate_src_new" != yes; then
 875   AC_MSG_WARN([libsamplerate will be required in a future version])
 876 fi
 877
 878 # Local Variables:
 879 # indent-tabs-mode:nil
 880 # End: