chiark / gitweb /
Macroize submit buttons so we can mess with them more easily
[disorder] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 #
3 # This file is part of DisOrder.
4 # Copyright (C) 2004-2008 Richard Kettlewell
5 # Portions copyright (C) 2007 Ross Younger
6 #
7 # This program is free software; you can redistribute it and/or modify
8 # it under the terms of the GNU General Public License as published by
9 # the Free Software Foundation; either version 2 of the License, or
10 # (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
15 # General Public License for more details.
16 #
17 # You should have received a copy of the GNU General Public License
18 # along with this program; if not, write to the Free Software
19 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
20 # USA
21 #
22
23 AC_INIT([disorder], [3.0+], [richard+disorder@sfere.greenend.org.uk])
24 AC_CONFIG_AUX_DIR([config.aux])
25 AM_INIT_AUTOMAKE(disorder, [3.0+])
26 AC_CONFIG_SRCDIR([server/disorderd.c])
27 AM_CONFIG_HEADER([config.h])
28
29 # Find host type
30 AC_CANONICAL_HOST
31
32 # What we want to build
33 want_gtk=yes
34 want_python=yes
35 want_tests=yes
36
37 # APIs we want
38 want_alsa=yes
39 want_oss=yes
40 want_coreaudio=yes
41
42 # Checks for programs.
43 AC_PROG_CC
44 AC_SET_MAKE
45 if test "x$GCC" = xyes; then
46   gcc_werror=-Werror
47 else
48   AC_MSG_ERROR([GNU C is required to build this program])
49   gcc_werror=""
50 fi
51
52 AC_ARG_WITH([alsa],
53             [AS_HELP_STRING([--without-alsa],
54                             [do not build with ALSA support])],
55             [want_alsa=$withval])
56 AC_ARG_WITH([oss],
57             [AS_HELP_STRING([--without-oss],
58                             [do not build with OSS support])],
59             [want_oss=$withval])
60 AC_ARG_WITH([coreaudio],
61             [AS_HELP_STRING([--without-coreaudio],
62                             [do not build with Core Audio support])],
63             [want_coreaudio=$withval])
64 AC_ARG_WITH([tests],
65             [AS_HELP_STRING([--without-tests],
66                             [do not build test suit])],
67             [want_tests=$withval])
68
69 AC_MSG_CHECKING([for a known target platform])
70 case "$host" in
71 *empeg* )
72   AC_MSG_RESULT([empeg car stereo])
73   AC_DEFINE([EMPEG_HOST],[1],[define if host is an empeg car stereo])
74   # work around broken toolchain
75   AC_CHECK_LIB([gpg-error], [gpg_strerror])
76   AC_CHECK_LIB([pthread], [pthread_create])
77   want_server=no
78  ;;
79 *linux* | *Linux* )
80   AC_MSG_RESULT([Linux])
81   want_server=yes
82   ;;
83 *-apple-darwin* )
84   AC_MSG_RESULT([Mac OS X])
85   want_server=yes
86   if test $want_coreaudio = yes; then
87     COREAUDIO="-framework CoreAudio"
88   fi
89   browser=open
90   AC_MSG_CHECKING([Mac OS X target version])
91   # We honor MACOSX_DEPLOYMENT_TARGET in the environment, emulating gcc's
92   # behaviour.  But we provide a command line option to override it and
93   # we default to wide support instead of supporting only the build platform.
94   #
95   # Currently if you ask for 10.5 you will get a deprecation warning
96   # when building the CoreAudio support code.  For the time being the
97   # answer to this is "don't do that then".  If a good reason to ask
98   # for a 10.5 deployment target emerges then this will be fixed.
99   if test -z "$MACOSX_DEPLOYMENT_TARGET"; then
100     MACOSX_DEPLOYMENT_TARGET=10.0
101   fi
102   AC_ARG_WITH([deployment-target],
103               [AS_HELP_STRING([--with-deployment-target=TARGET],
104                               [set target OS X version])],
105               [MACOSX_DEPLOYMENT_TARGET=$withval])
106   # Convert to desired format
107   underscored=`echo $MACOSX_DEPLOYMENT_TARGET|sed 's/\./_/'`
108   minver="MAC_OS_X_VERSION_$underscored"
109   AC_MSG_RESULT([$minver])
110   AC_DEFINE_UNQUOTED([MAC_OS_X_VERSION_MIN_REQUIRED], [$minver],
111                      [define to minimum version of Mac OS X to support])
112   ;;
113 *-freebsd* )
114   AC_MSG_RESULT([FreeBSD])
115   want_server=yes
116   # Ports install to /usr/local but the compiler stupidly doesn't look
117   # there by default
118   LDFLAGS="${LDFLAGS} -L/usr/local/lib"
119   CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include"
120   # Look for a suitable version of libdb among the versions found in FreeBSD 7.0
121   AC_CACHE_CHECK([looking for a libdb install],[rjk_cv_libdb],[
122     rjk_cv_libdb="none"
123     for db in db43 db44 db45 db46; do
124       if test -e /usr/local/lib/$db; then
125         rjk_cv_libdb=$db
126         break
127       fi
128     done
129   ])
130   if test $rjk_cv_libdb != none; then
131     LDFLAGS="${LDFLAGS} -L/usr/local/lib/$rjk_cv_libdb"
132     CPPFLAGS="${CPPFLAGS} -isystem /usr/local/include/$rjk_cv_libdb"
133   fi
134   ;;
135 * )
136   AC_MSG_RESULT([unknown, winging it])
137   want_server=no
138   ;;
139 esac
140 AC_SUBST([COREAUDIO])
141
142 AC_ARG_WITH([browser],
143             [AS_HELP_STRING([--with-browser=BROWSER],
144                             [use BROWSER to display HTML])],
145             [browser=$withval])
146
147 AC_CACHE_CHECK([default HTML viewer],[rjk_cv_browser],[
148   rjk_cv_browser=UNKNOWN
149   for candidate in x-www-browser sensible-browser firefox mozilla konqueror netscape; do
150     if type $candidate >/dev/null 2>&1; then
151       rjk_cv_browser="$candidate"
152       break
153     fi
154   done
155 ])
156 if test -z "$browser"; then
157   browser="$rjk_cv_browser"
158 fi
159 AC_DEFINE_UNQUOTED([BROWSER],["$browser"],[HTML viewer])
160
161 AC_ARG_WITH([server],
162             [AS_HELP_STRING([--without-server],
163                             [do not build server])],
164             [want_server=$withval])
165 AC_ARG_WITH([gtk],
166             [AS_HELP_STRING([--without-gtk],
167                             [do not build GTK+ client])],
168             [want_gtk=$withval])
169 AC_ARG_WITH([python],
170             [AS_HELP_STRING([--without-python],
171                             [do not build Python support])],
172             [want_python=$withval])
173
174 subdirs="scripts lib"
175 if test $want_tests = yes; then
176   subdirs="${subdirs} libtests"
177 fi
178 subdirs="${subdirs} clients doc examples debian"
179
180 if test $want_server = yes; then
181   subdirs="${subdirs} server cgi plugins driver templates sounds images"
182 fi
183 if test $want_gtk = yes; then
184   subdirs="${subdirs} disobedience"
185   if test $want_server = no; then
186     subdirs="${subdirs} images"
187   fi
188 fi
189 if test $want_tests = yes && test $want_python = yes; then
190   AM_PATH_PYTHON([2.4])
191   subdirs="${subdirs} python tests"
192 fi
193 AC_SUBST([subdirs])
194
195 # libtool config
196 AC_LIBTOOL_DLOPEN
197 AC_DISABLE_STATIC
198
199 AC_PROG_LIBTOOL
200
201 AC_CACHE_CHECK([for GNU sed],[rjk_cv_gnused],[
202   rjk_cv_gnused="not found"
203   for candidate in sed gsed; do
204     if $candidate --version >/dev/null 2>&1; then
205       rjk_cv_gnused=$candidate 
206     fi
207   done
208 ])
209 GNUSED="${GNUSED:-$rjk_cv_gnused}"
210 if test "$GNUSED" = "not found"; then
211   AC_MSG_ERROR([GNU sed is required to build this program])
212 fi
213 AC_SUBST([GNUSED])
214
215 AC_CHECK_PROGS([GROG],[grog])
216 AM_CONDITIONAL([GROG],[test "x$GROG" != xnone])
217
218 missing_libraries=""
219 missing_headers=""
220 missing_functions=""
221
222 AC_DEFINE(_GNU_SOURCE, 1, [required for e.g. strsignal])
223
224 AC_PATH_PROG([SENDMAIL],[sendmail],[none],[$PATH:/usr/sbin:/usr/lib])
225
226 # Macs might have libraries under fink's root
227 AC_PATH_PROG([FINK],[fink],[none],[$PATH:/sw/bin])
228 if test "x$FINK" != xnone; then
229   AC_CACHE_CHECK([fink install directory],[rjk_cv_finkprefix],[
230     rjk_cv_finkprefix="`echo "$FINK" | sed 's,/bin/fink$,,'`"
231   ])
232   finkdir="${rjk_cv_finkprefix}"
233   finkbindir="${rjk_cv_finkprefix}/bin"
234   CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/gc -I${rjk_cv_finkprefix}/include"
235   if test $want_server = yes; then
236     CPPFLAGS="${CPPFLAGS} -I${rjk_cv_finkprefix}/include/db4"
237   fi
238   LDFLAGS="${LDFLAGS} -L${rjk_cv_finkprefix}/lib"
239 else
240   finkbindir=""
241 fi
242 AC_SUBST([finkdir])
243 AC_SUBST([finkbindir])
244
245 # Checks for libraries.
246 # We save up a list of missing libraries that we can't do without
247 # and report them all at once.
248 AC_CHECK_LIB(gc, GC_malloc,            [AC_SUBST(LIBGC,[-lgc])],
249             [missing_libraries="$missing_libraries libgc"])
250 AC_CHECK_LIB(gcrypt, gcry_md_open,
251              [AC_SUBST(LIBGCRYPT,[-lgcrypt])],
252             [missing_libraries="$missing_libraries libgcrypt"])
253 AC_CHECK_LIB(pcre, pcre_compile,
254              [AC_SUBST(LIBPCRE,[-lpcre])],
255              [missing_libraries="$missing_libraries libpcre"])
256 if test $want_alsa = yes; then
257   AC_CHECK_LIB([asound], [snd_pcm_open],
258                [AC_SUBST(LIBASOUND,[-lasound])])
259 fi
260 if test $want_server = yes; then
261   RJK_CHECK_LIB(db, db_create, [#include <db.h>],
262                [AC_SUBST(LIBDB,[-ldb])],
263                [missing_libraries="$missing_libraries libdb"])
264   AC_CHECK_LIB(vorbis, vorbis_info_clear,
265                [:],
266                [missing_libraries="$missing_libraries libvorbis"])
267   AC_CHECK_LIB(vorbisfile, ov_open,
268                [AC_SUBST(LIBVORBISFILE,["-lvorbisfile -lvorbis"])],
269                [missing_libraries="$missing_libraries libvorbisfile"],
270                [-lvorbis])
271   AC_CHECK_LIB(mad, mad_stream_init,
272                [AC_SUBST(LIBMAD,[-lmad])],
273                [missing_libraries="$missing_libraries libmad"])
274   AC_CHECK_LIB([ao], [ao_initialize],
275                [AC_SUBST(LIBAO,[-lao])],
276                [missing_libraries="$missing_libraries libao"])
277   AC_CHECK_LIB([FLAC], [FLAC__stream_decoder_new],
278                [AC_SUBST(LIBFLAC,[-lFLAC])],
279                [missing_libraries="$missing_libraries libFLAC"])
280 fi
281 AC_CHECK_LIB([pthread], [pthread_create],
282              [AC_SUBST(LIBPTHREAD,[-lpthread])],
283              [missing_libraries="$missing_libraries libpthread"])
284
285 if test $want_gtk = yes; then
286   AM_PATH_GLIB_2_0([],[],[missing_libraries="$missing_libraries libglib"])
287   AM_PATH_GTK_2_0([],[],[missing_libraries="$missing_libraries libgtk"])
288 fi
289
290 # Some platforms have iconv already
291 AC_CHECK_FUNC(iconv_open, [:],
292               [RJK_CHECK_LIB(iconv, iconv_open, [#include <iconv.h>],
293                             [AC_SUBST(LIBICONV,[-liconv])],
294                             [missing_functions="$missing_functions iconv_open"])])
295 AC_CHECK_FUNC([gethostbyname],[:],[
296   AC_CHECK_LIB(nsl,gethostbyname,
297                [AC_SUBST(LIBNSL,[-lnsl])],
298                [missing_functions="$missing_functions gethostbyname"])])
299 AC_CHECK_FUNC([socket],[:],[
300   AC_CHECK_LIB(socket,socket,
301                [AC_SUBST(LIBSOCKET,[-lsocket])],
302                [missing_functions="$missing_functions socket"])])
303 AC_CHECK_FUNC([dlopen],[:],[
304   AC_CHECK_LIB(dl,dlopen,
305                [AC_SUBST(LIBDL,[-ldl])],
306                [missing_functions="$missing_functions dlopen"])])
307
308 if test ! -z "$missing_libraries"; then
309   AC_MSG_ERROR([missing libraries:$missing_libraries])
310 fi
311
312 # Checks for header files.
313 RJK_FIND_GC_H
314 if test $want_oss = yes; then
315   AC_CHECK_HEADERS([sys/soundcard.h])
316 fi
317 if test $want_alsa = yes; then
318   AC_CHECK_HEADERS([alsa/asoundlib.h])
319 fi
320 if test $want_coreaudio = yes; then
321   AC_CHECK_HEADERS([CoreAudio/AudioHardware.h])
322 fi
323 AC_CHECK_HEADERS([inttypes.h])
324 # We don't bother checking very standard stuff
325 # Compilation will fail if any of these headers are missing, so we
326 # check for them here and fail early.
327 if test $want_server = yes; then
328   AC_CHECK_HEADERS([db.h],[:],[
329     missing_headers="$missing_headers $ac_header"
330   ])
331   AC_CHECK_HEADERS([FLAC/file_decoder.h])
332 fi
333 AC_CHECK_HEADERS([dlfcn.h gcrypt.h \
334                  getopt.h iconv.h langinfo.h \
335                  pcre.h sys/ioctl.h \
336                  syslog.h unistd.h],[:],[
337   missing_headers="$missing_headers $ac_header"
338 ])
339
340 if test ! -z "$missing_headers"; then
341   AC_MSG_ERROR([missing headers:$missing_headers])
342 fi
343
344 # We require that libpcre support UTF-8
345 RJK_REQUIRE_PCRE_UTF8([-lpcre])
346
347 # Checks for typedefs, structures, and compiler characteristics.
348 AC_C_CONST
349 AC_TYPE_SIZE_T
350 AC_C_INLINE
351 AC_C_BIGENDIAN
352 AC_CHECK_TYPES([struct sockaddr_in6],,,[AC_INCLUDES_DEFAULT
353 #include <netinet/in.h>])
354
355 # enable -Werror when we check for certain characteristics:
356
357 old_CFLAGS="${CFLAGS}"
358 CFLAGS="${CFLAGS} $gcc_werror"
359 AC_CHECK_TYPES([long long,uint32_t,uint8_t,intmax_t,uintmax_t])
360
361 # Some GCC invocations warn for converting function pointers to void *.
362 # This is fair enough, as it's technically forbidden, but we use dlsym()
363 # which can pretty much only exist if object and function pointers are
364 # interconvertable.  So we disable -Werror if need be.
365 if test ! -z "$gcc_werror"; then
366   AC_CACHE_CHECK([whether function pointers can be converted to void * without a warning],
367                  [rjk_cv_function_pointer_cast],[
368     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
369   void somefunction(void);],
370                       [(void *)somefunction])],
371                       [rjk_cv_function_pointer_cast=yes],
372                       [rjk_cv_function_pointer_cast=no])])
373   if test $rjk_cv_function_pointer_cast = no; then
374     gcc_werror=""
375   fi
376 fi
377
378 CFLAGS="${old_CFLAGS}"
379
380 # gcrypt maintainers keep changing everything.  Design your interface
381 # first, then implement it once, rather than getting it wrong three or
382 # four times and shipping between each attempt.
383 AC_CACHE_CHECK([for hash handle type in <grypt.h>],
384                [rjk_cv_gcrypt_hash_handle],[
385   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
386 #include <gcrypt.h>
387 ],
388                [gcry_md_hd_t h;])],
389                [rjk_cv_gcrypt_hash_handle=gcry_md_hd_t],[
390     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
391 #include <gcrypt.h>
392 ],
393                  [GcryMDHd h;])],
394                  [rjk_cv_gcrypt_hash_handle=GcryMDHd],
395                  [rjk_cv_gcrypt_hash_handle=GCRY_MD_HD])])])
396 AC_DEFINE_UNQUOTED([gcrypt_hash_handle],[$rjk_cv_gcrypt_hash_handle],
397                    [libgcrypt hash handle type])
398
399 AC_CACHE_CHECK([for gcry_error_t in <grypt.h>],
400                [rjk_cv_have_gcry_error_t],[
401   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
402 #include <gcrypt.h>
403 ],
404                  [gcry_error_t e;])],
405                  [rjk_cv_have_gcry_error_t=yes],
406                  [rjk_cv_have_gcry_error_t=no])])
407 if test $rjk_cv_have_gcry_error_t = yes; then
408   AC_DEFINE([HAVE_GCRY_ERROR_T],1,[define if <gcrypt.h> defines gcry_error_t])
409 fi
410
411 # Checks for functions
412 if test $ac_cv_type_long_long = yes; then
413   AC_CHECK_FUNCS([atoll strtoll],[:],[
414     missing_functions="$missing_functions $ac_func"
415   ])
416   # Darwin sometimes fails to declare strtoll (e.g. if you ask for -std=c99)
417   AC_CACHE_CHECK([whether strtoll is declared in <stdlib.h>],
418                  [rjk_cv_strtoll_declared],[
419     AC_EGREP_HEADER([strtoll], [stdlib.h],
420                     [rjk_cv_strtoll_declared=yes],
421                     [rjk_cv_strtoll_declared=no])])
422   if test $rjk_cv_strtoll_declared = yes; then
423     AC_DEFINE([DECLARES_STRTOLL],[1],[define if <stdlib.h> declares strtoll])
424   fi
425   AC_CACHE_CHECK([whether atoll is declared in <stdlib.h>],
426                  [rjk_cv_atoll_declared],[
427     AC_EGREP_HEADER([atoll], [stdlib.h],
428                     [rjk_cv_atoll_declared=yes],
429                     [rjk_cv_atoll_declared=no])])
430   if test $rjk_cv_atoll_declared = yes; then
431     AC_DEFINE([DECLARES_ATOLL],[1],[define if <stdlib.h> declares atoll])
432   fi
433 fi
434 AC_CHECK_FUNCS([ioctl nl_langinfo strsignal setenv unsetenv],[:],[
435   missing_functions="$missing_functions $ac_func"
436 ])
437 # fsync will do if fdatasync not available
438 AC_CHECK_FUNCS([fdatasync],[:],[
439   AC_CHECK_FUNCS([fsync],
440                  [AC_DEFINE([fdatasync],[fsync],[define fdatasync to fsync if not available])],
441                  [missing_functions="$missing_functions fdatasync"])])
442 if test ! -z "$missing_functions"; then
443   AC_MSG_ERROR([missing functions:$missing_functions])
444 fi
445
446 # Functions we can take or leave
447 AC_CHECK_FUNCS([fls])
448
449 if test $want_server = yes; then
450   # <db.h> had better be version 3 or later
451   AC_CACHE_CHECK([db.h version],[rjk_cv_db_version],[
452     AC_PREPROC_IFELSE([
453                        #include <db.h>
454                        #ifndef DB_VERSION_MAJOR
455                        # error cannot determine db version
456                        #endif
457                        #if DB_VERSION_MAJOR < 4
458                        # error inadequate db version
459                        #endif
460                        #if DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR <= 2
461                        # error inadequate db version
462                        #endif
463                       ],
464                       [rjk_cv_db_version=ok],
465                       [rjk_cv_db_version=inadequate])
466   ])
467   if test $rjk_cv_db_version != ok; then
468     AC_MSG_ERROR([need db.h version at least 4.2])
469   fi
470 fi
471
472 AM_CONDITIONAL([SERVER], [test x$want_server = xyes])
473 if test $want_gtk = yes; then
474   AC_DEFINE([WITH_GTK], [1], [define if using GTK+])
475 fi
476
477 if test "x$GCC" = xyes; then
478   # We need LLONG_MAX and annoyingly GCC doesn't always give it to us
479   # by default.
480   AC_CACHE_CHECK([what C version to ask for],[rjk_cv_cstd],[
481     AC_TRY_COMPILE([#include <limits.h>],[
482       long long n = LLONG_MAX;
483     ],[rjk_cv_cstd=default],[
484       old_CC="$CC"
485       CC="${CC} -std=gnu99"
486       AC_TRY_COMPILE([#include <limits.h>],[
487         long long n = LLONG_MAX;
488       ],[rjk_cv_cstd=gnu99],[rjk_cv_cstd=unknown])
489       CC="$old_CC"
490     ])
491   ])
492   case $rjk_cv_cstd in
493   default | unknown )
494     ;;
495   * )
496     CC="${CC} -std=${rjk_cv_cstd}"
497     ;;
498   esac
499
500   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=29478
501   AC_CACHE_CHECK([checking for GCC bug 29478],[rjk_cv_pr29478],[
502     old_CC="$CC"
503     if test $GCC = yes; then
504       CC="$CC -Wall -Werror"
505     fi
506     AC_COMPILE_IFELSE([
507       static int x(char *f) {
508        return *f;
509       }
510       int z(const char *g) {
511         return x((char *)g);
512       }],
513       [rjk_cv_pr29478=no],
514       [rjk_cv_pr29478=yes]
515     )
516     CC="$old_CC"
517   ])
518   if test $rjk_cv_pr29478 = yes; then
519     gcc_werror=''
520   fi
521
522   # a reasonable default set of warnings
523   CC="${CC} -Wall -W -Wpointer-arith -Wbad-function-cast \
524         -Wwrite-strings -Wmissing-prototypes \
525         -Wmissing-declarations -Wnested-externs"
526
527   # Fix up GTK+ and GLib compiler flags
528   GTK_CFLAGS="`echo \"$GTK_CFLAGS\"|sed 's/-I/-isystem /g'`"
529   GLIB_CFLAGS="`echo \"$GLIB_CFLAGS\"|sed 's/-I/-isystem /g'`"
530
531   if test "$gcc_werror" != ''; then
532     # GCC 2.95 doesn't know to ignore warnings from system headers
533     AC_CACHE_CHECK([whether -Werror is usable],
534                     rjk_cv_werror, [
535       save_CFLAGS="${CFLAGS}"
536       CFLAGS="${CFLAGS} ${GTK_CFLAGS} -Werror"
537       AC_TRY_COMPILE([#if WITH_GTK
538  #include <gtk/gtk.h>
539 #endif
540
541 struct s { int a, b; };
542 const struct s sv = { .a = 1 };],
543                      [],
544                      [rjk_cv_werror=yes],
545                      [rjk_cv_werror=no])
546       CFLAGS="${save_CFLAGS}"
547     ])
548     if test $rjk_cv_werror = no; then
549       gcc_werror=''
550     fi
551   fi
552   CC="${CC} $gcc_werror"
553
554   # for older GCCs that don't know %ju (etc)
555   AC_CACHE_CHECK([whether -Wno-format is required],
556                  rjk_cv_noformat,
557                  AC_TRY_COMPILE([#include <stdio.h>
558 #include <stdint.h>
559 ],
560                                 [printf("%ju", (uintmax_t)0);],
561                                 [rjk_cv_noformat=no],
562                                 [rjk_cv_noformat=yes]))
563   if test $rjk_cv_noformat = yes; then
564     CC="${CC} -Wno-format"
565   fi
566
567   AC_CACHE_CHECK([whether -Wshadow is OK],
568                  rjk_cv_shadow,
569                  oldCC="${CC}"
570                  CC="${CC} -Wshadow"
571                  [AC_TRY_COMPILE([
572 #include <unistd.h>
573 #include <vorbis/vorbisfile.h>
574 ],
575                                 [],
576                                 [rjk_cv_shadow=yes],
577                                 [rjk_cv_shadow=no])
578                  CC="${oldCC}"])
579   if test $rjk_cv_shadow = yes; then
580     CC="${CC} -Wshadow"
581   fi
582 fi
583
584 RJK_GCOV
585
586 AH_BOTTOM([#ifdef __GNUC__
587 # define attribute(x) __attribute__(x)
588 #else
589 # define attribute(x)
590 #endif])
591
592 AC_CONFIG_FILES([Makefile
593                  images/Makefile
594                  scripts/Makefile
595                  lib/Makefile
596                  server/Makefile
597                  cgi/Makefile
598                  clients/Makefile
599                  disobedience/Makefile
600                  doc/Makefile
601                  templates/Makefile
602                  plugins/Makefile
603                  driver/Makefile
604                  debian/Makefile
605                  sounds/Makefile
606                  python/Makefile
607                  examples/Makefile
608                  libtests/Makefile
609                  tests/Makefile])
610 AC_OUTPUT
611
612 if test $GCC = yes && test "$gcc_werror" = ''; then
613   AC_MSG_WARN([building without -Werror])
614 fi
615 if test $want_python = no; then
616   AC_MSG_WARN([cannot run the test suit without Python])
617 fi